granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.6devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2015, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif])], [ICC=yes], [ICC=no])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # CFLAGS we determined above will be added back at the end
 418 user_CFLAGS=$CFLAGS
 419 CFLAGS=""
 420
 421 # set CFLAGS_VECTOR from the environment, if available
 422 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 423   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 424 fi
 425
 426 # Some versions of GCC support some additional useful warning flags.
 427 # Check whether they are supported, and add them to CFLAGS if so.
 428 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 429 # but has its own.  Also check other compiler-specific flags here.
 430
 431 if test "$GCC" = yes -a "$ICC" = no; then
 432   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 433   # These work in some but not all gcc versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 436   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 437   # This was included in -Wall/-Wformat in older GCC versions
 438   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 439   # Disable strict-aliasing rules; needed for gcc 3.3+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 442   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 443   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 444   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 445   # Optimization flags for specific files that benefit from vectorization
 446   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 447   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 448   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 449   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 450   # test for the positive form and if that works, add the negative form
 451   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 452   if test -n "$NOT_THE_CFLAGS"; then
 453     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 454   fi
 455 elif test "$ICC" = yes; then
 456   # Intel's compiler has a bug/misoptimization in checking for
 457   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 458   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 459   # Make sure strict aliasing is off (though this is said to be the default)
 460   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 461 elif test "$PORTNAME" = "aix"; then
 462   # AIX's xlc has to have strict aliasing turned off too
 463   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 464 elif test "$PORTNAME" = "hpux"; then
 465   # On some versions of HP-UX, libm functions do not set errno by default.
 466   # Fix that by using +Olibmerrno if the compiler recognizes it.
 467   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 468 fi
 469
 470 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 471
 472 # supply -g if --enable-debug
 473 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 474   CFLAGS="$CFLAGS -g"
 475 fi
 476
 477 # enable code coverage if --enable-coverage
 478 if test "$enable_coverage" = yes; then
 479   if test "$GCC" = yes; then
 480     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 481   else
 482     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 483   fi
 484 fi
 485
 486 # enable profiling if --enable-profiling
 487 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 488   if test "$GCC" = yes; then
 489     AC_DEFINE([PROFILE_PID_DIR], 1,
 490            [Define to 1 to allow profiling output to be saved separately for each process.])
 491     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 492   else
 493     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 494   fi
 495 fi
 496
 497 # We already have this in Makefile.win32, but configure needs it too
 498 if test "$PORTNAME" = "win32"; then
 499   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 500 fi
 501
 502 # Now that we're done automatically adding stuff to CFLAGS, put back the
 503 # user-specified flags (if any) at the end.  This lets users override
 504 # the automatic additions.
 505 CFLAGS="$CFLAGS $user_CFLAGS"
 506
 507 # Check if the compiler still works with the final flag settings
 508 AC_MSG_CHECKING([whether the C compiler still works])
 509 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 510   [AC_MSG_RESULT(yes)],
 511   [AC_MSG_RESULT(no)
 512    AC_MSG_ERROR([cannot proceed])])
 513
 514 # Defend against gcc -ffast-math
 515 if test "$GCC" = yes; then
 516 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 517 choke me
 518 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 519 fi
 520
 521 AC_PROG_CPP
 522 AC_SUBST(GCC)
 523
 524
 525 #
 526 # Set up TAS assembly code if needed; the template file has now had its
 527 # chance to request this.
 528 #
 529 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 530
 531 if test "$need_tas" = yes ; then
 532   TAS=tas.o
 533 else
 534   TAS=""
 535 fi
 536 AC_SUBST(TAS)
 537
 538
 539 #
 540 # Automatic dependency tracking
 541 #
 542 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 543               [autodepend=yes])
 544 AC_SUBST(autodepend)
 545
 546
 547 #
 548 # Enable assert checks
 549 #
 550 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 551               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 552                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 553
 554
 555 #
 556 # Include directories
 557 #
 558 ac_save_IFS=$IFS
 559 IFS="${IFS}${PATH_SEPARATOR}"
 560 # SRCH_INC comes from the template file
 561 for dir in $with_includes $SRCH_INC; do
 562   if test -d "$dir"; then
 563     INCLUDES="$INCLUDES -I$dir"
 564   else
 565     AC_MSG_WARN([*** Include directory $dir does not exist.])
 566   fi
 567 done
 568 IFS=$ac_save_IFS
 569 AC_SUBST(INCLUDES)
 570
 571
 572 #
 573 # Library directories
 574 #
 575 ac_save_IFS=$IFS
 576 IFS="${IFS}${PATH_SEPARATOR}"
 577 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 578 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 579   if test -d "$dir"; then
 580     LIBDIRS="$LIBDIRS -L$dir"
 581   else
 582     AC_MSG_WARN([*** Library directory $dir does not exist.])
 583   fi
 584 done
 585 IFS=$ac_save_IFS
 586
 587 #
 588 # Enable thread-safe client libraries
 589 #
 590 AC_MSG_CHECKING([allow thread-safe client libraries])
 591 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 592 if test "$enable_thread_safety" = yes; then
 593   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 594           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 595 fi
 596 AC_MSG_RESULT([$enable_thread_safety])
 597 AC_SUBST(enable_thread_safety)
 598
 599 #
 600 # Optionally build Tcl modules (PL/Tcl)
 601 #
 602 AC_MSG_CHECKING([whether to build with Tcl])
 603 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 604 AC_MSG_RESULT([$with_tcl])
 605 AC_SUBST([with_tcl])
 606
 607 # We see if the path to the Tcl/Tk configuration scripts is specified.
 608 # This will override the use of tclsh to find the paths to search.
 609
 610 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 611
 612 #
 613 # Optionally build Perl modules (PL/Perl)
 614 #
 615 AC_MSG_CHECKING([whether to build Perl modules])
 616 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 617 AC_MSG_RESULT([$with_perl])
 618 AC_SUBST(with_perl)
 619
 620 #
 621 # Optionally build Python modules (PL/Python)
 622 #
 623 AC_MSG_CHECKING([whether to build Python modules])
 624 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 625 AC_MSG_RESULT([$with_python])
 626 AC_SUBST(with_python)
 627
 628 #
 629 # GSSAPI
 630 #
 631 AC_MSG_CHECKING([whether to build with GSSAPI support])
 632 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 633 [
 634   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 635   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 636 ])
 637 AC_MSG_RESULT([$with_gssapi])
 638
 639
 640 AC_SUBST(krb_srvtab)
 641
 642
 643 #
 644 # Kerberos configuration parameters
 645 #
 646 PGAC_ARG_REQ(with, krb-srvnam,
 647              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 648              [],
 649              [with_krb_srvnam="postgres"])
 650 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 651                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 652
 653
 654 #
 655 # PAM
 656 #
 657 AC_MSG_CHECKING([whether to build with PAM support])
 658 PGAC_ARG_BOOL(with, pam, no,
 659               [build with PAM support],
 660               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 661 AC_MSG_RESULT([$with_pam])
 662
 663
 664 #
 665 # LDAP
 666 #
 667 AC_MSG_CHECKING([whether to build with LDAP support])
 668 PGAC_ARG_BOOL(with, ldap, no,
 669               [build with LDAP support],
 670               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 671 AC_MSG_RESULT([$with_ldap])
 672
 673
 674 #
 675 # Bonjour
 676 #
 677 AC_MSG_CHECKING([whether to build with Bonjour support])
 678 PGAC_ARG_BOOL(with, bonjour, no,
 679               [build with Bonjour support],
 680               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 681 AC_MSG_RESULT([$with_bonjour])
 682
 683
 684 #
 685 # OpenSSL
 686 #
 687 AC_MSG_CHECKING([whether to build with OpenSSL support])
 688 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 689               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 690 AC_MSG_RESULT([$with_openssl])
 691 AC_SUBST(with_openssl)
 692
 693 #
 694 # SELinux
 695 #
 696 AC_MSG_CHECKING([whether to build with SELinux support])
 697 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 698 AC_SUBST(with_selinux)
 699 AC_MSG_RESULT([$with_selinux])
 700
 701 #
 702 # Readline
 703 #
 704 PGAC_ARG_BOOL(with, readline, yes,
 705               [do not use GNU Readline nor BSD Libedit for editing])
 706 # readline on MinGW has problems with backslashes in psql and other bugs.
 707 # This is particularly a problem with non-US code pages.
 708 # Therefore disable its use until we understand the cause. 2004-07-20
 709 if test "$PORTNAME" = "win32"; then
 710   if test "$with_readline" = yes; then
 711     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 712     with_readline=no
 713   fi
 714 fi
 715
 716
 717 #
 718 # Prefer libedit
 719 #
 720 PGAC_ARG_BOOL(with, libedit-preferred, no,
 721               [prefer BSD Libedit over GNU Readline])
 722
 723
 724 #
 725 # UUID library
 726 #
 727 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 728 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 729 # UUID library.  More than one of these might be present on a given platform,
 730 # so we make the user say which one she wants.
 731 #
 732 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 733 if test x"$with_uuid" = x"" ; then
 734   with_uuid=no
 735 fi
 736 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 737 if test "$with_ossp_uuid" = yes ; then
 738   with_uuid=ossp
 739 fi
 740
 741 if test "$with_uuid" = bsd ; then
 742   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 743   UUID_EXTRA_OBJS="md5.o sha1.o"
 744 elif test "$with_uuid" = e2fs ; then
 745   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 746   UUID_EXTRA_OBJS="md5.o sha1.o"
 747 elif test "$with_uuid" = ossp ; then
 748   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 749   UUID_EXTRA_OBJS=""
 750 elif test "$with_uuid" = no ; then
 751   UUID_EXTRA_OBJS=""
 752 else
 753   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 754 fi
 755 AC_SUBST(with_uuid)
 756 AC_SUBST(UUID_EXTRA_OBJS)
 757
 758
 759 #
 760 # XML
 761 #
 762 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 763               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 764
 765 if test "$with_libxml" = yes ; then
 766   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 767   if test -n "$XML2_CONFIG"; then
 768     for pgac_option in `$XML2_CONFIG --cflags`; do
 769       case $pgac_option in
 770         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 771       esac
 772     done
 773     for pgac_option in `$XML2_CONFIG --libs`; do
 774       case $pgac_option in
 775         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 776       esac
 777     done
 778   fi
 779 fi
 780
 781 AC_SUBST(with_libxml)
 782
 783 #
 784 # XSLT
 785 #
 786 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 787               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 788
 789
 790 AC_SUBST(with_libxslt)
 791
 792 #
 793 # tzdata
 794 #
 795 PGAC_ARG_REQ(with, system-tzdata,
 796              [DIR], [use system time zone data in DIR])
 797 AC_SUBST(with_system_tzdata)
 798
 799 #
 800 # Zlib
 801 #
 802 PGAC_ARG_BOOL(with, zlib, yes,
 803               [do not use Zlib])
 804 AC_SUBST(with_zlib)
 805
 806 #
 807 # Elf
 808 #
 809
 810 # Assume system is ELF if it predefines __ELF__ as 1,
 811 # otherwise believe host_os based default.
 812 case $host_os in
 813     freebsd1*|freebsd2*) elf=no;;
 814     freebsd3*|freebsd4*) elf=yes;;
 815 esac
 816
 817 AC_EGREP_CPP(yes,
 818 [#if __ELF__
 819   yes
 820 #endif
 821 ],
 822 [ELF_SYS=true],
 823 [if test "X$elf" = "Xyes" ; then
 824   ELF_SYS=true
 825 else
 826   ELF_SYS=
 827 fi])
 828 AC_SUBST(ELF_SYS)
 829
 830 #
 831 # Assignments
 832 #
 833
 834 CPPFLAGS="$CPPFLAGS $INCLUDES"
 835 LDFLAGS="$LDFLAGS $LIBDIRS"
 836
 837 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 838 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 839
 840 PGAC_PROG_LD
 841 AC_SUBST(LD)
 842 AC_SUBST(with_gnu_ld)
 843 case $host_os in sysv5*)
 844   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 845   [
 846     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 847     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 848       [pgac_cv_prog_ld_R=yes],
 849       [pgac_cv_prog_ld_R=no])
 850     LDFLAGS=$pgac_save_LDFLAGS
 851   ])
 852   ld_R_works=$pgac_cv_prog_ld_R
 853   AC_SUBST(ld_R_works)
 854 esac
 855 AC_PROG_RANLIB
 856 PGAC_CHECK_STRIP
 857 AC_CHECK_TOOL(AR, ar, ar)
 858 if test "$PORTNAME" = "win32"; then
 859   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 860   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 861   AC_CHECK_TOOL(WINDRES, windres, windres)
 862 fi
 863
 864 AC_PROG_INSTALL
 865 # When Autoconf chooses install-sh as install program it tries to generate
 866 # a relative path to it in each makefile where it subsitutes it. This clashes
 867 # with our Makefile.global concept. This workaround helps.
 868 case $INSTALL in
 869   *install-sh*) install_bin='';;
 870   *) install_bin=$INSTALL;;
 871 esac
 872 AC_SUBST(install_bin)
 873
 874 AC_PATH_PROG(TAR, tar)
 875 AC_PROG_LN_S
 876 AC_PROG_AWK
 877 AC_PROG_MKDIR_P
 878 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 879 # a relative path to it in each makefile where it subsitutes it. This clashes
 880 # with our Makefile.global concept. This workaround helps.
 881 case $MKDIR_P in
 882   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 883 esac
 884
 885 PGAC_PATH_BISON
 886 PGAC_PATH_FLEX
 887
 888 PGAC_PATH_PERL
 889 if test "$with_perl" = yes; then
 890   if test -z "$PERL"; then
 891     AC_MSG_ERROR([Perl not found])
 892   fi
 893   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 894   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 895     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 896 You might have to rebuild your Perl installation.  Refer to the
 897 documentation for details.  Use --without-perl to disable building
 898 PL/Perl.])
 899   fi
 900   PGAC_CHECK_PERL_EMBED_LDFLAGS
 901 fi
 902
 903 if test "$with_python" = yes; then
 904   PGAC_PATH_PYTHON
 905   PGAC_CHECK_PYTHON_EMBED_SETUP
 906
 907   # We need libpython as a shared library.  With Python >=2.5, we
 908   # check the Py_ENABLE_SHARED setting.  On Debian, the setting is not
 909   # correct before the jessie release (http://bugs.debian.org/695979).
 910   # We also want to support older Python versions.  So as a fallback
 911   # we see if there is a file that is named like a shared library.
 912
 913   if test "$python_enable_shared" != 1; then
 914     if test "$PORTNAME" = darwin; then
 915       # OS X does supply a .dylib even though Py_ENABLE_SHARED does
 916       # not get set.  The file detection logic below doesn't succeed
 917       # on older OS X versions, so make it explicit.
 918       python_enable_shared=1
 919     elif test "$PORTNAME" = win32; then
 920       # Windows also needs an explicit override.
 921       python_enable_shared=1
 922     else
 923       # We don't know the platform shared library extension here yet,
 924       # so we try some candidates.
 925       for dlsuffix in .so .sl; do
 926         if ls "$python_libdir"/libpython*${dlsuffix}* >/dev/null 2>&1; then
 927           python_enable_shared=1
 928           break
 929         fi
 930       done
 931     fi
 932   fi
 933
 934   if test "$python_enable_shared" != 1; then
 935     AC_MSG_ERROR([cannot build PL/Python because libpython is not a shared library
 936 You might have to rebuild your Python installation.  Refer to the
 937 documentation for details.  Use --without-python to disable building
 938 PL/Python.])
 939   fi
 940 fi
 941
 942 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 943   AC_PATH_PROG(ZIC, zic)
 944   if test -z "$ZIC"; then
 945     AC_MSG_ERROR([
 946 When cross-compiling, either use the option --with-system-tzdata to use
 947 existing time-zone data, or set the environment variable ZIC to a zic
 948 program to use during the build.])
 949   fi
 950 fi
 951
 952 #
 953 # Pthreads
 954 #
 955 # For each platform, we need to know about any special compile and link
 956 # libraries, and whether the normal C function names are thread-safe.
 957 # See the comment at the top of src/port/thread.c for more information.
 958 # WIN32 doesn't need the pthread tests;  it always uses threads
 959 #
 960 # These tests are run before the library-tests, because linking with the
 961 # other libraries can pull in the pthread functions as a side-effect.  We
 962 # want to use the -pthread or similar flags directly, and not rely on
 963 # the side-effects of linking with some other library.
 964 #
 965 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 966 # invocation below is the first one in the script, and autoconf generates
 967 # additional code for that, which must not be inside the if-block. AS_IF
 968 # knows how to do that.
 969 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 970 [ # then
 971 AX_PTHREAD      # set thread flags
 972
 973 # Some platforms use these, so just define them.  They can't hurt if they
 974 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 975 # enables 5-arg getpwuid_r, among other things.
 976 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 977
 978 # Check for *_r functions
 979 _CFLAGS="$CFLAGS"
 980 _LIBS="$LIBS"
 981 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 982 LIBS="$LIBS $PTHREAD_LIBS"
 983
 984 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 985 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 986
 987 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 988
 989 # Do test here with the proper thread flags
 990 PGAC_FUNC_STRERROR_R_INT
 991
 992 CFLAGS="$_CFLAGS"
 993 LIBS="$_LIBS"
 994
 995 ], [ # else
 996 # do not use values from template file
 997 PTHREAD_CFLAGS=
 998 PTHREAD_LIBS=
 999 ]) # fi
