granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.281 2003/08/16 15:35:51 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4beta1], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55 # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect.  This can be overridden at run-time,
 182 but it's convenient if your clients have the right default compiled in.
 183 (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as a string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # adjust CFLAGS per template
 233 if test "$ac_env_CFLAGS_set" = set; then
 234   CFLAGS=$ac_env_CFLAGS_value
 235 fi
 236 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 237   CFLAGS="$CFLAGS -g"
 238 fi
 239 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 240
 241 # Check if the compiler still works with the template settings
 242 AC_MSG_CHECKING([whether the C compiler still works])
 243 AC_TRY_LINK([], [return 0;],
 244   [AC_MSG_RESULT(yes)],
 245   [AC_MSG_RESULT(no)
 246    AC_MSG_ERROR([cannot proceed])])
 247
 248 # Defend against gcc -ffastmath
 249 if test "$GCC" = yes; then
 250 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 251 choke me
 252 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 253 fi
 254
 255 AC_PROG_CPP
 256 AC_SUBST(GCC)
 257
 258 # Create compiler version string
 259 if test x"$GCC" = x"yes" ; then
 260   cc_string="GCC `${CC} --version | sed q`"
 261 else
 262   cc_string=$CC
 263 fi
 264 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 265                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 266                    [A string containing the version number, platform, and C compiler])
 267
 268
 269 #
 270 # Automatic dependency tracking
 271 #
 272 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 273               [autodepend=yes])
 274 AC_SUBST(autodepend)
 275
 276
 277 #
 278 # Enable assert checks
 279 #
 280 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 281               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 282                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 283
 284
 285 #
 286 # Include directories
 287 #
 288 ac_save_IFS=$IFS
 289 IFS="${IFS}:"
 290 # SRCH_INC comes from the template file
 291 for dir in $with_includes $SRCH_INC; do
 292   if test -d "$dir"; then
 293     INCLUDES="$INCLUDES -I$dir"
 294   else
 295     AC_MSG_WARN([*** Include directory $dir does not exist.])
 296   fi
 297 done
 298 IFS=$ac_save_IFS
 299 AC_SUBST(INCLUDES)
 300
 301
 302 #
 303 # Library directories
 304 #
 305 ac_save_IFS=$IFS
 306 IFS="${IFS}:"
 307 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 308 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 309   if test -d "$dir"; then
 310     LIBDIRS="$LIBDIRS -L$dir"
 311   else
 312     AC_MSG_WARN([*** Library directory $dir does not exist.])
 313   fi
 314 done
 315 IFS=$ac_save_IFS
 316
 317 #
 318 # Enable thread-safe client libraries
 319 #
 320 AC_MSG_CHECKING([allow thread-safe client libraries])
 321 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 322               [AC_DEFINE([USE_THREADS], 1,
 323                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 324 AC_MSG_RESULT([$enable_thread_safety])
 325 AC_SUBST(enable_thread_safety)
 326
 327 #
 328 # Tcl/Tk
 329 #
 330 AC_MSG_CHECKING([whether to build with Tcl])
 331 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 332 AC_MSG_RESULT([$with_tcl])
 333 AC_SUBST([with_tcl])
 334
 335 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 336 AC_MSG_CHECKING([whether to build with Tk])
 337 if test "$with_tcl" = yes; then
 338   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 339 else
 340   with_tk=no
 341 fi
 342 AC_MSG_RESULT([$with_tk])
 343 AC_SUBST([with_tk])
 344
 345
 346 # We see if the path to the Tcl/Tk configuration scripts is specified.
 347 # This will override the use of tclsh to find the paths to search.
 348
 349 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 350
 351 # We see if the path to the Tk configuration scripts is specified.
 352 # This will override the use of tclsh to find the paths to search.
 353
 354 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 355
 356 #
 357 # Optionally build Perl modules (PL/Perl)
 358 #
 359 AC_MSG_CHECKING([whether to build Perl modules])
 360 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 361 AC_MSG_RESULT([$with_perl])
 362 AC_SUBST(with_perl)
 363
 364 #
 365 # Optionally build Python interface module
 366 #
 367 AC_MSG_CHECKING([whether to build Python modules])
 368 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 369 AC_MSG_RESULT([$with_python])
 370 AC_SUBST(with_python)
 371
 372 #
 373 # Optionally build the Java/JDBC tools
 374 #
 375 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 376 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 377 [AC_MSG_RESULT(yes)
 378 PGAC_PATH_ANT
 379 if test -z "$ANT"; then
 380   AC_MSG_ERROR([Ant is required to build Java components
 381 If you have Ant already installed, see config.log for details on the failure.])
 382 fi
 383 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 384   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 385 fi],
 386 [AC_MSG_RESULT(no)])
 387 AC_SUBST(with_java)
 388
 389 dnl A note on the Kerberos and OpenSSL options:
 390 dnl
 391 dnl The user can give an argument to the option in order the specify
 392 dnl the base path of the respective installation (what he specified
 393 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 394 dnl then we take the path where the package installs by default. This
 395 dnl way the user doesn't have to use redundant --with-includes and
 396 dnl --with-libraries options, but he can still use them if the layout
 397 dnl is non-standard.
 398
 399 #
 400 # Kerberos 4
 401 #
 402 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 403 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 404                 [krb4_prefix=/usr/athena],
 405                 [krb4_prefix=$withval],
 406 [
 407   AC_MSG_RESULT(yes)
 408   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 409
 410   if test -d "$krb4_prefix/include"; then
 411     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 412   fi
 413   if test -d "$krb4_prefix/lib"; then
 414     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 415   fi
 416
 417   krb_srvtab="/etc/srvtab"
 418 ],
 419 [AC_MSG_RESULT(no)])
 420
 421 AC_SUBST(with_krb4)
 422
 423
 424 #
 425 # Kerberos 5
 426 #
 427 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 428 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 429               [krb5_prefix=/usr/athena],
 430               [krb5_prefix=$withval],
 431 [
 432   AC_MSG_RESULT([yes])
 433   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 434
 435   if test -d "$krb5_prefix/include"; then
 436     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 437   fi
 438   if test -d "$krb5_prefix/lib"; then
 439     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 440   fi
 441
 442   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 443 ],
 444 [AC_MSG_RESULT(no)])
 445
 446 AC_SUBST(with_krb5)
 447
 448
 449 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 450 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 451   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 452 fi
 453
 454 AC_SUBST(krb_srvtab)
 455
 456
 457 #
 458 # Kerberos configuration parameters
 459 #
 460 PGAC_ARG_REQ(with, krb-srvnam,
 461              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 462              [],
 463              [with_krb_srvnam="postgres"])
 464 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 465                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 466
 467
 468 #
 469 # PAM
 470 #
 471 AC_MSG_CHECKING([whether to build with PAM support])
 472 PGAC_ARG_BOOL(with, pam, no,
 473               [  --with-pam              build with PAM support],
 474               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 475 AC_MSG_RESULT([$with_pam])
 476 AC_SUBST(with_pam)
 477
 478
 479 #
 480 # Rendezvous
 481 #
 482 AC_MSG_CHECKING([whether to build with Rendezvous support])
 483 PGAC_ARG_BOOL(with, rendezvous, no,
 484               [  --with-rendezvous       build with Rendezvous support],
 485               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 486 AC_MSG_RESULT([$with_rendezvous])
 487 AC_SUBST(with_rendezvous)
 488
 489
 490 #
 491 # OpenSSL
 492 #
 493 PGAC_ARG_OPTARG(with, openssl,
 494                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 495                 [openssl_prefix=/usr/local/ssl],
 496                 [openssl_prefix=$withval],
 497 [
 498   AC_MSG_RESULT([building with OpenSSL support])
 499   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 500
 501   if test -d "${openssl_prefix}/include" ; then
 502     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 503   fi
 504   if test -d "${openssl_prefix}/lib" ; then
 505     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 506   fi
 507 ])
 508
 509 AC_SUBST(with_openssl)
 510
 511
 512 #
 513 # Readline
 514 #
 515 PGAC_ARG_BOOL(with, readline, yes,
 516               [  --without-readline      do not use Readline])
 517
 518 #
 519 # Zlib
 520 #
 521 PGAC_ARG_BOOL(with, zlib, yes,
 522               [  --without-zlib          do not use Zlib])
 523
 524
 525 #
 526 # Elf
 527 #
 528
 529 # Assume system is ELF if it predefines __ELF__ as 1,
 530 # otherwise believe host_os based default.
 531 case $host_os in
 532     freebsd1*|freebsd2*) elf=no;;
 533     freebsd3*|freebsd4*) elf=yes;;
 534 esac
 535
 536 AC_EGREP_CPP(yes,
 537 [#if __ELF__
 538   yes
 539 #endif
 540 ],
 541 [ELF_SYS=true],
 542 [if test "X$elf" = "Xyes" ; then
 543   ELF_SYS=true
 544 else
 545   ELF_SYS=
 546 fi])
 547 AC_SUBST(ELF_SYS)
 548
 549 #
 550 # Assignments
 551 #
 552
 553 CPPFLAGS="$CPPFLAGS $INCLUDES"
 554 LDFLAGS="$LDFLAGS $LIBDIRS"
 555
 556 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 557 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 558
 559
 560 AC_PROG_AWK
 561 PGAC_PATH_FLEX
 562 AC_PROG_LN_S
 563 AC_PROG_LD
 564 AC_SUBST(LD)
 565 AC_SUBST(with_gnu_ld)
 566 case $host_os in sysv5*)
 567   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 568   [
 569     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 570     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 571     LDFLAGS=$pgac_save_LDFLAGS
 572   ])
 573   ld_R_works=$pgac_cv_prog_ld_R
 574   AC_SUBST(ld_R_works)
 575 esac
 576 AC_PROG_RANLIB
 577 AC_CHECK_PROGS(LORDER, lorder)
 578 AC_PATH_PROG(TAR, tar)
 579 PGAC_CHECK_STRIP
 580
 581 AC_CHECK_PROGS(YACC, ['bison -y'])
 582
 583 if test "$YACC"; then
 584   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 585     AC_MSG_WARN([
 586 *** The installed version of Bison is too old.  PostgreSQL needs
 587 *** Bison version 1.875 or later.])
 588   fi
 589 fi
 590
 591 if test -z "$YACC"; then
 592   AC_MSG_WARN([
 593 *** Without Bison you will not be able to build PostgreSQL from CVS or
 594 *** change any of the parser definition files.  You can obtain Bison from
 595 *** a GNU mirror site.  (If you are using the official distribution of
 596 *** PostgreSQL then you do not need to worry about this because the Bison
 597 *** output is pre-generated.)  To use a different yacc program (possible,
 598 *** but not recommended), set the environment variable YACC before running
 599 *** 'configure'.])
 600 fi
 601 AC_SUBST(YFLAGS)
 602
 603 PGAC_PATH_PERL
 604 if test "$with_perl" = yes; then
 605   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 606   PGAC_CHECK_PERL_EMBED_LDFLAGS
 607 fi
 608
 609 if test "$with_python" = yes; then
 610   PGAC_PATH_PYTHON
 611   PGAC_CHECK_PYTHON_MODULE_SETUP
 612   PGAC_CHECK_PYTHON_EMBED_SETUP
 613 fi
 614
 615
 616 ##
 617 ## Libraries
 618 ##
 619
 620 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 621 then
 622         AC_CHECK_LIB(bsd,      main)
 623 fi
 624 AC_CHECK_LIB(util,     setproctitle)
 625 AC_CHECK_LIB(m,        main)
 626 AC_CHECK_LIB(dl,       main)
 627 AC_CHECK_LIB(nsl,      main)
 628 AC_CHECK_LIB(socket,   main)
 629 AC_CHECK_LIB(ipc,      main)
 630 AC_CHECK_LIB(IPC,      main)
 631 AC_CHECK_LIB(lc,       main)
 632 AC_CHECK_LIB(dld,      main)
 633 AC_CHECK_LIB(ld,       main)
 634 AC_CHECK_LIB(compat,   main)
 635 AC_CHECK_LIB(BSD,      main)
 636 AC_CHECK_LIB(gen,      main)
 637 AC_CHECK_LIB(PW,       main)
 638 AC_CHECK_LIB(resolv,   main)
 639 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 640 # QNX:
 641 AC_CHECK_LIB(unix, main)
 642 AC_SEARCH_LIBS(crypt,  crypt)
 643 # BeOS:
 644 if test "$PORTNAME" = "beos"
 645 then
 646         AC_CHECK_LIB(bind, __inet_ntoa)
 647 fi
 648 # Solaris:
 649 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 650 # Cygwin:
 651 AC_CHECK_LIB(cygipc, shmget)
 652 # WIN32:
 653 if test "$PORTNAME" = "win32"
 654 then
 655         AC_CHECK_LIB(wsock32, main)
 656 fi
 657
 658 if test "$with_readline" = yes; then
 659   PGAC_CHECK_READLINE
 660   if test x"$pgac_cv_check_readline" = x"no"; then
 661     AC_MSG_ERROR([readline library not found
 662 If you have readline already installed, see config.log for details on the
 663 failure.  It is possible the compiler isn't looking in the proper directory.
 664 Use --without-readline to disable readline support.])
 665   fi
 666 fi
 667
 668 if test "$with_zlib" = yes; then
 669   AC_CHECK_LIB(z, inflate, [],
 670                [AC_MSG_ERROR([zlib library not found
 671 If you have zlib already installed, see config.log for details on the
 672 failure.  It is possible the compiler isn't looking in the proper directory.
 673 Use --without-zlib to disable zlib support.])])
 674 fi
 675
 676 if test "$with_krb4" = yes ; then
 677   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 678   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 679   AC_REPLACE_FUNCS([gethostname])
 680 fi
 681
 682 if test "$with_krb5" = yes ; then
 683   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 684                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 685   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 686                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 687   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 688                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 689 fi
 690
 691 if test "$with_openssl" = yes ; then
 692   dnl Order matters!
 693   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 694   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 695 fi
 696
 697 if test "$with_pam" = yes ; then
 698   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 699 fi
 700
 701
 702 ##
 703 ## Header files
 704 ##
 705
 706 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 707 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 708
 709 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 710 # netinet/in.h is included first.
 711 AC_CHECK_HEADERS(netinet/in.h)
 712 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 713 [AC_INCLUDES_DEFAULT
 714 #ifdef HAVE_NETINET_IN_H
 715 #include <netinet/in.h>
 716 #endif
 717 ])
 718
 719 if test "$with_readline" = yes; then
 720   AC_CHECK_HEADERS(readline/readline.h, [],
 721                    [AC_CHECK_HEADERS(editline/readline.h, [],
 722                          [AC_CHECK_HEADERS(readline.h, [],
 723                                      [AC_MSG_ERROR([readline header not found
 724 If you have readline already installed, see config.log for details on the
 725 failure.  It is possible the compiler isn't looking in the proper directory.
 726 Use --without-readline to disable readline support.])])])])
 727   AC_CHECK_HEADERS(readline/history.h, [],
 728                    [AC_CHECK_HEADERS(editline/history.h, [],
 729                          [AC_CHECK_HEADERS(history.h, [],
 730                                      [AC_MSG_ERROR([history header not found
 731 If you have readline already installed, see config.log for details on the
 732 failure.  It is possible the compiler isn't looking in the proper directory.
 733 Use --without-readline to disable readline support.])])])])
 734 fi
 735
 736 if test "$with_zlib" = yes; then
 737   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 738 If you have zlib already installed, see config.log for details on the
 739 failure.  It is possible the compiler isn't looking in the proper directory.
 740 Use --without-zlib to disable zlib support.])])
 741 fi
 742
 743 if test "$with_krb4" = yes ; then
 744   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 745 fi
 746
 747 if test "$with_krb5" = yes ; then
 748   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 749   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 750 fi
 751
 752 if test "$with_openssl" = yes ; then
 753   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 754   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 755 fi
 756
 757 if test "$with_pam" = yes ; then
 758   AC_CHECK_HEADERS(security/pam_appl.h, [],
 759                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 760                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 761 fi
 762
 763 if test "$with_rendezvous" = yes ; then
 764   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 765 fi
 766
 767
 768 ##
 769 ## Types, structures, compiler characteristics
 770 ##
 771
 772 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 773 AC_C_CONST
 774 AC_C_INLINE
 775 AC_C_STRINGIZE
 776 PGAC_C_SIGNED
 777 AC_C_VOLATILE
 778 PGAC_C_FUNCNAME_SUPPORT
 779 PGAC_STRUCT_TIMEZONE
 780 PGAC_UNION_SEMUN
 781 PGAC_STRUCT_SOCKADDR_UN
 782 PGAC_STRUCT_SOCKADDR_STORAGE
 783 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 784 PGAC_STRUCT_ADDRINFO
 785
 786 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 787 [#include <sys/param.h>
 788 #include <sys/types.h>
 789 #include <sys/socket.h>
 790 #include <sys/ucred.h>])
 791
 792 AC_CHECK_TYPES([struct option], [], [],
 793 [#ifdef HAVE_GETOPT_H
 794 #include <getopt.h>
 795 #endif])
 796
 797 if test "$with_zlib" = yes; then
 798   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 799   # did not).  While we could work around the lack of z_streamp, it
 800   # seems unwise to encourage people to use such old zlib versions...
 801   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 802 Use --without-zlib to disable zlib support.])],
 803                 [#include <zlib.h>])
 804 fi
 805
 806 if test "$with_krb5" = yes; then
 807 # Check for differences between MIT and Heimdal (KTH) releases
 808   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 809                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 810                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 811                                      [#include <krb5.h>])],
 812                    [#include <krb5.h>])
 813   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 814                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 815                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 816                                      [#include <krb5.h>])],
 817                    [#include <krb5.h>])
 818 fi
 819
 820
 821 ##
 822 ## Functions, global variables
 823 ##
 824
 825 PGAC_VAR_INT_TIMEZONE
 826 AC_FUNC_ACCEPT_ARGTYPES
 827 PGAC_FUNC_GETTIMEOFDAY_1ARG
 828
 829 # SunOS doesn't handle negative byte comparisons properly with +/- return
 830 AC_FUNC_MEMCMP
 831
 832 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 833
 834 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 835
 836 AC_CHECK_TYPE([struct sockaddr_in6],
 837               [AC_CHECK_FUNC(inet_ntop,
 838                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])])],
 839               [],
 840 [$ac_includes_default
 841 #include <netinet/in.h>])
 842
 843 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 844 [AC_TRY_LINK(
 845 [#include <machine/vmparam.h>
 846 #include <sys/exec.h>
 847 ],
 848 [PS_STRINGS->ps_nargvstr = 1;
 849 PS_STRINGS->ps_argvstr = "foo";],
 850 [pgac_cv_var_PS_STRINGS=yes],
 851 [pgac_cv_var_PS_STRINGS=no])])
 852 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 853   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 854 fi
 855
 856
 857 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 858 # is missing.  Yes, there are machines that have only one.  We may
 859 # also decide to use snprintf.c if snprintf() is present but does not
 860 # have working "long long int" support -- see below.
 861
 862 pgac_need_repl_snprintf=no
 863 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 864 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 865
 866
 867 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 868 # include/c.h will provide declarations.  Note this is a separate test
 869 # from whether the functions exist in the C library --- there are
 870 # systems that have the functions but don't bother to declare them :-(
 871
 872 AC_CHECK_DECLS([snprintf, vsnprintf])
 873
 874
 875 # do this one the hard way in case isinf() is a macro
 876 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 877 [AC_TRY_LINK(
 878 [#include <math.h>
 879 ],
 880 [double x = 0.0; int res = isinf(x);],
 881 [ac_cv_func_isinf=yes],
 882 [ac_cv_func_isinf=no])])
 883
 884 if test $ac_cv_func_isinf = yes ; then
 885   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 886 else
 887   AC_LIBOBJ(isinf)
 888   # Look for a way to implement a substitute for isinf()
 889   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 890 fi
 891
 892 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 893
 894 # system's version of getaddrinfo(), if any, may be used only if we found
 895 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 896 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 897   AC_REPLACE_FUNCS([getaddrinfo])
 898 else
 899   AC_LIBOBJ(getaddrinfo)
 900 fi
 901
 902 # similarly, use system's getopt_long() only if system provides struct option.
 903 if test x"$ac_cv_type_struct_option" = xyes ; then
 904   AC_REPLACE_FUNCS([getopt_long])
 905 else
 906   AC_LIBOBJ(getopt_long)
 907 fi
 908
 909 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 910 # We override the previous test that said fseeko/ftello didn't exist
 911 # OS tests are also done in include/c.h and port/fseeko.c
 912 case $host_os in bsdi*|netbsd*)
 913 ac_cv_func_fseeko=yes
 914 esac
 915
 916 # Solaris has a very slow qsort in certain cases, so we replace it.
 917 case $host_os in solaris*)
 918 AC_LIBOBJ(qsort) ;;
 919 esac
 920
 921 # Win32 can't to rename or unlink on an open file
 922 case $host_os in mingw*)
 923 AC_LIBOBJ(dirmod)
 924 AC_LIBOBJ(copydir)
 925 AC_LIBOBJ(gettimeofday) ;;
 926 esac
 927
 928 if test "$with_readline" = yes; then
 929   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 930   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 931   AC_CHECK_FUNCS([replace_history_entry])
 932 fi
 933
 934
 935 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 936 AC_MSG_CHECKING(for finite)
 937 AC_TRY_LINK([#include <math.h>],
 938             [int dummy=finite(1.0);],
 939             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 940 AC_MSG_RESULT(yes)],
 941             [AC_MSG_RESULT(no)])
 942
 943 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 944 dnl (especially on GNU libc)
 945 dnl See also comments in c.h.
 946 AC_MSG_CHECKING(for sigsetjmp)
 947 AC_TRY_LINK([#include <setjmp.h>],
 948             [sigjmp_buf x; sigsetjmp(x, 1);],
 949             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 950 AC_MSG_RESULT(yes)],
 951             [AC_MSG_RESULT(no)])
 952
 953 AC_CHECK_FUNC(syslog,
 954               [AC_CHECK_HEADER(syslog.h,
 955                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 956
 957 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 958 [AC_TRY_LINK([#include <unistd.h>],
 959   [extern int optreset; optreset = 1;],
 960   [pgac_cv_var_int_optreset=yes],
 961   [pgac_cv_var_int_optreset=no])])
 962 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 963   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 964 fi
 965
 966 AC_CHECK_FUNCS([strtoll strtoq], [break])
 967 AC_CHECK_FUNCS([strtoull strtouq], [break])
 968
 969 # Check for one of atexit() or on_exit()
 970 AC_CHECK_FUNCS(atexit, [],
 971                [AC_CHECK_FUNCS(on_exit, [],
 972                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 973
 974 AC_FUNC_FSEEKO
 975
 976 #
 977 # Pthreads
 978 #
 979 # For each platform, we need to know about any special compile and link
 980 # libraries, and whether the normal C function names are thread-safe.
 981 # See the comment at the top of src/port/thread.c for more information.
 982 #
 983 if test "$enable_thread_safety" = yes; then
 984 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
 985
 986 if test "$SUPPORTS_THREADS" != yes; then
 987 AC_MSG_ERROR([
 988 Cannot enable threads on your platform.
 989 Please report your platform threading info to the PostgreSQL mailing lists
 990 so it can be added to the next release.  Report all compile flags, link flags,
 991 functions, or libraries required for threading support.
 992 See the comment at the top of src/port/thread.c for more information.
 993 ])
 994 fi
 995 else
 996 # do not use values from template file
 997 THREAD_CFLAGS=
 998 THREAD_LIBS=
 999 fi
1000 AC_SUBST(THREAD_CFLAGS)
1001 AC_SUBST(THREAD_LIBS)
1002
1003
1004 #
1005 # Check for re-entrant versions of certain functions
1006 #
1007 # Include special flags if threads are enabled _and_ if required for
1008 # threading on this platform.  Some platforms have *_r functions but
1009 # their natively named funcs are threadsafe, and should be used instead.
1010 #
1011 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1012 # functions are marked "not found", which is perfect.
1013 #
1014 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNC_NAMES" = yes ; then
1015 _CFLAGS="$CFLAGS"
1016 _LIBS="$LIBS"
1017 CFLAGS="$CFLAGS $THREAD_CFLAGS"
1018 LIBS="$LIBS $THREAD_LIBS"
1019 AC_CHECK_FUNC(strerror_r,
1020         [], [AC_MSG_ERROR([strerror_r not found, required on this platform for --enable-thread-safety])])
1021 AC_CHECK_FUNC(getpwuid_r,
1022         [], [AC_MSG_ERROR([getpwuid_r not found, required on this platform for --enable-thread-safety])])
1023 AC_CHECK_FUNC(gethostbyname_r,
1024         [], [AC_MSG_ERROR([gethostbyname_r not found, required on this platform for --enable-thread-safety])])
1025 CFLAGS="$_CFLAGS"
1026 LIBS="$_LIBS"
1027 fi
1028
1029
1030 # This test makes sure that run tests work at all.  Sometimes a shared
1031 # library is found by the linker, but the runtime linker can't find it.
1032 # This check should come after all modifications of compiler or linker
1033 # variables, and before any other run tests.
1034 AC_MSG_CHECKING([test program])
1035 AC_TRY_RUN([int main() { return 0; }],
1036 [AC_MSG_RESULT(ok)],
1037 [AC_MSG_RESULT(failed)
1038 AC_MSG_ERROR([[
1039 *** Could not execute a simple test program.  This may be a problem
1040 *** related to locating shared libraries.  Check the file 'config.log'
1041 *** for the exact reason.]])],
1042 [AC_MSG_RESULT([cross-compiling])])
1043
1044
1045 dnl Check to see if we have a working 64-bit integer type.
1046 dnl This breaks down into two steps:
1047 dnl (1) figure out if the compiler has a 64-bit int type with working
1048 dnl arithmetic, and if so
1049 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1050 dnl snprintf is the only library routine we really need for int8 support.)
1051 dnl It's entirely possible to have a compiler that handles a 64-bit type
1052 dnl when the C library doesn't; this is fairly likely when using gcc on
1053 dnl an older platform, for example.
1054 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1055 dnl we force our own version of snprintf() to be used instead.
1056 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1057
1058 PGAC_TYPE_64BIT_INT([long int])
1059
1060 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1061   PGAC_TYPE_64BIT_INT([long long int])
1062 fi
1063
1064
1065 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1066
1067 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1068   AC_TRY_COMPILE([
1069 #define INT64CONST(x)  x##LL
1070 long long int foo = INT64CONST(0x1234567890123456);
1071 ],
1072         [],
1073         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1074         [])
1075 fi
1076
1077
1078 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1079 # we found we need to use "long long int", better check.  We cope with
1080 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1081 # neither works, fall back to our own snprintf emulation (which we
1082 # know uses %lld).
1083
1084 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1085   if test $pgac_need_repl_snprintf = no; then
1086     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1087     if test "$LONG_LONG_INT_FORMAT" = ""; then
1088       # Force usage of our own snprintf, since system snprintf is broken
1089       pgac_need_repl_snprintf=yes
1090       LONG_LONG_INT_FORMAT='%lld'
1091     fi
1092   else
1093     # Here if we previously decided we needed to use our own snprintf
1094     LONG_LONG_INT_FORMAT='%lld'
1095   fi
1096   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1097 else
1098   # Here if we are not using 'long long int' at all
1099   INT64_FORMAT='"%ld"'
1100 fi
1101
1102 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1103                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1104
1105 if test $pgac_need_repl_snprintf = yes; then
1106   AC_LIBOBJ(snprintf)
1107 fi
1108
1109 # Need a #define for the size of Datum (unsigned long)
1110 AC_CHECK_SIZEOF([unsigned long])
1111
1112 # Determine memory alignment requirements for the basic C data types.
1113
1114 PGAC_CHECK_ALIGNOF(short)
1115 PGAC_CHECK_ALIGNOF(int)
1116 PGAC_CHECK_ALIGNOF(long)
1117 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1118   PGAC_CHECK_ALIGNOF(long long int)
1119 fi
1120 PGAC_CHECK_ALIGNOF(double)
1121
1122 # Compute maximum alignment of any basic type.
1123 # We assume long's alignment is at least as strong as char, short, or int;
1124 # but we must check long long (if it exists) and double.
1125
1126 MAX_ALIGNOF=$pgac_cv_alignof_long
1127 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1128   MAX_ALIGNOF=$pgac_cv_alignof_double
1129 fi
1130 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1131   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1132 fi
1133 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1134
1135
1136 # Some platforms predefine the types int8, int16, etc.  Only check
1137 # a (hopefully) representative subset.
1138 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1139 [#include <stdio.h>
1140 #ifdef HAVE_SUPPORTDEFS_H
1141 #include <SupportDefs.h>
1142 #endif])
1143
1144 # We also check for sig_atomic_t, which *should* be defined per ANSI
1145 # C, but is missing on some old platforms.
1146 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1147
1148
1149 PGAC_FUNC_POSIX_SIGNALS
1150 if test $ac_cv_func_fseeko = yes; then
1151 AC_SYS_LARGEFILE
1152 fi
1153
1154
1155 # Select semaphore implementation type.
1156 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1157   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1158   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1159 else
1160   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1161     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1162     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1163   else
1164     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1165     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1166   fi
1167 fi
1168
1169
1170 # Select shared-memory implementation type.
1171 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1172 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1173
1174
1175 if test "$enable_nls" = yes ; then
1176   PGAC_CHECK_GETTEXT
1177 fi
1178
1179 # Check for Tcl configuration script tclConfig.sh
1180 if test "$with_tcl" = yes; then
1181     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1182     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1183                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1184     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1185 fi
1186
1187 # Check for Tk configuration script tkConfig.sh
1188 if test "$with_tk" = yes; then
1189     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1190     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1191 fi
1192
1193
1194 #
1195 # Check for DocBook and tools
1196 #
1197 PGAC_PROG_NSGMLS
1198 PGAC_PROG_JADE
1199 PGAC_CHECK_DOCBOOK(3.1)
1200 PGAC_PATH_DOCBOOK_STYLESHEETS
1201 PGAC_PATH_COLLATEINDEX
1202 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1203
1204
1205 # prepare build tree if outside source tree
1206 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1207 # Note 2: /bin/pwd might be better than shell's built-in at getting
1208 #         a symlink-free name.
1209 if test "$no_create" != yes; then
1210   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1211     :
1212   else
1213     AC_SUBST(vpath_build, yes)
1214     _AS_ECHO_N([preparing build tree... ])
1215     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1216     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1217       || AC_MSG_ERROR(failed)
1218     AC_MSG_RESULT(done)
1219   fi
1220 fi
1221
1222
1223 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1224
1225 AC_CONFIG_LINKS([
1226   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1227   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1228   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1229   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1230   src/include/pg_config_os.h:src/include/port/${template}.h
1231   src/Makefile.port:src/makefiles/Makefile.${template}
1232 ])
1233
1234 AC_CONFIG_HEADERS([src/include/pg_config.h],
1235 [
1236 # Update timestamp for pg_config.h (see Makefile.global)
1237 echo >src/include/stamp-h
1238 ])
1239
1240 AC_OUTPUT