granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225
 226 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 227 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 228    PCRE_CONFIG=$with_pcre/bin/pcre-config
 229 elif test -x "$with_pcre"; then
 230    PCRE_CONFIG=$with_pcre
 231 fi
 232
 233 if test "$PCRE_CONFIG" != "false"; then
 234   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 235     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 236   fi
 237   case `$PCRE_CONFIG --version` in
 238   [[1-5].*])
 239     AC_MSG_ERROR([Need at least pcre version 6.0])
 240     ;;
 241   esac
 242   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 243   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 244   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 245 else
 246   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 247 fi
 248 APACHE_SUBST(PCRE_LIBS)
 249
 250 AC_MSG_NOTICE([])
 251 AC_MSG_NOTICE([Configuring Apache httpd...])
 252 AC_MSG_NOTICE([])
 253
 254 dnl If the source dir is not equal to the build dir,
 255 dnl then we are running in VPATH mode.
 256
 257 APR_ADDTO(INCLUDES, [-I.])
 258
 259 if test "$abs_builddir" != "$abs_srcdir"; then
 260   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 261 fi
 262
 263 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 264
 265 # apr/apr-util --includes may pick up system paths for dependent
 266 # libraries, so ensure these are later in INCLUDES than local source
 267 # directories.
 268 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 269 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 270
 271 dnl Add in path to PCRE includes
 272 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 273
 274 AC_MSG_NOTICE([])
 275 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 276 AC_MSG_NOTICE([])
 277
 278 case $host in
 279   *os2*)
 280       # Use a custom made libtool replacement
 281       echo "using aplibtool"
 282       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 283       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 284       SH_LIBS="\$(ALL_LIBS)"
 285       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 286       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 287       MK_IMPLIB="emximp"
 288       other_targets="$other_targets os2core"
 289       INSTALL_PROG_FLAGS="-e .exe"
 290       SHLTCFLAGS=""
 291       LTCFLAGS=""
 292       ;;
 293   *)
 294       if test "x$LTFLAGS" = "x"; then
 295           LTFLAGS='--silent'
 296       fi
 297       my_libtool=`$apr_config --apr-libtool`
 298       LIBTOOL="$my_libtool \$(LTFLAGS)"
 299       libtoolversion=`$my_libtool --version`
 300       case $libtoolversion in
 301           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 302               SH_LIBTOOL='$(LIBTOOL)'
 303               SHLTCFLAGS="-prefer-pic"
 304               LTCFLAGS="-prefer-non-pic -static"
 305               ;;
 306           *)
 307               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 308               SHLTCFLAGS=""
 309               LTCFLAGS=""
 310               ;;
 311       esac
 312       ;;
 313 esac
 314 APACHE_SUBST(SHLTCFLAGS)
 315 APACHE_SUBST(LTCFLAGS)
 316
 317 case $host in
 318   *-apple-aux3*)
 319       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320       ;;
 321   *os2-emx*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324   *-linux-*)
 325       case `uname -r` in
 326         2.[[2-9]]* )
 327             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 328             ;;
 329         * )
 330             ;;
 331       esac
 332       ;;
 333   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 334       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 335       ;;
 336   *-solaris2*)
 337       dnl This is a hack -- we should be using AC_TRY_RUN instead
 338       ap_platform_runtime_link_flag="-R"
 339       dnl solaris 8 and above don't have a thundering herd
 340       dnl not sure about rev's before this one.
 341       case `uname -r` in
 342         5.[567]*)
 343             ;;
 344         * )
 345             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 346             ;;
 347       esac
 348       ;;
 349   *cygwin*)
 350       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 351       ;;
 352   *mingw32*)
 353       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 354       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 355       APR_SETIFNULL(ac_cv_func_times, [no])
 356       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 357       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 358       ;;
 359   *aix*)
 360       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 361       if test $aixver -ge 4320; then
 362         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 363       fi
 364       ;;
 365   *os390*)
 366       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 367       ;;
 368 esac
 369
 370 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 371
 372 dnl
 373 dnl Process command line arguments. This is done early in the process so the
 374 dnl user can get feedback quickly in case of an error.
 375 dnl
 376 dnl ### need to move some of the arguments "up here"
 377
 378 dnl ## Check for programs
 379
 380 AC_PATH_PROG(RM, rm)
 381 AC_PATH_PROG(PKGCONFIG, pkg-config)
 382 AC_PATH_PROG(RSYNC, rsync)
 383 AC_PROG_AWK
 384 AC_PROG_LN_S
 385 AC_CHECK_TOOL(RANLIB, ranlib, true)
 386 dnl AC_PATH_PROG(PERL_PATH, perl)
 387 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 388
 389 # Hard-coded install programs
 390 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 391 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 392 APACHE_SUBST(MKINSTALLDIRS)
 393 APACHE_SUBST(INSTALL)
 394
 395 dnl Various OS checks that apparently set required flags
 396 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 397 AC_USE_SYSTEM_EXTENSIONS
 398 ], [
 399 AC_AIX
 400 AC_MINIX
 401 ])
 402
 403 AC_ISC_POSIX
 404
 405 # Ensure that satisfactory versions of apr and apr-util are
 406 # found if external copies are configured.
 407 if test "${apr_found}" = "yes"; then
 408   # Require at least APR 1.3.x otherwise fail
 409   APACHE_CHECK_APxVER([apr], 1, 3)
 410 fi
 411
 412 if test "${apu_found}" = "yes"; then
 413   # Require at least APR-util 1.3.x otherwise fail
 414   if test "${apr_found}" = "yes"; then
 415     # we need to add the APR includes to CPPFLAGS
 416     apu_ckver_CPPFLAGS="$CPPFLAGS"
 417     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 418     APACHE_CHECK_APxVER([apu], 1, 3)
 419     CPPFLAGS="$apu_ckver_CPPFLAGS"
 420   else
 421     APACHE_CHECK_APxVER([apu], 1, 3)
 422   fi
 423 fi
 424
 425 dnl Check for what we can generate dependency files with
 426 APR_CHECK_DEPEND
 427
 428 dnl ## Check for libraries
 429
 430 dnl ## Check for header files
 431
 432 dnl I think these are just used all over the place, so just check for
 433 dnl them at the base of the tree. If some are specific to a single
 434 dnl directory, they should be moved (Comment #Spoon)
 435
 436 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 437 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 438 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 439
 440 AC_HEADER_STDC
 441 AC_CHECK_HEADERS( \
 442 string.h \
 443 limits.h \
 444 unistd.h \
 445 sys/socket.h \
 446 pwd.h \
 447 grp.h \
 448 strings.h \
 449 sys/prctl.h \
 450 sys/processor.h \
 451 sys/sem.h \
 452 sys/sdt.h \
 453 sys/loadavg.h
 454 )
 455 AC_HEADER_SYS_WAIT
 456
 457 dnl ## Check for typedefs, structures, and compiler characteristics.
 458
 459 AC_C_CONST
 460
 461 dnl ## Check for library functions
 462 dnl ## sqrt() only needed in support/ab.c
 463 saved_LIBS="$LIBS"
 464 LIBS=""
 465 AC_SEARCH_LIBS(sqrt, m)
 466 MATH_LIBS="$LIBS"
 467 APACHE_SUBST(MATH_LIBS)
 468 LIBS="$saved_LIBS"
 469
 470 saved_LIBS="$LIBS"
 471 LIBS=""
 472 AC_SEARCH_LIBS(crypt, crypt)
 473 CRYPT_LIBS="$LIBS"
 474 APACHE_SUBST(CRYPT_LIBS)
 475 LIBS="$saved_LIBS"
 476
 477 dnl See Comment #Spoon
 478
 479 AC_CHECK_FUNCS( \
 480 getpwnam \
 481 getgrnam \
 482 initgroups \
 483 bindprocessor \
 484 prctl \
 485 timegm \
 486 getpgid \
 487 fopen64 \
 488 getloadavg
 489 )
 490
 491 dnl confirm that a void pointer is large enough to store a long integer
 492 APACHE_CHECK_VOID_PTR_LEN
 493
 494 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 495 [AC_TRY_RUN(#define _GNU_SOURCE
 496 #include <unistd.h>
 497 #include <sys/syscall.h>
 498 #include <sys/types.h>
 499 int main(int argc, char **argv) {
 500 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 501 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 502 if test "$ac_cv_gettid" = "yes"; then
 503     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 504 fi
 505
 506 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 507 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 508 [AC_TRY_COMPILE([#include <sys/types.h>
 509 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 510   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 511 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 512     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 513 fi
 514
 515 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 516
 517 case $host in
 518     *aix*)
 519         # for 32-bit builds, increase MAXDATA to allow lots of threads
 520         if test x$OBJECT_MODE != x64; then
 521             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 522         fi
 523         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 524         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 525         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 526         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 527         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 528         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 529         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 530         ;;
 531     *os390*)
 532         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 533         ;;
 534     *)
 535         OS_SPECIFIC_VARS=""
 536 esac
 537
 538 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 539         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 540         [PORT=80])
 541
 542 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 543         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 544         [SSLPORT=443])
 545
 546 DTRACE=true
 547 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 548 [
 549   enable_dtrace=$enableval
 550   if test "$enableval" = "yes"; then
 551     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 552     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 553   fi
 554 ],
 555 [
 556   enable_dtrace=no
 557 ])
 558
 559 dnl Disabled dtrace build for now.
 560 enable_dtrace=no
 561
 562 case $host in
 563   *-solaris2*)
 564     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 565         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 566                   [Enable DTrace probes])
 567         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 568         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 569     fi
 570     ;;
 571 esac
 572
 573 APACHE_SUBST(DTRACE)
 574
 575 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 576 [
 577     if test "$enableval" = "yes"; then
 578         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 579                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 580         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 581     fi
 582 ])dnl
 583
 584 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 585 [
 586     if test "$enableval" = "yes"; then
 587         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 588                   [Allow modules to run hook after a fatal exception])
 589     fi
 590 ])dnl
 591
 592 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 593 [
 594   LOAD_ALL_MODULES=$enableval
 595   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 596 ],
 597 [
 598   LOAD_ALL_MODULES="no"
 599 ])
 600
 601 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 602 [
 603   if test "$enableval" = "yes"; then
 604     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 605     if test "$GCC" = "yes"; then
 606       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 607       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 608       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 609       APACHE_ADD_GCC_CFLAG([-Wformat])
 610       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 611       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 612     elif test "$AIX_XLC" = "yes"; then
 613       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 614     fi
 615     if test "x$enable_load_all_modules" = "x"; then
 616       LOAD_ALL_MODULES=yes
 617       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 618     fi
 619   fi
 620 ])dnl
 621
 622 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 623 [
 624   if test "$enableval" = "yes"; then
 625     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 626     if test "$GCC" = "yes"; then
 627       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 628       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 629       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 630       APACHE_ADD_GCC_CFLAG([-Wformat])
 631       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 632       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 633     elif test "$AIX_XLC" = "yes"; then
 634       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 635     fi
 636   fi
 637 ])dnl
 638
 639 dnl Conditionally enable PIE support for GNU toolchains.
 640 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 641 if test "$enable_pie" = "yes"; then
 642    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 643      save_CFLAGS=$CFLAGS
 644      save_LDFLAGS=$LDFLAGS
 645      CFLAGS="$CFLAGS -fPIE"
 646      LDFLAGS="$LDFLAGS -pie"
 647      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 648       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 649      CFLAGS=$save_CFLAGS
 650      LDFLAGS=$save_LDFLAGS
 651    ])
 652    if test "$ap_cv_cc_pie" = "yes"; then
 653      PICFLAGS="-fPIE"
 654      PILDFLAGS="-pie"
 655    else
 656      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 657    fi
 658 fi
 659 APACHE_SUBST(PICFLAGS)
 660 APACHE_SUBST(PILDFLAGS)
 661
 662 AC_ARG_WITH(valgrind,
 663   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 664                           (optionally: set path to valgrind headers) ],
 665   [ if test "$withval" != no; then
 666       if test "$withval" = yes; then
 667         withval=/usr/include/valgrind
 668       fi
 669       APR_ADDTO(CPPFLAGS, -I$withval)
 670       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 671       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 672         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 673         [AC_MSG_ERROR(valgrind headers not found) ]
 674       )
 675     fi ]
 676 )
 677
 678 prefix="$orig_prefix"
 679 APACHE_ENABLE_MODULES
 680
 681 dnl reading config stubs
 682 esyscmd(./build/config-stubs .)
 683
 684 APACHE_SUBST(progname)
 685 APACHE_SUBST(OS)
 686 APACHE_SUBST(OS_DIR)
 687 APACHE_SUBST(BUILTIN_LIBS)
 688 APACHE_SUBST(SHLIBPATH_VAR)
 689 APACHE_SUBST(OS_SPECIFIC_VARS)
 690
 691 PRE_SHARED_CMDS='echo ""'
 692 POST_SHARED_CMDS='echo ""'
 693
 694 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 695
 696 if test "$apache_need_shared" = "yes"; then
 697   if test -f $ac_aux_dir/ltconfig; then
 698     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 699   fi
 700   shared_build="shared-build"
 701 fi
 702
 703 dnl enable_so tells us if *any* modules can be built as DSOs
 704
 705 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 706   case $host in
 707     *-ibm-aix*)
 708       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 709       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 710       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 711       ;;
 712     *os390)
 713       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 714       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 715   esac
 716   MOD_SO_ENABLED=yes
 717 fi
 718 AC_SUBST(MOD_SO_ENABLED)
 719
 720 APACHE_SUBST(PRE_SHARED_CMDS)
 721 APACHE_SUBST(POST_SHARED_CMDS)
 722 APACHE_SUBST(shared_build)
 723
 724 AC_ARG_WITH(program-name,
 725 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 726   progname="$withval" ], [
 727   progname="httpd"] )
 728
 729 # SuExec parameters
 730 AC_ARG_WITH(suexec-bin,
 731 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 732   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 733 ] )
 734
 735 AC_ARG_WITH(suexec-caller,
 736 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 737   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 738
 739 AC_ARG_WITH(suexec-userdir,
 740 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 741   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 742
 743 AC_ARG_WITH(suexec-docroot,
 744 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 745   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 746
 747 AC_ARG_WITH(suexec-uidmin,
 748 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 749   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 750
 751 AC_ARG_WITH(suexec-gidmin,
 752 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 753   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 754
 755 AC_ARG_WITH(suexec-logfile,
 756 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 757   if test "x$withval" = "xyes"; then
 758     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 759   elif test "x$withval" != "xno"; then
 760     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 761   fi
 762 ])
 763
 764 AC_ARG_WITH(suexec-syslog,
 765 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 766   if test $withval = "yes"; then
 767     if test "x${with_suexec_logfile}" != "xno"; then
 768       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 769       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 770     fi
 771     AC_CHECK_FUNCS([vsyslog], [], [
 772        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 773     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 774   fi
 775 ])
 776
 777
 778 AC_ARG_WITH(suexec-safepath,
 779 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 780   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 781
 782 AC_ARG_WITH(suexec-umask,
 783 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 784   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 785
 786 INSTALL_SUEXEC=setuid
 787 AC_ARG_ENABLE([suexec-capabilities],
 788 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 789   if test "$enableval" = "yes"; then
 790     INSTALL_SUEXEC=caps
 791     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 792               [Enable if suexec is installed with Linux capabilities, not setuid])
 793   fi
 794 ])
 795 APACHE_SUBST(INSTALL_SUEXEC)
 796
 797 dnl APR should go after the other libs, so the right symbols can be picked up
 798 if test x${apu_found} != xobsolete; then
 799   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 800 fi
 801 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 802 APACHE_SUBST(AP_LIBS)
 803 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 804 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 805
 806 AC_DEFINE(AP_USING_AUTOCONF, 1,
 807                 [Using autoconf to configure Apache])
 808
 809 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 810     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 811               [This platform doesn't suffer from the thundering herd problem])
 812 fi
 813
 814 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 815     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 816               [Listening sockets are non-blocking when there are more than 1])
 817 fi
 818
 819 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 820
 821 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 822 [
 823   v4mapped=$enableval
 824 ],
 825 [
 826     case $host in
 827     *freebsd5*|*netbsd*|*openbsd*)
 828         v4mapped=no
 829         ;;
 830     *)
 831         v4mapped=yes
 832         ;;
 833     esac
 834     if ap_mpm_is_enabled winnt; then
 835         dnl WinNT MPM doesn't support this.
 836         v4mapped=no
 837     fi
 838 ])
 839
 840 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 841     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 842               [Allow IPv4 connections on IPv6 listening sockets])
 843 fi
 844
 845 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 846 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 847 APACHE_FAST_OUTPUT(support/Makefile)
 848
 849 if test -d ./test; then
 850     APACHE_FAST_OUTPUT(test/Makefile)
 851 fi
 852
 853 dnl ## Finalize the variables
 854 AC_MSG_NOTICE([])
 855 AC_MSG_NOTICE([Restore user-defined environment settings...])
 856 AC_MSG_NOTICE([])
 857
 858 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 859 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 860 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 861 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 862 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 863 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 864
 865 AC_MSG_NOTICE([])
 866 AC_MSG_NOTICE([Construct makefiles and header files...])
 867 AC_MSG_NOTICE([])
 868
 869 APACHE_GEN_CONFIG_VARS
 870
 871 dnl ## Build modules.c
 872 rm -f modules.c
 873 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 874
 875 APR_EXPAND_VAR(ap_prefix, $prefix)
 876 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 877         [Root directory of the Apache install area])
 878 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 879         [Location of the config file, relative to the Apache root directory])
 880 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 881         [Location of the MIME types config file, relative to the Apache root directory])
 882
 883 perlbin=`$ac_aux_dir/PrintPath perl`
 884 if test "x$perlbin" = "x"; then
 885     perlbin="/replace/with/path/to/perl/interpreter"
 886 fi
 887 AC_SUBST(perlbin)
 888
 889 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 890
 891 BSD_MAKEFILE=no
 892 ap_make_include=include
 893 ap_make_delimiter=' '
 894 case $host in
 895 *bsdi*)
 896     # Check whether they've installed GNU make
 897     if make --version > /dev/null 2>&1; then
 898         true
 899     else
 900         BSD_MAKEFILE=yes
 901         ap_make_include=.include
 902         ap_make_delimiter='"'
 903     fi
 904     ;;
 905 esac
 906 AC_SUBST(ap_make_include)
 907 AC_SUBST(ap_make_delimiter)
 908
 909 dnl Ensure that docs/conf is created.
 910 test -d docs/conf||$mkdir_p docs/conf
 911
 912 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 913   APACHE_GEN_MAKEFILES
 914 ])