granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(srclib/apr/build/find_apr.m4)
  20 sinclude(srclib/apr-util/build/find_apu.m4)
  21 sinclude(acinclude.m4)
  22
  23 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  24 dnl by configure until it is too late.  Is that how it should be or not?
  25 dnl Something seems broken here.
  26 AC_PREFIX_DEFAULT(/usr/local/apache2)
  27
  28 dnl Get the layout here, so we can pass the required variables to apr
  29 APACHE_ENABLE_LAYOUT
  30
  31 dnl reparse the configure arguments.
  32 APACHE_PARSE_ARGUMENTS
  33
  34 dnl export expanded and relative configure argument variables
  35 APACHE_EXPORT_ARGUMENTS
  36
  37 dnl Save user-defined environment settings for later restoration
  38 dnl
  39 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  42 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  43 APR_SAVE_THE_ENVIRONMENT(LIBS)
  44 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  45
  46 dnl Generate ./config.nice for reproducing runs of configure
  47 dnl
  48 APR_CONFIG_NICE(config.nice)
  49
  50 nl='
  51 '
  52 dnl Check that mkdir -p works
  53 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  54
  55 dnl ## Run configure for packages Apache uses
  56
  57 dnl shared library support for these packages doesn't currently
  58 dnl work on some platforms
  59
  60 AC_CANONICAL_SYSTEM
  61
  62 orig_prefix="$prefix"
  63
  64 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  65
  66 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr")
  67
  68 if test "$apr_found" = "no"; then
  69   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  70 fi
  71
  72 if test "$apr_found" = "reconfig"; then
  73   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  80 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  81 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  82 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  83 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  84
  85 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  86
  87 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util")
  88
  89 if test "$apu_found" = "no"; then
  90   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  91 fi
  92
  93 if test "$apu_found" = "reconfig"; then
  94   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  95   dnl We must be the last to build and the first to be cleaned
  96   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  97   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  98 fi
  99
 100 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 101 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 102
 103 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 104
 105 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 106
 107 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 108
 109 dnl Absolute source/build directory
 110 abs_srcdir=`(cd $srcdir && pwd)`
 111 abs_builddir=`pwd`
 112
 113 dnl If the source dir is not equal to the build dir,
 114 dnl then we are running in VPATH mode.
 115
 116 if test "$abs_builddir" != "$abs_srcdir"; then
 117   USE_VPATH=1
 118   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/modules/proxy -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/modules/filters -I\$(top_srcdir)/modules/filters -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 119 else
 120   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 121 fi
 122
 123 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 124
 125 case $host in
 126   *os2*)
 127       # Use a custom made libtool replacement
 128       echo "using aplibtool"
 129       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 130       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 131       SH_LIBS="\$(ALL_LIBS)"
 132       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 133       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 134       MK_IMPLIB="emximp"
 135       other_targets="$other_targets os2core"
 136       INSTALL_PROG_FLAGS="-e .exe"
 137       SHLTCFLAGS=""
 138       LTCFLAGS=""
 139       ;;
 140   *)
 141       if test "x$LTFLAGS" = "x"; then
 142           LTFLAGS='--silent'
 143       fi
 144       my_libtool=`$apr_config --apr-libtool`
 145       LIBTOOL="$my_libtool \$(LTFLAGS)"
 146       libtoolversion=`$my_libtool --version`
 147       case $libtoolversion in
 148           *1.4*)
 149               SH_LIBTOOL='$(LIBTOOL)'
 150               SHLTCFLAGS="-prefer-pic"
 151               LTCFLAGS="-prefer-non-pic -static"
 152               ;;
 153           *)
 154               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 155               SHLTCFLAGS=""
 156               LTCFLAGS=""
 157               ;;
 158       esac
 159       ;;
 160 esac
 161 APACHE_SUBST(SHLTCFLAGS)
 162 APACHE_SUBST(LTCFLAGS)
 163
 164 AP_SIG_GRACEFUL=USR1
 165
 166 case $host in
 167   *-apple-aux3*)
 168       APR_SETVAR(APACHE_MPM, [prefork])
 169       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 170       ;;
 171   *-beos*)
 172       APR_SETVAR(APACHE_MPM, [beos])
 173       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 174       ;;
 175   *os2_emx*)
 176       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 177       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 178       ;;
 179   *-linux-*)
 180       case `uname -r` in
 181         2.0* )
 182             AP_SIG_GRACEFUL=WINCH
 183             ;;
 184         2.[[2-9]]* )
 185             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 186             ;;
 187         * )
 188             ;;
 189       esac
 190       ;;
 191   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 192       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 193       ;;
 194   *-solaris2*)
 195       dnl This is a hack -- we should be using AC_TRY_RUN instead
 196       ap_platform_runtime_link_flag="-R"
 197       dnl solaris 8 and above don't have a thundering herd
 198       dnl not sure about rev's before this one.
 199       case `uname -r` in
 200         5.[567]*)
 201             ;;
 202         * )
 203             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 204             ;;
 205       esac
 206       ;;
 207   *cygwin*)
 208       APR_SETVAR(APACHE_MPM, [prefork])
 209       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 210       ;;
 211   *aix*)
 212       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 213       if test $aixver -ge 4320; then
 214         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 215       fi
 216       ;;
 217 esac
 218
 219 dnl
 220 dnl Process command line arguments. This is done early in the process so the
 221 dnl user can get feedback quickly in case of an error.
 222 dnl
 223 dnl ### need to move some of the arguments "up here"
 224
 225 dnl ## Check for programs
 226
 227 AC_PATH_PROG(RM, rm)
 228 AC_PROG_AWK
 229 AC_PROG_CC
 230 AC_PROG_CPP
 231 AC_PROG_INSTALL
 232 AC_PROG_LN_S
 233 AC_CHECK_TOOL(RANLIB, ranlib, true)
 234 dnl AC_PATH_PROG(PERL_PATH, perl)
 235
 236 dnl various OS checks that apparently set required flags
 237 AC_AIX
 238 AC_ISC_POSIX
 239 AC_MINIX
 240
 241 dnl ## Check for libraries
 242
 243 dnl ## Check for header files
 244
 245 dnl I think these are just used all over the place, so just check for
 246 dnl them at the base of the tree. If some are specific to a single
 247 dnl directory, they should be moved (Comment #Spoon)
 248
 249 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 250 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 251 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 252
 253 AC_HEADER_STDC
 254 AC_CHECK_HEADERS( \
 255 string.h \
 256 limits.h \
 257 unistd.h \
 258 sys/socket.h \
 259 pwd.h \
 260 grp.h \
 261 strings.h \
 262 sys/processor.h \
 263 sys/sem.h
 264 )
 265 AC_HEADER_SYS_WAIT
 266
 267 dnl ## Check for typedefs, structures, and compiler characteristics.
 268
 269 AC_C_CONST
 270 if test "$ac_cv_prog_gcc" = "yes"; then
 271   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 272 fi
 273
 274 dnl ## Check for library functions
 275
 276 dnl See Comment #Spoon
 277
 278 AC_CHECK_FUNCS( \
 279 getpwnam \
 280 getgrnam \
 281 initgroups \
 282 bindprocessor \
 283 timegm \
 284 )
 285
 286 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 287 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 288 [AC_TRY_COMPILE([#include <sys/types.h>
 289 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 290   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 291 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 292     AC_DEFINE(HAVE_GMTOFF)
 293 fi
 294
 295 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 296
 297 case $host in
 298     *aix*)
 299         # for 32-bit builds, increase MAXDATA to allow lots of threads
 300         if test x$OBJECT_MODE != x64; then
 301             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 302         fi
 303         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 304         ;;
 305     *os390*)
 306         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 307         ;;
 308     *)
 309         OS_SPECIFIC_VARS=""
 310 esac
 311
 312 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 313         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 314         [PORT=80])
 315
 316 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 317 [
 318   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 319 ])dnl
 320
 321 prefix="$orig_prefix"
 322 APACHE_ENABLE_MODULES
 323
 324 dnl reading config stubs
 325 esyscmd(./build/config-stubs .)
 326
 327 APACHE_SUBST(progname)
 328 APACHE_SUBST(MPM_LIB)
 329 APACHE_SUBST(OS)
 330 APACHE_SUBST(OS_DIR)
 331 APACHE_SUBST(BUILTIN_LIBS)
 332 APACHE_SUBST(SHLIBPATH_VAR)
 333 APACHE_SUBST(OS_SPECIFIC_VARS)
 334
 335 PRE_SHARED_CMDS='echo ""'
 336 POST_SHARED_CMDS='echo ""'
 337
 338 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 339
 340 if test "$apache_need_shared" = "yes"; then
 341   if test -f $ac_aux_dir/ltconfig; then
 342     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 343   fi
 344   shared_build="shared-build"
 345 fi
 346
 347 dnl enable_so tells us if *any* modules can be built as DSOs
 348
 349 if test "$enable_so" = "yes"; then
 350   case $host in
 351     *-ibm-aix*)
 352       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 353       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 354       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 355       ;;
 356     *beos)
 357       SH_LDFLAGS='$(top_builddir)/_APP_'
 358       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 359       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 360       ;;
 361     *os390)
 362       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 363       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 364   esac
 365 fi
 366
 367 APACHE_SUBST(PRE_SHARED_CMDS)
 368 APACHE_SUBST(POST_SHARED_CMDS)
 369 APACHE_SUBST(shared_build)
 370
 371 AC_ARG_WITH(program-name,
 372 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 373   progname="$withval" ], [
 374   progname="httpd"] )
 375
 376 # SuExec parameters
 377 AC_ARG_WITH(suexec-bin,
 378 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 379   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 380 ] )
 381
 382 AC_ARG_WITH(suexec-caller,
 383 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 384   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 385
 386 AC_ARG_WITH(suexec-userdir,
 387 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 388   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 389
 390 AC_ARG_WITH(suexec-docroot,
 391 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 392   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 393
 394 AC_ARG_WITH(suexec-uidmin,
 395 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 396   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 397
 398 AC_ARG_WITH(suexec-gidmin,
 399 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 400   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 401
 402 AC_ARG_WITH(suexec-logfile,
 403 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 404   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 405
 406 AC_ARG_WITH(suexec-safepath,
 407 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 408   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 409
 410 AC_ARG_WITH(suexec-umask,
 411 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 412   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 413
 414 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 415 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 416
 417 dnl APR should go after the other libs, so the right symbols can be picked up
 418 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 419 APACHE_SUBST(AP_LIBS)
 420 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 421 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 422
 423 AC_DEFINE(AP_USING_AUTOCONF, 1,
 424                 [Using autoconf to configure Apache])
 425
 426 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 427     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 428               [This platform doesn't suffer from the thundering herd problem])
 429 fi
 430
 431 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 432 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 433 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 434 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 435 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 436 AC_SUBST(AP_SIG_GRACEFUL)
 437 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 438 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 439
 440 dnl check for endianness
 441 if test "$cross_compiling" = "no"; then
 442   AC_C_BIGENDIAN
 443 else
 444   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 445                 [byte order is unknown due to cross-compilation])
 446 fi
 447
 448 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 449 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 450 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 451 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 452
 453 if test -d ./test; then
 454     APACHE_FAST_OUTPUT(test/Makefile)
 455 fi
 456
 457 dnl ## Finalize the variables
 458 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 459
 460 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 461 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 462 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 463 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 464 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 465 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 466
 467 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 468
 469 APACHE_GEN_CONFIG_VARS
 470
 471 dnl ## Build modules.c
 472 rm -f modules.c
 473 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 474
 475 APR_EXPAND_VAR(ap_prefix, $prefix)
 476 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 477         [Root directory of the Apache install area])
 478 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 479         [Location of the config file, relative to the Apache root directory])
 480 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 481         [Location of the source for the current MPM])
 482
 483 perlbin=`$ac_aux_dir/PrintPath perl`
 484 if test "x$perlbin" = "x"; then
 485     perlbin="/replace/with/path/to/perl/interpreter"
 486 fi
 487 AC_SUBST(perlbin)
 488
 489 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 490
 491 BSD_MAKEFILE=no
 492 ap_make_include=include
 493 ap_make_delimiter=' '
 494 case $host in
 495 *bsdi*)
 496     # Check whether they've installed GNU make
 497     if make --version > /dev/null 2>&1; then
 498         true
 499     else
 500         BSD_MAKEFILE=yes
 501         ap_make_include=.include
 502         ap_make_delimiter='"'
 503     fi
 504     ;;
 505 esac
 506 AC_SUBST(ap_make_include)
 507 AC_SUBST(ap_make_delimiter)
 508
 509 dnl Ensure that docs/conf is created.
 510 test -d docs/conf||$mkdir_p docs/conf
 511
 512 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 513   APACHE_GEN_MAKEFILES
 514 ])
 515