granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="./srclib/apr/apr-${majorver}-config"
  97     if test -f "$test_apr_config"; then
  98       apr_config="$test_apr_config"
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 124    dnl isn't supported.
 125    ifdef([APR_FIND_APU], [
 126      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 127                   1, ${apr_major_version})
 128    ], [apu_found=no])
 129 fi
 130
 131 if test "$apu_found" = "no"; then
 132   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 133 fi
 134
 135 # Catch some misconfigurations:
 136 case ${apr_found}.${apu_found} in
 137 reconfig.yes)
 138   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 139   ;;
 140 yes.reconfig)
 141   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 142   ;;
 143 esac
 144
 145 if test "$apu_found" = "reconfig"; then
 146   APR_SUBDIR_CONFIG(srclib/apr-util,
 147                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 148                     [--enable-layout=*|\'--enable-layout=*])
 149   dnl We must be the last to build and the first to be cleaned
 150   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 151   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 152   dnl APR and APR-Util major versions must match
 153   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 154 fi
 155
 156 if test "$apu_found" = "obsolete"; then
 157   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 158 else
 159   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 160   APU_BINDIR=`$apu_config --bindir`
 161   APU_INCLUDEDIR=`$apu_config --includedir`
 162   APU_INCLUDES=`$apu_config --includes`
 163   APU_VERSION=`$apu_config --version`
 164   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 165 fi
 166
 167 dnl In case we picked up CC and CPP from APR, get that info into the
 168 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 169 dnl PCRE and for our config tests will be whatever PCRE determines.
 170 AC_PROG_CC
 171 AC_PROG_CPP
 172
 173 dnl Try to get c99 support for variadic macros
 174 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 175
 176 if test "x${cache_file}" = "x/dev/null"; then
 177   # Likewise, ensure that CC and CPP are passed through to the pcre
 178   # configure script iff caching is disabled (the autoconf 2.5x default).
 179   export CC; export CPP
 180 fi
 181
 182 dnl Absolute source/build directory
 183 abs_srcdir=`(cd $srcdir && pwd)`
 184 abs_builddir=`pwd`
 185
 186 AC_ARG_WITH(pcre,
 187 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 188
 189 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 190 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 191    PCRE_CONFIG=$with_pcre/bin/pcre-config
 192 elif test -x "$with_pcre"; then
 193    PCRE_CONFIG=$with_pcre
 194 fi
 195
 196 if test "$PCRE_CONFIG" != "false"; then
 197   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 198     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 199   fi
 200   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 201   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 202   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 203 else
 204   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 205 fi
 206 APACHE_SUBST(PCRE_LIBS)
 207
 208 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 209 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 210
 211 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 212
 213 dnl If the source dir is not equal to the build dir,
 214 dnl then we are running in VPATH mode.
 215
 216 APR_ADDTO(INCLUDES, [-I.])
 217
 218 if test "$abs_builddir" != "$abs_srcdir"; then
 219   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 220 fi
 221
 222 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 223
 224 # apr/apr-util --includes may pick up system paths for dependent
 225 # libraries, so ensure these are later in INCLUDES than local source
 226 # directories.
 227 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 228 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 229
 230 dnl Add in path to PCRE includes
 231 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 232
 233 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 234
 235 case $host in
 236   *os2*)
 237       # Use a custom made libtool replacement
 238       echo "using aplibtool"
 239       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 240       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 241       SH_LIBS="\$(ALL_LIBS)"
 242       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 243       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 244       MK_IMPLIB="emximp"
 245       other_targets="$other_targets os2core"
 246       INSTALL_PROG_FLAGS="-e .exe"
 247       SHLTCFLAGS=""
 248       LTCFLAGS=""
 249       ;;
 250   *)
 251       if test "x$LTFLAGS" = "x"; then
 252           LTFLAGS='--silent'
 253       fi
 254       my_libtool=`$apr_config --apr-libtool`
 255       LIBTOOL="$my_libtool \$(LTFLAGS)"
 256       libtoolversion=`$my_libtool --version`
 257       case $libtoolversion in
 258           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 259               SH_LIBTOOL='$(LIBTOOL)'
 260               SHLTCFLAGS="-prefer-pic"
 261               LTCFLAGS="-prefer-non-pic -static"
 262               ;;
 263           *)
 264               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 265               SHLTCFLAGS=""
 266               LTCFLAGS=""
 267               ;;
 268       esac
 269       ;;
 270 esac
 271 APACHE_SUBST(SHLTCFLAGS)
 272 APACHE_SUBST(LTCFLAGS)
 273
 274 case $host in
 275   *-apple-aux3*)
 276       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 277       ;;
 278   *os2-emx*)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *-linux-*)
 282       case `uname -r` in
 283         2.[[2-9]]* )
 284             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 285             ;;
 286         * )
 287             ;;
 288       esac
 289       ;;
 290   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 291       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 292       ;;
 293   *-solaris2*)
 294       dnl This is a hack -- we should be using AC_TRY_RUN instead
 295       ap_platform_runtime_link_flag="-R"
 296       dnl solaris 8 and above don't have a thundering herd
 297       dnl not sure about rev's before this one.
 298       case `uname -r` in
 299         5.[567]*)
 300             ;;
 301         * )
 302             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 303             ;;
 304       esac
 305       ;;
 306   *cygwin*)
 307       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 308       ;;
 309   *mingw32*)
 310       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 311       APR_SETIFNULL(ac_cv_func_times, [no])
 312       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 313       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 314       ;;
 315   *aix*)
 316       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 317       if test $aixver -ge 4320; then
 318         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 319       fi
 320       ;;
 321   *os390*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324 esac
 325
 326 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 327
 328 dnl
 329 dnl Process command line arguments. This is done early in the process so the
 330 dnl user can get feedback quickly in case of an error.
 331 dnl
 332 dnl ### need to move some of the arguments "up here"
 333
 334 dnl ## Check for programs
 335
 336 AC_PATH_PROG(RM, rm)
 337 AC_PATH_PROG(PKGCONFIG, pkg-config)
 338 AC_PATH_PROG(RSYNC, rsync)
 339 AC_PROG_AWK
 340 AC_PROG_LN_S
 341 AC_CHECK_TOOL(RANLIB, ranlib, true)
 342 dnl AC_PATH_PROG(PERL_PATH, perl)
 343 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 344
 345 # Hard-coded install programs
 346 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 347 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 348 APACHE_SUBST(MKINSTALLDIRS)
 349 APACHE_SUBST(INSTALL)
 350
 351 dnl Various OS checks that apparently set required flags
 352 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 353 AC_USE_SYSTEM_EXTENSIONS
 354 ], [
 355 AC_AIX
 356 AC_MINIX
 357 ])
 358
 359 AC_ISC_POSIX
 360
 361 # Ensure that satisfactory versions of apr and apr-util are
 362 # found if external copies are configured.
 363 if test "${apr_found}" = "yes"; then
 364   # Require at least APR 1.3.x otherwise fail
 365   APACHE_CHECK_APxVER([apr], 1, 3)
 366 fi
 367
 368 if test "${apu_found}" = "yes"; then
 369   # Require at least APR-util 1.3.x otherwise fail
 370   APACHE_CHECK_APxVER([apu], 1, 3)
 371 fi
 372
 373 dnl Check for what we can generate dependency files with
 374 APR_CHECK_DEPEND
 375
 376 dnl ## Check for libraries
 377
 378 dnl ## Check for header files
 379
 380 dnl I think these are just used all over the place, so just check for
 381 dnl them at the base of the tree. If some are specific to a single
 382 dnl directory, they should be moved (Comment #Spoon)
 383
 384 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 385 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 386 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 387
 388 AC_HEADER_STDC
 389 AC_CHECK_HEADERS( \
 390 string.h \
 391 limits.h \
 392 unistd.h \
 393 sys/socket.h \
 394 pwd.h \
 395 grp.h \
 396 strings.h \
 397 sys/prctl.h \
 398 sys/processor.h \
 399 sys/sem.h \
 400 sys/sdt.h
 401 )
 402 AC_HEADER_SYS_WAIT
 403
 404 dnl ## Check for typedefs, structures, and compiler characteristics.
 405
 406 AC_C_CONST
 407
 408 dnl ## Check for library functions
 409 dnl ## sqrt() only needed in support/ab.c
 410 saved_LIBS="$LIBS"
 411 LIBS=""
 412 AC_SEARCH_LIBS(sqrt, m)
 413 MATH_LIBS="$LIBS"
 414 APACHE_SUBST(MATH_LIBS)
 415 LIBS="$saved_LIBS"
 416
 417 dnl See Comment #Spoon
 418
 419 AC_CHECK_FUNCS( \
 420 getpwnam \
 421 getgrnam \
 422 initgroups \
 423 bindprocessor \
 424 prctl \
 425 timegm \
 426 getpgid \
 427 fopen64
 428 )
 429
 430 dnl confirm that a void pointer is large enough to store a long integer
 431 APACHE_CHECK_VOID_PTR_LEN
 432
 433 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 434 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 435 [AC_TRY_COMPILE([#include <sys/types.h>
 436 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 437   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 438 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 439     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 440 fi
 441
 442 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 443
 444 case $host in
 445     *aix*)
 446         # for 32-bit builds, increase MAXDATA to allow lots of threads
 447         if test x$OBJECT_MODE != x64; then
 448             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 449         fi
 450         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 451         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 452         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 453         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 454         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 455         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 456         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 457         ;;
 458     *os390*)
 459         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 460         ;;
 461     *)
 462         OS_SPECIFIC_VARS=""
 463 esac
 464
 465 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 466         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 467         [PORT=80])
 468
 469 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 470         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 471         [SSLPORT=443])
 472
 473 DTRACE=true
 474 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 475 [
 476   enable_dtrace=$enableval
 477   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 478   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 479 ],
 480 [
 481   enable_dtrace=no
 482 ])
 483
 484 dnl Disabled dtrace build for now.
 485 enable_dtrace=no
 486
 487 case $host in
 488   *-solaris2*)
 489     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 490         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 491                   [Enable DTrace probes])
 492         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 493         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 494     fi
 495     ;;
 496 esac
 497
 498 APACHE_SUBST(DTRACE)
 499
 500 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 501
 502 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 503 [
 504   v4mapped=$enableval
 505 ],
 506 [
 507     case $host in
 508     *freebsd5*|*netbsd*|*openbsd*)
 509         v4mapped=no
 510         ;;
 511     *)
 512         v4mapped=yes
 513         ;;
 514 esac
 515 ])
 516
 517 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 518     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 519               [Allow IPv4 connections on IPv6 listening sockets])
 520 fi
 521
 522 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 523 [
 524     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 525               [Allow modules to run hook after a fatal exception])
 526 ])dnl
 527
 528 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 529 [
 530   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 531   if test "$GCC" = "yes"; then
 532     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations])
 533     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 534       save_CFLAGS=$CFLAGS
 535       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 536       AC_COMPILE_IFELSE([int foo() { return 0; }],
 537         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 538       CFLAGS=$save_CFLAGS
 539     ])
 540     if test "$ap_cv_cc_Wdas" = "yes"; then
 541       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 542     fi
 543   elif test "$AIX_XLC" = "yes"; then
 544     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 545   fi
 546 ])dnl
 547
 548 dnl Conditionally enable PIE support for GNU toolchains.
 549 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 550 if test "$enable_pie" = "yes"; then
 551    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 552      save_CFLAGS=$CFLAGS
 553      save_LDFLAGS=$LDFLAGS
 554      CFLAGS="$CFLAGS -fPIE"
 555      LDFLAGS="$LDFLAGS -pie"
 556      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 557       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 558      CFLAGS=$save_CFLAGS
 559      LDFLAGS=$save_LDFLAGS
 560    ])
 561    if test "$ap_cv_cc_pie" = "yes"; then
 562      PICFLAGS="-fPIE"
 563      PILDFLAGS="-pie"
 564    else
 565      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 566    fi
 567 fi
 568 AC_SUBST(PICFLAGS)
 569 AC_SUBST(PILDFLAGS)
 570
 571 prefix="$orig_prefix"
 572 APACHE_ENABLE_MODULES
 573
 574 dnl reading config stubs
 575 esyscmd(./build/config-stubs .)
 576
 577 APACHE_SUBST(progname)
 578 APACHE_SUBST(OS)
 579 APACHE_SUBST(OS_DIR)
 580 APACHE_SUBST(BUILTIN_LIBS)
 581 APACHE_SUBST(SHLIBPATH_VAR)
 582 APACHE_SUBST(OS_SPECIFIC_VARS)
 583
 584 PRE_SHARED_CMDS='echo ""'
 585 POST_SHARED_CMDS='echo ""'
 586
 587 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 588
 589 if test "$apache_need_shared" = "yes"; then
 590   if test -f $ac_aux_dir/ltconfig; then
 591     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 592   fi
 593   shared_build="shared-build"
 594 fi
 595
 596 dnl enable_so tells us if *any* modules can be built as DSOs
 597
 598 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 599   case $host in
 600     *-ibm-aix*)
 601       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 602       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 603       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 604       ;;
 605     *os390)
 606       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 607       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 608   esac
 609   MOD_SO_ENABLED=yes
 610 fi
 611 AC_SUBST(MOD_SO_ENABLED)
 612
 613 APACHE_SUBST(PRE_SHARED_CMDS)
 614 APACHE_SUBST(POST_SHARED_CMDS)
 615 APACHE_SUBST(shared_build)
 616
 617 AC_ARG_WITH(program-name,
 618 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 619   progname="$withval" ], [
 620   progname="httpd"] )
 621
 622 # SuExec parameters
 623 AC_ARG_WITH(suexec-bin,
 624 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 625   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 626 ] )
 627
 628 AC_ARG_WITH(suexec-caller,
 629 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 630   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 631
 632 AC_ARG_WITH(suexec-userdir,
 633 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 634   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 635
 636 AC_ARG_WITH(suexec-docroot,
 637 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 638   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 639
 640 AC_ARG_WITH(suexec-uidmin,
 641 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 642   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 643
 644 AC_ARG_WITH(suexec-gidmin,
 645 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 646   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 647
 648 AC_ARG_WITH(suexec-logfile,
 649 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 650   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 651
 652 AC_ARG_WITH(suexec-safepath,
 653 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 654   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 655
 656 AC_ARG_WITH(suexec-umask,
 657 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 658   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 659
 660 dnl APR should go after the other libs, so the right symbols can be picked up
 661 if test x${apu_found} != xobsolete; then
 662   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 663 fi
 664 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 665 APACHE_SUBST(AP_LIBS)
 666 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 667 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 668
 669 AC_DEFINE(AP_USING_AUTOCONF, 1,
 670                 [Using autoconf to configure Apache])
 671
 672 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 673     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 674               [This platform doesn't suffer from the thundering herd problem])
 675 fi
 676
 677 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 678     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 679               [Listening sockets are non-blocking when there are more than 1])
 680 fi
 681
 682
 683 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 684 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 685 APACHE_FAST_OUTPUT(support/Makefile)
 686
 687 if test -d ./test; then
 688     APACHE_FAST_OUTPUT(test/Makefile)
 689 fi
 690
 691 dnl ## Finalize the variables
 692 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 693
 694 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 695 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 696 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 697 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 698 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 699 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 700
 701 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 702
 703 APACHE_GEN_CONFIG_VARS
 704
 705 dnl ## Build modules.c
 706 rm -f modules.c
 707 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 708
 709 APR_EXPAND_VAR(ap_prefix, $prefix)
 710 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 711         [Root directory of the Apache install area])
 712 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 713         [Location of the config file, relative to the Apache root directory])
 714 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 715         [Location of the MIME types config file, relative to the Apache root directory])
 716
 717 perlbin=`$ac_aux_dir/PrintPath perl`
 718 if test "x$perlbin" = "x"; then
 719     perlbin="/replace/with/path/to/perl/interpreter"
 720 fi
 721 AC_SUBST(perlbin)
 722
 723 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 724
 725 BSD_MAKEFILE=no
 726 ap_make_include=include
 727 ap_make_delimiter=' '
 728 case $host in
 729 *bsdi*)
 730     # Check whether they've installed GNU make
 731     if make --version > /dev/null 2>&1; then
 732         true
 733     else
 734         BSD_MAKEFILE=yes
 735         ap_make_include=.include
 736         ap_make_delimiter='"'
 737     fi
 738     ;;
 739 esac
 740 AC_SUBST(ap_make_include)
 741 AC_SUBST(ap_make_delimiter)
 742
 743 dnl Ensure that docs/conf is created.
 744 test -d docs/conf||$mkdir_p docs/conf
 745
 746 dnl Ensure that the httpd version is included
 747 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 748 AC_SUBST(HTTPD_VERSION)
 749
 750 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 751   APACHE_GEN_MAKEFILES
 752 ])