granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr,
  72                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  73                     [--enable-layout=*|\'--enable-layout=*])
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_SETIFNULL(CC, `$apr_config --cc`)
  80 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  81 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  82 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  83 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  84 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  85 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  86 APR_BINDIR=`$apr_config --bindir`
  87 APR_INCLUDEDIR=`$apr_config --includedir`
  88
  89 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  90
  91 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  92
  93 if test "$apu_found" = "no"; then
  94   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  95 fi
  96
  97 if test "$apu_found" = "reconfig"; then
  98   APR_SUBDIR_CONFIG(srclib/apr-util,
  99                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 100                     [--enable-layout=*|\'--enable-layout=*])
 101   dnl We must be the last to build and the first to be cleaned
 102   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 103   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 104 fi
 105
 106 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 107 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 108 APU_BINDIR=`$apu_config --bindir`
 109 APU_INCLUDEDIR=`$apu_config --includedir`
 110
 111 dnl In case we picked up CC and CPP from APR, get that info into the
 112 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 113 dnl PCRE and for our config tests will be whatever PCRE determines.
 114 AC_PROG_CC
 115 AC_PROG_CPP
 116
 117 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 118
 119 APR_SUBDIR_CONFIG(srclib/pcre,
 120                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 121
 122 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 123
 124 dnl Absolute source/build directory
 125 abs_srcdir=`(cd $srcdir && pwd)`
 126 abs_builddir=`pwd`
 127
 128 dnl If the source dir is not equal to the build dir,
 129 dnl then we are running in VPATH mode.
 130
 131 APR_ADDTO(INCLUDES, [-I.])
 132
 133 if test "$abs_builddir" != "$abs_srcdir"; then
 134   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 135 fi
 136
 137 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators])
 138
 139 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 140
 141 case $host in
 142   *os2*)
 143       # Use a custom made libtool replacement
 144       echo "using aplibtool"
 145       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 146       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 147       SH_LIBS="\$(ALL_LIBS)"
 148       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 149       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 150       MK_IMPLIB="emximp"
 151       other_targets="$other_targets os2core"
 152       INSTALL_PROG_FLAGS="-e .exe"
 153       SHLTCFLAGS=""
 154       LTCFLAGS=""
 155       ;;
 156   *)
 157       if test "x$LTFLAGS" = "x"; then
 158           LTFLAGS='--silent'
 159       fi
 160       my_libtool=`$apr_config --apr-libtool`
 161       LIBTOOL="$my_libtool \$(LTFLAGS)"
 162       libtoolversion=`$my_libtool --version`
 163       case $libtoolversion in
 164           *1.[[45]]*)
 165               SH_LIBTOOL='$(LIBTOOL)'
 166               SHLTCFLAGS="-prefer-pic"
 167               LTCFLAGS="-prefer-non-pic -static"
 168               ;;
 169           *)
 170               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 171               SHLTCFLAGS=""
 172               LTCFLAGS=""
 173               ;;
 174       esac
 175       ;;
 176 esac
 177 APACHE_SUBST(SHLTCFLAGS)
 178 APACHE_SUBST(LTCFLAGS)
 179
 180 AP_SIG_GRACEFUL=USR1
 181
 182 case $host in
 183   *-apple-aux3*)
 184       APR_SETVAR(APACHE_MPM, [prefork])
 185       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 186       ;;
 187   *-beos*)
 188       APR_SETVAR(APACHE_MPM, [beos])
 189       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 190       ;;
 191   *os2_emx*)
 192       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 193       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 194       ;;
 195   *-linux-*)
 196       case `uname -r` in
 197         2.0* )
 198             AP_SIG_GRACEFUL=WINCH
 199             ;;
 200         2.[[2-9]]* )
 201             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 202             ;;
 203         * )
 204             ;;
 205       esac
 206       ;;
 207   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 208       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 209       ;;
 210   *-solaris2*)
 211       dnl This is a hack -- we should be using AC_TRY_RUN instead
 212       ap_platform_runtime_link_flag="-R"
 213       dnl solaris 8 and above don't have a thundering herd
 214       dnl not sure about rev's before this one.
 215       case `uname -r` in
 216         5.[567]*)
 217             ;;
 218         * )
 219             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 220             ;;
 221       esac
 222       ;;
 223   *cygwin*)
 224       APR_SETVAR(APACHE_MPM, [prefork])
 225       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 226       ;;
 227   *aix*)
 228       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 229       if test $aixver -ge 4320; then
 230         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 231       fi
 232       ;;
 233   *os390*)
 234       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 235       ;;
 236 esac
 237
 238 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 239
 240 dnl
 241 dnl Process command line arguments. This is done early in the process so the
 242 dnl user can get feedback quickly in case of an error.
 243 dnl
 244 dnl ### need to move some of the arguments "up here"
 245
 246 dnl ## Check for programs
 247
 248 AC_PATH_PROG(RM, rm)
 249 AC_PROG_AWK
 250 AC_PROG_INSTALL
 251 AC_PROG_LN_S
 252 AC_CHECK_TOOL(RANLIB, ranlib, true)
 253 dnl AC_PATH_PROG(PERL_PATH, perl)
 254 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 255
 256 dnl various OS checks that apparently set required flags
 257 AC_AIX
 258 AC_ISC_POSIX
 259 AC_MINIX
 260
 261 dnl Check for what we can generate dependency files with
 262 APR_CHECK_DEPEND
 263
 264 dnl ## Check for libraries
 265
 266 dnl ## Check for header files
 267
 268 dnl I think these are just used all over the place, so just check for
 269 dnl them at the base of the tree. If some are specific to a single
 270 dnl directory, they should be moved (Comment #Spoon)
 271
 272 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 273 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 274 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 275
 276 AC_HEADER_STDC
 277 AC_CHECK_HEADERS( \
 278 string.h \
 279 limits.h \
 280 unistd.h \
 281 sys/socket.h \
 282 pwd.h \
 283 grp.h \
 284 strings.h \
 285 sys/prctl.h \
 286 sys/processor.h \
 287 sys/sem.h
 288 )
 289 AC_HEADER_SYS_WAIT
 290
 291 dnl ## Check for typedefs, structures, and compiler characteristics.
 292
 293 AC_C_CONST
 294 if test "$ac_cv_prog_gcc" = "yes"; then
 295   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 296 fi
 297
 298 dnl ## Check for library functions
 299 AC_SEARCH_LIBS(sqrt, m)
 300
 301 dnl See Comment #Spoon
 302
 303 AC_CHECK_FUNCS( \
 304 getpwnam \
 305 getgrnam \
 306 initgroups \
 307 bindprocessor \
 308 prctl \
 309 timegm \
 310 )
 311
 312 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 313 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 314 [AC_TRY_COMPILE([#include <sys/types.h>
 315 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 316   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 317 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 318     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 319 fi
 320
 321 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 322
 323 case $host in
 324     *aix*)
 325         # for 32-bit builds, increase MAXDATA to allow lots of threads
 326         if test x$OBJECT_MODE != x64; then
 327             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 328         fi
 329         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 330         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 331         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 332         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 333         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 334         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 335         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 336         ;;
 337     *os390*)
 338         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 339         ;;
 340     *)
 341         OS_SPECIFIC_VARS=""
 342 esac
 343
 344 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 345         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 346         [PORT=80])
 347
 348 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 349
 350 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 351 [
 352   v4mapped=$enableval
 353 ],
 354 [
 355     case $host in
 356     *freebsd5*|*netbsd*|*openbsd*)
 357         v4mapped=no
 358         ;;
 359     *)
 360         v4mapped=yes
 361         ;;
 362 esac
 363 ])
 364
 365 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 366     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 367               [Allow IPv4 connections on IPv6 listening sockets])
 368 fi
 369
 370 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 371 [
 372     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 373               [Allow modules to run hook after a fatal exception])
 374 ])dnl
 375
 376 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 377 [
 378   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 379 ])dnl
 380
 381 prefix="$orig_prefix"
 382 APACHE_ENABLE_MODULES
 383
 384 dnl reading config stubs
 385 esyscmd(./build/config-stubs .)
 386
 387 APACHE_SUBST(progname)
 388 APACHE_SUBST(MPM_LIB)
 389 APACHE_SUBST(OS)
 390 APACHE_SUBST(OS_DIR)
 391 APACHE_SUBST(BUILTIN_LIBS)
 392 APACHE_SUBST(SHLIBPATH_VAR)
 393 APACHE_SUBST(OS_SPECIFIC_VARS)
 394
 395 PRE_SHARED_CMDS='echo ""'
 396 POST_SHARED_CMDS='echo ""'
 397
 398 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 399
 400 if test "$apache_need_shared" = "yes"; then
 401   if test -f $ac_aux_dir/ltconfig; then
 402     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 403   fi
 404   shared_build="shared-build"
 405 fi
 406
 407 dnl enable_so tells us if *any* modules can be built as DSOs
 408
 409 if test "$enable_so" = "yes"; then
 410   case $host in
 411     *-ibm-aix*)
 412       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 413       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 414       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 415       ;;
 416     *beos)
 417       SH_LDFLAGS='$(top_builddir)/_APP_'
 418       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 419       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 420       ;;
 421     *os390)
 422       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 423       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 424   esac
 425 fi
 426
 427 APACHE_SUBST(PRE_SHARED_CMDS)
 428 APACHE_SUBST(POST_SHARED_CMDS)
 429 APACHE_SUBST(shared_build)
 430
 431 AC_ARG_WITH(program-name,
 432 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 433   progname="$withval" ], [
 434   progname="httpd"] )
 435
 436 # SuExec parameters
 437 AC_ARG_WITH(suexec-bin,
 438 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 439   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 440 ] )
 441
 442 AC_ARG_WITH(suexec-caller,
 443 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 444   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 445
 446 AC_ARG_WITH(suexec-userdir,
 447 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 448   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 449
 450 AC_ARG_WITH(suexec-docroot,
 451 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 452   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 453
 454 AC_ARG_WITH(suexec-uidmin,
 455 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 456   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 457
 458 AC_ARG_WITH(suexec-gidmin,
 459 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 460   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 461
 462 AC_ARG_WITH(suexec-logfile,
 463 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 464   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 465
 466 AC_ARG_WITH(suexec-safepath,
 467 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 468   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 469
 470 AC_ARG_WITH(suexec-umask,
 471 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 472   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 473
 474 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 475 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 476
 477 dnl APR should go after the other libs, so the right symbols can be picked up
 478 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 479 APACHE_SUBST(AP_LIBS)
 480 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 481 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 482
 483 AC_DEFINE(AP_USING_AUTOCONF, 1,
 484                 [Using autoconf to configure Apache])
 485
 486 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 487     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 488               [This platform doesn't suffer from the thundering herd problem])
 489 fi
 490
 491 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 492     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 493               [Listening sockets are non-blocking when there are more than 1])
 494 fi
 495
 496 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 497 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 498 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 499 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 500 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 501 AC_SUBST(AP_SIG_GRACEFUL)
 502 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 503 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 504
 505 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 506 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 507 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 508
 509 if test -d ./test; then
 510     APACHE_FAST_OUTPUT(test/Makefile)
 511 fi
 512
 513 dnl ## Finalize the variables
 514 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 515
 516 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 517 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 518 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 519 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 520 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 521 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 522
 523 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 524
 525 APACHE_GEN_CONFIG_VARS
 526
 527 dnl ## Build modules.c
 528 rm -f modules.c
 529 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 530
 531 APR_EXPAND_VAR(ap_prefix, $prefix)
 532 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 533         [Root directory of the Apache install area])
 534 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 535         [Location of the config file, relative to the Apache root directory])
 536 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 537         [Location of the MIME types config file, relative to the Apache root directory])
 538 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 539         [Location of the source for the current MPM])
 540
 541 perlbin=`$ac_aux_dir/PrintPath perl`
 542 if test "x$perlbin" = "x"; then
 543     perlbin="/replace/with/path/to/perl/interpreter"
 544 fi
 545 AC_SUBST(perlbin)
 546
 547 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 548
 549 BSD_MAKEFILE=no
 550 ap_make_include=include
 551 ap_make_delimiter=' '
 552 case $host in
 553 *bsdi*)
 554     # Check whether they've installed GNU make
 555     if make --version > /dev/null 2>&1; then
 556         true
 557     else
 558         BSD_MAKEFILE=yes
 559         ap_make_include=.include
 560         ap_make_delimiter='"'
 561     fi
 562     ;;
 563 esac
 564 AC_SUBST(ap_make_include)
 565 AC_SUBST(ap_make_delimiter)
 566
 567 dnl Ensure that docs/conf is created.
 568 test -d docs/conf||$mkdir_p docs/conf
 569
 570 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf docs/conf/ssl-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 571   APACHE_GEN_MAKEFILES
 572 ])
 573