granicus.if.org Git - linux-pam/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([conf/pam_conv1/pam_conv_y.y])
   4 AM_INIT_AUTOMAKE("Linux-PAM", 1.0.90)
   5 AC_PREREQ(2.61)
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CANONICAL_HOST
   9
  10 AC_SUBST(PACKAGE)
  11 AC_SUBST(VERSION)
  12
  13 dnl
  14 dnl By default, everything under PAM is installed below /usr.
  15 dnl
  16 AC_PREFIX_DEFAULT(/usr)
  17
  18 dnl and some hacks to use /etc and /lib
  19 test "${prefix}" = "NONE" && prefix="/usr"
  20 if test ${prefix} = '/usr'
  21 then
  22 dnl If we use /usr as prefix, use /etc for config files
  23         if test ${sysconfdir} = '${prefix}/etc'
  24         then
  25                 sysconfdir="/etc"
  26         fi
  27         if test ${libdir} = '${exec_prefix}/lib'
  28         then
  29                 case "`uname -m`" in
  30                     x86_64|ppc64|s390x|sparc64)
  31                         libdir="/lib64" ;;
  32                     *)
  33                         libdir="/lib" ;;
  34                 esac
  35         fi
  36         if test ${sbindir} = '${exec_prefix}/sbin'
  37         then
  38                 sbindir="/sbin"
  39         fi
  40 dnl If we use /usr as prefix, use /usr/share/man for manual pages
  41         if test ${mandir} = '${prefix}/man'
  42         then
  43                 mandir='${prefix}/share/man'
  44         fi
  45 dnl Add security to include directory
  46         if test ${includedir} = '${prefix}/include'
  47         then
  48                 includedir="${prefix}/include/security"
  49         fi
  50
  51 dnl Add /var directory
  52         if test ${localstatedir} = '${prefix}/var'
  53         then
  54                 localstatedir="/var"
  55         fi
  56
  57 fi
  58
  59 dnl
  60 dnl check if we should link everything static into libpam
  61 dnl
  62 AC_ARG_ENABLE(static-modules,AS_HELP_STRING([--enable-static-modules],
  63         [do not make the modules dynamically loadable]),
  64         STATIC_MODULES=$enableval,STATIC_MODULES=no)
  65 if test "$STATIC_MODULES" != "no" ; then
  66         CFLAGS="$CFLAGS -DPAM_STATIC"
  67         AC_ENABLE_STATIC([yes])
  68         AC_ENABLE_SHARED([no])
  69 else
  70 # per default don't build static libraries
  71         AC_ENABLE_STATIC([no])
  72         AC_ENABLE_SHARED([yes])
  73 fi
  74 AM_CONDITIONAL([STATIC_MODULES], [test "$STATIC_MODULES" != "no"])
  75
  76 dnl Checks for programs.
  77 AC_USE_SYSTEM_EXTENSIONS
  78 AC_PROG_CC
  79 AC_PROG_YACC
  80 AM_PROG_LEX
  81 AC_PROG_INSTALL
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_LIBTOOL
  85 AM_PROG_CC_C_O
  86 PAM_LD_AS_NEEDED
  87 PAM_LD_O1
  88
  89 dnl Largefile support
  90 AC_SYS_LARGEFILE
  91
  92 dnl icc claims to be GCC compatible, but use other flags for warnings
  93 if eval "test x$GCC = xyes -a $CC != icc"; then
  94   for flag in \
  95       -W \
  96       -Wall \
  97       -Wbad-function-cast \
  98       -Wcast-align \
  99       -Wcast-qual \
 100       -Wmissing-declarations \
 101       -Wmissing-prototypes \
 102       -Wpointer-arith \
 103       -Wreturn-type \
 104       -Wstrict-prototypes \
 105       -Wwrite-strings \
 106       -Winline \
 107       -Wshadow
 108   do
 109     JAPHAR_GREP_CFLAGS($flag, [ CFLAGS="$CFLAGS $flag" ])
 110   done
 111 fi
 112 dnl icc has special warning flags
 113 if eval "test x$CC = xicc"; then
 114   for flag in \
 115       -Wall \
 116       -Wmissing-prototypes \
 117       -Wpointer-arith \
 118       -Wreturn-type \
 119       -Wstrict-prototypes \
 120       -Wwrite-strings \
 121       -Wshadow \
 122       -Wp64 \
 123       -Wdeprecated \
 124       -Wuninitialized \
 125       -Wmain
 126   do
 127     JAPHAR_GREP_CFLAGS($flag, [ CFLAGS="$CFLAGS $flag" ])
 128   done
 129 fi
 130
 131 AC_C___ATTRIBUTE__
 132
 133 dnl
 134 dnl Check if --version-script is supported by ld
 135 dnl
 136 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 137 [cat > conftest.s <<EOF
 138 ${libc_cv_dot_text}
 139 _sym:
 140 .symver _sym,sym@VERS
 141 EOF
 142 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 143   libc_cv_asm_symver_directive=yes
 144 else
 145   libc_cv_asm_symver_directive=no
 146 fi
 147 rm -f conftest*])
 148 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 149 if test $libc_cv_asm_symver_directive = yes; then
 150   cat > conftest.s <<EOF
 151 ${libc_cv_dot_text}
 152 _sym:
 153 .symver _sym,sym@VERS
 154 EOF
 155   cat > conftest.map <<EOF
 156 VERS_1 {
 157         global: sym;
 158 };
 159
 160 VERS_2 {
 161         global: sym;
 162 } VERS_1;
 163 EOF
 164   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 165 then
 166     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
 167                                 -o conftest.so conftest.o
 168                                 -nostartfiles -nostdlib
 169                                 -Wl,--version-script,conftest.map
 170                        1>&AS_MESSAGE_LOG_FD]);
 171     then
 172       libc_cv_ld_version_script_option=yes
 173     else
 174       libc_cv_ld_version_script_option=no
 175     fi
 176   else
 177     libc_cv_ld_version_script_option=no
 178   fi
 179 else
 180   libc_cv_ld_version_script_option=no
 181 fi
 182 rm -f conftest*])
 183 AM_CONDITIONAL([HAVE_VERSIONING],
 184         [test "$libc_cv_ld_version_script_option" = "yes"])
 185
 186 dnl
 187 dnl check for -fPIE/-pie support
 188 dnl
 189 dnl icc handles -fpie as -fp without error, so blacklist icc
 190 dnl
 191 AC_ARG_ENABLE(pie,AS_HELP_STRING([--disable-pie],
 192                         [disable position-independent executeables (PIE)]),
 193         USE_PIE=$enableval, USE_PIE=yes)
 194
 195 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
 196   cat > conftest.c <<EOF
 197 int foo;
 198 main () { return 0;}
 199 EOF
 200   if test "$USE_PIE" = "yes" -a "$CC" != "icc" &&
 201         AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
 202                               -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
 203   then
 204     libc_cv_fpie=yes
 205     PIE_CFLAGS="-fpie"
 206     PIE_LDFLAGS="-pie"
 207   else
 208     libc_cv_fpie=no
 209     PIE_CFLAGS=""
 210     PIE_LDFLAGS=""
 211   fi
 212   rm -f conftest*])
 213 AC_SUBST(libc_cv_fpie)
 214 AC_SUBST(PIE_CFLAGS)
 215 AC_SUBST(PIE_LDFLAGS)
 216
 217
 218 dnl
 219 dnl options and defaults
 220 dnl
 221
 222 AC_ARG_ENABLE([prelude],
 223         AS_HELP_STRING([--disable-prelude],[do not use prelude]),
 224         WITH_PRELUDE=$enableval, WITH_PRELUDE=yes)
 225 if test "$WITH_PRELUDE" == "yes" ; then
 226   AM_PATH_LIBPRELUDE([0.9.0])
 227   if test "$LIBPRELUDE_CONFIG" != "no" ; then
 228     LIBPRELUDE_CFLAGS="$LIBPRELUDE_CFLAGS -DPRELUDE=1"
 229   fi
 230 fi
 231
 232 dnl lots of debugging information goes to /var/run/pam-debug.log
 233 AC_ARG_ENABLE([debug],
 234     AS_HELP_STRING([--enable-debug],[specify you are building with debugging on]))
 235
 236 if test x"$enable_debug" = x"yes" ; then
 237    AC_DEFINE([DEBUG],,
 238                 [lots of stuff gets written to /var/run/pam-debug.log])
 239 fi
 240
 241 AC_ARG_ENABLE(securedir,
 242         AS_HELP_STRING([--enable-securedir=DIR],[path to location of PAMs @<:@default=$libdir/security@:>@]),
 243         SECUREDIR=$enableval, SECUREDIR=$libdir/security)
 244 AC_SUBST(SECUREDIR)
 245
 246 AC_ARG_ENABLE([isadir],
 247         AS_HELP_STRING([--enable-isadir=DIR],[path to arch-specific module files @<:@default=../../(basename of $libdir)/security@:>@]),
 248 ISA=$enableval,
 249 ISA=../../`basename $libdir`/security)
 250 unset mylibdirbase
 251 AC_DEFINE_UNQUOTED(_PAM_ISA,"$ISA",[Define to the path, relative to SECUREDIR, where PAMs specific to this architecture can be found.])
 252 AC_MSG_RESULT([Defining \$ISA to "$ISA"])
 253
 254 AC_ARG_ENABLE(sconfigdir,
 255         AS_HELP_STRING([--enable-sconfigdir=DIR],[path to module conf files @<:@default=$sysconfdir/security@:>@]),
 256         SCONFIGDIR=$enableval, SCONFIGDIR=$sysconfdir/security)
 257 AC_SUBST(SCONFIGDIR)
 258
 259 AC_ARG_ENABLE(pamlocking,
 260         AS_HELP_STRING([--enable-pamlocking],[configure libpam to observe a global authentication lock]))
 261
 262 if test x"$enable_pamlocking" = "xyes"; then
 263    AC_DEFINE([PAM_LOCKING],,
 264         [libpam should observe a global authentication lock])
 265 fi
 266
 267 AC_ARG_ENABLE(read-both-confs,
 268         AS_HELP_STRING([--enable-read-both-confs],[read both /etc/pam.d and /etc/pam.conf files]))
 269
 270 if test x"$enable_read_both_confs" = "xyes"; then
 271    AC_DEFINE([PAM_READ_BOTH_CONFS],,
 272                 [read both /etc/pam.d and /etc/pam.conf files])
 273 fi
 274
 275 AC_ARG_ENABLE([lckpwdf],
 276         AS_HELP_STRING([--disable-lckpwdf],[do not use the lckpwdf function]),
 277         WITH_LCKPWDF=$enableval, WITH_LCKPWDF=yes)
 278 if test "$WITH_LCKPWDF" == "yes" ; then
 279     AC_DEFINE([USE_LCKPWDF], 1,
 280                 [Define to 1 if the lckpwdf function should be used])
 281 fi
 282
 283 AC_CHECK_HEADERS(paths.h)
 284 AC_ARG_WITH(mailspool,
 285 [  --with-mailspool        path to mail spool directory
 286                           [default _PATH_MAILDIR if defined in paths.h, otherwise /var/spool/mail]],
 287 with_mailspool=${withval})
 288 if test x$with_mailspool != x ; then
 289         pam_mail_spool="\"$with_mailspool\""
 290 else
 291         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 292 #include <paths.h>
 293 int main() {
 294 #ifdef _PATH_MAILDIR
 295 exit(0);
 296 #else
 297 exit(1);
 298 #endif
 299 }]])],[pam_mail_spool="_PATH_MAILDIR"],[pam_mail_spool="\"/var/spool/mail\""],[pam_mail_spool="\"/var/spool/mail\""])
 300 fi
 301 AC_DEFINE_UNQUOTED(PAM_PATH_MAILDIR, $pam_mail_spool,
 302         [Path where mails are stored])
 303
 304 AC_ARG_WITH(xauth,
 305 [  --with-xauth            additional path to check for xauth when it is called from pam_xauth
 306                           [added to the default of /usr/X11R6/bin/xauth, /usr/bin/xauth, /usr/bin/X11/xauth]],
 307 pam_xauth_path=${withval})
 308 if test x$with_xauth == x ; then
 309         AC_PATH_PROG(pam_xauth_path, xauth)
 310 dnl There is no sense in adding the first default path
 311         if test x$pam_xauth_path == x/usr/X11R6/bin/xauth ; then
 312                 unset pam_xauth_path
 313         fi
 314 fi
 315
 316 if test x$pam_xauth_path != x ; then
 317         AC_DEFINE_UNQUOTED(PAM_PATH_XAUTH, "$pam_xauth_path",
 318         [Additional path of xauth executable])
 319 fi
 320
 321 dnl Checks for the existence of libdl - on BSD and Tru64 its part of libc
 322 AC_CHECK_LIB([dl], [dlopen], LIBDL="-ldl", LIBDL="")
 323 AC_SUBST(LIBDL)
 324
 325 # Check for cracklib
 326 AC_ARG_ENABLE([cracklib],
 327         AS_HELP_STRING([--disable-cracklib],[do not use cracklib]),
 328         WITH_CRACKLIB=$enableval, WITH_CRACKLIB=yes)
 329 if test x"$WITH_CRACKLIB" != xno ; then
 330         AC_CHECK_HEADERS([crack.h],
 331               AC_CHECK_LIB([crack], [FascistCheck], LIBCRACK="-lcrack", LIBCRACK=""))
 332 else
 333         LIBCRACK=""
 334 fi
 335 AC_SUBST(LIBCRACK)
 336 AM_CONDITIONAL([HAVE_LIBCRACK], [test ! -z "$LIBCRACK"])
 337
 338 dnl Look for Linux Auditing library - see documentation
 339 AC_ARG_ENABLE([audit],
 340         AS_HELP_STRING([--disable-audit],[do not enable audit support]),
 341         WITH_LIBAUDIT=$enableval, WITH_LIBAUDIT=yes)
 342 if test x"$WITH_LIBAUDIT" != xno ; then
 343         AC_CHECK_HEADER([libaudit.h],
 344               [AC_CHECK_LIB(audit, audit_log_acct_message, LIBAUDIT=-laudit, LIBAUDIT="")
 345                AC_CHECK_TYPE([struct audit_tty_status],
 346                              [HAVE_AUDIT_TTY_STATUS=yes],
 347                              [HAVE_AUDIT_TTY_STATUS=""],
 348                              [#include <libaudit.h>])]
 349         )
 350         if test ! -z "$LIBAUDIT" -a "ac_cv_header_libaudit_h" != "no" ; then
 351             AC_DEFINE([HAVE_LIBAUDIT], 1, [Define to 1 if audit support should be compiled in.])
 352         fi
 353         if test ! -z "$HAVE_AUDIT_TTY_STATUS" ; then
 354             AC_DEFINE([HAVE_AUDIT_TTY_STATUS], 1, [Define to 1 if struct audit_tty_status exists.])
 355         fi
 356 else
 357         LIBAUDIT=""
 358 fi
 359 AC_SUBST(LIBAUDIT)
 360 AM_CONDITIONAL([HAVE_AUDIT_TTY_STATUS],
 361                [test "x$HAVE_AUDIT_TTY_STATUS" = xyes])
 362
 363 BACKUP_LIBS=$LIBS
 364 AC_SEARCH_LIBS([crypt],[xcrypt crypt], LIBCRYPT="-l$ac_lib", LIBCRYPT="")
 365 AC_CHECK_FUNCS(crypt_r)
 366 LIBS=$BACKUP_LIBS
 367 AC_SUBST(LIBCRYPT)
 368
 369 AC_ARG_WITH([randomdev], AS_HELP_STRING([--with-randomdev=(<path>|yes|no)],[use specified random device instead of /dev/urandom or 'no' to disable]), opt_randomdev=$withval)
 370 if test "$opt_randomdev" = yes -o -z "$opt_randomdev"; then
 371        opt_randomdev="/dev/urandom"
 372 elif test "$opt_randomdev" = no; then
 373        opt_randomdev=
 374 fi
 375 if test -n "$opt_randomdev"; then
 376        AC_DEFINE_UNQUOTED(PAM_PATH_RANDOMDEV, "$opt_randomdev", [Random device path.])
 377 fi
 378
 379 dnl check for libdb or libndbm as fallback. Some libndbm compat
 380 dnl libraries are unuseable, so try libdb first.
 381 AC_ARG_ENABLE([db],
 382         AS_HELP_STRING([--enable-db=(db|ndbm|yes|no)],[Default behavior 'yes', which is to check for libdb first, followed by ndbm. Use 'no' to disable db support.]),
 383         WITH_DB=$enableval, WITH_DB=yes)
 384 AC_ARG_WITH([db-uniquename],
 385         AS_HELP_STRING([--with-db-uniquename=extension],[Unique name for db libraries and functions.]))
 386 if test x"$WITH_DB" != xno ; then
 387         if test x"$WITH_DB" = xyes -o x"$WITH_DB" = xdb ; then
 388               AC_CHECK_LIB([db$with_db_uniquename], [db_create$with_db_uniquename], LIBDB="-ldb$with_db_uniquename", LIBDB="")
 389               if test -z "$LIBDB" ; then
 390                   AC_CHECK_LIB([db$with_db_uniquename], [dbm_store$with_db_uniquename], LIBDB="-ldb$with_db_uniquename", LIBDB="")
 391               fi
 392         fi
 393         if test -z "$LIBDB" ; then
 394             AC_CHECK_LIB([ndbm],[dbm_store], LIBDB="-lndbm", LIBDB="")
 395             if test ! -z "$LIBDB" ; then
 396                 AC_CHECK_HEADERS(ndbm.h)
 397             fi
 398         else
 399             AC_CHECK_HEADERS(db.h)
 400         fi
 401 fi
 402 AC_SUBST(LIBDB)
 403 AM_CONDITIONAL([HAVE_LIBDB], [test ! -z "$LIBDB"])
 404
 405 AC_CHECK_LIB([nsl],[yp_get_default_domain], LIBNSL="-lnsl", LIBNSL="")
 406 BACKUP_LIBS=$LIBS
 407 LIBS="$LIBS $LIBNSL"
 408 AC_CHECK_FUNCS(yp_get_default_domain)
 409 LIBS=$BACKUP_LIBS
 410 AC_SUBST(LIBNSL)
 411
 412 AC_ARG_ENABLE([selinux],
 413         AS_HELP_STRING([--disable-selinux],[do not use SELinux]),
 414         WITH_SELINUX=$enableval, WITH_SELINUX=yes)
 415 if test "$WITH_SELINUX" == "yes" ; then
 416   AC_CHECK_LIB([selinux],[getfilecon], LIBSELINUX="-lselinux", LIBSELINUX="")
 417 else
 418   LIBSELINUX=""
 419 fi
 420 AC_SUBST(LIBSELINUX)
 421 AM_CONDITIONAL([HAVE_LIBSELINUX], [test ! -z "$LIBSELINUX"])
 422 if test ! -z "$LIBSELINUX" ; then
 423     AC_DEFINE([WITH_SELINUX], 1, [Defined if SE Linux support is compiled in])
 424     BACKUP_LIBS=$LIBS
 425     LIBS="$LIBS $LIBSELINUX"
 426     AC_CHECK_FUNCS(setkeycreatecon)
 427     LIBS=$BACKUP_LIBS
 428 fi
 429
 430 dnl Checks for header files.
 431 AC_HEADER_DIRENT
 432 AC_HEADER_STDC
 433 AC_HEADER_SYS_WAIT
 434 AC_CHECK_HEADERS(fcntl.h limits.h malloc.h sys/file.h sys/ioctl.h sys/time.h syslog.h net/if.h termio.h unistd.h sys/fsuid.h inittypes.h)
 435
 436 AC_CHECK_HEADERS(crypt.h)
 437
 438 dnl For module/pam_lastlog
 439 AC_CHECK_HEADERS(lastlog.h utmp.h utmpx.h)
 440
 441 dnl Checks for typedefs, structures, and compiler characteristics.
 442 AC_C_BIGENDIAN
 443 AC_C_CONST
 444 AC_TYPE_UID_T
 445 AC_TYPE_OFF_T
 446 AC_TYPE_PID_T
 447 AC_TYPE_SIZE_T
 448 AC_HEADER_TIME
 449 AC_STRUCT_TM
 450
 451 dnl Checks for library functions.
 452 AC_TYPE_GETGROUPS
 453 AC_PROG_GCC_TRADITIONAL
 454 AC_FUNC_MEMCMP
 455 AC_FUNC_VPRINTF
 456 AC_CHECK_FUNCS(fseeko gethostname gettimeofday lckpwdf mkdir select)
 457 AC_CHECK_FUNCS(strcspn strdup strspn strstr strtol uname)
 458 AC_CHECK_FUNCS(getpwnam_r getpwuid_r getgrnam_r getgrgid_r getspnam_r)
 459 AC_CHECK_FUNCS(getgrouplist getline getdelim)
 460 AC_CHECK_FUNCS(inet_ntop inet_pton ruserok_af)
 461
 462 AC_CHECK_FUNCS(unshare, [UNSHARE=yes], [UNSHARE=no])
 463 AM_CONDITIONAL([HAVE_UNSHARE], [test "$UNSHARE" = yes])
 464
 465 dnl
 466 dnl Check for xsltproc
 467 dnl
 468 enable_man=yes
 469 AC_PATH_PROG([XSLTPROC], [xsltproc])
 470 if test -z "$XSLTPROC"; then
 471      enable_man=no
 472 fi
 473 AC_PATH_PROG([XMLLINT], [xmllint],[/bin/true])
 474 dnl check for DocBook DTD and stylesheets in the local catalog.
 475 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.4//EN],
 476                 [DocBook XML DTD V4.4], [], enable_man=no)
 477 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
 478                 [DocBook XSL Stylesheets], [], enable_man=no)
 479
 480 AC_PATH_PROG([BROWSER], [w3m])
 481 if test ! -z "$BROWSER"; then
 482      BROWSER="$BROWSER -T text/html -dump"
 483 else
 484      enable_man=no
 485 fi
 486
 487 AC_PATH_PROG([FO2PDF], [fop])
 488
 489 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test x$enable_man != xno)
 490 AM_CONDITIONAL(ENABLE_GENERATE_PDF, test ! -z "$FO2PDF")
 491
 492
 493 AM_GNU_GETTEXT_VERSION([0.15])
 494 AM_GNU_GETTEXT([external])
 495 AC_CHECK_FUNCS(dngettext)
 496
 497 AH_BOTTOM([#ifdef ENABLE_NLS
 498 #include <libintl.h>
 499 #define _(msgid) dgettext(PACKAGE, msgid)
 500 #define N_(msgid) msgid
 501 #else
 502 #define _(msgid) (msgid)
 503 #define N_(msgid) msgid
 504 #endif /* ENABLE_NLS */])
 505
 506 dnl
 507 dnl Check for the availability of the kernel key management facility
 508 dnl - The pam_keyinit module only requires the syscalls, not the error codes
 509 dnl
 510 AC_CHECK_DECL(__NR_keyctl, [have_key_syscalls=1],[have_key_syscalls=0],[#include <sys/syscall.h>])
 511 AC_CHECK_DECL(ENOKEY, [have_key_errors=1],[have_key_errors=0],[#include <errno.h>])
 512
 513 HAVE_KEY_MANAGEMENT=0
 514 if test $have_key_syscalls$have_key_errors = 11
 515 then
 516         HAVE_KEY_MANAGEMENT=1
 517 fi
 518
 519 if test $HAVE_KEY_MANAGEMENT = 1; then
 520    AC_DEFINE([HAVE_KEY_MANAGEMENT], 1,
 521              [Defined if the kernel key management facility is available])
 522 fi
 523 AC_SUBST([HAVE_KEY_MANAGEMENT], $HAVE_KEY_MANAGEMENT)
 524
 525 AM_CONDITIONAL([HAVE_KEY_MANAGEMENT], [test "$have_key_syscalls" = 1])
 526
 527 dnl Files to be created from when we run configure
 528 AC_CONFIG_FILES([Makefile libpam/Makefile libpamc/Makefile libpamc/test/Makefile \
 529         libpam_misc/Makefile conf/Makefile conf/pam_conv1/Makefile \
 530         po/Makefile.in \
 531         modules/Makefile \
 532         modules/pam_access/Makefile modules/pam_cracklib/Makefile \
 533         modules/pam_debug/Makefile modules/pam_deny/Makefile \
 534         modules/pam_echo/Makefile modules/pam_env/Makefile \
 535         modules/pam_faildelay/Makefile \
 536         modules/pam_filter/Makefile modules/pam_filter/upperLOWER/Makefile \
 537         modules/pam_ftp/Makefile modules/pam_group/Makefile \
 538         modules/pam_issue/Makefile modules/pam_keyinit/Makefile \
 539         modules/pam_lastlog/Makefile modules/pam_limits/Makefile \
 540         modules/pam_listfile/Makefile modules/pam_localuser/Makefile \
 541         modules/pam_loginuid/Makefile modules/pam_mail/Makefile \
 542         modules/pam_mkhomedir/Makefile modules/pam_motd/Makefile \
 543         modules/pam_namespace/Makefile \
 544         modules/pam_nologin/Makefile modules/pam_permit/Makefile \
 545         modules/pam_pwhistory/Makefile modules/pam_rhosts/Makefile \
 546         modules/pam_rootok/Makefile modules/pam_exec/Makefile \
 547         modules/pam_securetty/Makefile modules/pam_selinux/Makefile \
 548         modules/pam_sepermit/Makefile \
 549         modules/pam_shells/Makefile modules/pam_stress/Makefile \
 550         modules/pam_succeed_if/Makefile modules/pam_tally/Makefile \
 551         modules/pam_time/Makefile modules/pam_tty_audit/Makefile \
 552         modules/pam_umask/Makefile \
 553         modules/pam_unix/Makefile modules/pam_userdb/Makefile \
 554         modules/pam_warn/Makefile modules/pam_wheel/Makefile \
 555         modules/pam_xauth/Makefile doc/Makefile doc/specs/Makefile \
 556         doc/man/Makefile doc/sag/Makefile doc/adg/Makefile \
 557         doc/mwg/Makefile examples/Makefile tests/Makefile \
 558         xtests/Makefile])
 559 AC_OUTPUT