granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.2devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2011, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61 dragonfly*) template=netbsd ;;
  62     dgux*) template=dgux ;;
  63  freebsd*) template=freebsd ;;
  64     hpux*) template=hpux ;;
  65     irix*) template=irix ;;
  66  linux*|gnu*|k*bsd*-gnu)
  67            template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-bugs@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Initialize default assumption that we do not need separate assembly code
 107 # for TAS (test-and-set).  This can be overridden by the template file
 108 # when it's executed.
 109 need_tas=no
 110 tas_file=dummy.s
 111
 112
 113
 114 ##
 115 ## Command line options
 116 ##
 117
 118 #
 119 # Add non-standard directories to the include path
 120 #
 121 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 122
 123
 124 #
 125 # Add non-standard directories to the library search path
 126 #
 127 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 128              [LIBRARY_DIRS=$withval])
 129
 130 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 131              [LIBRARY_DIRS=$withval])
 132
 133
 134 #
 135 # 64-bit integer date/time storage: enabled by default.
 136 #
 137 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 138 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 139               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 140                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 141 AC_MSG_RESULT([$enable_integer_datetimes])
 142
 143
 144 #
 145 # NLS
 146 #
 147 AC_MSG_CHECKING([whether NLS is wanted])
 148 PGAC_ARG_OPTARG(enable, nls,
 149                 [LANGUAGES], [enable Native Language Support],
 150                 [],
 151                 [WANTED_LANGUAGES=$enableval],
 152                 [AC_DEFINE(ENABLE_NLS, 1,
 153                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 154 AC_MSG_RESULT([$enable_nls])
 155 AC_SUBST(enable_nls)
 156 AC_SUBST(WANTED_LANGUAGES)
 157
 158 #
 159 # Default port number (--with-pgport), default 5432
 160 #
 161 AC_MSG_CHECKING([for default port number])
 162 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 163              [default_port=$withval],
 164              [default_port=5432])
 165 AC_MSG_RESULT([$default_port])
 166 # Need both of these because some places want an integer and some a string
 167 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 168 [Define to the default TCP port number on which the server listens and
 169 to which clients will try to connect.  This can be overridden at run-time,
 170 but it's convenient if your clients have the right default compiled in.
 171 (--with-pgport=PORTNUM)])
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 173                    [Define to the default TCP port number as a string constant.])
 174 AC_SUBST(default_port)
 175
 176 #
 177 # Option to disable shared libraries
 178 #
 179 PGAC_ARG_BOOL(enable, shared, yes,
 180               [do not build shared libraries])
 181 AC_SUBST(enable_shared)
 182
 183 #
 184 # '-rpath'-like feature can be disabled
 185 #
 186 PGAC_ARG_BOOL(enable, rpath, yes,
 187               [do not embed shared library search path in executables])
 188 AC_SUBST(enable_rpath)
 189
 190 #
 191 # Spinlocks
 192 #
 193 PGAC_ARG_BOOL(enable, spinlocks, yes,
 194               [do not use spinlocks])
 195
 196 #
 197 # --enable-debug adds -g to compiler flags
 198 #
 199 PGAC_ARG_BOOL(enable, debug, no,
 200               [build with debugging symbols (-g)])
 201 AC_SUBST(enable_debug)
 202
 203 #
 204 # --enable-profiling enables gcc profiling
 205 #
 206 PGAC_ARG_BOOL(enable, profiling, no,
 207               [build with profiling enabled ])
 208 AC_SUBST(enable_profiling)
 209
 210 #
 211 # --enable-coverage enables generation of code coverage metrics with gcov
 212 #
 213 PGAC_ARG_BOOL(enable, coverage, no,
 214               [build with coverage testing instrumentation],
 215 [AC_CHECK_PROGS(GCOV, gcov)
 216 if test -z "$GCOV"; then
 217   AC_MSG_ERROR([gcov not found])
 218 fi
 219 AC_CHECK_PROGS(LCOV, lcov)
 220 if test -z "$LCOV"; then
 221   AC_MSG_ERROR([lcov not found])
 222 fi
 223 AC_CHECK_PROGS(GENHTML, genhtml)
 224 if test -z "$GENHTML"; then
 225   AC_MSG_ERROR([genhtml not found])
 226 fi])
 227 AC_SUBST(enable_coverage)
 228
 229 #
 230 # DTrace
 231 #
 232 PGAC_ARG_BOOL(enable, dtrace, no,
 233               [build with DTrace support],
 234 [AC_DEFINE([ENABLE_DTRACE], 1,
 235            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 236 AC_CHECK_PROGS(DTRACE, dtrace)
 237 if test -z "$DTRACE"; then
 238   AC_MSG_ERROR([dtrace not found])
 239 fi
 240 AC_SUBST(DTRACEFLAGS)])
 241 AC_SUBST(enable_dtrace)
 242
 243 #
 244 # Block size
 245 #
 246 AC_MSG_CHECKING([for block size])
 247 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 248              [blocksize=$withval],
 249              [blocksize=8])
 250 case ${blocksize} in
 251   1) BLCKSZ=1024;;
 252   2) BLCKSZ=2048;;
 253   4) BLCKSZ=4096;;
 254   8) BLCKSZ=8192;;
 255  16) BLCKSZ=16384;;
 256  32) BLCKSZ=32768;;
 257   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 258 esac
 259 AC_MSG_RESULT([${blocksize}kB])
 260
 261 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 262  Size of a disk block --- this also limits the size of a tuple.  You
 263  can set it bigger if you need bigger tuples (although TOAST should
 264  reduce the need to have large tuples, since fields can be spread
 265  across multiple tuples).
 266
 267  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 268  is currently 2^15 (32768).  This is determined by the 15-bit widths
 269  of the lp_off and lp_len fields in ItemIdData (see
 270  include/storage/itemid.h).
 271
 272  Changing BLCKSZ requires an initdb.
 273 ])
 274
 275 #
 276 # Relation segment size
 277 #
 278 AC_MSG_CHECKING([for segment size])
 279 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 280              [segsize=$withval],
 281              [segsize=1])
 282 # this expression is set up to avoid unnecessary integer overflow
 283 # blocksize is already guaranteed to be a factor of 1024
 284 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 285 test $? -eq 0 || exit 1
 286 AC_MSG_RESULT([${segsize}GB])
 287
 288 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 289  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 290  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 291  relations bigger than that are divided into multiple files.
 292
 293  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 294  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 295  have large file support enabled.  By default, we make the limit 1 GB
 296  to avoid any possible integer-overflow problems within the OS.
 297  A limit smaller than necessary only means we divide a large
 298  relation into more chunks than necessary, so it seems best to err
 299  in the direction of a small limit.
 300
 301  A power-of-2 value is recommended to save a few cycles in md.c,
 302  but is not absolutely required.
 303
 304  Changing RELSEG_SIZE requires an initdb.
 305 ])
 306
 307 #
 308 # WAL block size
 309 #
 310 AC_MSG_CHECKING([for WAL block size])
 311 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 312              [wal_blocksize=$withval],
 313              [wal_blocksize=8])
 314 case ${wal_blocksize} in
 315   1) XLOG_BLCKSZ=1024;;
 316   2) XLOG_BLCKSZ=2048;;
 317   4) XLOG_BLCKSZ=4096;;
 318   8) XLOG_BLCKSZ=8192;;
 319  16) XLOG_BLCKSZ=16384;;
 320  32) XLOG_BLCKSZ=32768;;
 321  64) XLOG_BLCKSZ=65536;;
 322   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 323 esac
 324 AC_MSG_RESULT([${wal_blocksize}kB])
 325
 326 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 327  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 328  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 329  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 330  buffers, else direct I/O may fail.
 331
 332  Changing XLOG_BLCKSZ requires an initdb.
 333 ])
 334
 335 #
 336 # WAL segment size
 337 #
 338 AC_MSG_CHECKING([for WAL segment size])
 339 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 340              [wal_segsize=$withval],
 341              [wal_segsize=16])
 342 case ${wal_segsize} in
 343   1) ;;
 344   2) ;;
 345   4) ;;
 346   8) ;;
 347  16) ;;
 348  32) ;;
 349  64) ;;
 350   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 351 esac
 352 AC_MSG_RESULT([${wal_segsize}MB])
 353
 354 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 355  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 356  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 357  XLOG_BLCKSZ).
 358
 359  Changing XLOG_SEG_SIZE requires an initdb.
 360 ])
 361
 362 #
 363 # C compiler
 364 #
 365
 366 # For historical reasons you can also use --with-CC to specify the C compiler
 367 # to use, although the standard way to do this is to set the CC environment
 368 # variable.
 369 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 370
 371 case $template in
 372   aix) pgac_cc_list="gcc xlc";;
 373  irix) pgac_cc_list="cc";; # no gcc
 374     *) pgac_cc_list="gcc cc";;
 375 esac
 376
 377 AC_PROG_CC([$pgac_cc_list])
 378
 379 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 380 # but has idiosyncrasies of its own.  We assume icc will define
 381 # __INTEL_COMPILER regardless of CFLAGS.
 382 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 383 choke me
 384 @%:@endif], [ICC=[yes]], [ICC=[no]])
 385
 386 # Check if it's Sun Studio compiler. We assume that
 387 # __SUNPRO_C will be defined for Sun Studio compilers
 388 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 389 choke me
 390 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 391
 392 AC_SUBST(SUN_STUDIO_CC)
 393
 394 unset CFLAGS
 395
 396 #
 397 # Read the template
 398 #
 399 . "$srcdir/src/template/$template" || exit
 400
 401 # CFLAGS are selected so:
 402 # If the user specifies something in the environment, that is used.
 403 # else:  If the template file set something, that is used.
 404 # else:  If coverage was enabled, don't set anything.
 405 # else:  If the compiler is GCC, then we use -O2.
 406 # else:  If the compiler is something else, then we use -O, unless debugging.
 407
 408 if test "$ac_env_CFLAGS_set" = set; then
 409   CFLAGS=$ac_env_CFLAGS_value
 410 elif test "${CFLAGS+set}" = set; then
 411   : # (keep what template set)
 412 elif test "$enable_coverage" = yes; then
 413   : # no optimization by default
 414 elif test "$GCC" = yes; then
 415   CFLAGS="-O2"
 416 else
 417   # if the user selected debug mode, don't use -O
 418   if test "$enable_debug" != yes; then
 419     CFLAGS="-O"
 420   fi
 421 fi
 422
 423 # Some versions of GCC support some additional useful warning flags.
 424 # Check whether they are supported, and add them to CFLAGS if so.
 425 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 426 # but has its own.  Also check other compiler-specific flags here.
 427
 428 if test "$GCC" = yes -a "$ICC" = no; then
 429   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 430   # These work in some but not all gcc versions
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 432   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 433   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 434   # This was included in -Wall/-Wformat in older GCC versions
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 436   # Disable strict-aliasing rules; needed for gcc 3.3+
 437   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 438   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 439   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 440 elif test "$ICC" = yes; then
 441   # Intel's compiler has a bug/misoptimization in checking for
 442   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 443   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 444   # Make sure strict aliasing is off (though this is said to be the default)
 445   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 446 elif test "$PORTNAME" = "aix"; then
 447   # AIX's xlc has to have strict aliasing turned off too
 448   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 449 elif test "$PORTNAME" = "hpux"; then
 450   # On some versions of HP-UX, libm functions do not set errno by default.
 451   # Fix that by using +Olibmerrno if the compiler recognizes it.
 452   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 453 fi
 454
 455 # supply -g if --enable-debug
 456 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 457   CFLAGS="$CFLAGS -g"
 458 fi
 459
 460 # enable code coverage if --enable-coverage
 461 if test "$enable_coverage" = yes; then
 462   if test "$GCC" = yes; then
 463     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 464   else
 465     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 466   fi
 467 fi
 468
 469 # enable profiling if --enable-profiling
 470 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 471   if test "$GCC" = yes; then
 472     AC_DEFINE([PROFILE_PID_DIR], 1,
 473            [Define to 1 to allow profiling output to be saved separately for each process.])
 474     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 475   else
 476     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 477   fi
 478 fi
 479
 480 # We already have this in Makefile.win32, but configure needs it too
 481 if test "$PORTNAME" = "win32"; then
 482   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 483 fi
 484
 485 # Check if the compiler still works with the template settings
 486 AC_MSG_CHECKING([whether the C compiler still works])
 487 AC_TRY_LINK([], [return 0;],
 488   [AC_MSG_RESULT(yes)],
 489   [AC_MSG_RESULT(no)
 490    AC_MSG_ERROR([cannot proceed])])
 491
 492 # Defend against gcc -ffast-math
 493 if test "$GCC" = yes; then
 494 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 495 choke me
 496 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 497 fi
 498
 499 AC_PROG_CPP
 500 AC_SUBST(GCC)
 501
 502
 503 #
 504 # Set up TAS assembly code if needed; the template file has now had its
 505 # chance to request this.
 506 #
 507 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 508
 509 if test "$need_tas" = yes ; then
 510   TAS=tas.o
 511 else
 512   TAS=""
 513 fi
 514 AC_SUBST(TAS)
 515
 516
 517 #
 518 # Automatic dependency tracking
 519 #
 520 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 521               [autodepend=yes])
 522 AC_SUBST(autodepend)
 523
 524
 525 #
 526 # Enable assert checks
 527 #
 528 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 529               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 530                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 531
 532
 533 #
 534 # Include directories
 535 #
 536 ac_save_IFS=$IFS
 537 IFS="${IFS}${PATH_SEPARATOR}"
 538 # SRCH_INC comes from the template file
 539 for dir in $with_includes $SRCH_INC; do
 540   if test -d "$dir"; then
 541     INCLUDES="$INCLUDES -I$dir"
 542   else
 543     AC_MSG_WARN([*** Include directory $dir does not exist.])
 544   fi
 545 done
 546 IFS=$ac_save_IFS
 547 AC_SUBST(INCLUDES)
 548
 549
 550 #
 551 # Library directories
 552 #
 553 ac_save_IFS=$IFS
 554 IFS="${IFS}${PATH_SEPARATOR}"
 555 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 556 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 557   if test -d "$dir"; then
 558     LIBDIRS="$LIBDIRS -L$dir"
 559   else
 560     AC_MSG_WARN([*** Library directory $dir does not exist.])
 561   fi
 562 done
 563 IFS=$ac_save_IFS
 564
 565 #
 566 # Enable thread-safe client libraries
 567 #
 568 AC_MSG_CHECKING([allow thread-safe client libraries])
 569 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 570 if test "$enable_thread_safety" = yes; then
 571   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 572           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 573 fi
 574 AC_MSG_RESULT([$enable_thread_safety])
 575 AC_SUBST(enable_thread_safety)
 576
 577 #
 578 # Optionally build Tcl modules (PL/Tcl)
 579 #
 580 AC_MSG_CHECKING([whether to build with Tcl])
 581 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 582 AC_MSG_RESULT([$with_tcl])
 583 AC_SUBST([with_tcl])
 584
 585 # We see if the path to the Tcl/Tk configuration scripts is specified.
 586 # This will override the use of tclsh to find the paths to search.
 587
 588 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 589
 590 #
 591 # Optionally build Perl modules (PL/Perl)
 592 #
 593 AC_MSG_CHECKING([whether to build Perl modules])
 594 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 595 AC_MSG_RESULT([$with_perl])
 596 AC_SUBST(with_perl)
 597
 598 #
 599 # Optionally build Python modules (PL/Python)
 600 #
 601 AC_MSG_CHECKING([whether to build Python modules])
 602 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 603 AC_MSG_RESULT([$with_python])
 604 AC_SUBST(with_python)
 605
 606 #
 607 # GSSAPI
 608 #
 609 AC_MSG_CHECKING([whether to build with GSSAPI support])
 610 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 611 [
 612   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 613   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 614 ])
 615 AC_MSG_RESULT([$with_gssapi])
 616 AC_SUBST(with_gssapi)
 617
 618 #
 619 # Kerberos 5
 620 #
 621 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 622 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 623 [
 624   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 625   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 626 ])
 627 AC_MSG_RESULT([$with_krb5])
 628 AC_SUBST(with_krb5)
 629
 630
 631 AC_SUBST(krb_srvtab)
 632
 633
 634 #
 635 # Kerberos configuration parameters
 636 #
 637 PGAC_ARG_REQ(with, krb-srvnam,
 638              [NAME], [default service principal name in Kerberos [postgres]],
 639              [],
 640              [with_krb_srvnam="postgres"])
 641 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 642                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 643
 644
 645 #
 646 # PAM
 647 #
 648 AC_MSG_CHECKING([whether to build with PAM support])
 649 PGAC_ARG_BOOL(with, pam, no,
 650               [build with PAM support],
 651               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 652 AC_MSG_RESULT([$with_pam])
 653 AC_SUBST(with_pam)
 654
 655
 656 #
 657 # LDAP
 658 #
 659 AC_MSG_CHECKING([whether to build with LDAP support])
 660 PGAC_ARG_BOOL(with, ldap, no,
 661               [build with LDAP support],
 662               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 663 AC_MSG_RESULT([$with_ldap])
 664 AC_SUBST(with_ldap)
 665
 666
 667 #
 668 # Bonjour
 669 #
 670 AC_MSG_CHECKING([whether to build with Bonjour support])
 671 PGAC_ARG_BOOL(with, bonjour, no,
 672               [build with Bonjour support],
 673               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 674 AC_MSG_RESULT([$with_bonjour])
 675 AC_SUBST(with_bonjour)
 676
 677
 678 #
 679 # OpenSSL
 680 #
 681 AC_MSG_CHECKING([whether to build with OpenSSL support])
 682 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 683               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 684 AC_MSG_RESULT([$with_openssl])
 685 AC_SUBST(with_openssl)
 686
 687 #
 688 # SELinux
 689 #
 690 AC_MSG_CHECKING([whether to build with SELinux support])
 691 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 692 AC_SUBST(with_selinux)
 693 AC_MSG_RESULT([$with_selinux])
 694
 695 #
 696 # Readline
 697 #
 698 PGAC_ARG_BOOL(with, readline, yes,
 699               [do not use GNU Readline nor BSD Libedit for editing])
 700 # readline on MinGW has problems with backslashes in psql and other bugs.
 701 # This is particularly a problem with non-US code pages.
 702 # Therefore disable its use until we understand the cause. 2004-07-20
 703 if test "$PORTNAME" = "win32"; then
 704   if test "$with_readline" = yes; then
 705     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 706     with_readline=no
 707   fi
 708 fi
 709
 710
 711 #
 712 # Prefer libedit
 713 #
 714 PGAC_ARG_BOOL(with, libedit-preferred, no,
 715               [prefer BSD Libedit over GNU Readline])
 716
 717
 718 #
 719 # OSSP UUID library
 720 #
 721 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 722 AC_SUBST(with_ossp_uuid)
 723
 724
 725 #
 726 # XML
 727 #
 728 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 729               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 730
 731 if test "$with_libxml" = yes ; then
 732   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 733   if test -n "$XML2_CONFIG"; then
 734     for pgac_option in `$XML2_CONFIG --cflags`; do
 735       case $pgac_option in
 736         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 737       esac
 738     done
 739     for pgac_option in `$XML2_CONFIG --libs`; do
 740       case $pgac_option in
 741         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 742       esac
 743     done
 744   fi
 745 fi
 746
 747 AC_SUBST(with_libxml)
 748
 749 #
 750 # XSLT
 751 #
 752 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 753               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 754
 755
 756 AC_SUBST(with_libxslt)
 757
 758 #
 759 # tzdata
 760 #
 761 PGAC_ARG_REQ(with, system-tzdata,
 762              [DIR], [use system time zone data in DIR])
 763 AC_SUBST(with_system_tzdata)
 764
 765 #
 766 # Zlib
 767 #
 768 PGAC_ARG_BOOL(with, zlib, yes,
 769               [do not use Zlib])
 770 AC_SUBST(with_zlib)
 771
 772 #
 773 # Elf
 774 #
 775
 776 # Assume system is ELF if it predefines __ELF__ as 1,
 777 # otherwise believe host_os based default.
 778 case $host_os in
 779     freebsd1*|freebsd2*) elf=no;;
 780     freebsd3*|freebsd4*) elf=yes;;
 781 esac
 782
 783 AC_EGREP_CPP(yes,
 784 [#if __ELF__
 785   yes
 786 #endif
 787 ],
 788 [ELF_SYS=true],
 789 [if test "X$elf" = "Xyes" ; then
 790   ELF_SYS=true
 791 else
 792   ELF_SYS=
 793 fi])
 794 AC_SUBST(ELF_SYS)
 795
 796 #
 797 # Assignments
 798 #
 799
 800 CPPFLAGS="$CPPFLAGS $INCLUDES"
 801 LDFLAGS="$LDFLAGS $LIBDIRS"
 802
 803 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 804 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 805
 806 PGAC_PROG_LD
 807 AC_SUBST(LD)
 808 AC_SUBST(with_gnu_ld)
 809 case $host_os in sysv5*)
 810   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 811   [
 812     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 813     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 814     LDFLAGS=$pgac_save_LDFLAGS
 815   ])
 816   ld_R_works=$pgac_cv_prog_ld_R
 817   AC_SUBST(ld_R_works)
 818 esac
 819 AC_PROG_RANLIB
 820 PGAC_CHECK_STRIP
 821 AC_CHECK_TOOL(AR, ar, ar)
 822 if test "$PORTNAME" = "win32"; then
 823   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 824   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 825   AC_CHECK_TOOL(WINDRES, windres, windres)
 826 fi
 827
 828 AC_PATH_PROG(TAR, tar)
 829 AC_PROG_LN_S
 830 AC_PROG_AWK
 831 AC_PROG_MKDIR_P
 832 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 833 # a relative path to it in each makefile where it subsitutes it. This clashes
 834 # with our Makefile.global concept. This workaround helps.
 835 case $MKDIR_P in
 836   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 837 esac
 838
 839 PGAC_PATH_BISON
 840 PGAC_PATH_FLEX
 841
 842 PGAC_PATH_PERL
 843 if test "$with_perl" = yes; then
 844   if test -z "$PERL"; then
 845     AC_MSG_ERROR([Perl not found])
 846   fi
 847   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 848   PGAC_CHECK_PERL_EMBED_LDFLAGS
 849 fi
 850
 851 if test "$with_python" = yes; then
 852   PGAC_PATH_PYTHON
 853   PGAC_CHECK_PYTHON_EMBED_SETUP
 854 fi
 855
 856 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 857   AC_PATH_PROG(ZIC, zic)
 858   if test -z "$ZIC"; then
 859     AC_MSG_ERROR([
 860 When cross-compiling, either use the option --with-system-tzdata to use
 861 existing time-zone data, or set the environment variable ZIC to a zic
 862 program to use during the build.])
 863   fi
 864 fi
 865
 866
 867 ##
 868 ## Libraries
 869 ##
 870 ## Most libraries are included only if they demonstrably provide a function
 871 ## we need, but libm is an exception: always include it, because there are
 872 ## too many compilers that play cute optimization games that will break
 873 ## probes for standard functions such as pow().
 874 ##
 875
 876 AC_CHECK_LIB(m, main)
 877 AC_SEARCH_LIBS(setproctitle, util)
 878 AC_SEARCH_LIBS(dlopen, dl)
 879 AC_SEARCH_LIBS(socket, [socket wsock32])
 880 AC_SEARCH_LIBS(shl_load, dld)
 881 # We only use libld in port/dynloader/aix.c
 882 case $host_os in
 883      aix*)
 884         AC_SEARCH_LIBS(ldopen, ld)
 885         ;;
 886 esac
 887 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 888 AC_SEARCH_LIBS(crypt, crypt)
 889 # Solaris:
 890 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 891 # Required for thread_test.c on Solaris 2.5:
 892 # Other ports use it too (HP-UX) so test unconditionally
 893 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 894 # Cygwin:
 895 AC_SEARCH_LIBS(shmget, cygipc)
 896
 897 if test "$with_readline" = yes; then
 898   PGAC_CHECK_READLINE
 899   if test x"$pgac_cv_check_readline" = x"no"; then
 900     AC_MSG_ERROR([readline library not found
 901 If you have readline already installed, see config.log for details on the
 902 failure.  It is possible the compiler isn't looking in the proper directory.
 903 Use --without-readline to disable readline support.])
 904   fi
 905 fi
 906
 907 if test "$with_zlib" = yes; then
 908   AC_CHECK_LIB(z, inflate, [],
 909                [AC_MSG_ERROR([zlib library not found
 910 If you have zlib already installed, see config.log for details on the
 911 failure.  It is possible the compiler isn't looking in the proper directory.
 912 Use --without-zlib to disable zlib support.])])
 913 fi
 914
 915 if test "$enable_spinlocks" = yes; then
 916   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 917 else
 918   AC_MSG_WARN([
 919 *** Not using spinlocks will cause poor performance.])
 920 fi
 921
 922 if test "$with_gssapi" = yes ; then
 923   if test "$PORTNAME" != "win32"; then
 924     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 925                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 926   else
 927     LIBS="$LIBS -lgssapi32"
 928   fi
 929 fi
 930
 931 if test "$with_krb5" = yes ; then
 932   if test "$PORTNAME" != "win32"; then
 933      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 934                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 935      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 936                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 937   else
 938      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 939                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 940   fi
 941 fi
 942
 943 if test "$with_openssl" = yes ; then
 944   dnl Order matters!
 945   if test "$PORTNAME" != "win32"; then
 946      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 947      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 948   else
 949      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 950      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 951   fi
 952 fi
 953
 954 if test "$with_pam" = yes ; then
 955   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 956 fi
 957
 958 if test "$with_libxml" = yes ; then
 959   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 960 fi
 961
 962 if test "$with_libxslt" = yes ; then
 963   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 964 fi
 965
 966 # for contrib/sepgsql
 967 if test "$with_selinux" = yes; then
 968   AC_CHECK_LIB(selinux, selinux_status_open, [],
 969                [AC_MSG_ERROR([library 'libselinux', version 2.0.99 or newer, is required for SELinux support])])
 970 fi
 971
 972 # for contrib/uuid-ossp
 973 if test "$with_ossp_uuid" = yes ; then
 974   AC_CHECK_LIB(ossp-uuid, uuid_export,
 975     [OSSP_UUID_LIBS="-lossp-uuid"],
 976     [AC_CHECK_LIB(uuid, uuid_export,
 977       [OSSP_UUID_LIBS="-luuid"],
 978       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 979 fi
 980 AC_SUBST(OSSP_UUID_LIBS)
 981
 982
 983 ##
 984 ## Header files
 985 ##
 986
 987 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 988 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/ucred.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 989
 990 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 991 # is included first.
 992 AC_CHECK_HEADERS(net/if.h, [], [],
 993 [AC_INCLUDES_DEFAULT
 994 #ifdef HAVE_SYS_SOCKET_H
 995 #include <sys/socket.h>
 996 #endif
 997 ])
 998
 999 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
1000 # netinet/in.h is included first.
1001 AC_CHECK_HEADERS(netinet/in.h)
1002 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1003 [AC_INCLUDES_DEFAULT
1004 #ifdef HAVE_NETINET_IN_H
1005 #include <netinet/in.h>
1006 #endif
1007 ])
1008
1009 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1010   AC_CHECK_HEADERS(readline/readline.h, [],
1011         [AC_CHECK_HEADERS(readline.h, [],
1012                 [AC_MSG_ERROR([readline header not found
1013 If you have readline already installed, see config.log for details on the
1014 failure.  It is possible the compiler isn't looking in the proper directory.
1015 Use --without-readline to disable readline support.])])])
1016   AC_CHECK_HEADERS(readline/history.h, [],
1017         [AC_CHECK_HEADERS(history.h, [],
1018                 [AC_MSG_ERROR([history header not found
1019 If you have readline already installed, see config.log for details on the
1020 failure.  It is possible the compiler isn't looking in the proper directory.
1021 Use --without-readline to disable readline support.])])])
1022 fi
1023
1024 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1025 # Some installations of libedit usurp /usr/include/readline/, which seems
1026 # bad practice, since in combined installations readline will have its headers
1027 # there.  We might have to resort to AC_EGREP checks to make sure we found
1028 # the proper header...
1029   AC_CHECK_HEADERS(editline/readline.h, [],
1030         [AC_CHECK_HEADERS(readline.h, [],
1031                 [AC_CHECK_HEADERS(readline/readline.h, [],
1032                         [AC_MSG_ERROR([readline header not found
1033 If you have libedit already installed, see config.log for details on the
1034 failure.  It is possible the compiler isn't looking in the proper directory.
1035 Use --without-readline to disable libedit support.])])])])
1036 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1037 # not be there at all.  Hence, don't complain if not found.  We must check
1038 # though, since in yet other versions it is an independent header.
1039   AC_CHECK_HEADERS(editline/history.h, [],
1040         [AC_CHECK_HEADERS(history.h, [],
1041                 [AC_CHECK_HEADERS(readline/history.h)])])
1042 fi
1043
1044 if test "$with_zlib" = yes; then
1045   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1046 If you have zlib already installed, see config.log for details on the
1047 failure.  It is possible the compiler isn't looking in the proper directory.
1048 Use --without-zlib to disable zlib support.])])
1049 fi
1050
1051 if test "$with_gssapi" = yes ; then
1052   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1053         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1054 fi
1055
1056 if test "$with_krb5" = yes ; then
1057   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1058 fi
1059
1060 if test "$with_openssl" = yes ; then
1061   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1062   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1063   AC_CHECK_FUNCS([ERR_set_mark])
1064 fi
1065
1066 if test "$with_pam" = yes ; then
1067   AC_CHECK_HEADERS(security/pam_appl.h, [],
1068                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1069                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1070 fi
1071
1072 if test "$with_libxml" = yes ; then
1073   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1074 fi
1075
1076 if test "$with_libxslt" = yes ; then
1077   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1078 fi
1079
1080 if test "$with_ldap" = yes ; then
1081   if test "$PORTNAME" != "win32"; then
1082      AC_CHECK_HEADERS(ldap.h, [],
1083                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1084   else
1085      AC_CHECK_HEADERS(winldap.h, [],
1086                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1087                       [AC_INCLUDES_DEFAULT
1088 #include <windows.h>
1089                       ])
1090   fi
1091 fi
1092
1093 if test "$with_bonjour" = yes ; then
1094   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1095 fi
1096
1097 # for contrib/uuid-ossp
1098 if test "$with_ossp_uuid" = yes ; then
1099   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1100     AC_CHECK_HEADERS(uuid.h, [],
1101       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1102 fi
1103
1104
1105 ##
1106 ## Types, structures, compiler characteristics
1107 ##
1108
1109 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1110 AC_C_BIGENDIAN
1111 AC_C_CONST
1112 PGAC_C_INLINE
1113 AC_C_STRINGIZE
1114 AC_C_FLEXIBLE_ARRAY_MEMBER
1115 PGAC_C_SIGNED
1116 AC_C_VOLATILE
1117 PGAC_C_FUNCNAME_SUPPORT
1118 PGAC_STRUCT_TIMEZONE
1119 PGAC_UNION_SEMUN
1120 PGAC_STRUCT_SOCKADDR_UN
1121 PGAC_STRUCT_SOCKADDR_STORAGE
1122 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1123 PGAC_STRUCT_ADDRINFO
1124 AC_TYPE_INTPTR_T
1125 AC_TYPE_UINTPTR_T
1126 AC_TYPE_LONG_LONG_INT
1127
1128 PGAC_TYPE_LOCALE_T
1129
1130 AC_CHECK_TYPES([struct cmsgcred], [], [],
1131 [#include <sys/socket.h>
1132 #ifdef HAVE_SYS_UCRED_H
1133 #include <sys/ucred.h>
1134 #endif])
1135
1136 AC_CHECK_TYPES([struct option], [], [],
1137 [#ifdef HAVE_GETOPT_H
1138 #include <getopt.h>
1139 #endif])
1140
1141 if test "$with_zlib" = yes; then
1142   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1143   # did not).  While we could work around the lack of z_streamp, it
1144   # seems unwise to encourage people to use such old zlib versions...
1145   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1146 Use --without-zlib to disable zlib support.])],
1147                 [#include <zlib.h>])
1148 fi
1149
1150 if test "$with_krb5" = yes; then
1151 # Check for differences between MIT and Heimdal (KTH) releases
1152   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1153                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1154                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1155                                      [#include <krb5.h>])],
1156                    [#include <krb5.h>])
1157   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1158                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1159                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1160                                      [#include <krb5.h>])],
1161                    [#include <krb5.h>])
1162
1163 # Win32 requires headers to be loaded for __stdcall, so can't use
1164 # AC_CHECK_FUNCS here.
1165   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1166   AC_TRY_LINK([#include <krb5.h>],
1167               [krb5_free_unparsed_name(NULL,NULL);],
1168               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1169 AC_MSG_RESULT(yes)],
1170               [AC_MSG_RESULT(no)])
1171 fi
1172
1173 # Check largefile support.  You might think this is a system service not a
1174 # compiler characteristic, but you'd be wrong.  We must check this before
1175 # probing existence of related functions such as fseeko, since the largefile
1176 # defines can affect what is generated for that.
1177 AC_SYS_LARGEFILE
1178
1179 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1180 AC_CHECK_SIZEOF([off_t])
1181
1182 # If we don't have largefile support, can't handle segsize >= 2GB.
1183 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1184    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1185 fi
1186
1187
1188 ##
1189 ## Functions, global variables
1190 ##
1191
1192 PGAC_VAR_INT_TIMEZONE
1193 AC_FUNC_ACCEPT_ARGTYPES
1194 PGAC_FUNC_GETTIMEOFDAY_1ARG
1195
1196 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeerucred getrlimit memmove poll pstat readlink scandir setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs wcstombs_l])
1197
1198 AC_REPLACE_FUNCS(fseeko)
1199 case $host_os in
1200         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1201         # Mingw uses macros to access Win32 API calls
1202         bsdi*|netbsd*|mingw*)
1203                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1204                 ac_cv_func_fseeko=yes;;
1205         *)
1206                 AC_FUNC_FSEEKO;;
1207 esac
1208
1209 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1210 # by calling it, 2009-04-02
1211 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1212 if test "$PORTNAME" != "solaris"; then
1213 AC_CHECK_FUNCS(posix_fadvise)
1214 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1215 fi
1216
1217 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1218 AC_CHECK_DECLS([strlcat, strlcpy])
1219 # This is probably only present on Darwin, but may as well check always
1220 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1221
1222 HAVE_IPV6=no
1223 AC_CHECK_TYPE([struct sockaddr_in6],
1224         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1225          HAVE_IPV6=yes],
1226         [],
1227 [$ac_includes_default
1228 #include <netinet/in.h>])
1229 AC_SUBST(HAVE_IPV6)
1230
1231 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1232 [AC_TRY_LINK(
1233 [#include <machine/vmparam.h>
1234 #include <sys/exec.h>
1235 ],
1236 [PS_STRINGS->ps_nargvstr = 1;
1237 PS_STRINGS->ps_argvstr = "foo";],
1238 [pgac_cv_var_PS_STRINGS=yes],
1239 [pgac_cv_var_PS_STRINGS=no])])
1240 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1241   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1242 fi
1243
1244
1245 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1246 # is missing.  Yes, there are machines that have only one.  We may
1247 # also decide to use snprintf.c if snprintf() is present but does not
1248 # have all the features we need --- see below.
1249
1250 if test "$PORTNAME" = "win32"; then
1251   # Win32 gets snprintf.c built unconditionally.
1252   #
1253   # To properly translate all NLS languages strings, we must support the
1254   # *printf() %$ format, which allows *printf() arguments to be selected
1255   # by position in the translated string.
1256   #
1257   # libintl versions < 0.13 use the native *printf() functions, and Win32
1258   # *printf() doesn't understand %$, so we must use our /port versions,
1259   # which do understand %$. libintl versions >= 0.13 include their own
1260   # *printf versions on Win32.  The libintl 0.13 release note text is:
1261   #
1262   #   C format strings with positions, as they arise when a translator
1263   #   needs to reorder a sentence, are now supported on all platforms.
1264   #   On those few platforms (NetBSD and Woe32) for which the native
1265   #   printf()/fprintf()/... functions don't support such format
1266   #   strings, replacements are provided through <libintl.h>.
1267   #
1268   # We could use libintl >= 0.13's *printf() if we were sure that we had
1269   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1270   # to guarantee that, it is best to just use our own, so we are sure to
1271   # get %$ support. In include/port.h we disable the *printf() macros
1272   # that might have been defined by libintl.
1273   #
1274   # We do this unconditionally whether NLS is used or not so we are sure
1275   # that all Win32 libraries and binaries behave the same.
1276   pgac_need_repl_snprintf=yes
1277 else
1278   pgac_need_repl_snprintf=no
1279   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1280   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1281 fi
1282
1283
1284 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1285 # include/c.h will provide declarations.  Note this is a separate test
1286 # from whether the functions exist in the C library --- there are
1287 # systems that have the functions but don't bother to declare them :-(
1288
1289 AC_CHECK_DECLS([snprintf, vsnprintf])
1290
1291
1292 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1293 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1294 [AC_TRY_LINK([
1295 #include <math.h>
1296 double glob_double;
1297 ],
1298 [return isinf(glob_double) ? 0 : 1;],
1299 [ac_cv_func_isinf=yes],
1300 [ac_cv_func_isinf=no])])
1301
1302 if test $ac_cv_func_isinf = yes ; then
1303   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1304 else
1305   AC_LIBOBJ(isinf)
1306   # Look for a way to implement a substitute for isinf()
1307   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1308 fi
1309
1310 # Some versions of libedit contain strlcpy(); so disregard that library while
1311 # checking for these standard libc functions.
1312 pgac_save_LIBS="$LIBS"
1313 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1314
1315 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul])
1316
1317 case $host_os in
1318
1319         # Windows uses a specialised env handler
1320         # and doesn't need a replacement getpeereid because it doesn't use
1321         # Unix sockets.
1322         mingw*)
1323                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1324                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1325                 ac_cv_func_unsetenv=yes
1326                 ac_cv_func_getpeereid=yes;;
1327         *)
1328                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1329                 ;;
1330 esac
1331
1332
1333 LIBS="$pgac_save_LIBS"
1334
1335 # System's version of getaddrinfo(), if any, may be used only if we found
1336 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1337 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1338 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1339 # because we want to use our own getaddrinfo.c on Windows anyway.)
1340 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1341   AC_REPLACE_FUNCS([getaddrinfo])
1342 else
1343   AC_LIBOBJ(getaddrinfo)
1344 fi
1345
1346 # Similarly, use system's getopt_long() only if system provides struct option.
1347 if test x"$ac_cv_type_struct_option" = xyes ; then
1348   AC_REPLACE_FUNCS([getopt_long])
1349 else
1350   AC_LIBOBJ(getopt_long)
1351 fi
1352
1353 # Solaris' getopt() doesn't do what we want for long options, so always use
1354 # our version on that platform.
1355 if test "$PORTNAME" = "solaris"; then
1356   AC_LIBOBJ(getopt)
1357 fi
1358
1359 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1360 # so always use our version on Windows.
1361 if test "$PORTNAME" = "win32"; then
1362   AC_LIBOBJ(getopt)
1363   AC_LIBOBJ(getopt_long)
1364 fi
1365
1366 # Win32 support
1367 if test "$PORTNAME" = "win32"; then
1368   AC_REPLACE_FUNCS(gettimeofday)
1369   AC_LIBOBJ(kill)
1370   AC_LIBOBJ(open)
1371   AC_LIBOBJ(win32env)
1372   AC_LIBOBJ(win32error)
1373   AC_LIBOBJ(win32setlocale)
1374   AC_DEFINE([HAVE_SYMLINK], 1,
1375             [Define to 1 if you have the `symlink' function.])
1376   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1377 #define WIN32_LEAN_AND_MEAN
1378 #include <windows.h>
1379 #include <string.h>
1380 #include <dbghelp.h>])
1381 fi
1382 if test x"$pgac_minidump_type" = x"yes" ; then
1383   AC_SUBST(have_win32_dbghelp,yes)
1384 else
1385   AC_SUBST(have_win32_dbghelp,no)
1386 fi
1387
1388 if test "$with_readline" = yes; then
1389   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1390   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1391   AC_CHECK_FUNCS([append_history history_truncate_file])
1392 fi
1393
1394
1395 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1396 dnl (especially on GNU libc)
1397 dnl See also comments in c.h.
1398 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1399 [AC_TRY_LINK([#include <setjmp.h>],
1400             [sigjmp_buf x; sigsetjmp(x, 1);],
1401             [pgac_cv_func_sigsetjmp=yes],
1402             [pgac_cv_func_sigsetjmp=no])])
1403 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1404   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1405 fi
1406
1407 AC_DECL_SYS_SIGLIST
1408
1409 AC_CHECK_FUNC(syslog,
1410               [AC_CHECK_HEADER(syslog.h,
1411                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1412
1413 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1414 [AC_TRY_LINK([#include <unistd.h>],
1415   [extern int opterr; opterr = 1;],
1416   [pgac_cv_var_int_opterr=yes],
1417   [pgac_cv_var_int_opterr=no])])
1418 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1419   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1420 fi
1421
1422 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1423 [AC_TRY_LINK([#include <unistd.h>],
1424   [extern int optreset; optreset = 1;],
1425   [pgac_cv_var_int_optreset=yes],
1426   [pgac_cv_var_int_optreset=no])])
1427 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1428   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1429 fi
1430
1431 AC_CHECK_FUNCS([strtoll strtoq], [break])
1432 AC_CHECK_FUNCS([strtoull strtouq], [break])
1433
1434 # Check for one of atexit() or on_exit()
1435 AC_CHECK_FUNCS(atexit, [],
1436                [AC_CHECK_FUNCS(on_exit, [],
1437                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1438
1439
1440 #
1441 # Pthreads
1442 #
1443 # For each platform, we need to know about any special compile and link
1444 # libraries, and whether the normal C function names are thread-safe.
1445 # See the comment at the top of src/port/thread.c for more information.
1446 # WIN32 doesn't need the pthread tests;  it always uses threads
1447 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1448 ACX_PTHREAD     # set thread flags
1449
1450 # Some platforms use these, so just define them.  They can't hurt if they
1451 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1452 # enables 5-arg getpwuid_r, among other things.
1453 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1454
1455
1456 # At this point, we don't want to muck with the compiler name for threading.
1457 # Let's see who fails, perhaps AIX.  2004-04-23
1458 if test "$PTHREAD_CC" != "$CC"; then
1459 AC_MSG_ERROR([
1460 PostgreSQL does not support platforms that require a special compiler
1461 for thread safety;  use --disable-thread-safety to disable thread safety.])
1462 fi
1463
1464 # Check for *_r functions
1465 _CFLAGS="$CFLAGS"
1466 _LIBS="$LIBS"
1467 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1468 LIBS="$LIBS $PTHREAD_LIBS"
1469
1470 if test "$PORTNAME" != "win32"; then
1471 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1472 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1473 fi
1474
1475 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1476
1477 # Do test here with the proper thread flags
1478 PGAC_FUNC_GETPWUID_R_5ARG
1479 PGAC_FUNC_STRERROR_R_INT
1480
1481 CFLAGS="$_CFLAGS"
1482 LIBS="$_LIBS"
1483
1484 else
1485 # do not use values from template file
1486 PTHREAD_CFLAGS=
1487 PTHREAD_LIBS=
1488 fi
1489
1490 AC_SUBST(PTHREAD_CFLAGS)
1491 AC_SUBST(PTHREAD_LIBS)
1492
1493
1494 # We can test for libldap_r only after we know PTHREAD_LIBS
1495 if test "$with_ldap" = yes ; then
1496   _LIBS="$LIBS"
1497   if test "$PORTNAME" != "win32"; then
1498     AC_CHECK_LIB(ldap, ldap_bind, [],
1499                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1500                  [$EXTRA_LDAP_LIBS])
1501     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1502     if test "$enable_thread_safety" = yes; then
1503       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1504       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1505                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1506                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1507       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1508     else
1509       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1510     fi
1511   else
1512     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1513     LDAP_LIBS_FE="-lwldap32"
1514     LDAP_LIBS_BE="-lwldap32"
1515   fi
1516   LIBS="$_LIBS"
1517 fi
1518 AC_SUBST(LDAP_LIBS_FE)
1519 AC_SUBST(LDAP_LIBS_BE)
1520
1521
1522 # Older versions of libxml2 lack the xmlStructuredErrorContext variable
1523 # (which could be a macro referring to a function, if threading is enabled)
1524 if test "$with_libxml" = yes ; then
1525   AC_CACHE_CHECK([for xmlStructuredErrorContext], pgac_cv_libxml_structerrctx,
1526   [AC_TRY_LINK([#include <libxml/globals.h>
1527                 void *globptr;],
1528                [globptr = xmlStructuredErrorContext],
1529                [pgac_cv_libxml_structerrctx=yes],
1530                [pgac_cv_libxml_structerrctx=no])])
1531   if test x"$pgac_cv_libxml_structerrctx" = x"yes"; then
1532     AC_DEFINE(HAVE_XMLSTRUCTUREDERRORCONTEXT,
1533              1,
1534              [Define to 1 if your libxml has xmlStructuredErrorContext.])
1535   fi
1536 fi
1537
1538
1539 # This test makes sure that run tests work at all.  Sometimes a shared
1540 # library is found by the linker, but the runtime linker can't find it.
1541 # This check should come after all modifications of compiler or linker
1542 # variables, and before any other run tests.
1543 AC_MSG_CHECKING([test program])
1544 AC_TRY_RUN([int main() { return 0; }],
1545 [AC_MSG_RESULT(ok)],
1546 [AC_MSG_RESULT(failed)
1547 AC_MSG_ERROR([[
1548 Could not execute a simple test program.  This may be a problem
1549 related to locating shared libraries.  Check the file 'config.log'
1550 for the exact reason.]])],
1551 [AC_MSG_RESULT([cross-compiling])])
1552
1553 # --------------------
1554 # Run tests below here
1555 # --------------------
1556
1557 # Force use of our snprintf if system's doesn't do arg control
1558 # See comment above at snprintf test for details.
1559 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1560   PGAC_FUNC_PRINTF_ARG_CONTROL
1561   if test $pgac_cv_printf_arg_control != yes ; then
1562     pgac_need_repl_snprintf=yes
1563   fi
1564 fi
1565
1566
1567 dnl Check to see if we have a working 64-bit integer type.
1568 dnl This breaks down into two steps:
1569 dnl (1) figure out if the compiler has a 64-bit int type with working
1570 dnl arithmetic, and if so
1571 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1572 dnl snprintf is the only library routine we really need for int8 support.)
1573 dnl It's entirely possible to have a compiler that handles a 64-bit type
1574 dnl when the C library doesn't; this is fairly likely when using gcc on
1575 dnl an older platform, for example.
1576 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1577 dnl we force our own version of snprintf() to be used instead.
1578 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1579
1580 dnl As of Postgres 8.4, we no longer support compilers without a working
1581 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1582
1583 PGAC_TYPE_64BIT_INT([long int])
1584
1585 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1586   PGAC_TYPE_64BIT_INT([long long int])
1587   if test x"$HAVE_LONG_LONG_INT_64" = x"no" ; then
1588     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1589   fi
1590 fi
1591
1592
1593 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1594
1595 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1596   AC_TRY_COMPILE([
1597 #define INT64CONST(x)  x##LL
1598 long long int foo = INT64CONST(0x1234567890123456);
1599 ],
1600         [],
1601         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1602         [])
1603 fi
1604
1605
1606 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1607 # we found we need to use "long long int", better check.  We cope with
1608 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1609 # work, fall back to our own snprintf emulation (which we know uses %lld).
1610
1611 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1612   if test $pgac_need_repl_snprintf = no; then
1613     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1614     if test "$LONG_LONG_INT_FORMAT" = ""; then
1615       # Force usage of our own snprintf, since system snprintf is broken
1616       pgac_need_repl_snprintf=yes
1617       LONG_LONG_INT_FORMAT='%lld'
1618     fi
1619   else
1620     # Here if we previously decided we needed to use our own snprintf
1621     LONG_LONG_INT_FORMAT='%lld'
1622   fi
1623   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1624   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1625   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1626 else
1627   # Here if we are not using 'long long int' at all
1628   INT64_FORMAT='"%ld"'
1629   UINT64_FORMAT='"%lu"'
1630 fi
1631
1632 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1633                    [Define to the appropriate snprintf format for 64-bit ints.])
1634
1635 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1636                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1637
1638 # Now we have checked all the reasons to replace snprintf
1639 if test $pgac_need_repl_snprintf = yes; then
1640   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1641   AC_LIBOBJ(snprintf)
1642 fi
1643
1644 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1645 AC_CHECK_SIZEOF([void *])
1646 AC_CHECK_SIZEOF([size_t])
1647 AC_CHECK_SIZEOF([long])
1648
1649 # Decide whether float4 is passed by value: user-selectable, enabled by default
1650 AC_MSG_CHECKING([whether to build with float4 passed by value])
1651 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1652               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1653                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1654                float4passbyval=true],
1655               [float4passbyval=false])
1656 AC_MSG_RESULT([$enable_float4_byval])
1657 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1658
1659 # Decide whether float8 is passed by value.
1660 # Note: this setting also controls int8 and related types such as timestamp.
1661 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1662 # If not, trying to select it is an error.
1663 AC_MSG_CHECKING([whether to build with float8 passed by value])
1664 if test $ac_cv_sizeof_void_p -ge 8 ; then
1665   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1666 else
1667   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1668   if test "$enable_float8_byval" = yes ; then
1669     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1670   fi
1671 fi
1672 if test "$enable_float8_byval" = yes ; then
1673   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1674             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1675   float8passbyval=true
1676 else
1677   float8passbyval=false
1678 fi
1679 AC_MSG_RESULT([$enable_float8_byval])
1680 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1681
1682 # Determine memory alignment requirements for the basic C data types.
1683
1684 AC_CHECK_ALIGNOF(short)
1685 AC_CHECK_ALIGNOF(int)
1686 AC_CHECK_ALIGNOF(long)
1687 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1688   AC_CHECK_ALIGNOF(long long int)
1689 fi
1690 AC_CHECK_ALIGNOF(double)
1691
1692 # Compute maximum alignment of any basic type.
1693 # We assume long's alignment is at least as strong as char, short, or int;
1694 # but we must check long long (if it exists) and double.
1695
1696 MAX_ALIGNOF=$ac_cv_alignof_long
1697 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1698   MAX_ALIGNOF=$ac_cv_alignof_double
1699 fi
1700 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1701   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1702 fi
1703 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1704
1705
1706 # Some platforms predefine the types int8, int16, etc.  Only check
1707 # a (hopefully) representative subset.
1708 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1709 [#include <stdio.h>
1710 #ifdef HAVE_SUPPORTDEFS_H
1711 #include <SupportDefs.h>
1712 #endif])
1713
1714 # We also check for sig_atomic_t, which *should* be defined per ANSI
1715 # C, but is missing on some old platforms.
1716 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1717
1718
1719 if test "$PORTNAME" != "win32"
1720 then
1721 PGAC_FUNC_POSIX_SIGNALS
1722 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1723   AC_MSG_ERROR([
1724 Thread-safety requires POSIX signals, which are not supported by this
1725 operating system;  use --disable-thread-safety to disable thread safety.])
1726 fi
1727 fi
1728
1729 # SunOS doesn't handle negative byte comparisons properly with +/- return
1730 AC_FUNC_MEMCMP
1731
1732
1733 # Select semaphore implementation type.
1734 if test "$PORTNAME" != "win32"; then
1735   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1736     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1737     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1738   else
1739     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1740       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1741       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1742     else
1743       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1744       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1745     fi
1746   fi
1747 else
1748   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1749   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1750 fi
1751
1752
1753 # Select shared-memory implementation type.
1754 if test "$PORTNAME" != "win32"; then
1755   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1756   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1757 else
1758   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1759   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1760 fi
1761
1762 # Select latch implementation type.
1763 if test "$PORTNAME" != "win32"; then
1764   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1765 else
1766   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1767 fi
1768
1769 # If not set in template file, set bytes to use libc memset()
1770 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1771   MEMSET_LOOP_LIMIT=1024
1772 fi
1773 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1774
1775
1776 if test "$enable_nls" = yes ; then
1777   PGAC_CHECK_GETTEXT
1778 fi
1779
1780 # Check for Tcl configuration script tclConfig.sh
1781 if test "$with_tcl" = yes; then
1782     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1783     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1784                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1785     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1786     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1787     ac_save_CPPFLAGS=$CPPFLAGS
1788     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1789     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1790     CPPFLAGS=$ac_save_CPPFLAGS
1791 fi
1792
1793 # check for <Python.h>
1794 if test "$with_python" = yes; then
1795   ac_save_CPPFLAGS=$CPPFLAGS
1796   CPPFLAGS="$python_includespec $CPPFLAGS"
1797   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1798   CPPFLAGS=$ac_save_CPPFLAGS
1799 fi
1800
1801 #
1802 # Check for DocBook and tools
1803 #
1804 PGAC_PROG_NSGMLS
1805 PGAC_PROG_JADE
1806 PGAC_CHECK_DOCBOOK(4.2)
1807 PGAC_PATH_DOCBOOK_STYLESHEETS
1808 PGAC_PATH_COLLATEINDEX
1809 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1810 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1811
1812 # Thread testing
1813
1814 # We have to run the thread test near the end so we have all our symbols
1815 # defined.  Cross compiling throws a warning.
1816 #
1817 if test "$enable_thread_safety" = yes; then
1818 if test "$PORTNAME" != "win32"
1819 then
1820 AC_MSG_CHECKING([thread safety of required library functions])
1821
1822 _CFLAGS="$CFLAGS"
1823 _LIBS="$LIBS"
1824 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1825 LIBS="$LIBS $PTHREAD_LIBS"
1826 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1827   [AC_MSG_RESULT(yes)],
1828   [AC_MSG_RESULT(no)
1829   AC_MSG_ERROR([thread test program failed
1830 This platform is not thread-safe.  Check the file 'config.log' or compile
1831 and run src/test/thread/thread_test for the exact reason.
1832 Use --disable-thread-safety to disable thread safety.])],
1833   [AC_MSG_RESULT(maybe)
1834   AC_MSG_WARN([
1835 *** Skipping thread test program because of cross-compile build.
1836 *** Run the program in src/test/thread on the target machine.
1837 ])])
1838 CFLAGS="$_CFLAGS"
1839 LIBS="$_LIBS"
1840 else
1841 AC_MSG_WARN([*** skipping thread test on Win32])
1842 fi
1843 fi
1844
1845 # If compiler will take -Wl,--as-needed (or various platform-specific
1846 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1847 # trying to filter LIBS to the minimum for each executable.
1848 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1849 # libreadline; therefore we postpone testing it until we know what library
1850 # dependencies readline has.  The test code will try to link with $LIBS.
1851 if test "$with_readline" = yes; then
1852   link_test_func=readline
1853 else
1854   link_test_func=exit
1855 fi
1856
1857 if test "$PORTNAME" = "darwin"; then
1858   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1859 elif test "$PORTNAME" = "openbsd"; then
1860   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1861 else
1862   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1863 fi
1864
1865 # Create compiler version string
1866 if test x"$GCC" = x"yes" ; then
1867   cc_string=`${CC} --version | sed q`
1868   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1869 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1870   cc_string=`${CC} -V 2>&1 | sed q`
1871 else
1872   cc_string=$CC
1873 fi
1874
1875 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1876                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1877                    [A string containing the version number, platform, and C compiler])
1878
1879 # Supply a numeric version string for use by 3rd party add-ons
1880 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1881 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1882 tr '.' '        ' |
1883 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1884 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1885
1886
1887 # Begin output steps
1888
1889 AC_MSG_NOTICE([using compiler=$cc_string])
1890 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1891 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1892 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1893
1894 # prepare build tree if outside source tree
1895 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1896 # Note 2: /bin/pwd might be better than shell's built-in at getting
1897 #         a symlink-free name.
1898 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1899   vpath_build=no
1900 else
1901   vpath_build=yes
1902   if test "$no_create" != yes; then
1903     _AS_ECHO_N([preparing build tree... ])
1904     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1905     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1906       || AC_MSG_ERROR(failed)
1907     AC_MSG_RESULT(done)
1908   fi
1909 fi
1910 AC_SUBST(vpath_build)
1911
1912
1913 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1914
1915 AC_CONFIG_LINKS([
1916   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1917   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1918   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1919   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1920   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1921   src/include/pg_config_os.h:src/include/port/${template}.h
1922   src/Makefile.port:src/makefiles/Makefile.${template}
1923 ])
1924
1925 if test "$PORTNAME" = "win32"; then
1926 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1927 # Links sometimes fail undetected on Mingw -
1928 # so here we detect it and warn the user
1929 for FILE in $CONFIG_LINKS
1930  do
1931         # test -e works for symlinks in the MinGW console
1932         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1933  done
1934 ])
1935 fi
1936
1937 AC_CONFIG_HEADERS([src/include/pg_config.h],
1938 [
1939 # Update timestamp for pg_config.h (see Makefile.global)
1940 echo >src/include/stamp-h
1941 ])
1942
1943 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1944                   [echo >src/interfaces/ecpg/include/stamp-h])
1945
1946 AC_OUTPUT