granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 AC_ARG_WITH(included-apr,
  65 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  66
  67 # Only APR 1.x is supported.
  68 apr_version=1
  69
  70 if test "x$with_included_apr" = "xyes"; then
  71    apr_found=reconfig
  72    apr_config="$srcdir/srclib/apr/apr-${apr_version}-config"
  73 else
  74    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, ${apr_version})
  75 fi
  76
  77 if test "$apr_found" = "no"; then
  78   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  79 fi
  80
  81 if test "$apr_found" = "reconfig"; then
  82   APR_SUBDIR_CONFIG(srclib/apr,
  83                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  84                     [--enable-layout=*|\'--enable-layout=*])
  85   dnl We must be the first to build and the last to be cleaned
  86   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  87   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  88 fi
  89
  90 APR_SETIFNULL(CC, `$apr_config --cc`)
  91 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  92 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  93 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  94 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  95 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  96 APR_BINDIR=`$apr_config --bindir`
  97 APR_INCLUDEDIR=`$apr_config --includedir`
  98 APR_INCLUDES=`$apr_config --includes`
  99 APR_VERSION=`$apr_config --version`
 100 APR_CONFIG="$APR_BINDIR/apr-`echo ${APR_VERSION} | sed 's,\..*,,'`-config"
 101
 102 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 103
 104 # Only APR-util 1.x is supported.
 105 apu_version=1
 106
 107 if test "x$with_included_apr" = "xyes"; then
 108    apu_found=reconfig
 109    apu_config="${srcdir}/srclib/apr-util/apu-${apu_version}-config"
 110 else
 111    APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1, ${apu_version})
 112 fi
 113
 114 if test "$apu_found" = "no"; then
 115   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 116 fi
 117
 118 # Catch some misconfigurations:
 119 case ${apr_found}.${apu_found} in
 120 reconfig.yes)
 121   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 122   ;;
 123 yes.reconfig)
 124   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 125   ;;
 126 esac
 127
 128 if test "$apu_found" = "reconfig"; then
 129   APR_SUBDIR_CONFIG(srclib/apr-util,
 130                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 131                     [--enable-layout=*|\'--enable-layout=*])
 132   dnl We must be the last to build and the first to be cleaned
 133   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 134   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 135 fi
 136
 137 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 138 APU_BINDIR=`$apu_config --bindir`
 139 APU_INCLUDEDIR=`$apu_config --includedir`
 140 APU_INCLUDES=`$apu_config --includes`
 141 APU_VERSION=`$apu_config --version`
 142 APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 143
 144 dnl In case we picked up CC and CPP from APR, get that info into the
 145 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 146 dnl PCRE and for our config tests will be whatever PCRE determines.
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149
 150 if test "x${cache_file}" = "x/dev/null"; then
 151   # Likewise, ensure that CC and CPP are passed through to the pcre
 152   # configure script iff caching is disabled (the autoconf 2.5x default).
 153   export CC; export CPP
 154 fi
 155
 156 dnl Absolute source/build directory
 157 abs_srcdir=`(cd $srcdir && pwd)`
 158 abs_builddir=`pwd`
 159
 160 AC_ARG_WITH(pcre,
 161 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 162
 163 case $with_pcre in
 164 yes) AC_PATH_PROG(PCRE_CONFIG, pcre-config, false) ;;
 165  /*) if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 166        PCRE_CONFIG=$with_pcre/bin/pcre-config
 167      elif test -x "$with_pcre"; then
 168        PCRE_CONFIG=$with_pcre
 169      fi
 170
 171      if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 172        AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 173      fi
 174      ;;
 175 *) PCRE_CONFIG=false ;;
 176 esac
 177
 178 if test "$PCRE_CONFIG" != "false"; then
 179   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 180   APR_ADDTO(CFLAGS, [`$PCRE_CONFIG --cflags`])
 181   APR_ADDTO(LIBS, [`$PCRE_CONFIG --libs`])
 182 else
 183   # Build the bundled PCRE
 184   AC_MSG_NOTICE([Configuring PCRE regular expression library])
 185
 186   APR_SUBDIR_CONFIG(srclib/pcre,
 187                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 188
 189   APR_ADDTO(AP_LIBS, [$abs_builddir/srclib/pcre/libpcre.la])
 190   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/srclib/pcre])
 191
 192   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS pcre"
 193   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS pcre"
 194 fi
 195
 196 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 197
 198 dnl If the source dir is not equal to the build dir,
 199 dnl then we are running in VPATH mode.
 200
 201 APR_ADDTO(INCLUDES, [-I.])
 202
 203 if test "$abs_builddir" != "$abs_srcdir"; then
 204   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 205 fi
 206
 207 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 208
 209 # apr/apr-util --includes may pick up system paths for dependent
 210 # libraries, so ensure these are later in INCLUDES than local source
 211 # directories.
 212 APR_ADDTO(INCLUDES, `$apr_config --includes`)
 213 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 214
 215 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 216
 217 case $host in
 218   *os2*)
 219       # Use a custom made libtool replacement
 220       echo "using aplibtool"
 221       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 222       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 223       SH_LIBS="\$(ALL_LIBS)"
 224       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 225       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 226       MK_IMPLIB="emximp"
 227       other_targets="$other_targets os2core"
 228       INSTALL_PROG_FLAGS="-e .exe"
 229       SHLTCFLAGS=""
 230       LTCFLAGS=""
 231       ;;
 232   *)
 233       if test "x$LTFLAGS" = "x"; then
 234           LTFLAGS='--silent'
 235       fi
 236       my_libtool=`$apr_config --apr-libtool`
 237       LIBTOOL="$my_libtool \$(LTFLAGS)"
 238       libtoolversion=`$my_libtool --version`
 239       case $libtoolversion in
 240           *1.[[45]]*)
 241               SH_LIBTOOL='$(LIBTOOL)'
 242               SHLTCFLAGS="-prefer-pic"
 243               LTCFLAGS="-prefer-non-pic -static"
 244               ;;
 245           *)
 246               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 247               SHLTCFLAGS=""
 248               LTCFLAGS=""
 249               ;;
 250       esac
 251       ;;
 252 esac
 253 APACHE_SUBST(SHLTCFLAGS)
 254 APACHE_SUBST(LTCFLAGS)
 255
 256 case $host in
 257   *-apple-aux3*)
 258       APR_SETVAR(APACHE_MPM, [prefork])
 259       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 260       ;;
 261   *-beos*)
 262       APR_SETVAR(APACHE_MPM, [beos])
 263       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 264       ;;
 265   *os2-emx*)
 266       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 267       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 268       ;;
 269   *-linux-*)
 270       case `uname -r` in
 271         2.[[2-9]]* )
 272             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 273             ;;
 274         * )
 275             ;;
 276       esac
 277       ;;
 278   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *-solaris2*)
 282       dnl This is a hack -- we should be using AC_TRY_RUN instead
 283       ap_platform_runtime_link_flag="-R"
 284       dnl solaris 8 and above don't have a thundering herd
 285       dnl not sure about rev's before this one.
 286       case `uname -r` in
 287         5.[567]*)
 288             ;;
 289         * )
 290             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 291             ;;
 292       esac
 293       ;;
 294   *cygwin*)
 295       APR_SETVAR(APACHE_MPM, [prefork])
 296       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 297       ;;
 298   *mingw32*)
 299       APR_SETVAR(APACHE_MPM, [winnt])
 300       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 301       APR_SETIFNULL(ac_cv_func_times, [no])
 302       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 303       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 304       ;;
 305   *aix*)
 306       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 307       if test $aixver -ge 4320; then
 308         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 309       fi
 310       ;;
 311   *os390*)
 312       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 313       ;;
 314 esac
 315
 316 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 317
 318 dnl
 319 dnl Process command line arguments. This is done early in the process so the
 320 dnl user can get feedback quickly in case of an error.
 321 dnl
 322 dnl ### need to move some of the arguments "up here"
 323
 324 dnl ## Check for programs
 325
 326 AC_PATH_PROG(RM, rm)
 327 AC_PATH_PROG(PKGCONFIG, pkg-config)
 328 AC_PATH_PROG(RSYNC, rsync)
 329 AC_PROG_AWK
 330 AC_PROG_LN_S
 331 AC_CHECK_TOOL(RANLIB, ranlib, true)
 332 dnl AC_PATH_PROG(PERL_PATH, perl)
 333 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 334
 335 # Hard-coded install programs
 336 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 337 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 338 APACHE_SUBST(MKINSTALLDIRS)
 339 APACHE_SUBST(INSTALL)
 340
 341 dnl various OS checks that apparently set required flags
 342 AC_AIX
 343 AC_ISC_POSIX
 344 AC_MINIX
 345
 346 # Ensure that satisfactory versions of apr and apr-util are
 347 # found if external copies are configured.
 348 if test "${apr_found}" = "yes"; then
 349   # Require APR 1.3.x otherwise fail
 350   APACHE_CHECK_APxVER([apr], 1, 3)
 351 fi
 352
 353 if test "${apu_found}" = "yes"; then
 354   # Require APR-util 1.2.x otherwise fail
 355   APACHE_CHECK_APxVER([apu], 1, 2)
 356 fi
 357
 358 dnl Check for what we can generate dependency files with
 359 APR_CHECK_DEPEND
 360
 361 dnl ## Check for libraries
 362
 363 dnl ## Check for header files
 364
 365 dnl I think these are just used all over the place, so just check for
 366 dnl them at the base of the tree. If some are specific to a single
 367 dnl directory, they should be moved (Comment #Spoon)
 368
 369 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 370 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 371 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 372
 373 AC_HEADER_STDC
 374 AC_CHECK_HEADERS( \
 375 string.h \
 376 limits.h \
 377 unistd.h \
 378 sys/socket.h \
 379 pwd.h \
 380 grp.h \
 381 strings.h \
 382 sys/prctl.h \
 383 sys/processor.h \
 384 sys/sem.h
 385 )
 386 AC_HEADER_SYS_WAIT
 387
 388 dnl ## Check for typedefs, structures, and compiler characteristics.
 389
 390 AC_C_CONST
 391
 392 dnl ## Check for library functions
 393 AC_SEARCH_LIBS(sqrt, m)
 394
 395 dnl See Comment #Spoon
 396
 397 AC_CHECK_FUNCS( \
 398 getpwnam \
 399 getgrnam \
 400 initgroups \
 401 bindprocessor \
 402 prctl \
 403 timegm \
 404 getpgid
 405 )
 406
 407 dnl confirm that a void pointer is large enough to store a long integer
 408 APACHE_CHECK_VOID_PTR_LEN
 409
 410 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 411 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 412 [AC_TRY_COMPILE([#include <sys/types.h>
 413 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 414   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 415 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 416     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 417 fi
 418
 419 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 420
 421 case $host in
 422     *aix*)
 423         # for 32-bit builds, increase MAXDATA to allow lots of threads
 424         if test x$OBJECT_MODE != x64; then
 425             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 426         fi
 427         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 428         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 429         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 430         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 431         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 432         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 433         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 434         ;;
 435     *os390*)
 436         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 437         ;;
 438     *)
 439         OS_SPECIFIC_VARS=""
 440 esac
 441
 442 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 443         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 444         [PORT=80])
 445
 446 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 447         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 448         [SSLPORT=443])
 449
 450 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 451
 452 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 453 [
 454   v4mapped=$enableval
 455 ],
 456 [
 457     case $host in
 458     *freebsd5*|*netbsd*|*openbsd*)
 459         v4mapped=no
 460         ;;
 461     *)
 462         v4mapped=yes
 463         ;;
 464 esac
 465 ])
 466
 467 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 468     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 469               [Allow IPv4 connections on IPv6 listening sockets])
 470 fi
 471
 472 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 473 [
 474     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 475               [Allow modules to run hook after a fatal exception])
 476 ])dnl
 477
 478 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 479 [
 480   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 481 ])dnl
 482
 483 dnl Conditionally enable PIE support for GNU toolchains.
 484 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 485 if test "$enable_pie" = "yes"; then
 486    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 487      save_CFLAGS=$CFLAGS
 488      save_LDFLAGS=$LDFLAGS
 489      CFLAGS="$CFLAGS -fPIE"
 490      LDFLAGS="$LDFLAGS -pie"
 491      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 492       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 493      CFLAGS=$save_CFLAGS
 494      LDFLAGS=$save_LDFLAGS
 495    ])
 496    if test "$ap_cv_cc_pie" = "yes"; then
 497      PICFLAGS="-fPIE"
 498      PILDFLAGS="-pie"
 499    else
 500      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 501    fi
 502 fi
 503 AC_SUBST(PICFLAGS)
 504 AC_SUBST(PILDFLAGS)
 505
 506 prefix="$orig_prefix"
 507 APACHE_ENABLE_MODULES
 508
 509 dnl reading config stubs
 510 esyscmd(./build/config-stubs .)
 511
 512 APACHE_SUBST(progname)
 513 APACHE_SUBST(MPM_LIB)
 514 APACHE_SUBST(OS)
 515 APACHE_SUBST(OS_DIR)
 516 APACHE_SUBST(BUILTIN_LIBS)
 517 APACHE_SUBST(SHLIBPATH_VAR)
 518 APACHE_SUBST(OS_SPECIFIC_VARS)
 519
 520 PRE_SHARED_CMDS='echo ""'
 521 POST_SHARED_CMDS='echo ""'
 522
 523 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 524
 525 if test "$apache_need_shared" = "yes"; then
 526   if test -f $ac_aux_dir/ltconfig; then
 527     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 528   fi
 529   shared_build="shared-build"
 530 fi
 531
 532 dnl enable_so tells us if *any* modules can be built as DSOs
 533
 534 if test "$enable_so" = "yes"; then
 535   case $host in
 536     *-ibm-aix*)
 537       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 538       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 539       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 540       ;;
 541     *beos)
 542       SH_LDFLAGS='$(top_builddir)/_APP_'
 543       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 544       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 545       ;;
 546     *os390)
 547       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 548       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 549   esac
 550   MOD_SO_ENABLED=yes
 551 fi
 552 AC_SUBST(MOD_SO_ENABLED)
 553
 554 APACHE_SUBST(PRE_SHARED_CMDS)
 555 APACHE_SUBST(POST_SHARED_CMDS)
 556 APACHE_SUBST(shared_build)
 557
 558 AC_ARG_WITH(program-name,
 559 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 560   progname="$withval" ], [
 561   progname="httpd"] )
 562
 563 # SuExec parameters
 564 AC_ARG_WITH(suexec-bin,
 565 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 566   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 567 ] )
 568
 569 AC_ARG_WITH(suexec-caller,
 570 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 571   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 572
 573 AC_ARG_WITH(suexec-userdir,
 574 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 575   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 576
 577 AC_ARG_WITH(suexec-docroot,
 578 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 579   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 580
 581 AC_ARG_WITH(suexec-uidmin,
 582 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 583   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 584
 585 AC_ARG_WITH(suexec-gidmin,
 586 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 587   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 588
 589 AC_ARG_WITH(suexec-logfile,
 590 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 591   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 592
 593 AC_ARG_WITH(suexec-safepath,
 594 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 595   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 596
 597 AC_ARG_WITH(suexec-umask,
 598 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 599   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 600
 601 dnl APR should go after the other libs, so the right symbols can be picked up
 602 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 603 APACHE_SUBST(AP_LIBS)
 604 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 605 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 606
 607 AC_DEFINE(AP_USING_AUTOCONF, 1,
 608                 [Using autoconf to configure Apache])
 609
 610 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 611     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 612               [This platform doesn't suffer from the thundering herd problem])
 613 fi
 614
 615 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 616     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 617               [Listening sockets are non-blocking when there are more than 1])
 618 fi
 619
 620
 621 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 622 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 623 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 624
 625 if test -d ./test; then
 626     APACHE_FAST_OUTPUT(test/Makefile)
 627 fi
 628
 629 dnl ## Finalize the variables
 630 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 631
 632 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 633 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 634 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 635 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 636 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 637 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 638
 639 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 640
 641 APACHE_GEN_CONFIG_VARS
 642
 643 dnl ## Build modules.c
 644 rm -f modules.c
 645 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 646
 647 APR_EXPAND_VAR(ap_prefix, $prefix)
 648 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 649         [Root directory of the Apache install area])
 650 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 651         [Location of the config file, relative to the Apache root directory])
 652 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 653         [Location of the MIME types config file, relative to the Apache root directory])
 654 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 655         [Location of the source for the current MPM])
 656
 657 perlbin=`$ac_aux_dir/PrintPath perl`
 658 if test "x$perlbin" = "x"; then
 659     perlbin="/replace/with/path/to/perl/interpreter"
 660 fi
 661 AC_SUBST(perlbin)
 662
 663 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 664
 665 BSD_MAKEFILE=no
 666 ap_make_include=include
 667 ap_make_delimiter=' '
 668 case $host in
 669 *bsdi*)
 670     # Check whether they've installed GNU make
 671     if make --version > /dev/null 2>&1; then
 672         true
 673     else
 674         BSD_MAKEFILE=yes
 675         ap_make_include=.include
 676         ap_make_delimiter='"'
 677     fi
 678     ;;
 679 esac
 680 AC_SUBST(ap_make_include)
 681 AC_SUBST(ap_make_delimiter)
 682
 683 dnl Ensure that docs/conf is created.
 684 test -d docs/conf||$mkdir_p docs/conf
 685
 686 dnl Ensure that the httpd version is included
 687 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 688 AC_SUBST(HTTPD_VERSION)
 689
 690 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 691   APACHE_GEN_MAKEFILES
 692 ])
 693
 694 case $MPM_SUBDIR_NAME in
 695 *experimental*)
 696     echo ""
 697     echo ""
 698     echo "============================================================"
 699     echo "    WARNING: THE '${APACHE_MPM}' MPM IS EXPERIMENTAL"
 700     echo "============================================================"
 701     echo " The selected MPM might not be fully functional!"
 702     echo ""
 703     echo " Development of this MPM is not complete. Do not use this"
 704     echo " MPM unless you are a programmer willing to help fix it."
 705     echo ""
 706     echo " If you are looking for a stable server, you should not use"
 707     echo " the '${APACHE_MPM}' MPM until it is moved out of experimental."
 708     echo "============================================================"
 709     echo ""
 710     echo ""
 711     ;;
 712 esac