granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.470 2006/07/27 13:20:24 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # DTrace
 210 #
 211 PGAC_ARG_BOOL(enable, dtrace, no,
 212               [  --enable-dtrace         build with DTrace support],
 213 [AC_DEFINE([ENABLE_DTRACE], 1,
 214            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 215 AC_CHECK_PROGS(DTRACE, dtrace)
 216 AC_SUBST(DTRACEFLAGS)])
 217 AC_SUBST(enable_dtrace)
 218
 219 #
 220 # C compiler
 221 #
 222
 223 # For historical reasons you can also use --with-CC to specify the C compiler
 224 # to use, although the standard way to do this is to set the CC environment
 225 # variable.
 226 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 227
 228 case $template in
 229   aix) pgac_cc_list="gcc xlc";;
 230  irix) pgac_cc_list="cc";; # no gcc
 231     *) pgac_cc_list="gcc cc";;
 232 esac
 233
 234 AC_PROG_CC([$pgac_cc_list])
 235
 236 unset CFLAGS
 237
 238 #
 239 # Read the template
 240 #
 241 . "$srcdir/src/template/$template" || exit
 242
 243 # CFLAGS are selected so:
 244 # If the user specifies something in the environment, that is used.
 245 # else:  If the template file set something, that is used.
 246 # else:  If the compiler is GCC, then we use -O2.
 247 # else:  If the compiler is something else, then we use -0.
 248
 249 if test "$ac_env_CFLAGS_set" = set; then
 250   CFLAGS=$ac_env_CFLAGS_value
 251 elif test "${CFLAGS+set}" = set; then
 252   : # (keep what template set)
 253 elif test "$GCC" = yes; then
 254   CFLAGS="-O2"
 255 else
 256   # if the user selected debug mode, don't use -O
 257   if test "$enable_debug" != yes; then
 258     CFLAGS="-O"
 259   fi
 260 fi
 261
 262 # Some versions of GCC support some additional useful warning flags.
 263 # Check whether they are supported, and add them to CFLAGS if so.
 264
 265 if test "$GCC" = yes; then
 266
 267 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 268 # So we have to check if "GCC" is really ICC.
 269 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 270 choke me
 271 @%:@endif], [ICC=[yes]], [ICC=[no]])
 272
 273   if test "$ICC" = no; then
 274     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 275
 276     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 277     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 278   else
 279     # Intel compiler has a bug/misoptimization in checking for
 280     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 281     # CFLAGS.
 282     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 283   fi
 284
 285   # Disable strict-aliasing rules; needed for gcc 3.3+
 286   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 287 elif test ${CC} = "xlc"; then
 288   # AIX xlc has to have strict aliasing turned off too
 289   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 290 fi
 291
 292 # supply -g if --enable-debug
 293 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 294   CFLAGS="$CFLAGS -g"
 295 fi
 296
 297 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 298
 299 # We already have this in Makefile.win32, but configure needs it too
 300 if test "$PORTNAME" = "win32"; then
 301   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 302 fi
 303
 304 # Check if the compiler still works with the template settings
 305 AC_MSG_CHECKING([whether the C compiler still works])
 306 AC_TRY_LINK([], [return 0;],
 307   [AC_MSG_RESULT(yes)],
 308   [AC_MSG_RESULT(no)
 309    AC_MSG_ERROR([cannot proceed])])
 310
 311 # Defend against gcc -ffast-math
 312 if test "$GCC" = yes; then
 313 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 314 choke me
 315 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 316 fi
 317
 318 AC_PROG_CPP
 319 AC_SUBST(GCC)
 320
 321 # Create compiler version string
 322 if test x"$GCC" = x"yes" ; then
 323   cc_string="GCC `${CC} --version | sed q`"
 324 else
 325   cc_string=$CC
 326 fi
 327 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 328                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 329                    [A string containing the version number, platform, and C compiler])
 330
 331
 332 #
 333 # Set up TAS assembly code if needed; the template file has now had its
 334 # chance to request this.
 335 #
 336 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 337
 338 if test "$need_tas" = yes ; then
 339   TAS=tas.o
 340 else
 341   TAS=""
 342 fi
 343 AC_SUBST(TAS)
 344
 345
 346 #
 347 # Automatic dependency tracking
 348 #
 349 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 350               [autodepend=yes])
 351 AC_SUBST(autodepend)
 352
 353
 354 #
 355 # Enable assert checks
 356 #
 357 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 358               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 359                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 360
 361
 362 #
 363 # Include directories
 364 #
 365 ac_save_IFS=$IFS
 366 IFS="${IFS}${PATH_SEPARATOR}"
 367 # SRCH_INC comes from the template file
 368 for dir in $with_includes $SRCH_INC; do
 369   if test -d "$dir"; then
 370     INCLUDES="$INCLUDES -I$dir"
 371   else
 372     AC_MSG_WARN([*** Include directory $dir does not exist.])
 373   fi
 374 done
 375 IFS=$ac_save_IFS
 376 AC_SUBST(INCLUDES)
 377
 378
 379 #
 380 # Library directories
 381 #
 382 ac_save_IFS=$IFS
 383 IFS="${IFS}${PATH_SEPARATOR}"
 384 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 385 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 386   if test -d "$dir"; then
 387     LIBDIRS="$LIBDIRS -L$dir"
 388   else
 389     AC_MSG_WARN([*** Library directory $dir does not exist.])
 390   fi
 391 done
 392 IFS=$ac_save_IFS
 393
 394 #
 395 # Enable thread-safe client libraries
 396 #
 397 AC_MSG_CHECKING([allow thread-safe client libraries])
 398 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 399 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 400 if test "$enable_thread_safety" = yes -o \
 401         "$enable_thread_safety_force" = yes; then
 402   enable_thread_safety="yes"    # for 'force'
 403   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 404           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 405 fi
 406 AC_MSG_RESULT([$enable_thread_safety])
 407 AC_SUBST(enable_thread_safety)
 408
 409 #
 410 # Optionally build Tcl modules (PL/Tcl)
 411 #
 412 AC_MSG_CHECKING([whether to build with Tcl])
 413 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 414 AC_MSG_RESULT([$with_tcl])
 415 AC_SUBST([with_tcl])
 416
 417 # We see if the path to the Tcl/Tk configuration scripts is specified.
 418 # This will override the use of tclsh to find the paths to search.
 419
 420 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 421
 422 #
 423 # Optionally build Perl modules (PL/Perl)
 424 #
 425 AC_MSG_CHECKING([whether to build Perl modules])
 426 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 427 AC_MSG_RESULT([$with_perl])
 428 AC_SUBST(with_perl)
 429
 430 #
 431 # Optionally build Python modules (PL/Python)
 432 #
 433 AC_MSG_CHECKING([whether to build Python modules])
 434 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 435 AC_MSG_RESULT([$with_python])
 436 AC_SUBST(with_python)
 437
 438 #
 439 # Kerberos 5
 440 #
 441 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 442 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 443 [
 444   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 445   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 446 ])
 447 AC_MSG_RESULT([$with_krb5])
 448 AC_SUBST(with_krb5)
 449
 450
 451 AC_SUBST(krb_srvtab)
 452
 453
 454 #
 455 # Kerberos configuration parameters
 456 #
 457 PGAC_ARG_REQ(with, krb-srvnam,
 458              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 459              [],
 460              [with_krb_srvnam="postgres"])
 461 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 462                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 463
 464
 465 #
 466 # PAM
 467 #
 468 AC_MSG_CHECKING([whether to build with PAM support])
 469 PGAC_ARG_BOOL(with, pam, no,
 470               [  --with-pam              build with PAM support],
 471               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 472 AC_MSG_RESULT([$with_pam])
 473 AC_SUBST(with_pam)
 474
 475
 476 #
 477 # LDAP
 478 #
 479 AC_MSG_CHECKING([whether to build with LDAP support])
 480 PGAC_ARG_BOOL(with, ldap, no,
 481               [  --with-ldap             build with LDAP support],
 482               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 483 AC_MSG_RESULT([$with_ldap])
 484 AC_SUBST(with_ldap)
 485
 486
 487 #
 488 # Bonjour
 489 #
 490 AC_MSG_CHECKING([whether to build with Bonjour support])
 491 PGAC_ARG_BOOL(with, bonjour, no,
 492               [  --with-bonjour          build with Bonjour support],
 493               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 494 AC_MSG_RESULT([$with_bonjour])
 495 AC_SUBST(with_bonjour)
 496
 497
 498 #
 499 # OpenSSL
 500 #
 501 AC_MSG_CHECKING([whether to build with OpenSSL support])
 502 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 503               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 504 AC_MSG_RESULT([$with_openssl])
 505 AC_SUBST(with_openssl)
 506
 507
 508 #
 509 # Prefer libedit
 510 #
 511 PGAC_ARG_BOOL(with, libedit-preferred, no,
 512               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 513
 514
 515 #
 516 # Readline
 517 #
 518 PGAC_ARG_BOOL(with, readline, yes,
 519               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 520 # readline on MinGW has problems with backslashes in psql and other bugs.
 521 # This is particularly a problem with non-US code pages.
 522 # Therefore disable its use until we understand the cause. 2004-07-20
 523 if test "$PORTNAME" = "win32"; then
 524   if test "$with_readline" = yes; then
 525     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 526     with_readline=no
 527   fi
 528 fi
 529
 530
 531 #
 532 # Zlib
 533 #
 534 PGAC_ARG_BOOL(with, zlib, yes,
 535               [  --without-zlib          do not use Zlib])
 536 AC_SUBST(with_zlib)
 537
 538 #
 539 # Elf
 540 #
 541
 542 # Assume system is ELF if it predefines __ELF__ as 1,
 543 # otherwise believe host_os based default.
 544 case $host_os in
 545     freebsd1*|freebsd2*) elf=no;;
 546     freebsd3*|freebsd4*) elf=yes;;
 547 esac
 548
 549 AC_EGREP_CPP(yes,
 550 [#if __ELF__
 551   yes
 552 #endif
 553 ],
 554 [ELF_SYS=true],
 555 [if test "X$elf" = "Xyes" ; then
 556   ELF_SYS=true
 557 else
 558   ELF_SYS=
 559 fi])
 560 AC_SUBST(ELF_SYS)
 561
 562 #
 563 # Assignments
 564 #
 565
 566 CPPFLAGS="$CPPFLAGS $INCLUDES"
 567 LDFLAGS="$LDFLAGS $LIBDIRS"
 568
 569 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 570 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 571
 572 AC_ARG_VAR(LDFLAGS_SL)
 573
 574 AC_PROG_AWK
 575 PGAC_PATH_FLEX
 576 AC_PROG_LN_S
 577 PGAC_PROG_LD
 578 AC_SUBST(LD)
 579 AC_SUBST(with_gnu_ld)
 580 case $host_os in sysv5*)
 581   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 582   [
 583     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 584     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 585     LDFLAGS=$pgac_save_LDFLAGS
 586   ])
 587   ld_R_works=$pgac_cv_prog_ld_R
 588   AC_SUBST(ld_R_works)
 589 esac
 590 AC_PROG_RANLIB
 591 AC_PATH_PROG(TAR, tar)
 592 PGAC_CHECK_STRIP
 593
 594 AC_CHECK_PROGS(YACC, ['bison -y'])
 595
 596 if test "$YACC"; then
 597   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 598     AC_MSG_WARN([
 599 *** If you are going to modify the grammar files or build from CVS, the installed
 600 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 601   fi
 602 fi
 603
 604 if test -z "$YACC"; then
 605   AC_MSG_WARN([
 606 *** Without Bison you will not be able to build PostgreSQL from CVS or
 607 *** change any of the parser definition files.  You can obtain Bison from
 608 *** a GNU mirror site.  (If you are using the official distribution of
 609 *** PostgreSQL then you do not need to worry about this because the Bison
 610 *** output is pre-generated.)  To use a different yacc program (possible,
 611 *** but not recommended), set the environment variable YACC before running
 612 *** 'configure'.])
 613 fi
 614 AC_SUBST(YFLAGS)
 615
 616 PGAC_PATH_PERL
 617 if test "$with_perl" = yes; then
 618   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 619   PGAC_CHECK_PERL_EMBED_LDFLAGS
 620 fi
 621
 622 if test "$with_python" = yes; then
 623   PGAC_PATH_PYTHON
 624   PGAC_CHECK_PYTHON_EMBED_SETUP
 625 fi
 626
 627 # Supply a numeric version string for use by 3rd party add-ons
 628 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 629 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 630 tr '.' '        ' |
 631 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 632 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 633
 634 ##
 635 ## Libraries
 636 ##
 637
 638 AC_SEARCH_LIBS(setproctitle, util)
 639 AC_SEARCH_LIBS(pow, m)
 640 AC_SEARCH_LIBS(dlopen, dl)
 641 AC_SEARCH_LIBS(socket, [socket wsock32])
 642 AC_SEARCH_LIBS(shl_load, dld)
 643 # We only use libld in port/dynloader/aix.c
 644 case $host_os in
 645      aix*)
 646         AC_SEARCH_LIBS(ldopen, ld)
 647         ;;
 648 esac
 649 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 650 AC_SEARCH_LIBS(crypt, crypt)
 651 # Solaris:
 652 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 653 # Cygwin:
 654 AC_SEARCH_LIBS(shmget, cygipc)
 655
 656 if test "$with_readline" = yes; then
 657   PGAC_CHECK_READLINE
 658   if test x"$pgac_cv_check_readline" = x"no"; then
 659     AC_MSG_ERROR([readline library not found
 660 If you have readline already installed, see config.log for details on the
 661 failure.  It is possible the compiler isn't looking in the proper directory.
 662 Use --without-readline to disable readline support.])
 663   fi
 664 fi
 665
 666 if test "$with_zlib" = yes; then
 667   AC_CHECK_LIB(z, inflate, [],
 668                [AC_MSG_ERROR([zlib library not found
 669 If you have zlib already installed, see config.log for details on the
 670 failure.  It is possible the compiler isn't looking in the proper directory.
 671 Use --without-zlib to disable zlib support.])])
 672 fi
 673
 674 if test "$enable_spinlocks" = yes; then
 675   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 676 else
 677   AC_MSG_WARN([
 678 *** Not using spinlocks will cause poor performance.])
 679 fi
 680
 681 if test "$with_krb5" = yes ; then
 682   if test "$PORTNAME" != "win32"; then
 683      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 684                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 685      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 686                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 687   else
 688      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 689                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 690   fi
 691 fi
 692
 693 if test "$with_openssl" = yes ; then
 694   dnl Order matters!
 695   if test "$PORTNAME" != "win32"; then
 696      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 697      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 698   else
 699      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 700      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 701   fi
 702 fi
 703
 704 if test "$with_pam" = yes ; then
 705   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 706 fi
 707
 708
 709 if test "$with_ldap" = yes ; then
 710   if test "$PORTNAME" != "win32"; then
 711      AC_CHECK_LIB(ldap,    ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
 712   else
 713      AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
 714   fi
 715 fi
 716
 717 ##
 718 ## Header files
 719 ##
 720
 721 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 722 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 723
 724 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 725 # netinet/in.h is included first.
 726 AC_CHECK_HEADERS(netinet/in.h)
 727 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 728 [AC_INCLUDES_DEFAULT
 729 #ifdef HAVE_NETINET_IN_H
 730 #include <netinet/in.h>
 731 #endif
 732 ])
 733
 734 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 735   AC_CHECK_HEADERS(readline/readline.h, [],
 736         [AC_CHECK_HEADERS(readline.h, [],
 737                 [AC_MSG_ERROR([readline header not found
 738 If you have readline already installed, see config.log for details on the
 739 failure.  It is possible the compiler isn't looking in the proper directory.
 740 Use --without-readline to disable readline support.])])])
 741   AC_CHECK_HEADERS(readline/history.h, [],
 742         [AC_CHECK_HEADERS(history.h, [],
 743                 [AC_MSG_ERROR([history header not found
 744 If you have readline already installed, see config.log for details on the
 745 failure.  It is possible the compiler isn't looking in the proper directory.
 746 Use --without-readline to disable readline support.])])])
 747 fi
 748
 749 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 750 # Some installations of libedit usurp /usr/include/readline/, which seems
 751 # bad practice, since in combined installations readline will have its headers
 752 # there.  We might have to resort to AC_EGREP checks to make sure we found
 753 # the proper header...
 754   AC_CHECK_HEADERS(editline/readline.h, [],
 755         [AC_CHECK_HEADERS(readline.h, [],
 756                 [AC_CHECK_HEADERS(readline/readline.h, [],
 757                         [AC_MSG_ERROR([readline header not found
 758 If you have libedit already installed, see config.log for details on the
 759 failure.  It is possible the compiler isn't looking in the proper directory.
 760 Use --without-readline to disable libedit support.])])])])
 761   AC_CHECK_HEADERS(editline/history.h, [],
 762         [AC_CHECK_HEADERS(history.h, [],
 763                 [AC_CHECK_HEADERS(readline/history.h, [],
 764                         [AC_MSG_ERROR([history header not found
 765 If you have libedit already installed, see config.log for details on the
 766 failure.  It is possible the compiler isn't looking in the proper directory.
 767 Use --without-readline to disable libedit support.])])])])
 768 fi
 769
 770 if test "$with_zlib" = yes; then
 771   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 772 If you have zlib already installed, see config.log for details on the
 773 failure.  It is possible the compiler isn't looking in the proper directory.
 774 Use --without-zlib to disable zlib support.])])
 775 fi
 776
 777 if test "$with_krb5" = yes ; then
 778   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 779 fi
 780
 781 if test "$with_openssl" = yes ; then
 782   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 783   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 784 fi
 785
 786 if test "$with_pam" = yes ; then
 787   AC_CHECK_HEADERS(security/pam_appl.h, [],
 788                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 789                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 790 fi
 791
 792 if test "$with_ldap" = yes ; then
 793   if test "$PORTNAME" != "win32"; then
 794      AC_CHECK_HEADERS(ldap.h, [],
 795                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 796   else
 797      AC_CHECK_HEADERS(winldap.h, [],
 798                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 799                       [AC_INCLUDES_DEFAULT
 800 #include <windows.h>
 801                       ])
 802   fi
 803 fi
 804
 805 if test "$with_bonjour" = yes ; then
 806   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 807 fi
 808
 809
 810 ##
 811 ## Types, structures, compiler characteristics
 812 ##
 813
 814 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 815 AC_C_CONST
 816 AC_C_INLINE
 817 AC_C_STRINGIZE
 818 PGAC_C_SIGNED
 819 AC_C_VOLATILE
 820 PGAC_C_FUNCNAME_SUPPORT
 821 PGAC_STRUCT_TIMEZONE
 822 PGAC_UNION_SEMUN
 823 PGAC_STRUCT_SOCKADDR_UN
 824 PGAC_STRUCT_SOCKADDR_STORAGE
 825 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 826 PGAC_STRUCT_ADDRINFO
 827
 828 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 829 [#include <sys/param.h>
 830 #include <sys/types.h>
 831 #include <sys/socket.h>
 832 #include <sys/ucred.h>])
 833
 834 AC_CHECK_TYPES([struct option], [], [],
 835 [#ifdef HAVE_GETOPT_H
 836 #include <getopt.h>
 837 #endif])
 838
 839 if test "$with_zlib" = yes; then
 840   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 841   # did not).  While we could work around the lack of z_streamp, it
 842   # seems unwise to encourage people to use such old zlib versions...
 843   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 844 Use --without-zlib to disable zlib support.])],
 845                 [#include <zlib.h>])
 846 fi
 847
 848 if test "$with_krb5" = yes; then
 849 # Check for differences between MIT and Heimdal (KTH) releases
 850   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 851                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 852                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 853                                      [#include <krb5.h>])],
 854                    [#include <krb5.h>])
 855   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 856                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 857                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 858                                      [#include <krb5.h>])],
 859                    [#include <krb5.h>])
 860 fi
 861
 862 # This is probably only present on Darwin, but may as well check always
 863 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 864
 865 ##
 866 ## Functions, global variables
 867 ##
 868
 869 PGAC_VAR_INT_TIMEZONE
 870 AC_FUNC_ACCEPT_ARGTYPES
 871 PGAC_FUNC_GETTIMEOFDAY_1ARG
 872
 873 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 874
 875 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 876 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 877
 878 HAVE_IPV6=no
 879 AC_CHECK_TYPE([struct sockaddr_in6],
 880         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 881          HAVE_IPV6=yes],
 882         [],
 883 [$ac_includes_default
 884 #include <netinet/in.h>])
 885 AC_SUBST(HAVE_IPV6)
 886
 887 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 888 [AC_TRY_LINK(
 889 [#include <machine/vmparam.h>
 890 #include <sys/exec.h>
 891 ],
 892 [PS_STRINGS->ps_nargvstr = 1;
 893 PS_STRINGS->ps_argvstr = "foo";],
 894 [pgac_cv_var_PS_STRINGS=yes],
 895 [pgac_cv_var_PS_STRINGS=no])])
 896 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 897   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 898 fi
 899
 900
 901 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 902 # is missing.  Yes, there are machines that have only one.  We may
 903 # also decide to use snprintf.c if snprintf() is present but does not
 904 # have all the features we need --- see below.
 905
 906 if test "$PORTNAME" = "win32"; then
 907   # Win32 gets snprintf.c built unconditionally.
 908   #
 909   # To properly translate all NLS languages strings, we must support the
 910   # *printf() %$ format, which allows *printf() arguments to be selected
 911   # by position in the translated string.
 912   #
 913   # libintl versions < 0.13 use the native *printf() functions, and Win32
 914   # *printf() doesn't understand %$, so we must use our /port versions,
 915   # which do understand %$. libintl versions >= 0.13 include their own
 916   # *printf versions on Win32.  The libintl 0.13 release note text is:
 917   #
 918   #   C format strings with positions, as they arise when a translator
 919   #   needs to reorder a sentence, are now supported on all platforms.
 920   #   On those few platforms (NetBSD and Woe32) for which the native
 921   #   printf()/fprintf()/... functions don't support such format
 922   #   strings, replacements are provided through <libintl.h>.
 923   #
 924   # We could use libintl >= 0.13's *printf() if we were sure that we had
 925   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 926   # to guarantee that, it is best to just use our own, so we are sure to
 927   # get %$ support. In include/port.h we disable the *printf() macros
 928   # that might have been defined by libintl.
 929   #
 930   # We do this unconditionally whether NLS is used or not so we are sure
 931   # that all Win32 libraries and binaries behave the same.
 932   pgac_need_repl_snprintf=yes
 933 else
 934   pgac_need_repl_snprintf=no
 935   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 936   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 937 fi
 938
 939
 940 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 941 # include/c.h will provide declarations.  Note this is a separate test
 942 # from whether the functions exist in the C library --- there are
 943 # systems that have the functions but don't bother to declare them :-(
 944
 945 AC_CHECK_DECLS([snprintf, vsnprintf])
 946
 947
 948 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 949 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 950 [AC_TRY_LINK([
 951 #include <math.h>
 952 double glob_double;
 953 ],
 954 [return isinf(glob_double) ? 0 : 1;],
 955 [ac_cv_func_isinf=yes],
 956 [ac_cv_func_isinf=no])])
 957
 958 if test $ac_cv_func_isinf = yes ; then
 959   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 960 else
 961   AC_LIBOBJ(isinf)
 962   # Look for a way to implement a substitute for isinf()
 963   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 964 fi
 965
 966 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 967
 968 # System's version of getaddrinfo(), if any, may be used only if we found
 969 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 970 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 971 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 972 # because we want to use our own getaddrinfo.c on Windows anyway.)
 973 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 974   AC_REPLACE_FUNCS([getaddrinfo])
 975 else
 976   AC_LIBOBJ(getaddrinfo)
 977 fi
 978
 979 # similarly, use system's getopt_long() only if system provides struct option.
 980 if test x"$ac_cv_type_struct_option" = xyes ; then
 981   AC_REPLACE_FUNCS([getopt_long])
 982 else
 983   AC_LIBOBJ(getopt_long)
 984 fi
 985
 986 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 987 # We override the previous test that said fseeko/ftello didn't exist
 988 # OS tests are also done in include/c.h and port/fseeko.c
 989 case $host_os in bsdi*|netbsd*)
 990 ac_cv_func_fseeko=yes
 991 esac
 992
 993 # Solaris has a very slow qsort in certain cases, so we replace it:
 994 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 995 # Supposedly it is fixed in Solaris, but not sure which version, and
 996 # no confirmed testing.  2005-12-16
 997 if test "$PORTNAME" = "solaris"; then
 998 AC_LIBOBJ(qsort)
 999 fi
1000
1001 # Win32 support
1002 if test "$PORTNAME" = "win32"; then
1003 AC_LIBOBJ(gettimeofday)
1004 AC_LIBOBJ(kill)
1005 AC_LIBOBJ(open)
1006 AC_LIBOBJ(rand)
1007 AC_LIBOBJ(win32error)
1008 AC_DEFINE([HAVE_SYMLINK], 1,
1009           [Define to 1 if you have the `symlink' function.])
1010 fi
1011
1012 if test "$with_readline" = yes; then
1013   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1014   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1015   AC_CHECK_FUNCS([replace_history_entry])
1016 fi
1017
1018
1019 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1020 AC_MSG_CHECKING(for finite)
1021 AC_TRY_LINK([
1022 #include <math.h>
1023 double glob_double;
1024 ],
1025             [return finite(glob_double) ? 0 : 1;],
1026             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1027 AC_MSG_RESULT(yes)],
1028             [AC_MSG_RESULT(no)])
1029
1030 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1031 dnl (especially on GNU libc)
1032 dnl See also comments in c.h.
1033 AC_MSG_CHECKING(for sigsetjmp)
1034 AC_TRY_LINK([#include <setjmp.h>],
1035             [sigjmp_buf x; sigsetjmp(x, 1);],
1036             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1037 AC_MSG_RESULT(yes)],
1038             [AC_MSG_RESULT(no)])
1039
1040 AC_CHECK_FUNC(syslog,
1041               [AC_CHECK_HEADER(syslog.h,
1042                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1043
1044 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1045 [AC_TRY_LINK([#include <unistd.h>],
1046   [extern int optreset; optreset = 1;],
1047   [pgac_cv_var_int_optreset=yes],
1048   [pgac_cv_var_int_optreset=no])])
1049 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1050   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1051 fi
1052
1053 AC_CHECK_FUNCS([strtoll strtoq], [break])
1054 AC_CHECK_FUNCS([strtoull strtouq], [break])
1055
1056 # Check for one of atexit() or on_exit()
1057 AC_CHECK_FUNCS(atexit, [],
1058                [AC_CHECK_FUNCS(on_exit, [],
1059                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1060
1061 AC_FUNC_FSEEKO
1062
1063 #
1064 # Pthreads
1065 #
1066 # For each platform, we need to know about any special compile and link
1067 # libraries, and whether the normal C function names are thread-safe.
1068 # See the comment at the top of src/port/thread.c for more information.
1069 #
1070 if test "$enable_thread_safety" = yes; then
1071 ACX_PTHREAD     # set thread flags
1072
1073 # Some platforms use these, so just defineed them.  They can't hurt if they
1074 # are not supported.
1075 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1076
1077
1078 # At this point, we don't want to muck with the compiler name for threading.
1079 # Let's see who fails, perhaps AIX.  2004-04-23
1080 if test "$PTHREAD_CC" != "$CC"; then
1081 AC_MSG_ERROR([
1082 PostgreSQL does not support platforms that require a special
1083 compiler binary for thread-safety.
1084 ])
1085 fi
1086
1087 if test "$THREAD_SUPPORT" = no; then
1088 AC_MSG_ERROR([
1089 Cannot enable threads on your platform.
1090 Your platform is known to not support thread-safe programs.
1091 For details, compile and run src/bin/pg_thread_test.
1092 ])
1093 fi
1094
1095 # Check for *_r functions
1096 _CFLAGS="$CFLAGS"
1097 _LIBS="$LIBS"
1098 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1099 LIBS="$LIBS $PTHREAD_LIBS"
1100
1101 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1102
1103 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1104
1105 # Do test here with the proper thread flags
1106 PGAC_FUNC_GETPWUID_R_5ARG
1107 PGAC_FUNC_STRERROR_R_INT
1108
1109 # this will link libpq against libldap_r
1110 if test "$with_ldap" = yes ; then
1111   if test "$PORTNAME" != "win32"; then
1112     AC_CHECK_LIB(ldap_r,    ldap_simple_bind, [], [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])])
1113     PTHREAD_LIBS="$PTHREAD_LIBS -lldap_r"
1114   fi
1115 fi
1116
1117 CFLAGS="$_CFLAGS"
1118 LIBS="$_LIBS"
1119
1120 else
1121 # do not use values from template file
1122 PTHREAD_CFLAGS=
1123 PTHREAD_LIBS=
1124 fi
1125
1126 AC_SUBST(PTHREAD_CFLAGS)
1127 AC_SUBST(PTHREAD_LIBS)
1128
1129
1130 # This test makes sure that run tests work at all.  Sometimes a shared
1131 # library is found by the linker, but the runtime linker can't find it.
1132 # This check should come after all modifications of compiler or linker
1133 # variables, and before any other run tests.
1134 AC_MSG_CHECKING([test program])
1135 AC_TRY_RUN([int main() { return 0; }],
1136 [AC_MSG_RESULT(ok)],
1137 [AC_MSG_RESULT(failed)
1138 AC_MSG_ERROR([[
1139 *** Could not execute a simple test program.  This may be a problem
1140 *** related to locating shared libraries.  Check the file 'config.log'
1141 *** for the exact reason.]])],
1142 [AC_MSG_RESULT([cross-compiling])])
1143
1144 # --------------------
1145 # Run tests below here
1146 # --------------------
1147
1148 # Force use of our snprintf if system's doesn't do arg control
1149 # See comment above at snprintf test for details.
1150 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1151   PGAC_FUNC_PRINTF_ARG_CONTROL
1152   if test $pgac_cv_printf_arg_control != yes ; then
1153     pgac_need_repl_snprintf=yes
1154   fi
1155 fi
1156
1157
1158 dnl Check to see if we have a working 64-bit integer type.
1159 dnl This breaks down into two steps:
1160 dnl (1) figure out if the compiler has a 64-bit int type with working
1161 dnl arithmetic, and if so
1162 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1163 dnl snprintf is the only library routine we really need for int8 support.)
1164 dnl It's entirely possible to have a compiler that handles a 64-bit type
1165 dnl when the C library doesn't; this is fairly likely when using gcc on
1166 dnl an older platform, for example.
1167 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1168 dnl we force our own version of snprintf() to be used instead.
1169 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1170
1171 PGAC_TYPE_64BIT_INT([long int])
1172
1173 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1174   PGAC_TYPE_64BIT_INT([long long int])
1175 fi
1176
1177
1178 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1179
1180 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1181   AC_TRY_COMPILE([
1182 #define INT64CONST(x)  x##LL
1183 long long int foo = INT64CONST(0x1234567890123456);
1184 ],
1185         [],
1186         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1187         [])
1188 fi
1189
1190
1191 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1192 # we found we need to use "long long int", better check.  We cope with
1193 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1194 # work, fall back to our own snprintf emulation (which we know uses %lld).
1195
1196 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1197   if test $pgac_need_repl_snprintf = no; then
1198     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1199     if test "$LONG_LONG_INT_FORMAT" = ""; then
1200       # Force usage of our own snprintf, since system snprintf is broken
1201       pgac_need_repl_snprintf=yes
1202       LONG_LONG_INT_FORMAT='%lld'
1203     fi
1204   else
1205     # Here if we previously decided we needed to use our own snprintf
1206     LONG_LONG_INT_FORMAT='%lld'
1207   fi
1208   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1209   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1210   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1211 else
1212   # Here if we are not using 'long long int' at all
1213   INT64_FORMAT='"%ld"'
1214   UINT64_FORMAT='"%lu"'
1215 fi
1216
1217 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1218                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1219
1220 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1221                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1222
1223 # Now we have checked all the reasons to replace snprintf
1224 if test $pgac_need_repl_snprintf = yes; then
1225   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1226   AC_LIBOBJ(snprintf)
1227 fi
1228
1229 # Need a #define for the size of Datum (unsigned long)
1230 AC_CHECK_SIZEOF([unsigned long])
1231
1232 # And one for the size of size_t (enables tweaks for > 32bit address space)
1233 AC_CHECK_SIZEOF([size_t])
1234
1235 # Determine memory alignment requirements for the basic C data types.
1236
1237 PGAC_CHECK_ALIGNOF(short)
1238 PGAC_CHECK_ALIGNOF(int)
1239 PGAC_CHECK_ALIGNOF(long)
1240 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1241   PGAC_CHECK_ALIGNOF(long long int)
1242 fi
1243 PGAC_CHECK_ALIGNOF(double)
1244
1245 # Compute maximum alignment of any basic type.
1246 # We assume long's alignment is at least as strong as char, short, or int;
1247 # but we must check long long (if it exists) and double.
1248
1249 MAX_ALIGNOF=$pgac_cv_alignof_long
1250 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1251   MAX_ALIGNOF=$pgac_cv_alignof_double
1252 fi
1253 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1254   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1255 fi
1256 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1257
1258
1259 # Some platforms predefine the types int8, int16, etc.  Only check
1260 # a (hopefully) representative subset.
1261 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1262 [#include <stdio.h>
1263 #ifdef HAVE_SUPPORTDEFS_H
1264 #include <SupportDefs.h>
1265 #endif])
1266
1267 # We also check for sig_atomic_t, which *should* be defined per ANSI
1268 # C, but is missing on some old platforms.
1269 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1270
1271
1272 if test x"$template" != x"win32"
1273 then
1274 PGAC_FUNC_POSIX_SIGNALS
1275 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1276   AC_MSG_ERROR([
1277 *** Thread-safety requires POSIX signals, which are not supported by your
1278 *** operating system.
1279 ])
1280 fi
1281 fi
1282
1283 if test $ac_cv_func_fseeko = yes; then
1284 AC_SYS_LARGEFILE
1285 fi
1286
1287 # SunOS doesn't handle negative byte comparisons properly with +/- return
1288 AC_FUNC_MEMCMP
1289
1290
1291 # Select semaphore implementation type.
1292 if test "$PORTNAME" != "win32"; then
1293   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1294     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1295     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1296   else
1297     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1298       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1299       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1300     else
1301       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1302       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1303     fi
1304   fi
1305 else
1306   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1307   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1308 fi
1309
1310
1311 # Select shared-memory implementation type.
1312 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1313 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1314
1315
1316 # If not set in template file, set bytes to use libc memset()
1317 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1318   MEMSET_LOOP_LIMIT=1024
1319 fi
1320 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1321
1322
1323 if test "$enable_nls" = yes ; then
1324   PGAC_CHECK_GETTEXT
1325 fi
1326
1327 # Check for Tcl configuration script tclConfig.sh
1328 if test "$with_tcl" = yes; then
1329     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1330     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1331                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1332     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1333     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1334     ac_save_CPPFLAGS=$CPPFLAGS
1335     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1336     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1337     CPPFLAGS=$ac_save_CPPFLAGS
1338 fi
1339
1340 #
1341 # Check for DocBook and tools
1342 #
1343 PGAC_PROG_NSGMLS
1344 PGAC_PROG_JADE
1345 PGAC_CHECK_DOCBOOK(4.2)
1346 PGAC_PATH_DOCBOOK_STYLESHEETS
1347 PGAC_PATH_COLLATEINDEX
1348 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1349
1350 # Thread testing
1351
1352 # We have to run the thread test near the end so we have all our symbols
1353 # defined.  Cross compiling throws a warning.
1354 #
1355 if test "$enable_thread_safety_force" = yes; then
1356 if test x"$template" != x"win32"
1357 then
1358   AC_MSG_WARN([
1359 *** Skipping thread test program.  --enable-thread-safety-force was used.
1360 *** Run the program in src/test/thread on the your machine and add
1361 proper locking function calls to your applications to guarantee thread
1362 safety.
1363 ])
1364 else
1365 AC_MSG_WARN([*** Skipping thread test on Win32])
1366 fi
1367 elif test "$enable_thread_safety" = yes; then
1368 if test x"$template" != x"win32"
1369 then
1370 AC_MSG_CHECKING([thread safety of required library functions])
1371
1372 _CFLAGS="$CFLAGS"
1373 _LIBS="$LIBS"
1374 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1375 LIBS="$LIBS $PTHREAD_LIBS"
1376 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1377   [AC_MSG_RESULT(yes)],
1378   [AC_MSG_RESULT(no)
1379   AC_MSG_ERROR([
1380 *** Thread test program failed.  Your platform is not thread-safe.
1381 *** Check the file 'config.log'for the exact reason.
1382 ***
1383 *** You can use the configure option --enable-thread-safety-force
1384 *** to force threads to be enabled.  However, you must then run
1385 *** the program in src/test/thread and add locking function calls
1386 *** to your applications to guarantee thread safety.
1387 ])],
1388   [AC_MSG_RESULT(maybe)
1389   AC_MSG_WARN([
1390 *** Skipping thread test program because of cross-compile build.
1391 *** Run the program in src/test/thread on the target machine.
1392 ])])
1393 CFLAGS="$_CFLAGS"
1394 LIBS="$_LIBS"
1395 else
1396 AC_MSG_WARN([*** Skipping thread test on Win32])
1397 fi
1398 fi
1399
1400 # prepare build tree if outside source tree
1401 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1402 # Note 2: /bin/pwd might be better than shell's built-in at getting
1403 #         a symlink-free name.
1404 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1405   vpath_build=no
1406 else
1407   vpath_build=yes
1408   if test "$no_create" != yes; then
1409     _AS_ECHO_N([preparing build tree... ])
1410     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1411     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1412       || AC_MSG_ERROR(failed)
1413     AC_MSG_RESULT(done)
1414   fi
1415 fi
1416 AC_SUBST(vpath_build)
1417
1418
1419 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1420
1421 AC_CONFIG_LINKS([
1422   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1423   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1424   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1425   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1426   src/include/pg_config_os.h:src/include/port/${template}.h
1427   src/Makefile.port:src/makefiles/Makefile.${template}
1428 ])
1429
1430 if test "$PORTNAME" = "win32"; then
1431 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1432 # Links sometimes fail undetected on Mingw -
1433 # so here we detect it and warn the user
1434 for FILE in $CONFIG_LINKS
1435  do
1436         # test -e works for symlinks in the MinGW console
1437         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1438  done
1439 ])
1440 fi
1441
1442 AC_CONFIG_HEADERS([src/include/pg_config.h],
1443 [
1444 # Update timestamp for pg_config.h (see Makefile.global)
1445 echo >src/include/stamp-h
1446 ])
1447
1448 #
1449 # Warn about unknown options
1450 #
1451
1452 PGAC_CHECK_ARGS
1453
1454 AC_OUTPUT
1455