granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2013, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58   cygwin*) template=cygwin ;;
  59   darwin*) template=darwin ;;
  60 dragonfly*) template=netbsd ;;
  61  freebsd*) template=freebsd ;;
  62     hpux*) template=hpux ;;
  63     irix*) template=irix ;;
  64  linux*|gnu*|k*bsd*-gnu)
  65            template=linux ;;
  66    mingw*) template=win32 ;;
  67   netbsd*) template=netbsd ;;
  68  openbsd*) template=openbsd ;;
  69      osf*) template=osf ;;
  70      sco*) template=sco ;;
  71  solaris*) template=solaris ;;
  72    sysv5*) template=unixware ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage: enabled by default.
 126 #
 127 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 128 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 129               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 130                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 131 AC_MSG_RESULT([$enable_integer_datetimes])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 #
 167 # '-rpath'-like feature can be disabled
 168 #
 169 PGAC_ARG_BOOL(enable, rpath, yes,
 170               [do not embed shared library search path in executables])
 171 AC_SUBST(enable_rpath)
 172
 173 #
 174 # Spinlocks
 175 #
 176 PGAC_ARG_BOOL(enable, spinlocks, yes,
 177               [do not use spinlocks])
 178
 179 #
 180 # --enable-debug adds -g to compiler flags
 181 #
 182 PGAC_ARG_BOOL(enable, debug, no,
 183               [build with debugging symbols (-g)])
 184 AC_SUBST(enable_debug)
 185
 186 #
 187 # --enable-profiling enables gcc profiling
 188 #
 189 PGAC_ARG_BOOL(enable, profiling, no,
 190               [build with profiling enabled ])
 191
 192 #
 193 # --enable-coverage enables generation of code coverage metrics with gcov
 194 #
 195 PGAC_ARG_BOOL(enable, coverage, no,
 196               [build with coverage testing instrumentation],
 197 [AC_CHECK_PROGS(GCOV, gcov)
 198 if test -z "$GCOV"; then
 199   AC_MSG_ERROR([gcov not found])
 200 fi
 201 AC_CHECK_PROGS(LCOV, lcov)
 202 if test -z "$LCOV"; then
 203   AC_MSG_ERROR([lcov not found])
 204 fi
 205 AC_CHECK_PROGS(GENHTML, genhtml)
 206 if test -z "$GENHTML"; then
 207   AC_MSG_ERROR([genhtml not found])
 208 fi])
 209 AC_SUBST(enable_coverage)
 210
 211 #
 212 # DTrace
 213 #
 214 PGAC_ARG_BOOL(enable, dtrace, no,
 215               [build with DTrace support],
 216 [AC_CHECK_PROGS(DTRACE, dtrace)
 217 if test -z "$DTRACE"; then
 218   AC_MSG_ERROR([dtrace not found])
 219 fi
 220 AC_SUBST(DTRACEFLAGS)])
 221 AC_SUBST(enable_dtrace)
 222
 223 #
 224 # Block size
 225 #
 226 AC_MSG_CHECKING([for block size])
 227 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 228              [blocksize=$withval],
 229              [blocksize=8])
 230 case ${blocksize} in
 231   1) BLCKSZ=1024;;
 232   2) BLCKSZ=2048;;
 233   4) BLCKSZ=4096;;
 234   8) BLCKSZ=8192;;
 235  16) BLCKSZ=16384;;
 236  32) BLCKSZ=32768;;
 237   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 238 esac
 239 AC_MSG_RESULT([${blocksize}kB])
 240
 241 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 242  Size of a disk block --- this also limits the size of a tuple.  You
 243  can set it bigger if you need bigger tuples (although TOAST should
 244  reduce the need to have large tuples, since fields can be spread
 245  across multiple tuples).
 246
 247  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 248  is currently 2^15 (32768).  This is determined by the 15-bit widths
 249  of the lp_off and lp_len fields in ItemIdData (see
 250  include/storage/itemid.h).
 251
 252  Changing BLCKSZ requires an initdb.
 253 ])
 254
 255 #
 256 # Relation segment size
 257 #
 258 AC_MSG_CHECKING([for segment size])
 259 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 260              [segsize=$withval],
 261              [segsize=1])
 262 # this expression is set up to avoid unnecessary integer overflow
 263 # blocksize is already guaranteed to be a factor of 1024
 264 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 265 test $? -eq 0 || exit 1
 266 AC_MSG_RESULT([${segsize}GB])
 267
 268 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 269  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 270  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 271  relations bigger than that are divided into multiple files.
 272
 273  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 274  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 275  have large file support enabled.  By default, we make the limit 1 GB
 276  to avoid any possible integer-overflow problems within the OS.
 277  A limit smaller than necessary only means we divide a large
 278  relation into more chunks than necessary, so it seems best to err
 279  in the direction of a small limit.
 280
 281  A power-of-2 value is recommended to save a few cycles in md.c,
 282  but is not absolutely required.
 283
 284  Changing RELSEG_SIZE requires an initdb.
 285 ])
 286
 287 #
 288 # WAL block size
 289 #
 290 AC_MSG_CHECKING([for WAL block size])
 291 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 292              [wal_blocksize=$withval],
 293              [wal_blocksize=8])
 294 case ${wal_blocksize} in
 295   1) XLOG_BLCKSZ=1024;;
 296   2) XLOG_BLCKSZ=2048;;
 297   4) XLOG_BLCKSZ=4096;;
 298   8) XLOG_BLCKSZ=8192;;
 299  16) XLOG_BLCKSZ=16384;;
 300  32) XLOG_BLCKSZ=32768;;
 301  64) XLOG_BLCKSZ=65536;;
 302   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 303 esac
 304 AC_MSG_RESULT([${wal_blocksize}kB])
 305
 306 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 307  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 308  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 309  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 310  buffers, else direct I/O may fail.
 311
 312  Changing XLOG_BLCKSZ requires an initdb.
 313 ])
 314
 315 #
 316 # WAL segment size
 317 #
 318 AC_MSG_CHECKING([for WAL segment size])
 319 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 320              [wal_segsize=$withval],
 321              [wal_segsize=16])
 322 case ${wal_segsize} in
 323   1) ;;
 324   2) ;;
 325   4) ;;
 326   8) ;;
 327  16) ;;
 328  32) ;;
 329  64) ;;
 330   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 331 esac
 332 AC_MSG_RESULT([${wal_segsize}MB])
 333
 334 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 335  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 336  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 337  XLOG_BLCKSZ).
 338
 339  Changing XLOG_SEG_SIZE requires an initdb.
 340 ])
 341
 342 #
 343 # C compiler
 344 #
 345
 346 # For historical reasons you can also use --with-CC to specify the C compiler
 347 # to use, although the standard way to do this is to set the CC environment
 348 # variable.
 349 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 350
 351 case $template in
 352   aix) pgac_cc_list="gcc xlc";;
 353  irix) pgac_cc_list="cc";; # no gcc
 354     *) pgac_cc_list="gcc cc";;
 355 esac
 356
 357 AC_PROG_CC([$pgac_cc_list])
 358
 359 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 360 # but has idiosyncrasies of its own.  We assume icc will define
 361 # __INTEL_COMPILER regardless of CFLAGS.
 362 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 363 choke me
 364 @%:@endif], [ICC=[yes]], [ICC=[no]])
 365
 366 # Check if it's Sun Studio compiler. We assume that
 367 # __SUNPRO_C will be defined for Sun Studio compilers
 368 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 369 choke me
 370 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 371
 372 AC_SUBST(SUN_STUDIO_CC)
 373
 374 unset CFLAGS
 375
 376 #
 377 # Read the template
 378 #
 379 . "$srcdir/src/template/$template" || exit
 380
 381 # CFLAGS are selected so:
 382 # If the user specifies something in the environment, that is used.
 383 # else:  If the template file set something, that is used.
 384 # else:  If coverage was enabled, don't set anything.
 385 # else:  If the compiler is GCC, then we use -O2.
 386 # else:  If the compiler is something else, then we use -O, unless debugging.
 387
 388 if test "$ac_env_CFLAGS_set" = set; then
 389   CFLAGS=$ac_env_CFLAGS_value
 390 elif test "${CFLAGS+set}" = set; then
 391   : # (keep what template set)
 392 elif test "$enable_coverage" = yes; then
 393   : # no optimization by default
 394 elif test "$GCC" = yes; then
 395   CFLAGS="-O2"
 396 else
 397   # if the user selected debug mode, don't use -O
 398   if test "$enable_debug" != yes; then
 399     CFLAGS="-O"
 400   fi
 401 fi
 402
 403 # set CFLAGS_VECTOR from the environment, if available
 404 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 405   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 406 fi
 407
 408 # Some versions of GCC support some additional useful warning flags.
 409 # Check whether they are supported, and add them to CFLAGS if so.
 410 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 411 # but has its own.  Also check other compiler-specific flags here.
 412
 413 if test "$GCC" = yes -a "$ICC" = no; then
 414   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 415   # These work in some but not all gcc versions
 416   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 417   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 419   # This was included in -Wall/-Wformat in older GCC versions
 420   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 421   # Disable strict-aliasing rules; needed for gcc 3.3+
 422   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 423   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 424   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 425   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 426   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 427   # Optimization flags for specific files that benefit from vectorization
 428   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 429   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 430 elif test "$ICC" = yes; then
 431   # Intel's compiler has a bug/misoptimization in checking for
 432   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 433   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 434   # Make sure strict aliasing is off (though this is said to be the default)
 435   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 436 elif test "$PORTNAME" = "aix"; then
 437   # AIX's xlc has to have strict aliasing turned off too
 438   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 439 elif test "$PORTNAME" = "hpux"; then
 440   # On some versions of HP-UX, libm functions do not set errno by default.
 441   # Fix that by using +Olibmerrno if the compiler recognizes it.
 442   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 443 fi
 444
 445 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 446
 447 # supply -g if --enable-debug
 448 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 449   CFLAGS="$CFLAGS -g"
 450 fi
 451
 452 # enable code coverage if --enable-coverage
 453 if test "$enable_coverage" = yes; then
 454   if test "$GCC" = yes; then
 455     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 456   else
 457     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 458   fi
 459 fi
 460
 461 # enable profiling if --enable-profiling
 462 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   if test "$GCC" = yes; then
 464     AC_DEFINE([PROFILE_PID_DIR], 1,
 465            [Define to 1 to allow profiling output to be saved separately for each process.])
 466     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 467   else
 468     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 469   fi
 470 fi
 471
 472 # We already have this in Makefile.win32, but configure needs it too
 473 if test "$PORTNAME" = "win32"; then
 474   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 475 fi
 476
 477 # Check if the compiler still works with the template settings
 478 AC_MSG_CHECKING([whether the C compiler still works])
 479 AC_TRY_LINK([], [return 0;],
 480   [AC_MSG_RESULT(yes)],
 481   [AC_MSG_RESULT(no)
 482    AC_MSG_ERROR([cannot proceed])])
 483
 484 # Defend against gcc -ffast-math
 485 if test "$GCC" = yes; then
 486 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 487 choke me
 488 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 489 fi
 490
 491 AC_PROG_CPP
 492 AC_SUBST(GCC)
 493
 494
 495 #
 496 # Set up TAS assembly code if needed; the template file has now had its
 497 # chance to request this.
 498 #
 499 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 500
 501 if test "$need_tas" = yes ; then
 502   TAS=tas.o
 503 else
 504   TAS=""
 505 fi
 506 AC_SUBST(TAS)
 507
 508
 509 #
 510 # Automatic dependency tracking
 511 #
 512 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 513               [autodepend=yes])
 514 AC_SUBST(autodepend)
 515
 516
 517 #
 518 # Enable assert checks
 519 #
 520 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 521               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 522                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 523
 524
 525 #
 526 # Include directories
 527 #
 528 ac_save_IFS=$IFS
 529 IFS="${IFS}${PATH_SEPARATOR}"
 530 # SRCH_INC comes from the template file
 531 for dir in $with_includes $SRCH_INC; do
 532   if test -d "$dir"; then
 533     INCLUDES="$INCLUDES -I$dir"
 534   else
 535     AC_MSG_WARN([*** Include directory $dir does not exist.])
 536   fi
 537 done
 538 IFS=$ac_save_IFS
 539 AC_SUBST(INCLUDES)
 540
 541
 542 #
 543 # Library directories
 544 #
 545 ac_save_IFS=$IFS
 546 IFS="${IFS}${PATH_SEPARATOR}"
 547 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 548 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 549   if test -d "$dir"; then
 550     LIBDIRS="$LIBDIRS -L$dir"
 551   else
 552     AC_MSG_WARN([*** Library directory $dir does not exist.])
 553   fi
 554 done
 555 IFS=$ac_save_IFS
 556
 557 #
 558 # Enable thread-safe client libraries
 559 #
 560 AC_MSG_CHECKING([allow thread-safe client libraries])
 561 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 562 if test "$enable_thread_safety" = yes; then
 563   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 564           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 565 fi
 566 AC_MSG_RESULT([$enable_thread_safety])
 567 AC_SUBST(enable_thread_safety)
 568
 569 #
 570 # Optionally build Tcl modules (PL/Tcl)
 571 #
 572 AC_MSG_CHECKING([whether to build with Tcl])
 573 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 574 AC_MSG_RESULT([$with_tcl])
 575 AC_SUBST([with_tcl])
 576
 577 # We see if the path to the Tcl/Tk configuration scripts is specified.
 578 # This will override the use of tclsh to find the paths to search.
 579
 580 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 581
 582 #
 583 # Optionally build Perl modules (PL/Perl)
 584 #
 585 AC_MSG_CHECKING([whether to build Perl modules])
 586 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 587 AC_MSG_RESULT([$with_perl])
 588 AC_SUBST(with_perl)
 589
 590 #
 591 # Optionally build Python modules (PL/Python)
 592 #
 593 AC_MSG_CHECKING([whether to build Python modules])
 594 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 595 AC_MSG_RESULT([$with_python])
 596 AC_SUBST(with_python)
 597
 598 #
 599 # GSSAPI
 600 #
 601 AC_MSG_CHECKING([whether to build with GSSAPI support])
 602 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 603 [
 604   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 605   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 606 ])
 607 AC_MSG_RESULT([$with_gssapi])
 608
 609 #
 610 # Kerberos 5
 611 #
 612 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 613 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 614 [
 615   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 616   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 617 ])
 618 AC_MSG_RESULT([$with_krb5])
 619
 620
 621 AC_SUBST(krb_srvtab)
 622
 623
 624 #
 625 # Kerberos configuration parameters
 626 #
 627 PGAC_ARG_REQ(with, krb-srvnam,
 628              [NAME], [default service principal name in Kerberos [postgres]],
 629              [],
 630              [with_krb_srvnam="postgres"])
 631 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 632                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 633
 634
 635 #
 636 # PAM
 637 #
 638 AC_MSG_CHECKING([whether to build with PAM support])
 639 PGAC_ARG_BOOL(with, pam, no,
 640               [build with PAM support],
 641               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 642 AC_MSG_RESULT([$with_pam])
 643
 644
 645 #
 646 # LDAP
 647 #
 648 AC_MSG_CHECKING([whether to build with LDAP support])
 649 PGAC_ARG_BOOL(with, ldap, no,
 650               [build with LDAP support],
 651               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 652 AC_MSG_RESULT([$with_ldap])
 653
 654
 655 #
 656 # Bonjour
 657 #
 658 AC_MSG_CHECKING([whether to build with Bonjour support])
 659 PGAC_ARG_BOOL(with, bonjour, no,
 660               [build with Bonjour support],
 661               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 662 AC_MSG_RESULT([$with_bonjour])
 663
 664
 665 #
 666 # OpenSSL
 667 #
 668 AC_MSG_CHECKING([whether to build with OpenSSL support])
 669 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 670               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 671 AC_MSG_RESULT([$with_openssl])
 672 AC_SUBST(with_openssl)
 673
 674 #
 675 # SELinux
 676 #
 677 AC_MSG_CHECKING([whether to build with SELinux support])
 678 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 679 AC_SUBST(with_selinux)
 680 AC_MSG_RESULT([$with_selinux])
 681
 682 #
 683 # Readline
 684 #
 685 PGAC_ARG_BOOL(with, readline, yes,
 686               [do not use GNU Readline nor BSD Libedit for editing])
 687 # readline on MinGW has problems with backslashes in psql and other bugs.
 688 # This is particularly a problem with non-US code pages.
 689 # Therefore disable its use until we understand the cause. 2004-07-20
 690 if test "$PORTNAME" = "win32"; then
 691   if test "$with_readline" = yes; then
 692     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 693     with_readline=no
 694   fi
 695 fi
 696
 697
 698 #
 699 # Prefer libedit
 700 #
 701 PGAC_ARG_BOOL(with, libedit-preferred, no,
 702               [prefer BSD Libedit over GNU Readline])
 703
 704
 705 #
 706 # OSSP UUID library
 707 #
 708 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 709 AC_SUBST(with_ossp_uuid)
 710
 711
 712 #
 713 # XML
 714 #
 715 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 716               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 717
 718 if test "$with_libxml" = yes ; then
 719   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 720   if test -n "$XML2_CONFIG"; then
 721     for pgac_option in `$XML2_CONFIG --cflags`; do
 722       case $pgac_option in
 723         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 724       esac
 725     done
 726     for pgac_option in `$XML2_CONFIG --libs`; do
 727       case $pgac_option in
 728         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 729       esac
 730     done
 731   fi
 732 fi
 733
 734 AC_SUBST(with_libxml)
 735
 736 #
 737 # XSLT
 738 #
 739 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 740               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 741
 742
 743 AC_SUBST(with_libxslt)
 744
 745 #
 746 # tzdata
 747 #
 748 PGAC_ARG_REQ(with, system-tzdata,
 749              [DIR], [use system time zone data in DIR])
 750 AC_SUBST(with_system_tzdata)
 751
 752 #
 753 # Zlib
 754 #
 755 PGAC_ARG_BOOL(with, zlib, yes,
 756               [do not use Zlib])
 757 AC_SUBST(with_zlib)
 758
 759 #
 760 # Elf
 761 #
 762
 763 # Assume system is ELF if it predefines __ELF__ as 1,
 764 # otherwise believe host_os based default.
 765 case $host_os in
 766     freebsd1*|freebsd2*) elf=no;;
 767     freebsd3*|freebsd4*) elf=yes;;
 768 esac
 769
 770 AC_EGREP_CPP(yes,
 771 [#if __ELF__
 772   yes
 773 #endif
 774 ],
 775 [ELF_SYS=true],
 776 [if test "X$elf" = "Xyes" ; then
 777   ELF_SYS=true
 778 else
 779   ELF_SYS=
 780 fi])
 781 AC_SUBST(ELF_SYS)
 782
 783 #
 784 # Assignments
 785 #
 786
 787 CPPFLAGS="$CPPFLAGS $INCLUDES"
 788 LDFLAGS="$LDFLAGS $LIBDIRS"
 789
 790 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 791 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 792
 793 PGAC_PROG_LD
 794 AC_SUBST(LD)
 795 AC_SUBST(with_gnu_ld)
 796 case $host_os in sysv5*)
 797   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 798   [
 799     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 800     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 801     LDFLAGS=$pgac_save_LDFLAGS
 802   ])
 803   ld_R_works=$pgac_cv_prog_ld_R
 804   AC_SUBST(ld_R_works)
 805 esac
 806 AC_PROG_RANLIB
 807 PGAC_CHECK_STRIP
 808 AC_CHECK_TOOL(AR, ar, ar)
 809 if test "$PORTNAME" = "win32"; then
 810   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 811   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 812   AC_CHECK_TOOL(WINDRES, windres, windres)
 813 fi
 814
 815 AC_PROG_INSTALL
 816 # When Autoconf chooses install-sh as install program it tries to generate
 817 # a relative path to it in each makefile where it subsitutes it. This clashes
 818 # with our Makefile.global concept. This workaround helps.
 819 case $INSTALL in
 820   *install-sh*) install_bin='';;
 821   *) install_bin=$INSTALL;;
 822 esac
 823 AC_SUBST(install_bin)
 824
 825 AC_PATH_PROG(TAR, tar)
 826 AC_PROG_LN_S
 827 AC_PROG_AWK
 828 AC_PROG_MKDIR_P
 829 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 830 # a relative path to it in each makefile where it subsitutes it. This clashes
 831 # with our Makefile.global concept. This workaround helps.
 832 case $MKDIR_P in
 833   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 834 esac
 835
 836 PGAC_PATH_BISON
 837 PGAC_PATH_FLEX
 838
 839 PGAC_PATH_PERL
 840 if test "$with_perl" = yes; then
 841   if test -z "$PERL"; then
 842     AC_MSG_ERROR([Perl not found])
 843   fi
 844   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 845   PGAC_CHECK_PERL_EMBED_LDFLAGS
 846 fi
 847
 848 if test "$with_python" = yes; then
 849   PGAC_PATH_PYTHON
 850   PGAC_CHECK_PYTHON_EMBED_SETUP
 851 fi
 852
 853 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 854   AC_PATH_PROG(ZIC, zic)
 855   if test -z "$ZIC"; then
 856     AC_MSG_ERROR([
 857 When cross-compiling, either use the option --with-system-tzdata to use
 858 existing time-zone data, or set the environment variable ZIC to a zic
 859 program to use during the build.])
 860   fi
 861 fi
 862
 863
 864 ##
 865 ## Libraries
 866 ##
 867 ## Most libraries are included only if they demonstrably provide a function
 868 ## we need, but libm is an exception: always include it, because there are
 869 ## too many compilers that play cute optimization games that will break
 870 ## probes for standard functions such as pow().
 871 ##
 872
 873 AC_CHECK_LIB(m, main)
 874 AC_SEARCH_LIBS(setproctitle, util)
 875 AC_SEARCH_LIBS(dlopen, dl)
 876 AC_SEARCH_LIBS(socket, [socket wsock32])
 877 AC_SEARCH_LIBS(shl_load, dld)
 878 # We only use libld in port/dynloader/aix.c
 879 case $host_os in
 880      aix*)
 881         AC_SEARCH_LIBS(ldopen, ld)
 882         ;;
 883 esac
 884 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 885 AC_SEARCH_LIBS(crypt, crypt)
 886 # Solaris:
 887 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 888 # Required for thread_test.c on Solaris 2.5:
 889 # Other ports use it too (HP-UX) so test unconditionally
 890 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 891 # Cygwin:
 892 AC_SEARCH_LIBS(shmget, cygipc)
 893
 894 if test "$with_readline" = yes; then
 895   PGAC_CHECK_READLINE
 896   if test x"$pgac_cv_check_readline" = x"no"; then
 897     AC_MSG_ERROR([readline library not found
 898 If you have readline already installed, see config.log for details on the
 899 failure.  It is possible the compiler isn't looking in the proper directory.
 900 Use --without-readline to disable readline support.])
 901   fi
 902 fi
 903
 904 if test "$with_zlib" = yes; then
 905   AC_CHECK_LIB(z, inflate, [],
 906                [AC_MSG_ERROR([zlib library not found
 907 If you have zlib already installed, see config.log for details on the
 908 failure.  It is possible the compiler isn't looking in the proper directory.
 909 Use --without-zlib to disable zlib support.])])
 910 fi
 911
 912 if test "$enable_spinlocks" = yes; then
 913   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 914 else
 915   AC_MSG_WARN([
 916 *** Not using spinlocks will cause poor performance.])
 917 fi
 918
 919 if test "$with_gssapi" = yes ; then
 920   if test "$PORTNAME" != "win32"; then
 921     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 922                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 923   else
 924     LIBS="$LIBS -lgssapi32"
 925   fi
 926 fi
 927
 928 if test "$with_krb5" = yes ; then
 929   if test "$PORTNAME" != "win32"; then
 930      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 931                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 932      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 933                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 934   else
 935      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 936                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 937   fi
 938 fi
 939
 940 if test "$with_openssl" = yes ; then
 941   dnl Order matters!
 942   if test "$PORTNAME" != "win32"; then
 943      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 944      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 945   else
 946      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 947      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 948   fi
 949 fi
 950
 951 if test "$with_pam" = yes ; then
 952   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 953 fi
 954
 955 if test "$with_libxml" = yes ; then
 956   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 957 fi
 958
 959 if test "$with_libxslt" = yes ; then
 960   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 961 fi
 962
 963 # for contrib/sepgsql
 964 if test "$with_selinux" = yes; then
 965   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 966                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 967 fi
 968
 969 # for contrib/uuid-ossp
 970 if test "$with_ossp_uuid" = yes ; then
 971   AC_CHECK_LIB(ossp-uuid, uuid_export,
 972     [OSSP_UUID_LIBS="-lossp-uuid"],
 973     [AC_CHECK_LIB(uuid, uuid_export,
 974       [OSSP_UUID_LIBS="-luuid"],
 975       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 976 fi
 977 AC_SUBST(OSSP_UUID_LIBS)
 978
 979
 980 ##
 981 ## Header files
 982 ##
 983
 984 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 985 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/ucred.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 986
 987 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 988 # is included first.
 989 AC_CHECK_HEADERS(net/if.h, [], [],
 990 [AC_INCLUDES_DEFAULT
 991 #ifdef HAVE_SYS_SOCKET_H
 992 #include <sys/socket.h>
 993 #endif
 994 ])
 995
 996 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 997 # netinet/in.h is included first.
 998 AC_CHECK_HEADERS(netinet/in.h)
 999 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1000 [AC_INCLUDES_DEFAULT
1001 #ifdef HAVE_NETINET_IN_H
1002 #include <netinet/in.h>
1003 #endif
1004 ])
1005
1006 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1007   AC_CHECK_HEADERS(readline/readline.h, [],
1008         [AC_CHECK_HEADERS(readline.h, [],
1009                 [AC_MSG_ERROR([readline header not found
1010 If you have readline already installed, see config.log for details on the
1011 failure.  It is possible the compiler isn't looking in the proper directory.
1012 Use --without-readline to disable readline support.])])])
1013   AC_CHECK_HEADERS(readline/history.h, [],
1014         [AC_CHECK_HEADERS(history.h, [],
1015                 [AC_MSG_ERROR([history header not found
1016 If you have readline already installed, see config.log for details on the
1017 failure.  It is possible the compiler isn't looking in the proper directory.
1018 Use --without-readline to disable readline support.])])])
1019 fi
1020
1021 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1022 # Some installations of libedit usurp /usr/include/readline/, which seems
1023 # bad practice, since in combined installations readline will have its headers
1024 # there.  We might have to resort to AC_EGREP checks to make sure we found
1025 # the proper header...
1026   AC_CHECK_HEADERS(editline/readline.h, [],
1027         [AC_CHECK_HEADERS(readline.h, [],
1028                 [AC_CHECK_HEADERS(readline/readline.h, [],
1029                         [AC_MSG_ERROR([readline header not found
1030 If you have libedit already installed, see config.log for details on the
1031 failure.  It is possible the compiler isn't looking in the proper directory.
1032 Use --without-readline to disable libedit support.])])])])
1033 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1034 # not be there at all.  Hence, don't complain if not found.  We must check
1035 # though, since in yet other versions it is an independent header.
1036   AC_CHECK_HEADERS(editline/history.h, [],
1037         [AC_CHECK_HEADERS(history.h, [],
1038                 [AC_CHECK_HEADERS(readline/history.h)])])
1039 fi
1040
1041 if test "$with_zlib" = yes; then
1042   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1043 If you have zlib already installed, see config.log for details on the
1044 failure.  It is possible the compiler isn't looking in the proper directory.
1045 Use --without-zlib to disable zlib support.])])
1046 fi
1047
1048 if test "$with_gssapi" = yes ; then
1049   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1050         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1051 fi
1052
1053 if test "$with_krb5" = yes ; then
1054   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1055 fi
1056
1057 if test "$with_openssl" = yes ; then
1058   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1059   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1060 fi
1061
1062 if test "$with_pam" = yes ; then
1063   AC_CHECK_HEADERS(security/pam_appl.h, [],
1064                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1065                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1066 fi
1067
1068 if test "$with_libxml" = yes ; then
1069   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1070 fi
1071
1072 if test "$with_libxslt" = yes ; then
1073   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1074 fi
1075
1076 if test "$with_ldap" = yes ; then
1077   if test "$PORTNAME" != "win32"; then
1078      AC_CHECK_HEADERS(ldap.h, [],
1079                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1080   else
1081      AC_CHECK_HEADERS(winldap.h, [],
1082                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1083                       [AC_INCLUDES_DEFAULT
1084 #include <windows.h>
1085                       ])
1086   fi
1087 fi
1088
1089 if test "$with_bonjour" = yes ; then
1090   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1091 fi
1092
1093 # for contrib/uuid-ossp
1094 if test "$with_ossp_uuid" = yes ; then
1095   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1096     AC_CHECK_HEADERS(uuid.h, [],
1097       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1098 fi
1099
1100 if test "$PORTNAME" = "win32" ; then
1101    AC_CHECK_HEADERS(crtdefs.h)
1102 fi
1103
1104 ##
1105 ## Types, structures, compiler characteristics
1106 ##
1107
1108 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1109 AC_C_BIGENDIAN
1110 AC_C_CONST
1111 PGAC_C_INLINE
1112 AC_C_STRINGIZE
1113 AC_C_FLEXIBLE_ARRAY_MEMBER
1114 PGAC_C_SIGNED
1115 AC_C_VOLATILE
1116 PGAC_C_FUNCNAME_SUPPORT
1117 PGAC_C_STATIC_ASSERT
1118 PGAC_C_TYPES_COMPATIBLE
1119 PGAC_C_BUILTIN_CONSTANT_P
1120 PGAC_C_BUILTIN_UNREACHABLE
1121 PGAC_C_VA_ARGS
1122 PGAC_STRUCT_TIMEZONE
1123 PGAC_UNION_SEMUN
1124 PGAC_STRUCT_SOCKADDR_UN
1125 PGAC_STRUCT_SOCKADDR_STORAGE
1126 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1127 PGAC_STRUCT_ADDRINFO
1128 AC_TYPE_INTPTR_T
1129 AC_TYPE_UINTPTR_T
1130 AC_TYPE_LONG_LONG_INT
1131
1132 PGAC_TYPE_LOCALE_T
1133
1134 AC_CHECK_TYPES([struct cmsgcred], [], [],
1135 [#include <sys/socket.h>
1136 #ifdef HAVE_SYS_UCRED_H
1137 #include <sys/ucred.h>
1138 #endif])
1139
1140 AC_CHECK_TYPES([struct option], [], [],
1141 [#ifdef HAVE_GETOPT_H
1142 #include <getopt.h>
1143 #endif])
1144
1145 if test "$with_zlib" = yes; then
1146   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1147   # did not).  While we could work around the lack of z_streamp, it
1148   # seems unwise to encourage people to use such old zlib versions...
1149   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1150 Use --without-zlib to disable zlib support.])],
1151                 [#include <zlib.h>])
1152 fi
1153
1154 if test "$with_krb5" = yes; then
1155 # Check for differences between MIT and Heimdal (KTH) releases
1156   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1157                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1158                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1159                                      [#include <krb5.h>])],
1160                    [#include <krb5.h>])
1161   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1162                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1163                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1164                                      [#include <krb5.h>])],
1165                    [#include <krb5.h>])
1166
1167 # Win32 requires headers to be loaded for __stdcall, so can't use
1168 # AC_CHECK_FUNCS here.
1169   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1170   AC_TRY_LINK([#include <krb5.h>],
1171               [krb5_free_unparsed_name(NULL,NULL);],
1172               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name.])
1173 AC_MSG_RESULT(yes)],
1174               [AC_MSG_RESULT(no)])
1175 fi
1176
1177 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1178 case $host_cpu in
1179   ppc*|powerpc*)
1180     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1181     AC_TRY_COMPILE([],
1182         [int a = 0; int *p = &a; int r;
1183          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1184         [pgac_cv_have_ppc_mutex_hint=yes],
1185         [pgac_cv_have_ppc_mutex_hint=no])
1186     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1187     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1188         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1189     fi
1190   ;;
1191 esac
1192
1193 # Check largefile support.  You might think this is a system service not a
1194 # compiler characteristic, but you'd be wrong.  We must check this before
1195 # probing existence of related functions such as fseeko, since the largefile
1196 # defines can affect what is generated for that.
1197 if test "$PORTNAME" != "win32"; then
1198    AC_SYS_LARGEFILE
1199 fi
1200
1201 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1202 AC_CHECK_SIZEOF([off_t])
1203
1204 # If we don't have largefile support, can't handle segsize >= 2GB.
1205 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1206    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1207 fi
1208
1209
1210 ##
1211 ## Functions, global variables
1212 ##
1213
1214 PGAC_VAR_INT_TIMEZONE
1215 AC_FUNC_ACCEPT_ARGTYPES
1216 PGAC_FUNC_GETTIMEOFDAY_1ARG
1217
1218 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1219 # symbols that that library has no business exposing to the world.  Pending
1220 # acquisition of a clue by those developers, ignore libedit (including its
1221 # possible alias of libreadline) while checking for everything else.
1222 LIBS_including_readline="$LIBS"
1223 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1224
1225 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1226
1227 AC_REPLACE_FUNCS(fseeko)
1228 case $host_os in
1229         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1230         # Mingw uses macros to access Win32 API calls
1231         netbsd*|mingw*)
1232                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1233                 ac_cv_func_fseeko=yes;;
1234         *)
1235                 AC_FUNC_FSEEKO;;
1236 esac
1237
1238 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1239 # by calling it, 2009-04-02
1240 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1241 if test "$PORTNAME" != "solaris"; then
1242 AC_CHECK_FUNCS(posix_fadvise)
1243 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1244 fi
1245
1246 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1247 AC_CHECK_DECLS([strlcat, strlcpy])
1248 # This is probably only present on Darwin, but may as well check always
1249 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1250
1251 HAVE_IPV6=no
1252 AC_CHECK_TYPE([struct sockaddr_in6],
1253         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1254          HAVE_IPV6=yes],
1255         [],
1256 [$ac_includes_default
1257 #include <netinet/in.h>])
1258 AC_SUBST(HAVE_IPV6)
1259
1260 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1261 [AC_TRY_LINK(
1262 [#include <machine/vmparam.h>
1263 #include <sys/exec.h>
1264 ],
1265 [PS_STRINGS->ps_nargvstr = 1;
1266 PS_STRINGS->ps_argvstr = "foo";],
1267 [pgac_cv_var_PS_STRINGS=yes],
1268 [pgac_cv_var_PS_STRINGS=no])])
1269 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1270   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1271 fi
1272
1273
1274 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1275 # is missing.  Yes, there are machines that have only one.  We may
1276 # also decide to use snprintf.c if snprintf() is present but does not
1277 # have all the features we need --- see below.
1278
1279 if test "$PORTNAME" = "win32"; then
1280   # Win32 gets snprintf.c built unconditionally.
1281   #
1282   # To properly translate all NLS languages strings, we must support the
1283   # *printf() %$ format, which allows *printf() arguments to be selected
1284   # by position in the translated string.
1285   #
1286   # libintl versions < 0.13 use the native *printf() functions, and Win32
1287   # *printf() doesn't understand %$, so we must use our /port versions,
1288   # which do understand %$. libintl versions >= 0.13 include their own
1289   # *printf versions on Win32.  The libintl 0.13 release note text is:
1290   #
1291   #   C format strings with positions, as they arise when a translator
1292   #   needs to reorder a sentence, are now supported on all platforms.
1293   #   On those few platforms (NetBSD and Woe32) for which the native
1294   #   printf()/fprintf()/... functions don't support such format
1295   #   strings, replacements are provided through <libintl.h>.
1296   #
1297   # We could use libintl >= 0.13's *printf() if we were sure that we had
1298   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1299   # to guarantee that, it is best to just use our own, so we are sure to
1300   # get %$ support. In include/port.h we disable the *printf() macros
1301   # that might have been defined by libintl.
1302   #
1303   # We do this unconditionally whether NLS is used or not so we are sure
1304   # that all Win32 libraries and binaries behave the same.
1305   pgac_need_repl_snprintf=yes
1306 else
1307   pgac_need_repl_snprintf=no
1308   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1309   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1310 fi
1311
1312
1313 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1314 # include/c.h will provide declarations.  Note this is a separate test
1315 # from whether the functions exist in the C library --- there are
1316 # systems that have the functions but don't bother to declare them :-(
1317
1318 AC_CHECK_DECLS([snprintf, vsnprintf])
1319
1320
1321 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1322 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1323 [AC_TRY_LINK([
1324 #include <math.h>
1325 double glob_double;
1326 ],
1327 [return isinf(glob_double) ? 0 : 1;],
1328 [ac_cv_func_isinf=yes],
1329 [ac_cv_func_isinf=no])])
1330
1331 if test $ac_cv_func_isinf = yes ; then
1332   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1333 else
1334   AC_LIBOBJ(isinf)
1335   # Look for a way to implement a substitute for isinf()
1336   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1337 fi
1338
1339 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1340
1341 case $host_os in
1342
1343         # Windows uses a specialised env handler
1344         # and doesn't need a replacement getpeereid because it doesn't use
1345         # Unix sockets.
1346         mingw*)
1347                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1348                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1349                 ac_cv_func_unsetenv=yes
1350                 ac_cv_func_getpeereid=yes;;
1351         *)
1352                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1353                 ;;
1354 esac
1355
1356 # System's version of getaddrinfo(), if any, may be used only if we found
1357 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1358 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1359 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1360 # because we want to use our own getaddrinfo.c on Windows anyway.)
1361 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1362   AC_REPLACE_FUNCS([getaddrinfo])
1363 else
1364   AC_LIBOBJ(getaddrinfo)
1365 fi
1366
1367 # Similarly, use system's getopt_long() only if system provides struct option.
1368 if test x"$ac_cv_type_struct_option" = xyes ; then
1369   AC_REPLACE_FUNCS([getopt_long])
1370 else
1371   AC_LIBOBJ(getopt_long)
1372 fi
1373
1374 # Solaris' getopt() doesn't do what we want for long options, so always use
1375 # our version on that platform.
1376 if test "$PORTNAME" = "solaris"; then
1377   AC_LIBOBJ(getopt)
1378 fi
1379
1380 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1381 # so always use our version on Windows.
1382 if test "$PORTNAME" = "win32"; then
1383   AC_LIBOBJ(getopt)
1384   AC_LIBOBJ(getopt_long)
1385 fi
1386
1387 # Win32 support
1388 if test "$PORTNAME" = "win32"; then
1389   AC_REPLACE_FUNCS(gettimeofday)
1390   AC_LIBOBJ(kill)
1391   AC_LIBOBJ(open)
1392   AC_LIBOBJ(win32env)
1393   AC_LIBOBJ(win32error)
1394   AC_LIBOBJ(win32setlocale)
1395   AC_DEFINE([HAVE_SYMLINK], 1,
1396             [Define to 1 if you have the `symlink' function.])
1397   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1398 #define WIN32_LEAN_AND_MEAN
1399 #include <windows.h>
1400 #include <string.h>
1401 #include <dbghelp.h>])
1402 fi
1403 if test x"$pgac_minidump_type" = x"yes" ; then
1404   AC_SUBST(have_win32_dbghelp,yes)
1405 else
1406   AC_SUBST(have_win32_dbghelp,no)
1407 fi
1408
1409 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1410 dnl (especially on GNU libc)
1411 dnl See also comments in c.h.
1412 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1413 [AC_TRY_LINK([#include <setjmp.h>],
1414             [sigjmp_buf x; sigsetjmp(x, 1);],
1415             [pgac_cv_func_sigsetjmp=yes],
1416             [pgac_cv_func_sigsetjmp=no])])
1417 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1418   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1419 fi
1420
1421 AC_DECL_SYS_SIGLIST
1422
1423 AC_CHECK_FUNC(syslog,
1424               [AC_CHECK_HEADER(syslog.h,
1425                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1426
1427 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1428 [AC_TRY_LINK([#include <unistd.h>],
1429   [extern int opterr; opterr = 1;],
1430   [pgac_cv_var_int_opterr=yes],
1431   [pgac_cv_var_int_opterr=no])])
1432 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1433   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1434 fi
1435
1436 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1437 [AC_TRY_LINK([#include <unistd.h>],
1438   [extern int optreset; optreset = 1;],
1439   [pgac_cv_var_int_optreset=yes],
1440   [pgac_cv_var_int_optreset=no])])
1441 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1442   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1443 fi
1444
1445 AC_CHECK_FUNCS([strtoll strtoq], [break])
1446 AC_CHECK_FUNCS([strtoull strtouq], [break])
1447
1448 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1449 [AC_TRY_LINK([],
1450   [int lock = 0;
1451    __sync_lock_test_and_set(&lock, 1);
1452    __sync_lock_release(&lock);],
1453   [pgac_cv_gcc_int_atomics="yes"],
1454   [pgac_cv_gcc_int_atomics="no"])])
1455 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1456   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1457 fi
1458
1459 # Lastly, restore full LIBS list and check for readline/libedit symbols
1460 LIBS="$LIBS_including_readline"
1461
1462 if test "$with_readline" = yes; then
1463   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1464   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1465   AC_CHECK_FUNCS([append_history history_truncate_file])
1466 fi
1467
1468
1469 #
1470 # Pthreads
1471 #
1472 # For each platform, we need to know about any special compile and link
1473 # libraries, and whether the normal C function names are thread-safe.
1474 # See the comment at the top of src/port/thread.c for more information.
1475 # WIN32 doesn't need the pthread tests;  it always uses threads
1476 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1477 ACX_PTHREAD     # set thread flags
1478
1479 # Some platforms use these, so just define them.  They can't hurt if they
1480 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1481 # enables 5-arg getpwuid_r, among other things.
1482 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1483
1484
1485 # At this point, we don't want to muck with the compiler name for threading.
1486 # Let's see who fails, perhaps AIX.  2004-04-23
1487 if test "$PTHREAD_CC" != "$CC"; then
1488 AC_MSG_ERROR([
1489 PostgreSQL does not support platforms that require a special compiler
1490 for thread safety;  use --disable-thread-safety to disable thread safety.])
1491 fi
1492
1493 # Check for *_r functions
1494 _CFLAGS="$CFLAGS"
1495 _LIBS="$LIBS"
1496 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1497 LIBS="$LIBS $PTHREAD_LIBS"
1498
1499 if test "$PORTNAME" != "win32"; then
1500 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1501 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1502 fi
1503
1504 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1505
1506 # Do test here with the proper thread flags
1507 PGAC_FUNC_GETPWUID_R_5ARG
1508 PGAC_FUNC_STRERROR_R_INT
1509
1510 CFLAGS="$_CFLAGS"
1511 LIBS="$_LIBS"
1512
1513 else
1514 # do not use values from template file
1515 PTHREAD_CFLAGS=
1516 PTHREAD_LIBS=
1517 fi
1518
1519 AC_SUBST(PTHREAD_CFLAGS)
1520 AC_SUBST(PTHREAD_LIBS)
1521
1522
1523 # We can test for libldap_r only after we know PTHREAD_LIBS
1524 if test "$with_ldap" = yes ; then
1525   _LIBS="$LIBS"
1526   if test "$PORTNAME" != "win32"; then
1527     AC_CHECK_LIB(ldap, ldap_bind, [],
1528                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1529                  [$EXTRA_LDAP_LIBS])
1530     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1531     if test "$enable_thread_safety" = yes; then
1532       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1533       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1534                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1535                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1536       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1537     else
1538       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1539     fi
1540   else
1541     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1542     LDAP_LIBS_FE="-lwldap32"
1543     LDAP_LIBS_BE="-lwldap32"
1544   fi
1545   LIBS="$_LIBS"
1546 fi
1547 AC_SUBST(LDAP_LIBS_FE)
1548 AC_SUBST(LDAP_LIBS_BE)
1549
1550
1551 # This test makes sure that run tests work at all.  Sometimes a shared
1552 # library is found by the linker, but the runtime linker can't find it.
1553 # This check should come after all modifications of compiler or linker
1554 # variables, and before any other run tests.
1555 AC_MSG_CHECKING([test program])
1556 AC_TRY_RUN([int main() { return 0; }],
1557 [AC_MSG_RESULT(ok)],
1558 [AC_MSG_RESULT(failed)
1559 AC_MSG_ERROR([[
1560 Could not execute a simple test program.  This may be a problem
1561 related to locating shared libraries.  Check the file 'config.log'
1562 for the exact reason.]])],
1563 [AC_MSG_RESULT([cross-compiling])])
1564
1565 # --------------------
1566 # Run tests below here
1567 # --------------------
1568
1569 # Force use of our snprintf if system's doesn't do arg control
1570 # See comment above at snprintf test for details.
1571 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1572   PGAC_FUNC_PRINTF_ARG_CONTROL
1573   if test $pgac_cv_printf_arg_control != yes ; then
1574     pgac_need_repl_snprintf=yes
1575   fi
1576 fi
1577
1578
1579 dnl Check to see if we have a working 64-bit integer type.
1580 dnl This breaks down into two steps:
1581 dnl (1) figure out if the compiler has a 64-bit int type with working
1582 dnl arithmetic, and if so
1583 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1584 dnl snprintf is the only library routine we really need for int8 support.)
1585 dnl It's entirely possible to have a compiler that handles a 64-bit type
1586 dnl when the C library doesn't; this is fairly likely when using gcc on
1587 dnl an older platform, for example.
1588 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1589 dnl we force our own version of snprintf() to be used instead.
1590 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1591
1592 dnl As of Postgres 8.4, we no longer support compilers without a working
1593 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1594
1595 PGAC_TYPE_64BIT_INT([long int])
1596
1597 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1598   pg_int64_type="long int"
1599 else
1600   PGAC_TYPE_64BIT_INT([long long int])
1601   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1602     pg_int64_type="long long int"
1603   else
1604     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1605   fi
1606 fi
1607
1608 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1609   [Define to the name of a signed 64-bit integer type.])
1610
1611 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1612
1613 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1614   AC_TRY_COMPILE([
1615 #define INT64CONST(x)  x##LL
1616 long long int foo = INT64CONST(0x1234567890123456);
1617 ],
1618         [],
1619         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1620         [])
1621 fi
1622
1623
1624 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1625 # we found we need to use "long long int", better check.  We cope with
1626 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1627 # work, fall back to our own snprintf emulation (which we know uses %lld).
1628
1629 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1630   if test $pgac_need_repl_snprintf = no; then
1631     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1632     if test "$LONG_LONG_INT_FORMAT" = ""; then
1633       # Force usage of our own snprintf, since system snprintf is broken
1634       pgac_need_repl_snprintf=yes
1635       LONG_LONG_INT_FORMAT='%lld'
1636     fi
1637   else
1638     # Here if we previously decided we needed to use our own snprintf
1639     LONG_LONG_INT_FORMAT='%lld'
1640   fi
1641   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1642   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1643   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1644 else
1645   # Here if we are not using 'long long int' at all
1646   INT64_FORMAT='"%ld"'
1647   UINT64_FORMAT='"%lu"'
1648 fi
1649
1650 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1651                    [Define to the appropriate snprintf format for 64-bit ints.])
1652
1653 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1654                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1655
1656 # Now we have checked all the reasons to replace snprintf
1657 if test $pgac_need_repl_snprintf = yes; then
1658   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1659   AC_LIBOBJ(snprintf)
1660 fi
1661
1662 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1663 AC_CHECK_SIZEOF([void *])
1664 AC_CHECK_SIZEOF([size_t])
1665 AC_CHECK_SIZEOF([long])
1666
1667 # Decide whether float4 is passed by value: user-selectable, enabled by default
1668 AC_MSG_CHECKING([whether to build with float4 passed by value])
1669 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1670               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1671                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1672                float4passbyval=true],
1673               [float4passbyval=false])
1674 AC_MSG_RESULT([$enable_float4_byval])
1675 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1676
1677 # Decide whether float8 is passed by value.
1678 # Note: this setting also controls int8 and related types such as timestamp.
1679 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1680 # If not, trying to select it is an error.
1681 AC_MSG_CHECKING([whether to build with float8 passed by value])
1682 if test $ac_cv_sizeof_void_p -ge 8 ; then
1683   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1684 else
1685   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1686   if test "$enable_float8_byval" = yes ; then
1687     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1688   fi
1689 fi
1690 if test "$enable_float8_byval" = yes ; then
1691   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1692             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1693   float8passbyval=true
1694 else
1695   float8passbyval=false
1696 fi
1697 AC_MSG_RESULT([$enable_float8_byval])
1698 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1699
1700 # Determine memory alignment requirements for the basic C data types.
1701
1702 AC_CHECK_ALIGNOF(short)
1703 AC_CHECK_ALIGNOF(int)
1704 AC_CHECK_ALIGNOF(long)
1705 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1706   AC_CHECK_ALIGNOF(long long int)
1707 fi
1708 AC_CHECK_ALIGNOF(double)
1709
1710 # Compute maximum alignment of any basic type.
1711 # We assume long's alignment is at least as strong as char, short, or int;
1712 # but we must check long long (if it exists) and double.
1713
1714 MAX_ALIGNOF=$ac_cv_alignof_long
1715 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1716   MAX_ALIGNOF=$ac_cv_alignof_double
1717 fi
1718 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1719   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1720 fi
1721 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1722
1723
1724 # Some platforms predefine the types int8, int16, etc.  Only check
1725 # a (hopefully) representative subset.
1726 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1727 [#include <stdio.h>])
1728
1729 # We also check for sig_atomic_t, which *should* be defined per ANSI
1730 # C, but is missing on some old platforms.
1731 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1732
1733
1734 if test "$PORTNAME" != "win32"
1735 then
1736 PGAC_FUNC_POSIX_SIGNALS
1737 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1738   AC_MSG_ERROR([
1739 Thread-safety requires POSIX signals, which are not supported by this
1740 operating system;  use --disable-thread-safety to disable thread safety.])
1741 fi
1742 fi
1743
1744 # SunOS doesn't handle negative byte comparisons properly with +/- return
1745 AC_FUNC_MEMCMP
1746
1747
1748 # Select semaphore implementation type.
1749 if test "$PORTNAME" != "win32"; then
1750   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1751     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1752     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1753   else
1754     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1755       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1756       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1757     else
1758       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1759       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1760     fi
1761   fi
1762 else
1763   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1764   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1765 fi
1766
1767
1768 # Select shared-memory implementation type.
1769 if test "$PORTNAME" != "win32"; then
1770   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1771   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1772 else
1773   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1774   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1775 fi
1776
1777 # Select latch implementation type.
1778 if test "$PORTNAME" != "win32"; then
1779   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1780 else
1781   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1782 fi
1783
1784 # If not set in template file, set bytes to use libc memset()
1785 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1786   MEMSET_LOOP_LIMIT=1024
1787 fi
1788 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1789
1790
1791 if test "$enable_nls" = yes ; then
1792   PGAC_CHECK_GETTEXT
1793 fi
1794
1795 # Check for Tcl configuration script tclConfig.sh
1796 if test "$with_tcl" = yes; then
1797     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1798     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1799                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1800     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1801     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1802     ac_save_CPPFLAGS=$CPPFLAGS
1803     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1804     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1805     CPPFLAGS=$ac_save_CPPFLAGS
1806 fi
1807
1808 # check for <perl.h>
1809 if test "$with_perl" = yes; then
1810   ac_save_CPPFLAGS=$CPPFLAGS
1811   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1812   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1813                   [#include <EXTERN.h>])
1814   # While we're at it, check that we can link to libperl.
1815   # On most platforms, if perl.h is there then libperl.so will be too, but at
1816   # this writing Debian packages them separately.  There is no known reason to
1817   # waste cycles on separate probes for the Tcl or Python libraries, though.
1818   pgac_save_LIBS=$LIBS
1819   LIBS="$perl_embed_ldflags"
1820   AC_MSG_CHECKING([for libperl])
1821   AC_TRY_LINK([
1822 #include <EXTERN.h>
1823 #include <perl.h>
1824 ],  [perl_alloc();],
1825     [AC_MSG_RESULT(yes)],
1826     [AC_MSG_RESULT(no)
1827      AC_MSG_ERROR([libperl library is required for Perl])])
1828   LIBS=$pgac_save_LIBS
1829   CPPFLAGS=$ac_save_CPPFLAGS
1830 fi
1831
1832 # check for <Python.h>
1833 if test "$with_python" = yes; then
1834   ac_save_CPPFLAGS=$CPPFLAGS
1835   CPPFLAGS="$python_includespec $CPPFLAGS"
1836   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1837   CPPFLAGS=$ac_save_CPPFLAGS
1838 fi
1839
1840 #
1841 # Check for DocBook and tools
1842 #
1843 PGAC_PROG_NSGMLS
1844 PGAC_PROG_JADE
1845 PGAC_CHECK_DOCBOOK(4.2)
1846 PGAC_PATH_DOCBOOK_STYLESHEETS
1847 PGAC_PATH_COLLATEINDEX
1848 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1849 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1850
1851 # Thread testing
1852
1853 # We have to run the thread test near the end so we have all our symbols
1854 # defined.  Cross compiling throws a warning.
1855 #
1856 if test "$enable_thread_safety" = yes; then
1857 if test "$PORTNAME" != "win32"
1858 then
1859 AC_MSG_CHECKING([thread safety of required library functions])
1860
1861 _CFLAGS="$CFLAGS"
1862 _LIBS="$LIBS"
1863 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1864 LIBS="$LIBS $PTHREAD_LIBS"
1865 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1866   [AC_MSG_RESULT(yes)],
1867   [AC_MSG_RESULT(no)
1868   AC_MSG_ERROR([thread test program failed
1869 This platform is not thread-safe.  Check the file 'config.log' or compile
1870 and run src/test/thread/thread_test for the exact reason.
1871 Use --disable-thread-safety to disable thread safety.])],
1872   [AC_MSG_RESULT(maybe)
1873   AC_MSG_WARN([
1874 *** Skipping thread test program because of cross-compile build.
1875 *** Run the program in src/test/thread on the target machine.
1876 ])])
1877 CFLAGS="$_CFLAGS"
1878 LIBS="$_LIBS"
1879 else
1880 AC_MSG_WARN([*** skipping thread test on Win32])
1881 fi
1882 fi
1883
1884 # If compiler will take -Wl,--as-needed (or various platform-specific
1885 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1886 # trying to filter LIBS to the minimum for each executable.
1887 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1888 # libreadline; therefore we postpone testing it until we know what library
1889 # dependencies readline has.  The test code will try to link with $LIBS.
1890 if test "$with_readline" = yes; then
1891   link_test_func=readline
1892 else
1893   link_test_func=exit
1894 fi
1895
1896 if test "$PORTNAME" = "darwin"; then
1897   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1898 elif test "$PORTNAME" = "openbsd"; then
1899   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1900 else
1901   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1902 fi
1903
1904 # Create compiler version string
1905 if test x"$GCC" = x"yes" ; then
1906   cc_string=`${CC} --version | sed q`
1907   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1908 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1909   cc_string=`${CC} -V 2>&1 | sed q`
1910 else
1911   cc_string=$CC
1912 fi
1913
1914 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1915                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1916                    [A string containing the version number, platform, and C compiler])
1917
1918 # Supply a numeric version string for use by 3rd party add-ons
1919 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1920 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1921 tr '.' '        ' |
1922 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1923 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1924
1925
1926 # Begin output steps
1927
1928 AC_MSG_NOTICE([using compiler=$cc_string])
1929 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1930 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1931 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1932
1933 # prepare build tree if outside source tree
1934 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1935 # Note 2: /bin/pwd might be better than shell's built-in at getting
1936 #         a symlink-free name.
1937 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1938   vpath_build=no
1939 else
1940   vpath_build=yes
1941   if test "$no_create" != yes; then
1942     _AS_ECHO_N([preparing build tree... ])
1943     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1944     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1945       || AC_MSG_ERROR(failed)
1946     AC_MSG_RESULT(done)
1947   fi
1948 fi
1949 AC_SUBST(vpath_build)
1950
1951
1952 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1953
1954 AC_CONFIG_LINKS([
1955   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1956   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1957   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1958   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1959   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1960   src/include/pg_config_os.h:src/include/port/${template}.h
1961   src/Makefile.port:src/makefiles/Makefile.${template}
1962 ])
1963
1964 if test "$PORTNAME" = "win32"; then
1965 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1966 # Links sometimes fail undetected on Mingw -
1967 # so here we detect it and warn the user
1968 for FILE in $CONFIG_LINKS
1969  do
1970         # test -e works for symlinks in the MinGW console
1971         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1972  done
1973 ])
1974 fi
1975
1976 AC_CONFIG_HEADERS([src/include/pg_config.h],
1977 [
1978 # Update timestamp for pg_config.h (see Makefile.global)
1979 echo >src/include/stamp-h
1980 ])
1981
1982 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
1983 [
1984 # Update timestamp for pg_config_ext.h (see Makefile.global)
1985 echo >src/include/stamp-ext-h
1986 ])
1987
1988 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1989                   [echo >src/interfaces/ecpg/include/stamp-h])
1990
1991 AC_OUTPUT