granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.373 2004/08/08 23:27:11 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.0.0beta1], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Initialize default assumption that we do not need separate assembly code
 101 # for TAS (test-and-set).  This can be overridden by the template file
 102 # when it's executed.
 103 need_tas=no
 104 tas_file=dummy.s
 105
 106
 107
 108 ##
 109 ## Command line options
 110 ##
 111
 112 #
 113 # Installation directory for documentation
 114 #
 115 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 116   --without-docdir        do not install the documentation],
 117          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 118          [docdir=],
 119          [docdir=$withval],
 120          [docdir='${prefix}/doc'])
 121 AC_SUBST(docdir)
 122
 123
 124 #
 125 # Add non-standard directories to the include path
 126 #
 127 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 128
 129
 130 #
 131 # Add non-standard directories to the library search path
 132 #
 133 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 134              [LIBRARY_DIRS=$withval])
 135
 136 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 137              [LIBRARY_DIRS=$withval])
 138
 139
 140 #
 141 # 64-bit integer date/time storage (--enable-integer-datetimes)
 142 #
 143 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 144 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 145               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 146                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 147 AC_MSG_RESULT([$enable_integer_datetimes])
 148
 149
 150 #
 151 # NLS
 152 #
 153 AC_MSG_CHECKING([whether NLS is wanted])
 154 PGAC_ARG_OPTARG(enable, nls,
 155                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 156                 [],
 157                 [WANTED_LANGUAGES=$enableval],
 158                 [AC_DEFINE(ENABLE_NLS, 1,
 159                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 160 AC_MSG_RESULT([$enable_nls])
 161 AC_SUBST(enable_nls)
 162 AC_SUBST(WANTED_LANGUAGES)
 163
 164 #
 165 # Default port number (--with-pgport), default 5432
 166 #
 167 AC_MSG_CHECKING([for default port number])
 168 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 169              [default_port=$withval],
 170              [default_port=5432])
 171 AC_MSG_RESULT([$default_port])
 172 # Need both of these because some places want an integer and some a string
 173 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 174 [Define to the default TCP port number on which the server listens and
 175 to which clients will try to connect.  This can be overridden at run-time,
 176 but it's convenient if your clients have the right default compiled in.
 177 (--with-pgport=PORTNUM)])
 178 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 179                    [Define to the default TCP port number as a string constant.])
 180 AC_SUBST(default_port)
 181
 182 #
 183 # Option to disable shared libraries
 184 #
 185 PGAC_ARG_BOOL(enable, shared, yes,
 186               [  --disable-shared        do not build shared libraries])
 187 AC_SUBST(enable_shared)
 188
 189 #
 190 # '-rpath'-like feature can be disabled
 191 #
 192 PGAC_ARG_BOOL(enable, rpath, yes,
 193               [  --disable-rpath         do not embed shared library search path in executables])
 194 AC_SUBST(enable_rpath)
 195
 196 #
 197 # Spinlocks
 198 #
 199 PGAC_ARG_BOOL(enable, spinlocks, yes,
 200               [  --disable-spinlocks     do not use spinlocks])
 201
 202 #
 203 # --enable-debug adds -g to compiler flags
 204 #
 205 PGAC_ARG_BOOL(enable, debug, no,
 206               [  --enable-debug          build with debugging symbols (-g)])
 207 AC_SUBST(enable_debug)
 208
 209 #
 210 # C compiler
 211 #
 212
 213 # For historical reasons you can also use --with-CC to specify the C compiler
 214 # to use, although the standard way to do this is to set the CC environment
 215 # variable.
 216 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 217
 218 case $template in
 219   aix) pgac_cc_list="gcc xlc";;
 220  irix) pgac_cc_list="cc";; # no gcc
 221     *) pgac_cc_list="gcc cc";;
 222 esac
 223
 224 AC_PROG_CC([$pgac_cc_list])
 225
 226 unset CFLAGS
 227
 228 #
 229 # Read the template
 230 #
 231 . "$srcdir/src/template/$template" || exit
 232
 233 # CFLAGS are selected so:
 234 # If the user specifies something in the environment, that is used.
 235 # else:  If the template file set something, that is used.
 236 # else:  If the compiler is GCC, then we use -O2.
 237 # else:  If the compiler is something else, then we use -0.
 238
 239 if test "$ac_env_CFLAGS_set" = set; then
 240   CFLAGS=$ac_env_CFLAGS_value
 241 elif test "${CFLAGS+set}" = set; then
 242   : # (keep what template set)
 243 elif test "$GCC" = yes; then
 244   CFLAGS="-O2"
 245 else
 246   # if the user selected debug mode, don't use -O
 247   if test "$enable_debug" != yes; then
 248     CFLAGS="-O"
 249   fi
 250 fi
 251
 252 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 253 PGAC_PROG_CC_NO_STRICT_ALIASING
 254
 255 # supply -g if --enable-debug
 256 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 257   CFLAGS="$CFLAGS -g"
 258 fi
 259
 260 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 261
 262 # We already have this in Makefile.win32, but configure needs it too
 263 if test "$PORTNAME" = "win32"; then
 264   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 265 fi
 266
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273
 274 # Defend against gcc -ffast-math
 275 if test "$GCC" = yes; then
 276 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 277 choke me
 278 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 279 fi
 280
 281 AC_PROG_CPP
 282 AC_SUBST(GCC)
 283
 284 # Create compiler version string
 285 if test x"$GCC" = x"yes" ; then
 286   cc_string="GCC `${CC} --version | sed q`"
 287 else
 288   cc_string=$CC
 289 fi
 290 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 291                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 292                    [A string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Set up TAS assembly code if needed; the template file has now had its
 297 # chance to request this.
 298 #
 299 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 300
 301 if test "$need_tas" = yes ; then
 302   TAS=tas.o
 303 else
 304   TAS=""
 305 fi
 306 AC_SUBST(TAS)
 307
 308
 309 #
 310 # Automatic dependency tracking
 311 #
 312 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 313               [autodepend=yes])
 314 AC_SUBST(autodepend)
 315
 316
 317 #
 318 # Enable assert checks
 319 #
 320 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 321               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 322                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 323
 324
 325 #
 326 # Include directories
 327 #
 328 ac_save_IFS=$IFS
 329 IFS="${IFS}:"
 330 # SRCH_INC comes from the template file
 331 for dir in $with_includes $SRCH_INC; do
 332   if test -d "$dir"; then
 333     INCLUDES="$INCLUDES -I$dir"
 334   else
 335     AC_MSG_WARN([*** Include directory $dir does not exist.])
 336   fi
 337 done
 338 IFS=$ac_save_IFS
 339 AC_SUBST(INCLUDES)
 340
 341
 342 #
 343 # Library directories
 344 #
 345 ac_save_IFS=$IFS
 346 IFS="${IFS}:"
 347 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 348 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 349   if test -d "$dir"; then
 350     LIBDIRS="$LIBDIRS -L$dir"
 351   else
 352     AC_MSG_WARN([*** Library directory $dir does not exist.])
 353   fi
 354 done
 355 IFS=$ac_save_IFS
 356
 357 #
 358 # Enable thread-safe client libraries
 359 #
 360 AC_MSG_CHECKING([allow thread-safe client libraries])
 361 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 362 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 363 if test "$enable_thread_safety" = yes -o \
 364         "$enable_thread_safety_force" = yes; then
 365   enable_thread_safety="yes"    # for 'force'
 366   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 367           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 368 fi
 369 AC_MSG_RESULT([$enable_thread_safety])
 370 AC_SUBST(enable_thread_safety)
 371
 372 #
 373 # Tcl/Tk
 374 #
 375 AC_MSG_CHECKING([whether to build with Tcl])
 376 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 377 AC_MSG_RESULT([$with_tcl])
 378 AC_SUBST([with_tcl])
 379
 380 # We see if the path to the Tcl/Tk configuration scripts is specified.
 381 # This will override the use of tclsh to find the paths to search.
 382
 383 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 384
 385 #
 386 # Optionally build Perl modules (PL/Perl)
 387 #
 388 AC_MSG_CHECKING([whether to build Perl modules])
 389 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 390 AC_MSG_RESULT([$with_perl])
 391 AC_SUBST(with_perl)
 392
 393 #
 394 # Optionally build Python modules (PL/Python)
 395 #
 396 AC_MSG_CHECKING([whether to build Python modules])
 397 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 398 AC_MSG_RESULT([$with_python])
 399 AC_SUBST(with_python)
 400
 401 #
 402 # Kerberos 4
 403 #
 404 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 405 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 406 [
 407   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 408   krb_srvtab="/etc/srvtab"
 409 ])
 410 AC_MSG_RESULT([$with_krb4])
 411 AC_SUBST(with_krb4)
 412
 413
 414 #
 415 # Kerberos 5
 416 #
 417 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 418 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 419 [
 420   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 421   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 422 ])
 423 AC_MSG_RESULT([$with_krb5])
 424 AC_SUBST(with_krb5)
 425
 426
 427 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 428 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 429   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 430 fi
 431
 432 AC_SUBST(krb_srvtab)
 433
 434
 435 #
 436 # Kerberos configuration parameters
 437 #
 438 PGAC_ARG_REQ(with, krb-srvnam,
 439              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 440              [],
 441              [with_krb_srvnam="postgres"])
 442 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 443                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 444
 445
 446 #
 447 # PAM
 448 #
 449 AC_MSG_CHECKING([whether to build with PAM support])
 450 PGAC_ARG_BOOL(with, pam, no,
 451               [  --with-pam              build with PAM support],
 452               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 453 AC_MSG_RESULT([$with_pam])
 454 AC_SUBST(with_pam)
 455
 456
 457 #
 458 # Rendezvous
 459 #
 460 AC_MSG_CHECKING([whether to build with Rendezvous support])
 461 PGAC_ARG_BOOL(with, rendezvous, no,
 462               [  --with-rendezvous       build with Rendezvous support],
 463               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 464 AC_MSG_RESULT([$with_rendezvous])
 465 AC_SUBST(with_rendezvous)
 466
 467
 468 #
 469 # OpenSSL
 470 #
 471 AC_MSG_CHECKING([whether to build with OpenSSL support])
 472 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 473               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 474 AC_MSG_RESULT([$with_openssl])
 475 AC_SUBST(with_openssl)
 476
 477
 478 #
 479 # Readline
 480 #
 481 PGAC_ARG_BOOL(with, readline, yes,
 482               [  --without-readline      do not use Readline])
 483 # readline on MinGW has problems with backslashes in psql and other bugs.
 484 # This is particularly a problem with non-US code pages.
 485 # Therefore disable its use until we understand the cause. 2004-07-20
 486 case $host_os in mingw*)
 487   if test "$with_readline" = yes; then
 488     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 489     with_readline=no
 490   fi;;
 491 esac
 492
 493
 494 #
 495 # Zlib
 496 #
 497 PGAC_ARG_BOOL(with, zlib, yes,
 498               [  --without-zlib          do not use Zlib])
 499
 500 #
 501 # Elf
 502 #
 503
 504 # Assume system is ELF if it predefines __ELF__ as 1,
 505 # otherwise believe host_os based default.
 506 case $host_os in
 507     freebsd1*|freebsd2*) elf=no;;
 508     freebsd3*|freebsd4*) elf=yes;;
 509 esac
 510
 511 AC_EGREP_CPP(yes,
 512 [#if __ELF__
 513   yes
 514 #endif
 515 ],
 516 [ELF_SYS=true],
 517 [if test "X$elf" = "Xyes" ; then
 518   ELF_SYS=true
 519 else
 520   ELF_SYS=
 521 fi])
 522 AC_SUBST(ELF_SYS)
 523
 524 #
 525 # Assignments
 526 #
 527
 528 CPPFLAGS="$CPPFLAGS $INCLUDES"
 529 LDFLAGS="$LDFLAGS $LIBDIRS"
 530
 531 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 532 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 533
 534
 535 AC_PROG_AWK
 536 PGAC_PATH_FLEX
 537 AC_PROG_LN_S
 538 PGAC_PROG_LD
 539 AC_SUBST(LD)
 540 AC_SUBST(with_gnu_ld)
 541 case $host_os in sysv5*)
 542   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 543   [
 544     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 545     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 546     LDFLAGS=$pgac_save_LDFLAGS
 547   ])
 548   ld_R_works=$pgac_cv_prog_ld_R
 549   AC_SUBST(ld_R_works)
 550 esac
 551 AC_PROG_RANLIB
 552 AC_CHECK_PROGS(LORDER, lorder)
 553 AC_PATH_PROG(TAR, tar)
 554 PGAC_CHECK_STRIP
 555
 556 AC_CHECK_PROGS(YACC, ['bison -y'])
 557
 558 if test "$YACC"; then
 559   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 560     AC_MSG_WARN([
 561 *** If you are going to modify the grammar files or build from CVS, the installed
 562 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 563   fi
 564 fi
 565
 566 if test -z "$YACC"; then
 567   AC_MSG_WARN([
 568 *** Without Bison you will not be able to build PostgreSQL from CVS or
 569 *** change any of the parser definition files.  You can obtain Bison from
 570 *** a GNU mirror site.  (If you are using the official distribution of
 571 *** PostgreSQL then you do not need to worry about this because the Bison
 572 *** output is pre-generated.)  To use a different yacc program (possible,
 573 *** but not recommended), set the environment variable YACC before running
 574 *** 'configure'.])
 575 fi
 576 AC_SUBST(YFLAGS)
 577
 578 PGAC_PATH_PERL
 579 if test "$with_perl" = yes; then
 580   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 581   PGAC_CHECK_PERL_EMBED_LDFLAGS
 582 fi
 583
 584 if test "$with_python" = yes; then
 585   PGAC_PATH_PYTHON
 586   PGAC_CHECK_PYTHON_EMBED_SETUP
 587 fi
 588
 589
 590 ##
 591 ## Libraries
 592 ##
 593
 594 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 595 then
 596         AC_CHECK_LIB(bsd,      main)
 597 fi
 598 AC_CHECK_LIB(util,     setproctitle)
 599 AC_CHECK_LIB(m,        main)
 600 AC_CHECK_LIB(dl,       main)
 601 AC_CHECK_LIB(nsl,      main)
 602 AC_CHECK_LIB(socket,   main)
 603 AC_CHECK_LIB(ipc,      main)
 604 AC_CHECK_LIB(IPC,      main)
 605 AC_CHECK_LIB(lc,       main)
 606 AC_CHECK_LIB(dld,      main)
 607 AC_CHECK_LIB(ld,       main)
 608 AC_CHECK_LIB(compat,   main)
 609 AC_CHECK_LIB(BSD,      main)
 610 AC_CHECK_LIB(gen,      main)
 611 AC_CHECK_LIB(PW,       main)
 612 AC_CHECK_LIB(resolv,   main)
 613 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 614 # QNX:
 615 AC_CHECK_LIB(unix, main)
 616 AC_SEARCH_LIBS(crypt,  crypt)
 617 # BeOS:
 618 if test "$PORTNAME" = "beos"
 619 then
 620         AC_CHECK_LIB(bind, __inet_ntoa)
 621 fi
 622 # Solaris:
 623 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 624 # Cygwin:
 625 AC_CHECK_LIB(cygipc, shmget)
 626 # WIN32:
 627 if test "$PORTNAME" = "win32"
 628 then
 629         AC_CHECK_LIB(wsock32, main)
 630 fi
 631
 632 if test "$with_readline" = yes; then
 633   PGAC_CHECK_READLINE
 634   if test x"$pgac_cv_check_readline" = x"no"; then
 635     AC_MSG_ERROR([readline library not found
 636 If you have readline already installed, see config.log for details on the
 637 failure.  It is possible the compiler isn't looking in the proper directory.
 638 Use --without-readline to disable readline support.])
 639   fi
 640 fi
 641
 642 if test "$with_zlib" = yes; then
 643   AC_CHECK_LIB(z, inflate, [],
 644                [AC_MSG_ERROR([zlib library not found
 645 If you have zlib already installed, see config.log for details on the
 646 failure.  It is possible the compiler isn't looking in the proper directory.
 647 Use --without-zlib to disable zlib support.])])
 648 fi
 649
 650 if test "$enable_spinlocks" = yes; then
 651   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 652 else
 653   AC_MSG_WARN([
 654 *** Not using spinlocks will cause poor performance.])
 655 fi
 656
 657 if test "$with_krb4" = yes ; then
 658   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 659   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 660   AC_REPLACE_FUNCS([gethostname])
 661 fi
 662
 663 if test "$with_krb5" = yes ; then
 664   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 665                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 666   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 667                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 668   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 669                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 670 fi
 671
 672 if test "$with_openssl" = yes ; then
 673   dnl Order matters!
 674   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 675   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 676 fi
 677
 678 if test "$with_pam" = yes ; then
 679   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 680 fi
 681
 682
 683 ##
 684 ## Header files
 685 ##
 686
 687 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 688 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 689
 690 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 691 # netinet/in.h is included first.
 692 AC_CHECK_HEADERS(netinet/in.h)
 693 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 694 [AC_INCLUDES_DEFAULT
 695 #ifdef HAVE_NETINET_IN_H
 696 #include <netinet/in.h>
 697 #endif
 698 ])
 699
 700 if test "$with_readline" = yes; then
 701   AC_CHECK_HEADERS(readline/readline.h, [],
 702                    [AC_CHECK_HEADERS(editline/readline.h, [],
 703                          [AC_CHECK_HEADERS(readline.h, [],
 704                                      [AC_MSG_ERROR([readline header not found
 705 If you have readline already installed, see config.log for details on the
 706 failure.  It is possible the compiler isn't looking in the proper directory.
 707 Use --without-readline to disable readline support.])])])])
 708   AC_CHECK_HEADERS(readline/history.h, [],
 709                    [AC_CHECK_HEADERS(editline/history.h, [],
 710                          [AC_CHECK_HEADERS(history.h, [],
 711                                      [AC_MSG_ERROR([history header not found
 712 If you have readline already installed, see config.log for details on the
 713 failure.  It is possible the compiler isn't looking in the proper directory.
 714 Use --without-readline to disable readline support.])])])])
 715 fi
 716
 717 if test "$with_zlib" = yes; then
 718   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 719 If you have zlib already installed, see config.log for details on the
 720 failure.  It is possible the compiler isn't looking in the proper directory.
 721 Use --without-zlib to disable zlib support.])])
 722 fi
 723
 724 if test "$with_krb4" = yes ; then
 725   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 726 fi
 727
 728 if test "$with_krb5" = yes ; then
 729   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 730   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 731 fi
 732
 733 if test "$with_openssl" = yes ; then
 734   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 735   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 736 fi
 737
 738 if test "$with_pam" = yes ; then
 739   AC_CHECK_HEADERS(security/pam_appl.h, [],
 740                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 741                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 742 fi
 743
 744 if test "$with_rendezvous" = yes ; then
 745   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 746 fi
 747
 748
 749 ##
 750 ## Types, structures, compiler characteristics
 751 ##
 752
 753 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 754 AC_C_CONST
 755 AC_C_INLINE
 756 AC_C_STRINGIZE
 757 PGAC_C_SIGNED
 758 AC_C_VOLATILE
 759 PGAC_C_FUNCNAME_SUPPORT
 760 PGAC_STRUCT_TIMEZONE
 761 PGAC_UNION_SEMUN
 762 PGAC_STRUCT_SOCKADDR_UN
 763 PGAC_STRUCT_SOCKADDR_STORAGE
 764 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 765 PGAC_STRUCT_ADDRINFO
 766
 767 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 768 [#include <sys/param.h>
 769 #include <sys/types.h>
 770 #include <sys/socket.h>
 771 #include <sys/ucred.h>])
 772
 773 AC_CHECK_TYPES([struct option], [], [],
 774 [#ifdef HAVE_GETOPT_H
 775 #include <getopt.h>
 776 #endif])
 777
 778 if test "$with_zlib" = yes; then
 779   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 780   # did not).  While we could work around the lack of z_streamp, it
 781   # seems unwise to encourage people to use such old zlib versions...
 782   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 783 Use --without-zlib to disable zlib support.])],
 784                 [#include <zlib.h>])
 785 fi
 786
 787 if test "$with_krb5" = yes; then
 788 # Check for differences between MIT and Heimdal (KTH) releases
 789   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 790                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 791                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 792                                      [#include <krb5.h>])],
 793                    [#include <krb5.h>])
 794   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 795                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 796                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 797                                      [#include <krb5.h>])],
 798                    [#include <krb5.h>])
 799 fi
 800
 801
 802 ##
 803 ## Functions, global variables
 804 ##
 805
 806 PGAC_VAR_INT_TIMEZONE
 807 AC_FUNC_ACCEPT_ARGTYPES
 808 PGAC_FUNC_GETTIMEOFDAY_1ARG
 809
 810 # SunOS doesn't handle negative byte comparisons properly with +/- return
 811 AC_FUNC_MEMCMP
 812
 813 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 814
 815 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 816
 817 HAVE_IPV6=no
 818 AC_CHECK_TYPE([struct sockaddr_in6],
 819               [AC_CHECK_FUNC(inet_ntop,
 820                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 821                                                           HAVE_IPV6=yes])],
 822               [],
 823 [$ac_includes_default
 824 #include <netinet/in.h>])
 825 AC_SUBST(HAVE_IPV6)
 826
 827 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 828 [AC_TRY_LINK(
 829 [#include <machine/vmparam.h>
 830 #include <sys/exec.h>
 831 ],
 832 [PS_STRINGS->ps_nargvstr = 1;
 833 PS_STRINGS->ps_argvstr = "foo";],
 834 [pgac_cv_var_PS_STRINGS=yes],
 835 [pgac_cv_var_PS_STRINGS=no])])
 836 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 837   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 838 fi
 839
 840
 841 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 842 # is missing.  Yes, there are machines that have only one.  We may
 843 # also decide to use snprintf.c if snprintf() is present but does not
 844 # have working "long long int" support -- see below.
 845
 846 pgac_need_repl_snprintf=no
 847 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 848 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 849
 850
 851 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 852 # include/c.h will provide declarations.  Note this is a separate test
 853 # from whether the functions exist in the C library --- there are
 854 # systems that have the functions but don't bother to declare them :-(
 855
 856 AC_CHECK_DECLS([snprintf, vsnprintf])
 857
 858
 859 # do this one the hard way in case isinf() is a macro
 860 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 861 [AC_TRY_LINK(
 862 [#include <math.h>
 863 ],
 864 [double x = 0.0; int res = isinf(x);],
 865 [ac_cv_func_isinf=yes],
 866 [ac_cv_func_isinf=no])])
 867
 868 if test $ac_cv_func_isinf = yes ; then
 869   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 870 else
 871   AC_LIBOBJ(isinf)
 872   # Look for a way to implement a substitute for isinf()
 873   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 874 fi
 875
 876 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 877
 878 # system's version of getaddrinfo(), if any, may be used only if we found
 879 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 880 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 881   AC_REPLACE_FUNCS([getaddrinfo])
 882 else
 883   AC_LIBOBJ(getaddrinfo)
 884 fi
 885
 886 # similarly, use system's getopt_long() only if system provides struct option.
 887 if test x"$ac_cv_type_struct_option" = xyes ; then
 888   AC_REPLACE_FUNCS([getopt_long])
 889 else
 890   AC_LIBOBJ(getopt_long)
 891 fi
 892
 893 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 894 # We override the previous test that said fseeko/ftello didn't exist
 895 # OS tests are also done in include/c.h and port/fseeko.c
 896 case $host_os in bsdi*|netbsd*)
 897 ac_cv_func_fseeko=yes
 898 esac
 899
 900 # Solaris has a very slow qsort in certain cases, so we replace it.
 901 case $host_os in solaris*)
 902 AC_LIBOBJ(qsort) ;;
 903 esac
 904
 905 # Win32 support
 906 case $host_os in mingw*)
 907 AC_LIBOBJ(copydir)
 908 AC_LIBOBJ(gettimeofday)
 909 AC_LIBOBJ(kill)
 910 AC_LIBOBJ(open)
 911 AC_LIBOBJ(rand)
 912 AC_DEFINE([HAVE_SYMLINK], 1,
 913           [Define to 1 if you have the `symlink' function.])
 914 ;;
 915 esac
 916
 917 if test "$with_readline" = yes; then
 918   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 919   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 920   AC_CHECK_FUNCS([replace_history_entry])
 921 fi
 922
 923
 924 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 925 AC_MSG_CHECKING(for finite)
 926 AC_TRY_LINK([#include <math.h>],
 927             [int dummy=finite(1.0);],
 928             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 929 AC_MSG_RESULT(yes)],
 930             [AC_MSG_RESULT(no)])
 931
 932 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 933 dnl (especially on GNU libc)
 934 dnl See also comments in c.h.
 935 AC_MSG_CHECKING(for sigsetjmp)
 936 AC_TRY_LINK([#include <setjmp.h>],
 937             [sigjmp_buf x; sigsetjmp(x, 1);],
 938             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 939 AC_MSG_RESULT(yes)],
 940             [AC_MSG_RESULT(no)])
 941
 942 AC_CHECK_FUNC(syslog,
 943               [AC_CHECK_HEADER(syslog.h,
 944                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 945
 946 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 947 [AC_TRY_LINK([#include <unistd.h>],
 948   [extern int optreset; optreset = 1;],
 949   [pgac_cv_var_int_optreset=yes],
 950   [pgac_cv_var_int_optreset=no])])
 951 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 952   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 953 fi
 954
 955 AC_CHECK_FUNCS([strtoll strtoq], [break])
 956 AC_CHECK_FUNCS([strtoull strtouq], [break])
 957
 958 # Check for one of atexit() or on_exit()
 959 AC_CHECK_FUNCS(atexit, [],
 960                [AC_CHECK_FUNCS(on_exit, [],
 961                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 962
 963 AC_FUNC_FSEEKO
 964
 965 #
 966 # Pthreads
 967 #
 968 # For each platform, we need to know about any special compile and link
 969 # libraries, and whether the normal C function names are thread-safe.
 970 # See the comment at the top of src/port/thread.c for more information.
 971 #
 972 if test "$enable_thread_safety" = yes; then
 973 ACX_PTHREAD     # set thread flags
 974
 975 # Some platforms use these, so just defineed them.  They can't hurt if they
 976 # are not supported.
 977 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 978
 979
 980 # At this point, we don't want to muck with the compiler name for threading.
 981 # Let's see who fails, perhaps AIX.  2004-04-23
 982 if test "$PTHREAD_CC" != "$CC"; then
 983 AC_MSG_ERROR([
 984 PostgreSQL does not support platforms that require a special
 985 compiler binary for thread-safety.
 986 ])
 987 fi
 988
 989 if test "$THREAD_SUPPORT" = no; then
 990 AC_MSG_ERROR([
 991 Cannot enable threads on your platform.
 992 Your platform is known to not support thread-safe programs.
 993 For details, compile and run src/bin/pg_thread_test.
 994 ])
 995 fi
 996
 997 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
 998
 999 # Check for *_r functions
1000 _CFLAGS="$CFLAGS"
1001 _LIBS="$LIBS"
1002 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1003 LIBS="$LIBS $PTHREAD_LIBS"
1004 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1005
1006 # Do test here with the proper thread flags
1007 PGAC_FUNC_GETPWUID_R_5ARG
1008 PGAC_FUNC_STRERROR_R_INT
1009
1010 CFLAGS="$_CFLAGS"
1011 LIBS="$_LIBS"
1012
1013 else
1014 # do not use values from template file
1015 PTHREAD_CFLAGS=
1016 PTHREAD_LIBS=
1017 fi
1018
1019 AC_SUBST(PTHREAD_CFLAGS)
1020 AC_SUBST(PTHREAD_LIBS)
1021
1022
1023 # This test makes sure that run tests work at all.  Sometimes a shared
1024 # library is found by the linker, but the runtime linker can't find it.
1025 # This check should come after all modifications of compiler or linker
1026 # variables, and before any other run tests.
1027 AC_MSG_CHECKING([test program])
1028 AC_TRY_RUN([int main() { return 0; }],
1029 [AC_MSG_RESULT(ok)],
1030 [AC_MSG_RESULT(failed)
1031 AC_MSG_ERROR([[
1032 *** Could not execute a simple test program.  This may be a problem
1033 *** related to locating shared libraries.  Check the file 'config.log'
1034 *** for the exact reason.]])],
1035 [AC_MSG_RESULT([cross-compiling])])
1036
1037
1038 dnl Check to see if we have a working 64-bit integer type.
1039 dnl This breaks down into two steps:
1040 dnl (1) figure out if the compiler has a 64-bit int type with working
1041 dnl arithmetic, and if so
1042 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1043 dnl snprintf is the only library routine we really need for int8 support.)
1044 dnl It's entirely possible to have a compiler that handles a 64-bit type
1045 dnl when the C library doesn't; this is fairly likely when using gcc on
1046 dnl an older platform, for example.
1047 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1048 dnl we force our own version of snprintf() to be used instead.
1049 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1050
1051 PGAC_TYPE_64BIT_INT([long int])
1052
1053 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1054   PGAC_TYPE_64BIT_INT([long long int])
1055 fi
1056
1057
1058 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1059
1060 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1061   AC_TRY_COMPILE([
1062 #define INT64CONST(x)  x##LL
1063 long long int foo = INT64CONST(0x1234567890123456);
1064 ],
1065         [],
1066         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1067         [])
1068 fi
1069
1070
1071 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1072 # we found we need to use "long long int", better check.  We cope with
1073 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1074 # work, fall back to our own snprintf emulation (which we know uses %lld).
1075
1076 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1077   if test $pgac_need_repl_snprintf = no; then
1078     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1079     if test "$LONG_LONG_INT_FORMAT" = ""; then
1080       # Force usage of our own snprintf, since system snprintf is broken
1081       pgac_need_repl_snprintf=yes
1082       LONG_LONG_INT_FORMAT='%lld'
1083     fi
1084   else
1085     # Here if we previously decided we needed to use our own snprintf
1086     LONG_LONG_INT_FORMAT='%lld'
1087   fi
1088   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1089   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1090   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1091 else
1092   # Here if we are not using 'long long int' at all
1093   INT64_FORMAT='"%ld"'
1094   UINT64_FORMAT='"%lu"'
1095 fi
1096
1097 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1098                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1099
1100 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1101                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1102
1103 if test $pgac_need_repl_snprintf = yes; then
1104   AC_LIBOBJ(snprintf)
1105 fi
1106
1107 # Need a #define for the size of Datum (unsigned long)
1108 AC_CHECK_SIZEOF([unsigned long])
1109
1110 # Determine memory alignment requirements for the basic C data types.
1111
1112 PGAC_CHECK_ALIGNOF(short)
1113 PGAC_CHECK_ALIGNOF(int)
1114 PGAC_CHECK_ALIGNOF(long)
1115 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1116   PGAC_CHECK_ALIGNOF(long long int)
1117 fi
1118 PGAC_CHECK_ALIGNOF(double)
1119
1120 # Compute maximum alignment of any basic type.
1121 # We assume long's alignment is at least as strong as char, short, or int;
1122 # but we must check long long (if it exists) and double.
1123
1124 MAX_ALIGNOF=$pgac_cv_alignof_long
1125 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1126   MAX_ALIGNOF=$pgac_cv_alignof_double
1127 fi
1128 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1129   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1130 fi
1131 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1132
1133
1134 # Some platforms predefine the types int8, int16, etc.  Only check
1135 # a (hopefully) representative subset.
1136 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1137 [#include <stdio.h>
1138 #ifdef HAVE_SUPPORTDEFS_H
1139 #include <SupportDefs.h>
1140 #endif])
1141
1142 # We also check for sig_atomic_t, which *should* be defined per ANSI
1143 # C, but is missing on some old platforms.
1144 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1145
1146
1147 PGAC_FUNC_POSIX_SIGNALS
1148 if test $ac_cv_func_fseeko = yes; then
1149 AC_SYS_LARGEFILE
1150 fi
1151
1152
1153 # Select semaphore implementation type.
1154 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1155   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1156   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1157 else
1158   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1159     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1160     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1161   else
1162     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1163     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1164   fi
1165 fi
1166
1167
1168 # Select shared-memory implementation type.
1169 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1170 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1171
1172
1173 if test "$enable_nls" = yes ; then
1174   PGAC_CHECK_GETTEXT
1175 fi
1176
1177 # Check for Tcl configuration script tclConfig.sh
1178 if test "$with_tcl" = yes; then
1179     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1180     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1181                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1182     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1183 fi
1184
1185 #
1186 # Check for DocBook and tools
1187 #
1188 PGAC_PROG_NSGMLS
1189 PGAC_PROG_JADE
1190 PGAC_CHECK_DOCBOOK(4.2)
1191 PGAC_PATH_DOCBOOK_STYLESHEETS
1192 PGAC_PATH_COLLATEINDEX
1193 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1194
1195 # Thread testing
1196
1197 # We have to run the thread test near the end so we have all our symbols
1198 # defined.  Cross compiling throws a warning.
1199 #
1200 if test "$enable_thread_safety_force" = yes; then
1201   AC_MSG_WARN([
1202 *** Skipping thread test program.  --enable-thread-safety-force was used.
1203 *** Run the program in src/tools/thread on the your machine and add
1204 proper locking function calls to your applications to guarantee thread
1205 safety.
1206 ])
1207 elif test "$enable_thread_safety" = yes; then
1208 AC_MSG_CHECKING([thread safety of required library functions])
1209
1210 _CFLAGS="$CFLAGS"
1211 _LIBS="$LIBS"
1212 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1213 LIBS="$LIBS $PTHREAD_LIBS"
1214 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1215   [AC_MSG_RESULT(yes)],
1216   [AC_MSG_RESULT(no)
1217   AC_MSG_ERROR([
1218 *** Thread test program failed.  Your platform is not thread-safe.
1219 *** Check the file 'config.log'for the exact reason.
1220 ***
1221 *** You can use the configure option --enable-thread-safety-force
1222 *** to force threads to be enabled.  However, you must then run
1223 *** the program in src/tools/thread and add locking function calls
1224 *** to your applications to guarantee thread safety.
1225 ])],
1226   [AC_MSG_RESULT(maybe)
1227   AC_MSG_WARN([
1228 *** Skipping thread test program because of cross-compile build.
1229 *** Run the program in src/tools/thread on the target machine.
1230 ])])
1231 CFLAGS="$_CFLAGS"
1232 LIBS="$_LIBS"
1233 fi
1234
1235 # prepare build tree if outside source tree
1236 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1237 # Note 2: /bin/pwd might be better than shell's built-in at getting
1238 #         a symlink-free name.
1239 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1240   vpath_build=no
1241 else
1242   vpath_build=yes
1243   if test "$no_create" != yes; then
1244     _AS_ECHO_N([preparing build tree... ])
1245     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1246     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1247       || AC_MSG_ERROR(failed)
1248     AC_MSG_RESULT(done)
1249   fi
1250 fi
1251 AC_SUBST(vpath_build)
1252
1253
1254 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1255
1256 AC_CONFIG_LINKS([
1257   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1258   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1259   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1260   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1261   src/include/pg_config_os.h:src/include/port/${template}.h
1262   src/Makefile.port:src/makefiles/Makefile.${template}
1263 ])
1264
1265 case $host_os in mingw*)
1266 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1267 # Links sometimes fail undetected on Mingw -
1268 # so here we detect it and warn the user
1269 for FILE in $CONFIG_LINKS
1270  do
1271         # test -e works for symlinks in the MinGW console
1272         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1273  done
1274 ])
1275         ;;
1276 esac
1277
1278 AC_CONFIG_HEADERS([src/include/pg_config.h],
1279 [
1280 # Update timestamp for pg_config.h (see Makefile.global)
1281 echo >src/include/stamp-h
1282 ])
1283
1284 AC_OUTPUT
1285