granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [10devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2017, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [AC_CHECK_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 AC_CHECK_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 AC_CHECK_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [AC_CHECK_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # WAL segment size
 348 #
 349 AC_MSG_CHECKING([for WAL segment size])
 350 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 351              [wal_segsize=$withval],
 352              [wal_segsize=16])
 353 case ${wal_segsize} in
 354   1) ;;
 355   2) ;;
 356   4) ;;
 357   8) ;;
 358  16) ;;
 359  32) ;;
 360  64) ;;
 361   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 362 esac
 363 AC_MSG_RESULT([${wal_segsize}MB])
 364
 365 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 366  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 367  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 368  XLOG_BLCKSZ).
 369
 370  Changing XLOG_SEG_SIZE requires an initdb.
 371 ])
 372
 373 #
 374 # C compiler
 375 #
 376
 377 # For historical reasons you can also use --with-CC to specify the C compiler
 378 # to use, although the standard way to do this is to set the CC environment
 379 # variable.
 380 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 381
 382 case $template in
 383   aix) pgac_cc_list="gcc xlc";;
 384     *) pgac_cc_list="gcc cc";;
 385 esac
 386
 387 AC_PROG_CC([$pgac_cc_list])
 388
 389 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 390 # but has idiosyncrasies of its own.  We assume icc will define
 391 # __INTEL_COMPILER regardless of CFLAGS.
 392 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 393 choke me
 394 @%:@endif])], [ICC=yes], [ICC=no])
 395
 396 # Check if it's Sun Studio compiler. We assume that
 397 # __SUNPRO_C will be defined for Sun Studio compilers
 398 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 399 choke me
 400 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 401
 402 AC_SUBST(SUN_STUDIO_CC)
 403
 404 unset CFLAGS
 405
 406 #
 407 # Read the template
 408 #
 409 . "$srcdir/src/template/$template" || exit
 410
 411 # CFLAGS are selected so:
 412 # If the user specifies something in the environment, that is used.
 413 # else:  If the template file set something, that is used.
 414 # else:  If coverage was enabled, don't set anything.
 415 # else:  If the compiler is GCC, then we use -O2.
 416 # else:  If the compiler is something else, then we use -O, unless debugging.
 417
 418 if test "$ac_env_CFLAGS_set" = set; then
 419   CFLAGS=$ac_env_CFLAGS_value
 420 elif test "${CFLAGS+set}" = set; then
 421   : # (keep what template set)
 422 elif test "$enable_coverage" = yes; then
 423   : # no optimization by default
 424 elif test "$GCC" = yes; then
 425   CFLAGS="-O2"
 426 else
 427   # if the user selected debug mode, don't use -O
 428   if test "$enable_debug" != yes; then
 429     CFLAGS="-O"
 430   fi
 431 fi
 432
 433 # CFLAGS we determined above will be added back at the end
 434 user_CFLAGS=$CFLAGS
 435 CFLAGS=""
 436
 437 # set CFLAGS_VECTOR from the environment, if available
 438 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 439   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 440 fi
 441
 442 # Some versions of GCC support some additional useful warning flags.
 443 # Check whether they are supported, and add them to CFLAGS if so.
 444 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 445 # but has its own.  Also check other compiler-specific flags here.
 446
 447 if test "$GCC" = yes -a "$ICC" = no; then
 448   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 449   # These work in some but not all gcc versions
 450   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 451   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 452   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 453   # This was included in -Wall/-Wformat in older GCC versions
 454   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 455   # Disable strict-aliasing rules; needed for gcc 3.3+
 456   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 457   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 458   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 459   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 460   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 461   # Optimization flags for specific files that benefit from vectorization
 462   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 463   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 464   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 465   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 466   # test for the positive form and if that works, add the negative form
 467   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 468   if test -n "$NOT_THE_CFLAGS"; then
 469     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 470   fi
 471 elif test "$ICC" = yes; then
 472   # Intel's compiler has a bug/misoptimization in checking for
 473   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 474   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 475   # Make sure strict aliasing is off (though this is said to be the default)
 476   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 477 elif test "$PORTNAME" = "aix"; then
 478   # AIX's xlc has to have strict aliasing turned off too
 479   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 480   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 481 elif test "$PORTNAME" = "hpux"; then
 482   # On some versions of HP-UX, libm functions do not set errno by default.
 483   # Fix that by using +Olibmerrno if the compiler recognizes it.
 484   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 485 fi
 486
 487 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 488
 489 # supply -g if --enable-debug
 490 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 491   CFLAGS="$CFLAGS -g"
 492 fi
 493
 494 # enable code coverage if --enable-coverage
 495 if test "$enable_coverage" = yes; then
 496   if test "$GCC" = yes; then
 497     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 498   else
 499     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 500   fi
 501 fi
 502
 503 # enable profiling if --enable-profiling
 504 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 505   if test "$GCC" = yes; then
 506     AC_DEFINE([PROFILE_PID_DIR], 1,
 507            [Define to 1 to allow profiling output to be saved separately for each process.])
 508     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 509   else
 510     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 511   fi
 512 fi
 513
 514 # We already have this in Makefile.win32, but configure needs it too
 515 if test "$PORTNAME" = "win32"; then
 516   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 517 fi
 518
 519 # Now that we're done automatically adding stuff to CFLAGS, put back the
 520 # user-specified flags (if any) at the end.  This lets users override
 521 # the automatic additions.
 522 CFLAGS="$CFLAGS $user_CFLAGS"
 523
 524 # Check if the compiler still works with the final flag settings
 525 AC_MSG_CHECKING([whether the C compiler still works])
 526 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 527   [AC_MSG_RESULT(yes)],
 528   [AC_MSG_RESULT(no)
 529    AC_MSG_ERROR([cannot proceed])])
 530
 531 # Defend against gcc -ffast-math
 532 if test "$GCC" = yes; then
 533 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 534 choke me
 535 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 536 fi
 537
 538 AC_PROG_CPP
 539 AC_SUBST(GCC)
 540
 541
 542 #
 543 # Set up TAS assembly code if needed; the template file has now had its
 544 # chance to request this.
 545 #
 546 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 547
 548 if test "$need_tas" = yes ; then
 549   TAS=tas.o
 550 else
 551   TAS=""
 552 fi
 553 AC_SUBST(TAS)
 554
 555
 556 #
 557 # Automatic dependency tracking
 558 #
 559 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 560               [autodepend=yes])
 561 AC_SUBST(autodepend)
 562
 563
 564 #
 565 # Enable assert checks
 566 #
 567 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 568               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 569                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 570
 571
 572 #
 573 # Include directories
 574 #
 575 ac_save_IFS=$IFS
 576 IFS="${IFS}${PATH_SEPARATOR}"
 577 # SRCH_INC comes from the template file
 578 for dir in $with_includes $SRCH_INC; do
 579   if test -d "$dir"; then
 580     INCLUDES="$INCLUDES -I$dir"
 581   else
 582     AC_MSG_WARN([*** Include directory $dir does not exist.])
 583   fi
 584 done
 585 IFS=$ac_save_IFS
 586 AC_SUBST(INCLUDES)
 587
 588
 589 #
 590 # Library directories
 591 #
 592 ac_save_IFS=$IFS
 593 IFS="${IFS}${PATH_SEPARATOR}"
 594 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 595 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 596   if test -d "$dir"; then
 597     LIBDIRS="$LIBDIRS -L$dir"
 598   else
 599     AC_MSG_WARN([*** Library directory $dir does not exist.])
 600   fi
 601 done
 602 IFS=$ac_save_IFS
 603
 604 #
 605 # Enable thread-safe client libraries
 606 #
 607 AC_MSG_CHECKING([allow thread-safe client libraries])
 608 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 609 if test "$enable_thread_safety" = yes; then
 610   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 611           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 612 fi
 613 AC_MSG_RESULT([$enable_thread_safety])
 614 AC_SUBST(enable_thread_safety)
 615
 616 #
 617 # ICU
 618 #
 619 AC_MSG_CHECKING([whether to build with ICU support])
 620 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 621               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 622 AC_MSG_RESULT([$with_icu])
 623 AC_SUBST(with_icu)
 624
 625 if test "$with_icu" = yes; then
 626   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 627 fi
 628
 629 #
 630 # Optionally build Tcl modules (PL/Tcl)
 631 #
 632 AC_MSG_CHECKING([whether to build with Tcl])
 633 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 634 AC_MSG_RESULT([$with_tcl])
 635 AC_SUBST([with_tcl])
 636
 637 # We see if the path to the Tcl/Tk configuration scripts is specified.
 638 # This will override the use of tclsh to find the paths to search.
 639
 640 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 641
 642 #
 643 # Optionally build Perl modules (PL/Perl)
 644 #
 645 AC_MSG_CHECKING([whether to build Perl modules])
 646 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 647 AC_MSG_RESULT([$with_perl])
 648 AC_SUBST(with_perl)
 649
 650 #
 651 # Optionally build Python modules (PL/Python)
 652 #
 653 AC_MSG_CHECKING([whether to build Python modules])
 654 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 655 AC_MSG_RESULT([$with_python])
 656 AC_SUBST(with_python)
 657
 658 #
 659 # GSSAPI
 660 #
 661 AC_MSG_CHECKING([whether to build with GSSAPI support])
 662 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 663 [
 664   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 665   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 666 ])
 667 AC_MSG_RESULT([$with_gssapi])
 668
 669
 670 AC_SUBST(krb_srvtab)
 671
 672
 673 #
 674 # Kerberos configuration parameters
 675 #
 676 PGAC_ARG_REQ(with, krb-srvnam,
 677              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 678              [],
 679              [with_krb_srvnam="postgres"])
 680 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 681                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 682
 683
 684 #
 685 # PAM
 686 #
 687 AC_MSG_CHECKING([whether to build with PAM support])
 688 PGAC_ARG_BOOL(with, pam, no,
 689               [build with PAM support],
 690               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 691 AC_MSG_RESULT([$with_pam])
 692
 693
 694 #
 695 # BSD AUTH
 696 #
 697 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 698 PGAC_ARG_BOOL(with, bsd-auth, no,
 699               [build with BSD Authentication support],
 700               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 701 AC_MSG_RESULT([$with_bsd_auth])
 702
 703
 704 #
 705 # LDAP
 706 #
 707 AC_MSG_CHECKING([whether to build with LDAP support])
 708 PGAC_ARG_BOOL(with, ldap, no,
 709               [build with LDAP support],
 710               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 711 AC_MSG_RESULT([$with_ldap])
 712
 713
 714 #
 715 # Bonjour
 716 #
 717 AC_MSG_CHECKING([whether to build with Bonjour support])
 718 PGAC_ARG_BOOL(with, bonjour, no,
 719               [build with Bonjour support],
 720               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 721 AC_MSG_RESULT([$with_bonjour])
 722
 723
 724 #
 725 # OpenSSL
 726 #
 727 AC_MSG_CHECKING([whether to build with OpenSSL support])
 728 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 729               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 730 AC_MSG_RESULT([$with_openssl])
 731 AC_SUBST(with_openssl)
 732
 733 #
 734 # SELinux
 735 #
 736 AC_MSG_CHECKING([whether to build with SELinux support])
 737 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 738 AC_SUBST(with_selinux)
 739 AC_MSG_RESULT([$with_selinux])
 740
 741 #
 742 # Systemd
 743 #
 744 AC_MSG_CHECKING([whether to build with systemd support])
 745 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 746               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 747 AC_SUBST(with_systemd)
 748 AC_MSG_RESULT([$with_systemd])
 749
 750 #
 751 # Readline
 752 #
 753 PGAC_ARG_BOOL(with, readline, yes,
 754               [do not use GNU Readline nor BSD Libedit for editing])
 755 # readline on MinGW has problems with backslashes in psql and other bugs.
 756 # This is particularly a problem with non-US code pages.
 757 # Therefore disable its use until we understand the cause. 2004-07-20
 758 if test "$PORTNAME" = "win32"; then
 759   if test "$with_readline" = yes; then
 760     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 761     with_readline=no
 762   fi
 763 fi
 764
 765
 766 #
 767 # Prefer libedit
 768 #
 769 PGAC_ARG_BOOL(with, libedit-preferred, no,
 770               [prefer BSD Libedit over GNU Readline])
 771
 772
 773 #
 774 # UUID library
 775 #
 776 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 777 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 778 # UUID library.  More than one of these might be present on a given platform,
 779 # so we make the user say which one she wants.
 780 #
 781 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 782 if test x"$with_uuid" = x"" ; then
 783   with_uuid=no
 784 fi
 785 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 786 if test "$with_ossp_uuid" = yes ; then
 787   with_uuid=ossp
 788 fi
 789
 790 if test "$with_uuid" = bsd ; then
 791   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 792   UUID_EXTRA_OBJS="md5.o sha1.o"
 793 elif test "$with_uuid" = e2fs ; then
 794   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 795   UUID_EXTRA_OBJS="md5.o sha1.o"
 796 elif test "$with_uuid" = ossp ; then
 797   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 798   UUID_EXTRA_OBJS=""
 799 elif test "$with_uuid" = no ; then
 800   UUID_EXTRA_OBJS=""
 801 else
 802   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 803 fi
 804 AC_SUBST(with_uuid)
 805 AC_SUBST(UUID_EXTRA_OBJS)
 806
 807
 808 #
 809 # XML
 810 #
 811 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 812               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 813
 814 if test "$with_libxml" = yes ; then
 815   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 816   if test -n "$XML2_CONFIG"; then
 817     for pgac_option in `$XML2_CONFIG --cflags`; do
 818       case $pgac_option in
 819         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 820       esac
 821     done
 822     for pgac_option in `$XML2_CONFIG --libs`; do
 823       case $pgac_option in
 824         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 825       esac
 826     done
 827   fi
 828 fi
 829
 830 AC_SUBST(with_libxml)
 831
 832 #
 833 # XSLT
 834 #
 835 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 836               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 837
 838
 839 AC_SUBST(with_libxslt)
 840
 841 #
 842 # tzdata
 843 #
 844 PGAC_ARG_REQ(with, system-tzdata,
 845              [DIR], [use system time zone data in DIR])
 846 AC_SUBST(with_system_tzdata)
 847
 848 #
 849 # Zlib
 850 #
 851 PGAC_ARG_BOOL(with, zlib, yes,
 852               [do not use Zlib])
 853 AC_SUBST(with_zlib)
 854
 855 #
 856 # Elf
 857 #
 858
 859 # Assume system is ELF if it predefines __ELF__ as 1,
 860 # otherwise believe host_os based default.
 861 case $host_os in
 862     freebsd1*|freebsd2*) elf=no;;
 863     freebsd3*|freebsd4*) elf=yes;;
 864 esac
 865
 866 AC_EGREP_CPP(yes,
 867 [#if __ELF__
 868   yes
 869 #endif
 870 ],
 871 [ELF_SYS=true],
 872 [if test "X$elf" = "Xyes" ; then
 873   ELF_SYS=true
 874 else
 875   ELF_SYS=
 876 fi])
 877 AC_SUBST(ELF_SYS)
 878
 879 #
 880 # Assignments
 881 #
 882
 883 CPPFLAGS="$CPPFLAGS $INCLUDES"
 884 LDFLAGS="$LDFLAGS $LIBDIRS"
 885
 886 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 887 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 888
 889 PGAC_PROG_LD
 890 AC_SUBST(LD)
 891 AC_SUBST(with_gnu_ld)
 892 AC_PROG_RANLIB
 893 PGAC_CHECK_STRIP
 894 AC_CHECK_TOOL(AR, ar, ar)
 895 if test "$PORTNAME" = "win32"; then
 896   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 897   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 898   AC_CHECK_TOOL(WINDRES, windres, windres)
 899 fi
 900
 901 AC_PROG_INSTALL
 902 # When Autoconf chooses install-sh as install program it tries to generate
 903 # a relative path to it in each makefile where it substitutes it. This clashes
 904 # with our Makefile.global concept. This workaround helps.
 905 case $INSTALL in
 906   *install-sh*) install_bin='';;
 907   *) install_bin=$INSTALL;;
 908 esac
 909 AC_SUBST(install_bin)
 910
 911 AC_PATH_PROG(TAR, tar)
 912 AC_PROG_LN_S
 913 AC_PROG_AWK
 914 AC_PROG_MKDIR_P
 915 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 916 # a relative path to it in each makefile where it substitutes it. This clashes
 917 # with our Makefile.global concept. This workaround helps.
 918 case $MKDIR_P in
 919   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 920 esac
 921
 922 PGAC_PATH_BISON
 923 PGAC_PATH_FLEX
 924
 925 PGAC_PATH_PERL
 926 if test "$with_perl" = yes; then
 927   if test -z "$PERL"; then
 928     AC_MSG_ERROR([Perl not found])
 929   fi
 930   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 931   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 932     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 933 You might have to rebuild your Perl installation.  Refer to the
 934 documentation for details.  Use --without-perl to disable building
 935 PL/Perl.])
 936   fi
 937   PGAC_CHECK_PERL_EMBED_LDFLAGS
 938 fi
 939
 940 if test "$with_python" = yes; then
 941   PGAC_PATH_PYTHON
 942   PGAC_CHECK_PYTHON_EMBED_SETUP
 943 fi
 944
 945 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 946   AC_PATH_PROG(ZIC, zic)
 947   if test -z "$ZIC"; then
 948     AC_MSG_ERROR([
 949 When cross-compiling, either use the option --with-system-tzdata to use
 950 existing time-zone data, or set the environment variable ZIC to a zic
 951 program to use during the build.])
 952   fi
 953 fi
 954
 955 #
 956 # Pthreads
 957 #
 958 # For each platform, we need to know about any special compile and link
 959 # libraries, and whether the normal C function names are thread-safe.
 960 # See the comment at the top of src/port/thread.c for more information.
 961 # WIN32 doesn't need the pthread tests;  it always uses threads
 962 #
 963 # These tests are run before the library-tests, because linking with the
 964 # other libraries can pull in the pthread functions as a side-effect.  We
 965 # want to use the -pthread or similar flags directly, and not rely on
 966 # the side-effects of linking with some other library.
 967 #
 968 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 969 # invocation below is the first one in the script, and autoconf generates
 970 # additional code for that, which must not be inside the if-block. AS_IF
 971 # knows how to do that.
 972 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 973 [ # then
 974 AX_PTHREAD      # set thread flags
 975
 976 # Some platforms use these, so just define them.  They can't hurt if they
 977 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 978 # enables 5-arg getpwuid_r, among other things.
 979 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 980
 981 # Check for *_r functions
 982 _CFLAGS="$CFLAGS"
 983 _LIBS="$LIBS"
 984 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 985 LIBS="$LIBS $PTHREAD_LIBS"
 986
 987 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 988 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 989
 990 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 991
 992 # Do test here with the proper thread flags
 993 PGAC_FUNC_STRERROR_R_INT
 994
 995 CFLAGS="$_CFLAGS"
 996 LIBS="$_LIBS"
 997
 998 ], [ # else
 999 # do not use values from template file
1000 PTHREAD_CFLAGS=
1001 PTHREAD_LIBS=
1002 ]) # fi
1003
1004 AC_SUBST(PTHREAD_CFLAGS)
1005 AC_SUBST(PTHREAD_LIBS)
1006
1007
1008 ##
1009 ## Libraries
1010 ##
1011 ## Most libraries are included only if they demonstrably provide a function
1012 ## we need, but libm is an exception: always include it, because there are
1013 ## too many compilers that play cute optimization games that will break
1014 ## probes for standard functions such as pow().
1015 ##
1016
1017 AC_CHECK_LIB(m, main)
1018 AC_SEARCH_LIBS(setproctitle, util)
1019 AC_SEARCH_LIBS(dlopen, dl)
1020 AC_SEARCH_LIBS(socket, [socket ws2_32])
1021 AC_SEARCH_LIBS(shl_load, dld)
1022 # We only use libld in port/dynloader/aix.c
1023 case $host_os in
1024      aix*)
1025         AC_SEARCH_LIBS(ldopen, ld)
1026         ;;
1027 esac
1028 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1029 AC_SEARCH_LIBS(crypt, crypt)
1030 AC_SEARCH_LIBS(shm_open, rt)
1031 AC_SEARCH_LIBS(shm_unlink, rt)
1032 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1033 # Solaris:
1034 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1035 # Required for thread_test.c on Solaris
1036 AC_SEARCH_LIBS(sched_yield, rt)
1037 # Required for thread_test.c on Solaris 2.5:
1038 # Other ports use it too (HP-UX) so test unconditionally
1039 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1040 # Cygwin:
1041 AC_SEARCH_LIBS(shmget, cygipc)
1042
1043 if test "$with_readline" = yes; then
1044   PGAC_CHECK_READLINE
1045   if test x"$pgac_cv_check_readline" = x"no"; then
1046     AC_MSG_ERROR([readline library not found
1047 If you have readline already installed, see config.log for details on the
1048 failure.  It is possible the compiler isn't looking in the proper directory.
1049 Use --without-readline to disable readline support.])
1050   fi
1051 fi
1052
1053 if test "$with_zlib" = yes; then
1054   AC_CHECK_LIB(z, inflate, [],
1055                [AC_MSG_ERROR([zlib library not found
1056 If you have zlib already installed, see config.log for details on the
1057 failure.  It is possible the compiler isn't looking in the proper directory.
1058 Use --without-zlib to disable zlib support.])])
1059 fi
1060
1061 if test "$enable_spinlocks" = yes; then
1062   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1063 else
1064   AC_MSG_WARN([
1065 *** Not using spinlocks will cause poor performance.])
1066 fi
1067
1068 if test "$enable_atomics" = yes; then
1069   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1070 else
1071   AC_MSG_WARN([
1072 *** Not using atomic operations will cause poor performance.])
1073 fi
1074
1075 if test "$with_gssapi" = yes ; then
1076   if test "$PORTNAME" != "win32"; then
1077     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1078                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1079   else
1080     LIBS="$LIBS -lgssapi32"
1081   fi
1082 fi
1083
1084 if test "$with_openssl" = yes ; then
1085   dnl Order matters!
1086   if test "$PORTNAME" != "win32"; then
1087      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1088      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1089   else
1090      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1091      AC_SEARCH_LIBS(SSL_new, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1092   fi
1093   AC_CHECK_FUNCS([SSL_get_current_compression])
1094   # Functions introduced in OpenSSL 1.1.0. We used to check for
1095   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1096   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1097   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1098   # functions.
1099   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1100   # OpenSSL versions before 1.1.0 required setting callback functions, for
1101   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1102   # function was removed.
1103   AC_CHECK_FUNCS([CRYPTO_lock])
1104 fi
1105
1106 if test "$with_pam" = yes ; then
1107   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1108 fi
1109
1110 if test "$with_libxml" = yes ; then
1111   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1112 fi
1113
1114 if test "$with_libxslt" = yes ; then
1115   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1116 fi
1117
1118 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1119 if test "$with_ldap" = yes ; then
1120   _LIBS="$LIBS"
1121   if test "$PORTNAME" != "win32"; then
1122     AC_CHECK_LIB(ldap, ldap_bind, [],
1123                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1124                  [$EXTRA_LDAP_LIBS])
1125     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1126     if test "$enable_thread_safety" = yes; then
1127       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1128       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1129                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1130                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1131       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1132     else
1133       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1134     fi
1135   else
1136     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1137     LDAP_LIBS_FE="-lwldap32"
1138     LDAP_LIBS_BE="-lwldap32"
1139   fi
1140   LIBS="$_LIBS"
1141 fi
1142 AC_SUBST(LDAP_LIBS_FE)
1143 AC_SUBST(LDAP_LIBS_BE)
1144
1145 # for contrib/sepgsql
1146 if test "$with_selinux" = yes; then
1147   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1148                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1149 fi
1150
1151 # for contrib/uuid-ossp
1152 if test "$with_uuid" = bsd ; then
1153   # On BSD, the UUID functions are in libc
1154   AC_CHECK_FUNC(uuid_to_string,
1155     [UUID_LIBS=""],
1156     [AC_MSG_ERROR([BSD UUID functions are not present])])
1157 elif test "$with_uuid" = e2fs ; then
1158   # On macOS, the UUID functions are in libc
1159   AC_CHECK_FUNC(uuid_generate,
1160     [UUID_LIBS=""],
1161     [AC_CHECK_LIB(uuid, uuid_generate,
1162       [UUID_LIBS="-luuid"],
1163       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1164 elif test "$with_uuid" = ossp ; then
1165   AC_CHECK_LIB(ossp-uuid, uuid_export,
1166     [UUID_LIBS="-lossp-uuid"],
1167     [AC_CHECK_LIB(uuid, uuid_export,
1168       [UUID_LIBS="-luuid"],
1169       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1170 fi
1171 AC_SUBST(UUID_LIBS)
1172
1173
1174 ##
1175 ## Header files
1176 ##
1177
1178 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1179
1180 # On BSD, test for net/if.h will fail unless sys/socket.h
1181 # is included first.
1182 AC_CHECK_HEADERS(net/if.h, [], [],
1183 [AC_INCLUDES_DEFAULT
1184 #include <sys/socket.h>
1185 ])
1186
1187 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1188 # is included first.
1189 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1190 [AC_INCLUDES_DEFAULT
1191 #include <sys/param.h>
1192 ])
1193
1194 # At least on IRIX, test for netinet/tcp.h will fail unless
1195 # netinet/in.h is included first.
1196 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1197 [AC_INCLUDES_DEFAULT
1198 #include <netinet/in.h>
1199 ])
1200
1201 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1202   AC_CHECK_HEADERS(readline/readline.h, [],
1203         [AC_CHECK_HEADERS(readline.h, [],
1204                 [AC_MSG_ERROR([readline header not found
1205 If you have readline already installed, see config.log for details on the
1206 failure.  It is possible the compiler isn't looking in the proper directory.
1207 Use --without-readline to disable readline support.])])])
1208   AC_CHECK_HEADERS(readline/history.h, [],
1209         [AC_CHECK_HEADERS(history.h, [],
1210                 [AC_MSG_ERROR([history header not found
1211 If you have readline already installed, see config.log for details on the
1212 failure.  It is possible the compiler isn't looking in the proper directory.
1213 Use --without-readline to disable readline support.])])])
1214 fi
1215
1216 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1217 # Some installations of libedit usurp /usr/include/readline/, which seems
1218 # bad practice, since in combined installations readline will have its headers
1219 # there.  We might have to resort to AC_EGREP checks to make sure we found
1220 # the proper header...
1221   AC_CHECK_HEADERS(editline/readline.h, [],
1222         [AC_CHECK_HEADERS(readline.h, [],
1223                 [AC_CHECK_HEADERS(readline/readline.h, [],
1224                         [AC_MSG_ERROR([readline header not found
1225 If you have libedit already installed, see config.log for details on the
1226 failure.  It is possible the compiler isn't looking in the proper directory.
1227 Use --without-readline to disable libedit support.])])])])
1228 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1229 # not be there at all.  Hence, don't complain if not found.  We must check
1230 # though, since in yet other versions it is an independent header.
1231   AC_CHECK_HEADERS(editline/history.h, [],
1232         [AC_CHECK_HEADERS(history.h, [],
1233                 [AC_CHECK_HEADERS(readline/history.h)])])
1234 fi
1235
1236 if test "$with_zlib" = yes; then
1237   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1238 If you have zlib already installed, see config.log for details on the
1239 failure.  It is possible the compiler isn't looking in the proper directory.
1240 Use --without-zlib to disable zlib support.])])
1241 fi
1242
1243 if test "$with_gssapi" = yes ; then
1244   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1245         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1246 fi
1247
1248 if test "$with_openssl" = yes ; then
1249   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1250   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1251 fi
1252
1253 if test "$with_pam" = yes ; then
1254   AC_CHECK_HEADERS(security/pam_appl.h, [],
1255                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1256                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1257 fi
1258
1259 if test "$with_bsd_auth" = yes ; then
1260   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1261 fi
1262
1263 if test "$with_systemd" = yes ; then
1264   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1265 fi
1266
1267 if test "$with_libxml" = yes ; then
1268   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1269 fi
1270
1271 if test "$with_libxslt" = yes ; then
1272   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1273 fi
1274
1275 if test "$with_ldap" = yes ; then
1276   if test "$PORTNAME" != "win32"; then
1277      AC_CHECK_HEADERS(ldap.h, [],
1278                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1279      PGAC_LDAP_SAFE
1280   else
1281      AC_CHECK_HEADERS(winldap.h, [],
1282                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1283                       [AC_INCLUDES_DEFAULT
1284 #include <windows.h>
1285                       ])
1286   fi
1287 fi
1288
1289 if test "$with_bonjour" = yes ; then
1290   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1291 fi
1292
1293 # for contrib/uuid-ossp
1294 if test "$with_uuid" = bsd ; then
1295   AC_CHECK_HEADERS(uuid.h,
1296     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1297       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1298     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1299 elif test "$with_uuid" = e2fs ; then
1300   AC_CHECK_HEADERS(uuid/uuid.h,
1301     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1302       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1303     [AC_CHECK_HEADERS(uuid.h,
1304       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1305         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1306       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1307 elif test "$with_uuid" = ossp ; then
1308   AC_CHECK_HEADERS(ossp/uuid.h,
1309     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1310       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1311     [AC_CHECK_HEADERS(uuid.h,
1312       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1313         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1314       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1315 fi
1316
1317 if test "$PORTNAME" = "win32" ; then
1318    AC_CHECK_HEADERS(crtdefs.h)
1319 fi
1320
1321 ##
1322 ## Types, structures, compiler characteristics
1323 ##
1324
1325 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1326 AC_C_BIGENDIAN
1327 AC_C_INLINE
1328 PGAC_PRINTF_ARCHETYPE
1329 AC_C_FLEXIBLE_ARRAY_MEMBER
1330 PGAC_C_SIGNED
1331 PGAC_C_FUNCNAME_SUPPORT
1332 PGAC_C_STATIC_ASSERT
1333 PGAC_C_TYPES_COMPATIBLE
1334 PGAC_C_BUILTIN_BSWAP32
1335 PGAC_C_BUILTIN_BSWAP64
1336 PGAC_C_BUILTIN_CONSTANT_P
1337 PGAC_C_BUILTIN_UNREACHABLE
1338 PGAC_C_COMPUTED_GOTO
1339 PGAC_C_VA_ARGS
1340 PGAC_STRUCT_TIMEZONE
1341 PGAC_UNION_SEMUN
1342 PGAC_STRUCT_SOCKADDR_UN
1343 PGAC_STRUCT_SOCKADDR_STORAGE
1344 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1345 PGAC_STRUCT_ADDRINFO
1346 AC_TYPE_INTPTR_T
1347 AC_TYPE_UINTPTR_T
1348 AC_TYPE_LONG_LONG_INT
1349
1350 PGAC_TYPE_LOCALE_T
1351
1352 AC_CHECK_TYPES([struct cmsgcred], [], [],
1353 [#include <sys/socket.h>
1354 #include <sys/param.h>
1355 #ifdef HAVE_SYS_UCRED_H
1356 #include <sys/ucred.h>
1357 #endif])
1358
1359 AC_CHECK_TYPES([struct option], [], [],
1360 [#ifdef HAVE_GETOPT_H
1361 #include <getopt.h>
1362 #endif])
1363
1364 if test "$with_zlib" = yes; then
1365   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1366   # did not).  While we could work around the lack of z_streamp, it
1367   # seems unwise to encourage people to use such old zlib versions...
1368   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1369 Use --without-zlib to disable zlib support.])],
1370                 [#include <zlib.h>])
1371 fi
1372
1373 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1374 case $host_cpu in
1375   ppc*|powerpc*)
1376     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1377     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1378         [int a = 0; int *p = &a; int r;
1379          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1380         [pgac_cv_have_ppc_mutex_hint=yes],
1381         [pgac_cv_have_ppc_mutex_hint=no])
1382     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1383     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1384         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1385     fi
1386   ;;
1387 esac
1388
1389 # Check largefile support.  You might think this is a system service not a
1390 # compiler characteristic, but you'd be wrong.  We must check this before
1391 # probing existence of related functions such as fseeko, since the largefile
1392 # defines can affect what is generated for that.
1393 if test "$PORTNAME" != "win32"; then
1394    AC_SYS_LARGEFILE
1395    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1396    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1397    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1398    dnl versions where the feature actually works, it's on by default anyway.
1399    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1400 fi
1401
1402 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1403 AC_CHECK_SIZEOF([off_t])
1404
1405 # If we don't have largefile support, can't handle segsize >= 2GB.
1406 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1407    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1408 fi
1409
1410
1411 ##
1412 ## Functions, global variables
1413 ##
1414
1415 PGAC_VAR_INT_TIMEZONE
1416 AC_FUNC_ACCEPT_ARGTYPES
1417 PGAC_FUNC_GETTIMEOFDAY_1ARG
1418 PGAC_FUNC_WCSTOMBS_L
1419
1420 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1421 # symbols that that library has no business exposing to the world.  Pending
1422 # acquisition of a clue by those developers, ignore libedit (including its
1423 # possible alias of libreadline) while checking for everything else.
1424 LIBS_including_readline="$LIBS"
1425 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1426
1427 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1428
1429 AC_REPLACE_FUNCS(fseeko)
1430 case $host_os in
1431         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1432         # Mingw uses macros to access Win32 API calls
1433         netbsd*|mingw*)
1434                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1435                 ac_cv_func_fseeko=yes;;
1436         *)
1437                 AC_FUNC_FSEEKO;;
1438 esac
1439
1440 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1441 # by calling it, 2009-04-02
1442 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1443 if test "$PORTNAME" != "solaris"; then
1444 AC_CHECK_FUNCS(posix_fadvise)
1445 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1446 fi
1447
1448 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1449 AC_CHECK_DECLS([strlcat, strlcpy])
1450 # This is probably only present on macOS, but may as well check always
1451 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1452
1453 HAVE_IPV6=no
1454 AC_CHECK_TYPE([struct sockaddr_in6],
1455         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1456          HAVE_IPV6=yes],
1457         [],
1458 [$ac_includes_default
1459 #include <netinet/in.h>])
1460 AC_SUBST(HAVE_IPV6)
1461
1462 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1463 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1464 [#include <machine/vmparam.h>
1465 #include <sys/exec.h>
1466 ],
1467 [PS_STRINGS->ps_nargvstr = 1;
1468 PS_STRINGS->ps_argvstr = "foo";])],
1469 [pgac_cv_var_PS_STRINGS=yes],
1470 [pgac_cv_var_PS_STRINGS=no])])
1471 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1472   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1473 fi
1474
1475
1476 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1477 # is missing.  Yes, there are machines that have only one.  We may
1478 # also decide to use snprintf.c if snprintf() is present but does not
1479 # have all the features we need --- see below.
1480
1481 if test "$PORTNAME" = "win32"; then
1482   # Win32 gets snprintf.c built unconditionally.
1483   #
1484   # To properly translate all NLS languages strings, we must support the
1485   # *printf() %$ format, which allows *printf() arguments to be selected
1486   # by position in the translated string.
1487   #
1488   # libintl versions < 0.13 use the native *printf() functions, and Win32
1489   # *printf() doesn't understand %$, so we must use our /port versions,
1490   # which do understand %$. libintl versions >= 0.13 include their own
1491   # *printf versions on Win32.  The libintl 0.13 release note text is:
1492   #
1493   #   C format strings with positions, as they arise when a translator
1494   #   needs to reorder a sentence, are now supported on all platforms.
1495   #   On those few platforms (NetBSD and Woe32) for which the native
1496   #   printf()/fprintf()/... functions don't support such format
1497   #   strings, replacements are provided through <libintl.h>.
1498   #
1499   # We could use libintl >= 0.13's *printf() if we were sure that we had
1500   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1501   # to guarantee that, it is best to just use our own, so we are sure to
1502   # get %$ support. In include/port.h we disable the *printf() macros
1503   # that might have been defined by libintl.
1504   #
1505   # We do this unconditionally whether NLS is used or not so we are sure
1506   # that all Win32 libraries and binaries behave the same.
1507   pgac_need_repl_snprintf=yes
1508 else
1509   pgac_need_repl_snprintf=no
1510   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1511   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1512 fi
1513
1514
1515 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1516 # include/c.h will provide declarations.  Note this is a separate test
1517 # from whether the functions exist in the C library --- there are
1518 # systems that have the functions but don't bother to declare them :-(
1519
1520 AC_CHECK_DECLS([snprintf, vsnprintf])
1521
1522
1523 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1524 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1525 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1526 #include <math.h>
1527 double glob_double;
1528 ],
1529 [return isinf(glob_double) ? 0 : 1;])],
1530 [ac_cv_func_isinf=yes],
1531 [ac_cv_func_isinf=no])])
1532
1533 if test $ac_cv_func_isinf = yes ; then
1534   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1535 else
1536   AC_LIBOBJ(isinf)
1537   # Look for a way to implement a substitute for isinf()
1538   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1539 fi
1540
1541 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1542
1543 case $host_os in
1544
1545         # Windows uses a specialised env handler
1546         # and doesn't need a replacement getpeereid because it doesn't use
1547         # Unix sockets.
1548         mingw*)
1549                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1550                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1551                 ac_cv_func_unsetenv=yes
1552                 ac_cv_func_getpeereid=yes;;
1553         *)
1554                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1555                 ;;
1556 esac
1557
1558 # System's version of getaddrinfo(), if any, may be used only if we found
1559 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1560 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1561 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1562    test "$PORTNAME" != "win32"; then
1563   AC_REPLACE_FUNCS([getaddrinfo])
1564 else
1565   AC_LIBOBJ(getaddrinfo)
1566 fi
1567
1568 # Similarly, use system's getopt_long() only if system provides struct option.
1569 if test x"$ac_cv_type_struct_option" = xyes ; then
1570   AC_REPLACE_FUNCS([getopt_long])
1571 else
1572   AC_LIBOBJ(getopt_long)
1573 fi
1574
1575 # Solaris' getopt() doesn't do what we want for long options, so always use
1576 # our version on that platform.
1577 if test "$PORTNAME" = "solaris"; then
1578   AC_LIBOBJ(getopt)
1579 fi
1580
1581 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1582 # so always use our version on Windows.
1583 if test "$PORTNAME" = "win32"; then
1584   AC_LIBOBJ(getopt)
1585   AC_LIBOBJ(getopt_long)
1586 fi
1587
1588 # Win32 (really MinGW) support
1589 if test "$PORTNAME" = "win32"; then
1590   AC_REPLACE_FUNCS(gettimeofday)
1591   AC_LIBOBJ(dirmod)
1592   AC_LIBOBJ(kill)
1593   AC_LIBOBJ(open)
1594   AC_LIBOBJ(system)
1595   AC_LIBOBJ(win32env)
1596   AC_LIBOBJ(win32error)
1597   AC_LIBOBJ(win32security)
1598   AC_LIBOBJ(win32setlocale)
1599   AC_DEFINE([HAVE_SYMLINK], 1,
1600             [Define to 1 if you have the `symlink' function.])
1601   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1602 #define WIN32_LEAN_AND_MEAN
1603 #include <windows.h>
1604 #include <string.h>
1605 #include <dbghelp.h>])
1606 fi
1607 if test x"$pgac_minidump_type" = x"yes" ; then
1608   AC_SUBST(have_win32_dbghelp,yes)
1609 else
1610   AC_SUBST(have_win32_dbghelp,no)
1611 fi
1612
1613 # Cygwin needs only a bit of that
1614 if test "$PORTNAME" = "cygwin"; then
1615   AC_LIBOBJ(dirmod)
1616 fi
1617
1618 AC_CHECK_DECLS([sys_siglist], [], [],
1619 [#include <signal.h>
1620 /* NetBSD declares sys_siglist in unistd.h.  */
1621 #ifdef HAVE_UNISTD_H
1622 # include <unistd.h>
1623 #endif
1624 ])
1625
1626 AC_CHECK_FUNC(syslog,
1627               [AC_CHECK_HEADER(syslog.h,
1628                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1629
1630 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1631 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1632   [extern int opterr; opterr = 1;])],
1633   [pgac_cv_var_int_opterr=yes],
1634   [pgac_cv_var_int_opterr=no])])
1635 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1636   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1637 fi
1638
1639 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1640 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1641   [extern int optreset; optreset = 1;])],
1642   [pgac_cv_var_int_optreset=yes],
1643   [pgac_cv_var_int_optreset=no])])
1644 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1645   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1646 fi
1647
1648 AC_CHECK_FUNCS([strtoll strtoq], [break])
1649 AC_CHECK_FUNCS([strtoull strtouq], [break])
1650
1651 if test "$with_icu" = yes; then
1652   # ICU functions are macros, so we need to do this the long way.
1653
1654   # ucol_strcollUTF8() appeared in ICU 50.
1655   AC_CACHE_CHECK([for ucol_strcollUTF8], [pgac_cv_func_ucol_strcollUTF8],
1656 [ac_save_CPPFLAGS=$CPPFLAGS
1657 CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1658 ac_save_LIBS=$LIBS
1659 LIBS="$ICU_LIBS $LIBS"
1660 AC_LINK_IFELSE([AC_LANG_PROGRAM(
1661 [#include <unicode/ucol.h>
1662 ],
1663 [ucol_strcollUTF8(NULL, NULL, 0, NULL, 0, NULL);])],
1664 [pgac_cv_func_ucol_strcollUTF8=yes],
1665 [pgac_cv_func_ucol_strcollUTF8=no])
1666 CPPFLAGS=$ac_save_CPPFLAGS
1667 LIBS=$ac_save_LIBS])
1668   if test "$pgac_cv_func_ucol_strcollUTF8" = yes ; then
1669     AC_DEFINE([HAVE_UCOL_STRCOLLUTF8], 1, [Define to 1 if you have the `ucol_strcollUTF8' function.])
1670   fi
1671 fi
1672
1673 # Lastly, restore full LIBS list and check for readline/libedit symbols
1674 LIBS="$LIBS_including_readline"
1675
1676 if test "$with_readline" = yes; then
1677   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1678   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1679   AC_CHECK_FUNCS([append_history history_truncate_file])
1680 fi
1681
1682
1683 # This test makes sure that run tests work at all.  Sometimes a shared
1684 # library is found by the linker, but the runtime linker can't find it.
1685 # This check should come after all modifications of compiler or linker
1686 # variables, and before any other run tests.
1687 AC_MSG_CHECKING([test program])
1688 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1689 [AC_MSG_RESULT(ok)],
1690 [AC_MSG_RESULT(failed)
1691 AC_MSG_ERROR([[
1692 Could not execute a simple test program.  This may be a problem
1693 related to locating shared libraries.  Check the file 'config.log'
1694 for the exact reason.]])],
1695 [AC_MSG_RESULT([cross-compiling])])
1696
1697 # --------------------
1698 # Run tests below here
1699 # --------------------
1700
1701 # Force use of our snprintf if system's doesn't do arg control
1702 # See comment above at snprintf test for details.
1703 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1704   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1705   if test $pgac_cv_snprintf_arg_control != yes ; then
1706     pgac_need_repl_snprintf=yes
1707   fi
1708 fi
1709
1710
1711 dnl Check to see if we have a working 64-bit integer type.
1712 dnl This breaks down into two steps:
1713 dnl (1) figure out if the compiler has a 64-bit int type with working
1714 dnl arithmetic, and if so
1715 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1716 dnl snprintf is the only library routine we really need for int8 support.)
1717 dnl It's entirely possible to have a compiler that handles a 64-bit type
1718 dnl when the C library doesn't; this is fairly likely when using gcc on
1719 dnl an older platform, for example.
1720 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1721 dnl we force our own version of snprintf() to be used instead.
1722 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1723
1724 dnl As of Postgres 8.4, we no longer support compilers without a working
1725 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1726
1727 PGAC_TYPE_64BIT_INT([long int])
1728
1729 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1730   pg_int64_type="long int"
1731 else
1732   PGAC_TYPE_64BIT_INT([long long int])
1733   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1734     pg_int64_type="long long int"
1735   else
1736     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1737   fi
1738 fi
1739
1740 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1741   [Define to the name of a signed 64-bit integer type.])
1742
1743 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1744
1745 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1746   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1747 #define INT64CONST(x)  x##LL
1748 long long int foo = INT64CONST(0x1234567890123456);
1749 ])],
1750         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1751         [])
1752 fi
1753
1754
1755 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1756 # we found we need to use "long long int", better check.  We cope with
1757 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1758 # work, fall back to our own snprintf emulation (which we know uses %lld).
1759
1760 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1761   if test $pgac_need_repl_snprintf = no; then
1762     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1763     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1764       # Force usage of our own snprintf, since system snprintf is broken
1765       pgac_need_repl_snprintf=yes
1766       LONG_LONG_INT_MODIFIER='ll'
1767     fi
1768   else
1769     # Here if we previously decided we needed to use our own snprintf
1770     LONG_LONG_INT_MODIFIER='ll'
1771   fi
1772 else
1773   # Here if we are not using 'long long int' at all
1774   LONG_LONG_INT_MODIFIER='l'
1775 fi
1776
1777 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1778
1779 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1780                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1781
1782 # Also force use of our snprintf if the system's doesn't support the %z flag.
1783 if test "$pgac_need_repl_snprintf" = no; then
1784   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1785   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1786     pgac_need_repl_snprintf=yes
1787   fi
1788 fi
1789
1790 # Now we have checked all the reasons to replace snprintf
1791 if test $pgac_need_repl_snprintf = yes; then
1792   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1793   AC_LIBOBJ(snprintf)
1794 fi
1795
1796 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1797 AC_CHECK_SIZEOF([void *])
1798 AC_CHECK_SIZEOF([size_t])
1799 AC_CHECK_SIZEOF([long])
1800
1801 # Decide whether float4 is passed by value: user-selectable, enabled by default
1802 AC_MSG_CHECKING([whether to build with float4 passed by value])
1803 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1804               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1805                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1806                float4passbyval=true],
1807               [float4passbyval=false])
1808 AC_MSG_RESULT([$enable_float4_byval])
1809 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1810
1811 # Decide whether float8 is passed by value.
1812 # Note: this setting also controls int8 and related types such as timestamp.
1813 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1814 # If not, trying to select it is an error.
1815 AC_MSG_CHECKING([whether to build with float8 passed by value])
1816 if test $ac_cv_sizeof_void_p -ge 8 ; then
1817   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1818 else
1819   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1820   if test "$enable_float8_byval" = yes ; then
1821     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1822   fi
1823 fi
1824 if test "$enable_float8_byval" = yes ; then
1825   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1826             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1827   float8passbyval=true
1828 else
1829   float8passbyval=false
1830 fi
1831 AC_MSG_RESULT([$enable_float8_byval])
1832 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1833
1834 # Determine memory alignment requirements for the basic C data types.
1835
1836 AC_CHECK_ALIGNOF(short)
1837 AC_CHECK_ALIGNOF(int)
1838 AC_CHECK_ALIGNOF(long)
1839 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1840   AC_CHECK_ALIGNOF(long long int)
1841 fi
1842 AC_CHECK_ALIGNOF(double)
1843
1844 # Compute maximum alignment of any basic type.
1845 # We assume long's alignment is at least as strong as char, short, or int;
1846 # but we must check long long (if it exists) and double.
1847
1848 MAX_ALIGNOF=$ac_cv_alignof_long
1849 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1850   MAX_ALIGNOF=$ac_cv_alignof_double
1851 fi
1852 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1853   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1854 fi
1855 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1856
1857
1858 # Some platforms predefine the types int8, int16, etc.  Only check
1859 # a (hopefully) representative subset.
1860 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1861 [#include <stdio.h>])
1862
1863 # Check for extensions offering the integer scalar type __int128.
1864 PGAC_TYPE_128BIT_INT
1865
1866 # Check for various atomic operations now that we have checked how to declare
1867 # 64bit integers.
1868 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1869 PGAC_HAVE_GCC__SYNC_INT32_TAS
1870 PGAC_HAVE_GCC__SYNC_INT32_CAS
1871 PGAC_HAVE_GCC__SYNC_INT64_CAS
1872 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1873 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1874
1875
1876 # Check for x86 cpuid instruction
1877 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1878 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1879   [[unsigned int exx[4] = {0, 0, 0, 0};
1880   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1881   ]])],
1882   [pgac_cv__get_cpuid="yes"],
1883   [pgac_cv__get_cpuid="no"])])
1884 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1885   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1886 fi
1887
1888 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1889 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1890   [[unsigned int exx[4] = {0, 0, 0, 0};
1891   __get_cpuid(exx[0], 1);
1892   ]])],
1893   [pgac_cv__cpuid="yes"],
1894   [pgac_cv__cpuid="no"])])
1895 if test x"$pgac_cv__cpuid" = x"yes"; then
1896   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1897 fi
1898
1899 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1900 #
1901 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1902 # with the default compiler flags. If not, check if adding the -msse4.2
1903 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1904 PGAC_SSE42_CRC32_INTRINSICS([])
1905 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1906   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1907 fi
1908 AC_SUBST(CFLAGS_SSE42)
1909
1910 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1911 # define __SSE4_2__ in that case.
1912 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1913 #ifndef __SSE4_2__
1914 #error __SSE4_2__ not defined
1915 #endif
1916 ])], [SSE4_2_TARGETED=1])
1917
1918 # Select CRC-32C implementation.
1919 #
1920 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1921 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1922 # a processor, but we can nevertheless produce code that uses the SSE
1923 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1924 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1925 # by the processor we're running on.
1926 #
1927 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1928 # in the template or configure command line.
1929 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1930   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1931     USE_SSE42_CRC32C=1
1932   else
1933     # the CPUID instruction is needed for the runtime check.
1934     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1935       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1936     else
1937       # fall back to slicing-by-8 algorithm which doesn't require any special
1938       # CPU support.
1939       USE_SLICING_BY_8_CRC32C=1
1940     fi
1941   fi
1942 fi
1943
1944 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1945 AC_MSG_CHECKING([which CRC-32C implementation to use])
1946 if test x"$USE_SSE42_CRC32C" = x"1"; then
1947   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1948   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1949   AC_MSG_RESULT(SSE 4.2)
1950 else
1951   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1952     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1953     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1954     AC_MSG_RESULT(SSE 4.2 with runtime check)
1955   else
1956     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1957     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1958     AC_MSG_RESULT(slicing-by-8)
1959   fi
1960 fi
1961 AC_SUBST(PG_CRC32C_OBJS)
1962
1963
1964 # Select semaphore implementation type.
1965 if test "$PORTNAME" != "win32"; then
1966   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1967     # Need sem_open for this
1968     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1969   fi
1970   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1971     # Need sem_init for this
1972     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1973   fi
1974   AC_MSG_CHECKING([which semaphore API to use])
1975   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1976     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1977     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1978     sematype="named POSIX"
1979   else
1980     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1981       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1982       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1983       sematype="unnamed POSIX"
1984     else
1985       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1986       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1987       sematype="System V"
1988     fi
1989   fi
1990   AC_MSG_RESULT([$sematype])
1991 else
1992   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1993   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1994 fi
1995
1996
1997 # Select shared-memory implementation type.
1998 if test "$PORTNAME" != "win32"; then
1999   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2000   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2001 else
2002   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2003   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2004 fi
2005
2006 # Select random number source
2007 #
2008 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2009 # in the template or configure command line.
2010
2011 # If not selected manually, try to select a source automatically.
2012 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2013   if test x"$with_openssl" = x"yes" ; then
2014     USE_OPENSSL_RANDOM=1
2015   elif test "$PORTNAME" = "win32" ; then
2016     USE_WIN32_RANDOM=1
2017   else
2018     AC_CHECK_FILE([/dev/urandom], [], [])
2019
2020     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2021       USE_DEV_URANDOM=1
2022     fi
2023   fi
2024 fi
2025
2026 AC_MSG_CHECKING([which random number source to use])
2027 if test "$enable_strong_random" = yes ; then
2028   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2029     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2030     AC_MSG_RESULT([OpenSSL])
2031   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2032     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2033     AC_MSG_RESULT([Windows native])
2034   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2035     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2036     AC_MSG_RESULT([/dev/urandom])
2037   else
2038     AC_MSG_ERROR([
2039 no source of strong random numbers was found
2040 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2041 for authentication protocols. You can use --disable-strong-random to use a
2042 built-in pseudo random number generator, but that may be insecure.])
2043   fi
2044   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2045 else
2046     AC_MSG_RESULT([weak builtin PRNG])
2047     AC_MSG_WARN([
2048 *** Not using a strong random number source may be insecure.])
2049 fi
2050
2051 # If not set in template file, set bytes to use libc memset()
2052 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2053   MEMSET_LOOP_LIMIT=1024
2054 fi
2055 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2056
2057
2058 if test "$enable_nls" = yes ; then
2059   PGAC_CHECK_GETTEXT
2060 fi
2061
2062 # Check for Tcl configuration script tclConfig.sh
2063 if test "$with_tcl" = yes; then
2064     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2065     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2066                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2067     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2068     if test "$TCL_SHARED_BUILD" != 1; then
2069       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2070 Use --without-tcl to disable building PL/Tcl.])
2071     fi
2072     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2073     ac_save_CPPFLAGS=$CPPFLAGS
2074     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2075     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2076     CPPFLAGS=$ac_save_CPPFLAGS
2077 fi
2078
2079 # check for <perl.h>
2080 if test "$with_perl" = yes; then
2081   ac_save_CPPFLAGS=$CPPFLAGS
2082   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2083   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2084                   [#include <EXTERN.h>])
2085   # While we're at it, check that we can link to libperl.
2086   # On most platforms, if perl.h is there then libperl.so will be too, but at
2087   # this writing Debian packages them separately.  There is no known reason to
2088   # waste cycles on separate probes for the Tcl or Python libraries, though.
2089   pgac_save_LIBS=$LIBS
2090   LIBS="$perl_embed_ldflags"
2091   AC_MSG_CHECKING([for libperl])
2092   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2093 #include <EXTERN.h>
2094 #include <perl.h>
2095 ],  [perl_alloc();])],
2096     [AC_MSG_RESULT(yes)],
2097     [AC_MSG_RESULT(no)
2098      AC_MSG_ERROR([libperl library is required for Perl])])
2099   LIBS=$pgac_save_LIBS
2100   CPPFLAGS=$ac_save_CPPFLAGS
2101 fi
2102
2103 # check for <Python.h>
2104 if test "$with_python" = yes; then
2105   ac_save_CPPFLAGS=$CPPFLAGS
2106   CPPFLAGS="$python_includespec $CPPFLAGS"
2107   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2108   CPPFLAGS=$ac_save_CPPFLAGS
2109 fi
2110
2111 #
2112 # Check for DocBook and tools
2113 #
2114 PGAC_PROG_NSGMLS
2115 PGAC_PROG_JADE
2116 PGAC_CHECK_DOCBOOK(4.2)
2117 PGAC_PATH_DOCBOOK_STYLESHEETS
2118 PGAC_PATH_COLLATEINDEX
2119 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2120 AC_CHECK_PROGS(XMLLINT, xmllint)
2121 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2122 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2123
2124 #
2125 # Check for test tools
2126 #
2127 if test "$enable_tap_tests" = yes; then
2128   AC_CHECK_PROGS(PROVE, prove)
2129   if test -z "$PROVE"; then
2130     AC_MSG_ERROR([prove not found])
2131   fi
2132   if test -z "$PERL"; then
2133     AC_MSG_ERROR([Perl not found])
2134   fi
2135 fi
2136
2137 # Thread testing
2138
2139 # We have to run the thread test near the end so we have all our symbols
2140 # defined.  Cross compiling throws a warning.
2141 #
2142 if test "$enable_thread_safety" = yes; then
2143 if test "$PORTNAME" != "win32"
2144 then
2145 AC_MSG_CHECKING([thread safety of required library functions])
2146
2147 _CFLAGS="$CFLAGS"
2148 _LIBS="$LIBS"
2149 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2150 LIBS="$LIBS $PTHREAD_LIBS"
2151 AC_RUN_IFELSE(
2152   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2153   [AC_MSG_RESULT(yes)],
2154   [AC_MSG_RESULT(no)
2155   AC_MSG_ERROR([thread test program failed
2156 This platform is not thread-safe.  Check the file 'config.log' or compile
2157 and run src/test/thread/thread_test for the exact reason.
2158 Use --disable-thread-safety to disable thread safety.])],
2159   [AC_MSG_RESULT(maybe)
2160   AC_MSG_WARN([
2161 *** Skipping thread test program because of cross-compile build.
2162 *** Run the program in src/test/thread on the target machine.
2163 ])])
2164 CFLAGS="$_CFLAGS"
2165 LIBS="$_LIBS"
2166 else
2167 AC_MSG_WARN([*** skipping thread test on Win32])
2168 fi
2169 fi
2170
2171 # If compiler will take -Wl,--as-needed (or various platform-specific
2172 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2173 # trying to filter LIBS to the minimum for each executable.
2174 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2175 # libreadline; therefore we postpone testing it until we know what library
2176 # dependencies readline has.  The test code will try to link with $LIBS.
2177 if test "$with_readline" = yes; then
2178   link_test_func=readline
2179 else
2180   link_test_func=exit
2181 fi
2182
2183 if test "$PORTNAME" = "darwin"; then
2184   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2185 elif test "$PORTNAME" = "openbsd"; then
2186   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2187 else
2188   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2189 fi
2190
2191 # Create compiler version string
2192 if test x"$GCC" = x"yes" ; then
2193   cc_string=`${CC} --version | sed q`
2194   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2195 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2196   cc_string=`${CC} -V 2>&1 | sed q`
2197 else
2198   cc_string=$CC
2199 fi
2200
2201 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2202                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2203                    [A string containing the version number, platform, and C compiler])
2204
2205 # Supply a numeric version string for use by 3rd party add-ons
2206 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2207 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2208 tr '.' '        ' |
2209 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2210 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2211 AC_SUBST(PG_VERSION_NUM)
2212
2213
2214 # Begin output steps
2215
2216 AC_MSG_NOTICE([using compiler=$cc_string])
2217 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2218 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2219 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2220
2221 # prepare build tree if outside source tree
2222 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2223 # Note 2: /bin/pwd might be better than shell's built-in at getting
2224 #         a symlink-free name.
2225 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2226   vpath_build=no
2227 else
2228   vpath_build=yes
2229   if test "$no_create" != yes; then
2230     _AS_ECHO_N([preparing build tree... ])
2231     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2232     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2233       || AC_MSG_ERROR(failed)
2234     AC_MSG_RESULT(done)
2235   fi
2236 fi
2237 AC_SUBST(vpath_build)
2238
2239
2240 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2241
2242 AC_CONFIG_LINKS([
2243   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2244   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2245   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2246   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2247   src/include/pg_config_os.h:src/include/port/${template}.h
2248   src/Makefile.port:src/makefiles/Makefile.${template}
2249 ])
2250
2251 if test "$PORTNAME" = "win32"; then
2252 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2253 # Links sometimes fail undetected on Mingw -
2254 # so here we detect it and warn the user
2255 for FILE in $CONFIG_LINKS
2256  do
2257         # test -e works for symlinks in the MinGW console
2258         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2259  done
2260 ])
2261 fi
2262
2263 AC_CONFIG_HEADERS([src/include/pg_config.h],
2264 [
2265 # Update timestamp for pg_config.h (see Makefile.global)
2266 echo >src/include/stamp-h
2267 ])
2268
2269 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2270 [
2271 # Update timestamp for pg_config_ext.h (see Makefile.global)
2272 echo >src/include/stamp-ext-h
2273 ])
2274
2275 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2276                   [echo >src/interfaces/ecpg/include/stamp-h])
2277
2278 AC_OUTPUT