1000
1001 AC_SUBST(PTHREAD_CFLAGS)
1002 AC_SUBST(PTHREAD_LIBS)
1003
1004
1005 ##
1006 ## Libraries
1007 ##
1008 ## Most libraries are included only if they demonstrably provide a function
1009 ## we need, but libm is an exception: always include it, because there are
1010 ## too many compilers that play cute optimization games that will break
1011 ## probes for standard functions such as pow().
1012 ##
1013
1014 AC_CHECK_LIB(m, main)
1015 AC_SEARCH_LIBS(setproctitle, util)
1016 AC_SEARCH_LIBS(dlopen, dl)
1017 AC_SEARCH_LIBS(socket, [socket ws2_32])
1018 AC_SEARCH_LIBS(shl_load, dld)
1019 # We only use libld in port/dynloader/aix.c
1020 case $host_os in
1021      aix*)
1022         AC_SEARCH_LIBS(ldopen, ld)
1023         ;;
1024 esac
1025 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1026 AC_SEARCH_LIBS(crypt, crypt)
1027 AC_SEARCH_LIBS(shm_open, rt)
1028 AC_SEARCH_LIBS(shm_unlink, rt)
1029 # Solaris:
1030 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1031 # Required for thread_test.c on Solaris
1032 AC_SEARCH_LIBS(sched_yield, rt)
1033 # Required for thread_test.c on Solaris 2.5:
1034 # Other ports use it too (HP-UX) so test unconditionally
1035 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1036 # Cygwin:
1037 AC_SEARCH_LIBS(shmget, cygipc)
1038
1039 if test "$with_readline" = yes; then
1040   PGAC_CHECK_READLINE
1041   if test x"$pgac_cv_check_readline" = x"no"; then
1042     AC_MSG_ERROR([readline library not found
1043 If you have readline already installed, see config.log for details on the
1044 failure.  It is possible the compiler isn't looking in the proper directory.
1045 Use --without-readline to disable readline support.])
1046   fi
1047 fi
1048
1049 if test "$with_zlib" = yes; then
1050   AC_CHECK_LIB(z, inflate, [],
1051                [AC_MSG_ERROR([zlib library not found
1052 If you have zlib already installed, see config.log for details on the
1053 failure.  It is possible the compiler isn't looking in the proper directory.
1054 Use --without-zlib to disable zlib support.])])
1055 fi
1056
1057 if test "$enable_spinlocks" = yes; then
1058   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1059 else
1060   AC_MSG_WARN([
1061 *** Not using spinlocks will cause poor performance.])
1062 fi
1063
1064 if test "$enable_atomics" = yes; then
1065   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1066 else
1067   AC_MSG_WARN([
1068 *** Not using atomic operations will cause poor performance.])
1069 fi
1070
1071 if test "$with_gssapi" = yes ; then
1072   if test "$PORTNAME" != "win32"; then
1073     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1074                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1075   else
1076     LIBS="$LIBS -lgssapi32"
1077   fi
1078 fi
1079
1080 if test "$with_openssl" = yes ; then
1081   dnl Order matters!
1082   if test "$PORTNAME" != "win32"; then
1083      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1084      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1085   else
1086      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1087      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1088   fi
1089   AC_CHECK_FUNCS([SSL_get_current_compression])
1090 fi
1091
1092 if test "$with_pam" = yes ; then
1093   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1094 fi
1095
1096 if test "$with_libxml" = yes ; then
1097   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1098 fi
1099
1100 if test "$with_libxslt" = yes ; then
1101   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1102 fi
1103
1104 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1105 if test "$with_ldap" = yes ; then
1106   _LIBS="$LIBS"
1107   if test "$PORTNAME" != "win32"; then
1108     AC_CHECK_LIB(ldap, ldap_bind, [],
1109                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1110                  [$EXTRA_LDAP_LIBS])
1111     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1112     if test "$enable_thread_safety" = yes; then
1113       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1114       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1115                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1116                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1117       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1118     else
1119       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1120     fi
1121   else
1122     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1123     LDAP_LIBS_FE="-lwldap32"
1124     LDAP_LIBS_BE="-lwldap32"
1125   fi
1126   LIBS="$_LIBS"
1127 fi
1128 AC_SUBST(LDAP_LIBS_FE)
1129 AC_SUBST(LDAP_LIBS_BE)
1130
1131 # for contrib/sepgsql
1132 if test "$with_selinux" = yes; then
1133   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1134                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1135 fi
1136
1137 # for contrib/uuid-ossp
1138 if test "$with_uuid" = bsd ; then
1139   # On BSD, the UUID functions are in libc
1140   AC_CHECK_FUNC(uuid_to_string,
1141     [UUID_LIBS=""],
1142     [AC_MSG_ERROR([BSD UUID functions are not present])])
1143 elif test "$with_uuid" = e2fs ; then
1144   # On OS X, the UUID functions are in libc
1145   AC_CHECK_FUNC(uuid_generate,
1146     [UUID_LIBS=""],
1147     [AC_CHECK_LIB(uuid, uuid_generate,
1148       [UUID_LIBS="-luuid"],
1149       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1150 elif test "$with_uuid" = ossp ; then
1151   AC_CHECK_LIB(ossp-uuid, uuid_export,
1152     [UUID_LIBS="-lossp-uuid"],
1153     [AC_CHECK_LIB(uuid, uuid_export,
1154       [UUID_LIBS="-luuid"],
1155       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1156 fi
1157 AC_SUBST(UUID_LIBS)
1158
1159
1160 ##
1161 ## Header files
1162 ##
1163
1164 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1165 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1166
1167 # On BSD, test for net/if.h will fail unless sys/socket.h
1168 # is included first.
1169 AC_CHECK_HEADERS(net/if.h, [], [],
1170 [AC_INCLUDES_DEFAULT
1171 #ifdef HAVE_SYS_SOCKET_H
1172 #include <sys/socket.h>
1173 #endif
1174 ])
1175
1176 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1177 # is included first.
1178 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1179 [AC_INCLUDES_DEFAULT
1180 #include <sys/param.h>
1181 ])
1182
1183 # At least on IRIX, test for netinet/tcp.h will fail unless
1184 # netinet/in.h is included first.
1185 AC_CHECK_HEADERS(netinet/in.h)
1186 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1187 [AC_INCLUDES_DEFAULT
1188 #ifdef HAVE_NETINET_IN_H
1189 #include <netinet/in.h>
1190 #endif
1191 ])
1192
1193 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1194   AC_CHECK_HEADERS(readline/readline.h, [],
1195         [AC_CHECK_HEADERS(readline.h, [],
1196                 [AC_MSG_ERROR([readline header not found
1197 If you have readline already installed, see config.log for details on the
1198 failure.  It is possible the compiler isn't looking in the proper directory.
1199 Use --without-readline to disable readline support.])])])
1200   AC_CHECK_HEADERS(readline/history.h, [],
1201         [AC_CHECK_HEADERS(history.h, [],
1202                 [AC_MSG_ERROR([history header not found
1203 If you have readline already installed, see config.log for details on the
1204 failure.  It is possible the compiler isn't looking in the proper directory.
1205 Use --without-readline to disable readline support.])])])
1206 fi
1207
1208 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1209 # Some installations of libedit usurp /usr/include/readline/, which seems
1210 # bad practice, since in combined installations readline will have its headers
1211 # there.  We might have to resort to AC_EGREP checks to make sure we found
1212 # the proper header...
1213   AC_CHECK_HEADERS(editline/readline.h, [],
1214         [AC_CHECK_HEADERS(readline.h, [],
1215                 [AC_CHECK_HEADERS(readline/readline.h, [],
1216                         [AC_MSG_ERROR([readline header not found
1217 If you have libedit already installed, see config.log for details on the
1218 failure.  It is possible the compiler isn't looking in the proper directory.
1219 Use --without-readline to disable libedit support.])])])])
1220 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1221 # not be there at all.  Hence, don't complain if not found.  We must check
1222 # though, since in yet other versions it is an independent header.
1223   AC_CHECK_HEADERS(editline/history.h, [],
1224         [AC_CHECK_HEADERS(history.h, [],
1225                 [AC_CHECK_HEADERS(readline/history.h)])])
1226 fi
1227
1228 if test "$with_zlib" = yes; then
1229   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1230 If you have zlib already installed, see config.log for details on the
1231 failure.  It is possible the compiler isn't looking in the proper directory.
1232 Use --without-zlib to disable zlib support.])])
1233 fi
1234
1235 if test "$with_gssapi" = yes ; then
1236   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1237         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1238 fi
1239
1240 if test "$with_openssl" = yes ; then
1241   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1242   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1243 fi
1244
1245 if test "$with_pam" = yes ; then
1246   AC_CHECK_HEADERS(security/pam_appl.h, [],
1247                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1248                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1249 fi
1250
1251 if test "$with_libxml" = yes ; then
1252   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1253 fi
1254
1255 if test "$with_libxslt" = yes ; then
1256   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1257 fi
1258
1259 if test "$with_ldap" = yes ; then
1260   if test "$PORTNAME" != "win32"; then
1261      AC_CHECK_HEADERS(ldap.h, [],
1262                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1263      PGAC_LDAP_SAFE
1264   else
1265      AC_CHECK_HEADERS(winldap.h, [],
1266                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1267                       [AC_INCLUDES_DEFAULT
1268 #include <windows.h>
1269                       ])
1270   fi
1271 fi
1272
1273 if test "$with_bonjour" = yes ; then
1274   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1275 fi
1276
1277 # for contrib/uuid-ossp
1278 if test "$with_uuid" = bsd ; then
1279   AC_CHECK_HEADERS(uuid.h,
1280     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1281       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1282     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1283 elif test "$with_uuid" = e2fs ; then
1284   AC_CHECK_HEADERS(uuid/uuid.h,
1285     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1286       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1287     [AC_CHECK_HEADERS(uuid.h,
1288       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1289         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1290       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1291 elif test "$with_uuid" = ossp ; then
1292   AC_CHECK_HEADERS(ossp/uuid.h,
1293     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1294       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1295     [AC_CHECK_HEADERS(uuid.h,
1296       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1297         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1298       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1299 fi
1300
1301 if test "$PORTNAME" = "win32" ; then
1302    AC_CHECK_HEADERS(crtdefs.h)
1303 fi
1304
1305 ##
1306 ## Types, structures, compiler characteristics
1307 ##
1308
1309 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1310 AC_C_BIGENDIAN
1311 PGAC_C_INLINE
1312 PGAC_PRINTF_ARCHETYPE
1313 AC_C_FLEXIBLE_ARRAY_MEMBER
1314 PGAC_C_SIGNED
1315 PGAC_C_FUNCNAME_SUPPORT
1316 PGAC_C_STATIC_ASSERT
1317 PGAC_C_TYPES_COMPATIBLE
1318 PGAC_C_BUILTIN_BSWAP32
1319 PGAC_C_BUILTIN_CONSTANT_P
1320 PGAC_C_BUILTIN_UNREACHABLE
1321 PGAC_C_VA_ARGS
1322 PGAC_STRUCT_TIMEZONE
1323 PGAC_UNION_SEMUN
1324 PGAC_STRUCT_SOCKADDR_UN
1325 PGAC_STRUCT_SOCKADDR_STORAGE
1326 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1327 PGAC_STRUCT_ADDRINFO
1328 AC_TYPE_INTPTR_T
1329 AC_TYPE_UINTPTR_T
1330 AC_TYPE_LONG_LONG_INT
1331
1332 PGAC_TYPE_LOCALE_T
1333
1334 AC_CHECK_TYPES([struct cmsgcred], [], [],
1335 [#include <sys/socket.h>
1336 #include <sys/param.h>
1337 #ifdef HAVE_SYS_UCRED_H
1338 #include <sys/ucred.h>
1339 #endif])
1340
1341 AC_CHECK_TYPES([struct option], [], [],
1342 [#ifdef HAVE_GETOPT_H
1343 #include <getopt.h>
1344 #endif])
1345
1346 if test "$with_zlib" = yes; then
1347   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1348   # did not).  While we could work around the lack of z_streamp, it
1349   # seems unwise to encourage people to use such old zlib versions...
1350   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1351 Use --without-zlib to disable zlib support.])],
1352                 [#include <zlib.h>])
1353 fi
1354
1355 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1356 case $host_cpu in
1357   ppc*|powerpc*)
1358     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1359     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1360         [int a = 0; int *p = &a; int r;
1361          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1362         [pgac_cv_have_ppc_mutex_hint=yes],
1363         [pgac_cv_have_ppc_mutex_hint=no])
1364     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1365     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1366         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1367     fi
1368   ;;
1369 esac
1370
1371 # Check largefile support.  You might think this is a system service not a
1372 # compiler characteristic, but you'd be wrong.  We must check this before
1373 # probing existence of related functions such as fseeko, since the largefile
1374 # defines can affect what is generated for that.
1375 if test "$PORTNAME" != "win32"; then
1376    AC_SYS_LARGEFILE
1377    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1378    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1379    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1380    dnl versions where the feature actually works, it's on by default anyway.
1381    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1382 fi
1383
1384 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1385 AC_CHECK_SIZEOF([off_t])
1386
1387 # If we don't have largefile support, can't handle segsize >= 2GB.
1388 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1389    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1390 fi
1391
1392
1393 ##
1394 ## Functions, global variables
1395 ##
1396
1397 PGAC_VAR_INT_TIMEZONE
1398 AC_FUNC_ACCEPT_ARGTYPES
1399 PGAC_FUNC_GETTIMEOFDAY_1ARG
1400
1401 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1402 # symbols that that library has no business exposing to the world.  Pending
1403 # acquisition of a clue by those developers, ignore libedit (including its
1404 # possible alias of libreadline) while checking for everything else.
1405 LIBS_including_readline="$LIBS"
1406 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1407
1408 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1409
1410 AC_REPLACE_FUNCS(fseeko)
1411 case $host_os in
1412         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1413         # Mingw uses macros to access Win32 API calls
1414         netbsd*|mingw*)
1415                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1416                 ac_cv_func_fseeko=yes;;
1417         *)
1418                 AC_FUNC_FSEEKO;;
1419 esac
1420
1421 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1422 # by calling it, 2009-04-02
1423 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1424 if test "$PORTNAME" != "solaris"; then
1425 AC_CHECK_FUNCS(posix_fadvise)
1426 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1427 fi
1428
1429 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1430 AC_CHECK_DECLS([strlcat, strlcpy])
1431 # This is probably only present on Darwin, but may as well check always
1432 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1433
1434 HAVE_IPV6=no
1435 AC_CHECK_TYPE([struct sockaddr_in6],
1436         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1437          HAVE_IPV6=yes],
1438         [],
1439 [$ac_includes_default
1440 #include <netinet/in.h>])
1441 AC_SUBST(HAVE_IPV6)
1442
1443 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1444 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1445 [#include <machine/vmparam.h>
1446 #include <sys/exec.h>
1447 ],
1448 [PS_STRINGS->ps_nargvstr = 1;
1449 PS_STRINGS->ps_argvstr = "foo";])],
1450 [pgac_cv_var_PS_STRINGS=yes],
1451 [pgac_cv_var_PS_STRINGS=no])])
1452 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1453   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1454 fi
1455
1456
1457 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1458 # is missing.  Yes, there are machines that have only one.  We may
1459 # also decide to use snprintf.c if snprintf() is present but does not
1460 # have all the features we need --- see below.
1461
1462 if test "$PORTNAME" = "win32"; then
1463   # Win32 gets snprintf.c built unconditionally.
1464   #
1465   # To properly translate all NLS languages strings, we must support the
1466   # *printf() %$ format, which allows *printf() arguments to be selected
1467   # by position in the translated string.
1468   #
1469   # libintl versions < 0.13 use the native *printf() functions, and Win32
1470   # *printf() doesn't understand %$, so we must use our /port versions,
1471   # which do understand %$. libintl versions >= 0.13 include their own
1472   # *printf versions on Win32.  The libintl 0.13 release note text is:
1473   #
1474   #   C format strings with positions, as they arise when a translator
1475   #   needs to reorder a sentence, are now supported on all platforms.
1476   #   On those few platforms (NetBSD and Woe32) for which the native
1477   #   printf()/fprintf()/... functions don't support such format
1478   #   strings, replacements are provided through <libintl.h>.
1479   #
1480   # We could use libintl >= 0.13's *printf() if we were sure that we had
1481   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1482   # to guarantee that, it is best to just use our own, so we are sure to
1483   # get %$ support. In include/port.h we disable the *printf() macros
1484   # that might have been defined by libintl.
1485   #
1486   # We do this unconditionally whether NLS is used or not so we are sure
1487   # that all Win32 libraries and binaries behave the same.
1488   pgac_need_repl_snprintf=yes
1489 else
1490   pgac_need_repl_snprintf=no
1491   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1492   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1493 fi
1494
1495
1496 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1497 # include/c.h will provide declarations.  Note this is a separate test
1498 # from whether the functions exist in the C library --- there are
1499 # systems that have the functions but don't bother to declare them :-(
1500
1501 AC_CHECK_DECLS([snprintf, vsnprintf])
1502
1503
1504 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1505 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1506 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1507 #include <math.h>
1508 double glob_double;
1509 ],
1510 [return isinf(glob_double) ? 0 : 1;])],
1511 [ac_cv_func_isinf=yes],
1512 [ac_cv_func_isinf=no])])
1513
1514 if test $ac_cv_func_isinf = yes ; then
1515   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1516 else
1517   AC_LIBOBJ(isinf)
1518   # Look for a way to implement a substitute for isinf()
1519   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1520 fi
1521
1522 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1523
1524 case $host_os in
1525
1526         # Windows uses a specialised env handler
1527         # and doesn't need a replacement getpeereid because it doesn't use
1528         # Unix sockets.
1529         mingw*)
1530                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1531                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1532                 ac_cv_func_unsetenv=yes
1533                 ac_cv_func_getpeereid=yes;;
1534         *)
1535                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1536                 ;;
1537 esac
1538
1539 # System's version of getaddrinfo(), if any, may be used only if we found
1540 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1541 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1542 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1543    test "$PORTNAME" != "win32"; then
1544   AC_REPLACE_FUNCS([getaddrinfo])
1545 else
1546   AC_LIBOBJ(getaddrinfo)
1547 fi
1548
1549 # Similarly, use system's getopt_long() only if system provides struct option.
1550 if test x"$ac_cv_type_struct_option" = xyes ; then
1551   AC_REPLACE_FUNCS([getopt_long])
1552 else
1553   AC_LIBOBJ(getopt_long)
1554 fi
1555
1556 # Solaris' getopt() doesn't do what we want for long options, so always use
1557 # our version on that platform.
1558 if test "$PORTNAME" = "solaris"; then
1559   AC_LIBOBJ(getopt)
1560 fi
1561
1562 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1563 # so always use our version on Windows.
1564 if test "$PORTNAME" = "win32"; then
1565   AC_LIBOBJ(getopt)
1566   AC_LIBOBJ(getopt_long)
1567 fi
1568
1569 # Win32 (really MinGW) support
1570 if test "$PORTNAME" = "win32"; then
1571   AC_REPLACE_FUNCS(gettimeofday)
1572   AC_LIBOBJ(dirmod)
1573   AC_LIBOBJ(kill)
1574   AC_LIBOBJ(open)
1575   AC_LIBOBJ(system)
1576   AC_LIBOBJ(win32env)
1577   AC_LIBOBJ(win32error)
1578   AC_LIBOBJ(win32setlocale)
1579   AC_DEFINE([HAVE_SYMLINK], 1,
1580             [Define to 1 if you have the `symlink' function.])
1581   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1582 #define WIN32_LEAN_AND_MEAN
1583 #include <windows.h>
1584 #include <string.h>
1585 #include <dbghelp.h>])
1586 fi
1587 if test x"$pgac_minidump_type" = x"yes" ; then
1588   AC_SUBST(have_win32_dbghelp,yes)
1589 else
1590   AC_SUBST(have_win32_dbghelp,no)
1591 fi
1592
1593 # Cygwin needs only a bit of that
1594 if test "$PORTNAME" = "cygwin"; then
1595   AC_LIBOBJ(dirmod)
1596 fi
1597
1598 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1599 dnl (especially on GNU libc)
1600 dnl See also comments in c.h.
1601 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1602 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <setjmp.h>],
1603             [sigjmp_buf x; sigsetjmp(x, 1);])],
1604             [pgac_cv_func_sigsetjmp=yes],
1605             [pgac_cv_func_sigsetjmp=no])])
1606 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1607   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1608 fi
1609
1610 AC_CHECK_DECLS([sys_siglist], [], [],
1611 [#include <signal.h>
1612 /* NetBSD declares sys_siglist in unistd.h.  */
1613 #ifdef HAVE_UNISTD_H
1614 # include <unistd.h>
1615 #endif
1616 ])
1617
1618 AC_CHECK_FUNC(syslog,
1619               [AC_CHECK_HEADER(syslog.h,
1620                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1621
1622 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1623 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1624   [extern int opterr; opterr = 1;])],
1625   [pgac_cv_var_int_opterr=yes],
1626   [pgac_cv_var_int_opterr=no])])
1627 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1628   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1629 fi
1630
1631 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1632 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1633   [extern int optreset; optreset = 1;])],
1634   [pgac_cv_var_int_optreset=yes],
1635   [pgac_cv_var_int_optreset=no])])
1636 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1637   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1638 fi
1639
1640 AC_CHECK_FUNCS([strtoll strtoq], [break])
1641 AC_CHECK_FUNCS([strtoull strtouq], [break])
1642
1643 # Lastly, restore full LIBS list and check for readline/libedit symbols
1644 LIBS="$LIBS_including_readline"
1645
1646 if test "$with_readline" = yes; then
1647   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1648   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1649   AC_CHECK_FUNCS([append_history history_truncate_file])
1650 fi
1651
1652
1653 # This test makes sure that run tests work at all.  Sometimes a shared
1654 # library is found by the linker, but the runtime linker can't find it.
1655 # This check should come after all modifications of compiler or linker
1656 # variables, and before any other run tests.
1657 AC_MSG_CHECKING([test program])
1658 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1659 [AC_MSG_RESULT(ok)],
1660 [AC_MSG_RESULT(failed)
1661 AC_MSG_ERROR([[
1662 Could not execute a simple test program.  This may be a problem
1663 related to locating shared libraries.  Check the file 'config.log'
1664 for the exact reason.]])],
1665 [AC_MSG_RESULT([cross-compiling])])
1666
1667 # --------------------
1668 # Run tests below here
1669 # --------------------
1670
1671 # Force use of our snprintf if system's doesn't do arg control
1672 # See comment above at snprintf test for details.
1673 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1674   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1675   if test $pgac_cv_snprintf_arg_control != yes ; then
1676     pgac_need_repl_snprintf=yes
1677   fi
1678 fi
1679
1680
1681 dnl Check to see if we have a working 64-bit integer type.
1682 dnl This breaks down into two steps:
1683 dnl (1) figure out if the compiler has a 64-bit int type with working
1684 dnl arithmetic, and if so
1685 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1686 dnl snprintf is the only library routine we really need for int8 support.)
1687 dnl It's entirely possible to have a compiler that handles a 64-bit type
1688 dnl when the C library doesn't; this is fairly likely when using gcc on
1689 dnl an older platform, for example.
1690 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1691 dnl we force our own version of snprintf() to be used instead.
1692 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1693
1694 dnl As of Postgres 8.4, we no longer support compilers without a working
1695 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1696
1697 PGAC_TYPE_64BIT_INT([long int])
1698
1699 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1700   pg_int64_type="long int"
1701 else
1702   PGAC_TYPE_64BIT_INT([long long int])
1703   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1704     pg_int64_type="long long int"
1705   else
1706     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1707   fi
1708 fi
1709
1710 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1711   [Define to the name of a signed 64-bit integer type.])
1712
1713 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1714
1715 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1716   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1717 #define INT64CONST(x)  x##LL
1718 long long int foo = INT64CONST(0x1234567890123456);
1719 ])],
1720         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1721         [])
1722 fi
1723
1724
1725 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1726 # we found we need to use "long long int", better check.  We cope with
1727 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1728 # work, fall back to our own snprintf emulation (which we know uses %lld).
1729
1730 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1731   if test $pgac_need_repl_snprintf = no; then
1732     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1733     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1734       # Force usage of our own snprintf, since system snprintf is broken
1735       pgac_need_repl_snprintf=yes
1736       LONG_LONG_INT_MODIFIER='ll'
1737     fi
1738   else
1739     # Here if we previously decided we needed to use our own snprintf
1740     LONG_LONG_INT_MODIFIER='ll'
1741   fi
1742 else
1743   # Here if we are not using 'long long int' at all
1744   LONG_LONG_INT_MODIFIER='l'
1745 fi
1746
1747 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1748
1749 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1750                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1751
1752 # Also force use of our snprintf if the system's doesn't support the %z flag.
1753 if test "$pgac_need_repl_snprintf" = no; then
1754   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1755   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1756     pgac_need_repl_snprintf=yes
1757   fi
1758 fi
1759
1760 # Now we have checked all the reasons to replace snprintf
1761 if test $pgac_need_repl_snprintf = yes; then
1762   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1763   AC_LIBOBJ(snprintf)
1764 fi
1765
1766 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1767 AC_CHECK_SIZEOF([void *])
1768 AC_CHECK_SIZEOF([size_t])
1769 AC_CHECK_SIZEOF([long])
1770
1771 # Decide whether float4 is passed by value: user-selectable, enabled by default
1772 AC_MSG_CHECKING([whether to build with float4 passed by value])
1773 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1774               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1775                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1776                float4passbyval=true],
1777               [float4passbyval=false])
1778 AC_MSG_RESULT([$enable_float4_byval])
1779 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1780
1781 # Decide whether float8 is passed by value.
1782 # Note: this setting also controls int8 and related types such as timestamp.
1783 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1784 # If not, trying to select it is an error.
1785 AC_MSG_CHECKING([whether to build with float8 passed by value])
1786 if test $ac_cv_sizeof_void_p -ge 8 ; then
1787   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1788 else
1789   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1790   if test "$enable_float8_byval" = yes ; then
1791     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1792   fi
1793 fi
1794 if test "$enable_float8_byval" = yes ; then
1795   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1796             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1797   float8passbyval=true
1798 else
1799   float8passbyval=false
1800 fi
1801 AC_MSG_RESULT([$enable_float8_byval])
1802 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1803
1804 # Determine memory alignment requirements for the basic C data types.
1805
1806 AC_CHECK_ALIGNOF(short)
1807 AC_CHECK_ALIGNOF(int)
1808 AC_CHECK_ALIGNOF(long)
1809 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1810   AC_CHECK_ALIGNOF(long long int)
1811 fi
1812 AC_CHECK_ALIGNOF(double)
1813
1814 # Compute maximum alignment of any basic type.
1815 # We assume long's alignment is at least as strong as char, short, or int;
1816 # but we must check long long (if it exists) and double.
1817
1818 MAX_ALIGNOF=$ac_cv_alignof_long
1819 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1820   MAX_ALIGNOF=$ac_cv_alignof_double
1821 fi
1822 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1823   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1824 fi
1825 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1826
1827
1828 # Some platforms predefine the types int8, int16, etc.  Only check
1829 # a (hopefully) representative subset.
1830 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1831 [#include <stdio.h>])
1832
1833 # We also check for sig_atomic_t, which *should* be defined per ANSI
1834 # C, but is missing on some old platforms.
1835 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1836
1837 # Check for extensions offering the integer scalar type __int128.
1838 PGAC_TYPE_128BIT_INT
1839
1840 # Check for various atomic operations now that we have checked how to declare
1841 # 64bit integers.
1842 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1843 PGAC_HAVE_GCC__SYNC_INT32_TAS
1844 PGAC_HAVE_GCC__SYNC_INT32_CAS
1845 PGAC_HAVE_GCC__SYNC_INT64_CAS
1846 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1847 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1848
1849
1850 # Check for x86 cpuid instruction
1851 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1852 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1853   [[unsigned int exx[4] = {0, 0, 0, 0};
1854   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1855   ]])],
1856   [pgac_cv__get_cpuid="yes"],
1857   [pgac_cv__get_cpuid="no"])])
1858 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1859   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1860 fi
1861
1862 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1863 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1864   [[unsigned int exx[4] = {0, 0, 0, 0};
1865   __get_cpuid(exx[0], 1);
1866   ]])],
1867   [pgac_cv__cpuid="yes"],
1868   [pgac_cv__cpuid="no"])])
1869 if test x"$pgac_cv__cpuid" = x"yes"; then
1870   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1871 fi
1872
1873 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1874 #
1875 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1876 # with the default compiler flags. If not, check if adding the -msse4.2
1877 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1878 PGAC_SSE42_CRC32_INTRINSICS([])
1879 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1880   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1881 fi
1882 AC_SUBST(CFLAGS_SSE42)
1883
1884 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1885 # define __SSE4_2__ in that case.
1886 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1887 #ifndef __SSE4_2__
1888 #error __SSE4_2__ not defined
1889 #endif
1890 ])], [SSE4_2_TARGETED=1])
1891
1892 # Select CRC-32C implementation.
1893 #
1894 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1895 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1896 # a processor, but we can nevertheless produce code that uses the SSE
1897 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1898 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1899 # by the processor we're running on.
1900 #
1901 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1902 # in the template or configure command line.
1903 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1904   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1905     USE_SSE42_CRC32C=1
1906   else
1907     # the CPUID instruction is needed for the runtime check.
1908     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1909       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1910     else
1911       # fall back to slicing-by-8 algorithm which doesn't require any special
1912       # CPU support.
1913       USE_SLICING_BY_8_CRC32C=1
1914     fi
1915   fi
1916 fi
1917
1918 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1919 AC_MSG_CHECKING([which CRC-32C implementation to use])
1920 if test x"$USE_SSE42_CRC32C" = x"1"; then
1921   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1922   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1923   AC_MSG_RESULT(SSE 4.2)
1924 else
1925   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1926     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1927     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1928     AC_MSG_RESULT(SSE 4.2 with runtime check)
1929   else
1930     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1931     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1932     AC_MSG_RESULT(slicing-by-8)
1933   fi
1934 fi
1935 AC_SUBST(PG_CRC32C_OBJS)
1936
1937
1938 # Check that POSIX signals are available if thread safety is enabled.
1939 if test "$PORTNAME" != "win32"
1940 then
1941 PGAC_FUNC_POSIX_SIGNALS
1942 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1943   AC_MSG_ERROR([
1944 Thread-safety requires POSIX signals, which are not supported by this
1945 operating system;  use --disable-thread-safety to disable thread safety.])
1946 fi
1947 fi
1948
1949
1950 # Select semaphore implementation type.
1951 if test "$PORTNAME" != "win32"; then
1952   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1953     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1954     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1955   else
1956     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1957       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1958       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1959     else
1960       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1961       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1962     fi
1963   fi
1964 else
1965   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1966   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1967 fi
1968
1969
1970 # Select shared-memory implementation type.
1971 if test "$PORTNAME" != "win32"; then
1972   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1973   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1974 else
1975   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1976   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1977 fi
1978
1979 # Select latch implementation type.
1980 if test "$PORTNAME" != "win32"; then
1981   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1982 else
1983   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1984 fi
1985
1986 # If not set in template file, set bytes to use libc memset()
1987 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1988   MEMSET_LOOP_LIMIT=1024
1989 fi
1990 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1991
1992
1993 if test "$enable_nls" = yes ; then
1994   PGAC_CHECK_GETTEXT
1995 fi
1996
1997 # Check for Tcl configuration script tclConfig.sh
1998 if test "$with_tcl" = yes; then
1999     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2000     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2001                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2002     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2003     if test "$TCL_SHARED_BUILD" != 1; then
2004       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2005 Use --without-tcl to disable building PL/Tcl.])
2006     fi
2007     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2008     ac_save_CPPFLAGS=$CPPFLAGS
2009     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2010     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2011     CPPFLAGS=$ac_save_CPPFLAGS
2012 fi
2013
2014 # check for <perl.h>
2015 if test "$with_perl" = yes; then
2016   ac_save_CPPFLAGS=$CPPFLAGS
2017   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2018   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2019                   [#include <EXTERN.h>])
2020   # While we're at it, check that we can link to libperl.
2021   # On most platforms, if perl.h is there then libperl.so will be too, but at
2022   # this writing Debian packages them separately.  There is no known reason to
2023   # waste cycles on separate probes for the Tcl or Python libraries, though.
2024   pgac_save_LIBS=$LIBS
2025   LIBS="$perl_embed_ldflags"
2026   AC_MSG_CHECKING([for libperl])
2027   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2028 #include <EXTERN.h>
2029 #include <perl.h>
2030 ],  [perl_alloc();])],
2031     [AC_MSG_RESULT(yes)],
2032     [AC_MSG_RESULT(no)
2033      AC_MSG_ERROR([libperl library is required for Perl])])
2034   LIBS=$pgac_save_LIBS
2035   CPPFLAGS=$ac_save_CPPFLAGS
2036 fi
2037
2038 # check for <Python.h>
2039 if test "$with_python" = yes; then
2040   ac_save_CPPFLAGS=$CPPFLAGS
2041   CPPFLAGS="$python_includespec $CPPFLAGS"
2042   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2043   CPPFLAGS=$ac_save_CPPFLAGS
2044 fi
2045
2046 #
2047 # Check for DocBook and tools
2048 #
2049 PGAC_PROG_NSGMLS
2050 PGAC_PROG_JADE
2051 PGAC_CHECK_DOCBOOK(4.2)
2052 PGAC_PATH_DOCBOOK_STYLESHEETS
2053 PGAC_PATH_COLLATEINDEX
2054 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2055 AC_CHECK_PROGS(XMLLINT, xmllint)
2056 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2057 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2058
2059 #
2060 # Check for test tools
2061 #
2062 if test "$enable_tap_tests" = yes; then
2063   AC_CHECK_PROGS(PROVE, prove)
2064   if test -z "$PROVE"; then
2065     AC_MSG_ERROR([prove not found])
2066   fi
2067   if test -z "$PERL"; then
2068     AC_MSG_ERROR([Perl not found])
2069   fi
2070 fi
2071
2072 # Thread testing
2073
2074 # We have to run the thread test near the end so we have all our symbols
2075 # defined.  Cross compiling throws a warning.
2076 #
2077 if test "$enable_thread_safety" = yes; then
2078 if test "$PORTNAME" != "win32"
2079 then
2080 AC_MSG_CHECKING([thread safety of required library functions])
2081
2082 _CFLAGS="$CFLAGS"
2083 _LIBS="$LIBS"
2084 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2085 LIBS="$LIBS $PTHREAD_LIBS"
2086 AC_RUN_IFELSE(
2087   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2088   [AC_MSG_RESULT(yes)],
2089   [AC_MSG_RESULT(no)
2090   AC_MSG_ERROR([thread test program failed
2091 This platform is not thread-safe.  Check the file 'config.log' or compile
2092 and run src/test/thread/thread_test for the exact reason.
2093 Use --disable-thread-safety to disable thread safety.])],
2094   [AC_MSG_RESULT(maybe)
2095   AC_MSG_WARN([
2096 *** Skipping thread test program because of cross-compile build.
2097 *** Run the program in src/test/thread on the target machine.
2098 ])])
2099 CFLAGS="$_CFLAGS"
2100 LIBS="$_LIBS"
2101 else
2102 AC_MSG_WARN([*** skipping thread test on Win32])
2103 fi
2104 fi
2105
2106 # If compiler will take -Wl,--as-needed (or various platform-specific
2107 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2108 # trying to filter LIBS to the minimum for each executable.
2109 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2110 # libreadline; therefore we postpone testing it until we know what library
2111 # dependencies readline has.  The test code will try to link with $LIBS.
2112 if test "$with_readline" = yes; then
2113   link_test_func=readline
2114 else
2115   link_test_func=exit
2116 fi
2117
2118 if test "$PORTNAME" = "darwin"; then
2119   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2120 elif test "$PORTNAME" = "openbsd"; then
2121   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2122 else
2123   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2124 fi
2125
2126 # Create compiler version string
2127 if test x"$GCC" = x"yes" ; then
2128   cc_string=`${CC} --version | sed q`
2129   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2130 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2131   cc_string=`${CC} -V 2>&1 | sed q`
2132 else
2133   cc_string=$CC
2134 fi
2135
2136 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2137                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2138                    [A string containing the version number, platform, and C compiler])
2139
2140 # Supply a numeric version string for use by 3rd party add-ons
2141 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2142 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2143 tr '.' '        ' |
2144 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2145 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2146 AC_SUBST(PG_VERSION_NUM)
2147
2148
2149 # Begin output steps
2150
2151 AC_MSG_NOTICE([using compiler=$cc_string])
2152 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2153 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2154 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2155
2156 # prepare build tree if outside source tree
2157 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2158 # Note 2: /bin/pwd might be better than shell's built-in at getting
2159 #         a symlink-free name.
2160 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2161   vpath_build=no
2162 else
2163   vpath_build=yes
2164   if test "$no_create" != yes; then
2165     _AS_ECHO_N([preparing build tree... ])
2166     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2167     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2168       || AC_MSG_ERROR(failed)
2169     AC_MSG_RESULT(done)
2170   fi
2171 fi
2172 AC_SUBST(vpath_build)
2173
2174
2175 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2176
2177 AC_CONFIG_LINKS([
2178   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2179   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2180   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2181   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2182   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2183   src/include/pg_config_os.h:src/include/port/${template}.h
2184   src/Makefile.port:src/makefiles/Makefile.${template}
2185 ])
2186
2187 if test "$PORTNAME" = "win32"; then
2188 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2189 # Links sometimes fail undetected on Mingw -
2190 # so here we detect it and warn the user
2191 for FILE in $CONFIG_LINKS
2192  do
2193         # test -e works for symlinks in the MinGW console
2194         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2195  done
2196 ])
2197 fi
2198
2199 AC_CONFIG_HEADERS([src/include/pg_config.h],
2200 [
2201 # Update timestamp for pg_config.h (see Makefile.global)
2202 echo >src/include/stamp-h
2203 ])
2204
2205 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2206 [
2207 # Update timestamp for pg_config_ext.h (see Makefile.global)
2208 echo >src/include/stamp-ext-h
2209 ])
2210
2211 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2212                   [echo >src/interfaces/ecpg/include/stamp-h])
2213
2214 AC_OUTPUT