granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2013, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58   cygwin*) template=cygwin ;;
  59   darwin*) template=darwin ;;
  60 dragonfly*) template=netbsd ;;
  61  freebsd*) template=freebsd ;;
  62     hpux*) template=hpux ;;
  63  linux*|gnu*|k*bsd*-gnu)
  64            template=linux ;;
  65    mingw*) template=win32 ;;
  66   netbsd*) template=netbsd ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sysv5*) template=unixware ;;
  72 esac
  73
  74   if test x"$template" = x"" ; then
  75     AC_MSG_ERROR([[
  76 *******************************************************************
  77 PostgreSQL has apparently not been ported to your platform yet.
  78 To try a manual configuration, look into the src/template directory
  79 for a similar platform and use the '--with-template=' option.
  80
  81 Please also contact <pgsql-bugs@postgresql.org> to see about
  82 rectifying this.  Include the above 'checking host system type...'
  83 line.
  84 *******************************************************************
  85 ]])
  86   fi
  87
  88 ])
  89
  90 AC_MSG_RESULT([$template])
  91
  92 PORTNAME=$template
  93 AC_SUBST(PORTNAME)
  94
  95 # Initialize default assumption that we do not need separate assembly code
  96 # for TAS (test-and-set).  This can be overridden by the template file
  97 # when it's executed.
  98 need_tas=no
  99 tas_file=dummy.s
 100
 101
 102
 103 ##
 104 ## Command line options
 105 ##
 106
 107 #
 108 # Add non-standard directories to the include path
 109 #
 110 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 111
 112
 113 #
 114 # Add non-standard directories to the library search path
 115 #
 116 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 117              [LIBRARY_DIRS=$withval])
 118
 119 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 120              [LIBRARY_DIRS=$withval])
 121
 122
 123 #
 124 # 64-bit integer date/time storage: enabled by default.
 125 #
 126 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 127 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 128               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 129                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 130 AC_MSG_RESULT([$enable_integer_datetimes])
 131
 132
 133 #
 134 # NLS
 135 #
 136 AC_MSG_CHECKING([whether NLS is wanted])
 137 PGAC_ARG_OPTARG(enable, nls,
 138                 [LANGUAGES], [enable Native Language Support],
 139                 [],
 140                 [WANTED_LANGUAGES=$enableval],
 141                 [AC_DEFINE(ENABLE_NLS, 1,
 142                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 143 AC_MSG_RESULT([$enable_nls])
 144 AC_SUBST(enable_nls)
 145 AC_SUBST(WANTED_LANGUAGES)
 146
 147 #
 148 # Default port number (--with-pgport), default 5432
 149 #
 150 AC_MSG_CHECKING([for default port number])
 151 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 152              [default_port=$withval],
 153              [default_port=5432])
 154 AC_MSG_RESULT([$default_port])
 155 # Need both of these because some places want an integer and some a string
 156 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 157 [Define to the default TCP port number on which the server listens and
 158 to which clients will try to connect.  This can be overridden at run-time,
 159 but it's convenient if your clients have the right default compiled in.
 160 (--with-pgport=PORTNUM)])
 161 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 162                    [Define to the default TCP port number as a string constant.])
 163 AC_SUBST(default_port)
 164
 165 #
 166 # '-rpath'-like feature can be disabled
 167 #
 168 PGAC_ARG_BOOL(enable, rpath, yes,
 169               [do not embed shared library search path in executables])
 170 AC_SUBST(enable_rpath)
 171
 172 #
 173 # Spinlocks
 174 #
 175 PGAC_ARG_BOOL(enable, spinlocks, yes,
 176               [do not use spinlocks])
 177
 178 #
 179 # --enable-debug adds -g to compiler flags
 180 #
 181 PGAC_ARG_BOOL(enable, debug, no,
 182               [build with debugging symbols (-g)])
 183 AC_SUBST(enable_debug)
 184
 185 #
 186 # --enable-profiling enables gcc profiling
 187 #
 188 PGAC_ARG_BOOL(enable, profiling, no,
 189               [build with profiling enabled ])
 190
 191 #
 192 # --enable-coverage enables generation of code coverage metrics with gcov
 193 #
 194 PGAC_ARG_BOOL(enable, coverage, no,
 195               [build with coverage testing instrumentation],
 196 [AC_CHECK_PROGS(GCOV, gcov)
 197 if test -z "$GCOV"; then
 198   AC_MSG_ERROR([gcov not found])
 199 fi
 200 AC_CHECK_PROGS(LCOV, lcov)
 201 if test -z "$LCOV"; then
 202   AC_MSG_ERROR([lcov not found])
 203 fi
 204 AC_CHECK_PROGS(GENHTML, genhtml)
 205 if test -z "$GENHTML"; then
 206   AC_MSG_ERROR([genhtml not found])
 207 fi])
 208 AC_SUBST(enable_coverage)
 209
 210 #
 211 # DTrace
 212 #
 213 PGAC_ARG_BOOL(enable, dtrace, no,
 214               [build with DTrace support],
 215 [AC_CHECK_PROGS(DTRACE, dtrace)
 216 if test -z "$DTRACE"; then
 217   AC_MSG_ERROR([dtrace not found])
 218 fi
 219 AC_SUBST(DTRACEFLAGS)])
 220 AC_SUBST(enable_dtrace)
 221
 222 #
 223 # Block size
 224 #
 225 AC_MSG_CHECKING([for block size])
 226 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 227              [blocksize=$withval],
 228              [blocksize=8])
 229 case ${blocksize} in
 230   1) BLCKSZ=1024;;
 231   2) BLCKSZ=2048;;
 232   4) BLCKSZ=4096;;
 233   8) BLCKSZ=8192;;
 234  16) BLCKSZ=16384;;
 235  32) BLCKSZ=32768;;
 236   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 237 esac
 238 AC_MSG_RESULT([${blocksize}kB])
 239
 240 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 241  Size of a disk block --- this also limits the size of a tuple.  You
 242  can set it bigger if you need bigger tuples (although TOAST should
 243  reduce the need to have large tuples, since fields can be spread
 244  across multiple tuples).
 245
 246  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 247  is currently 2^15 (32768).  This is determined by the 15-bit widths
 248  of the lp_off and lp_len fields in ItemIdData (see
 249  include/storage/itemid.h).
 250
 251  Changing BLCKSZ requires an initdb.
 252 ])
 253
 254 #
 255 # Relation segment size
 256 #
 257 AC_MSG_CHECKING([for segment size])
 258 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 259              [segsize=$withval],
 260              [segsize=1])
 261 # this expression is set up to avoid unnecessary integer overflow
 262 # blocksize is already guaranteed to be a factor of 1024
 263 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 264 test $? -eq 0 || exit 1
 265 AC_MSG_RESULT([${segsize}GB])
 266
 267 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 268  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 269  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 270  relations bigger than that are divided into multiple files.
 271
 272  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 273  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 274  have large file support enabled.  By default, we make the limit 1 GB
 275  to avoid any possible integer-overflow problems within the OS.
 276  A limit smaller than necessary only means we divide a large
 277  relation into more chunks than necessary, so it seems best to err
 278  in the direction of a small limit.
 279
 280  A power-of-2 value is recommended to save a few cycles in md.c,
 281  but is not absolutely required.
 282
 283  Changing RELSEG_SIZE requires an initdb.
 284 ])
 285
 286 #
 287 # WAL block size
 288 #
 289 AC_MSG_CHECKING([for WAL block size])
 290 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 291              [wal_blocksize=$withval],
 292              [wal_blocksize=8])
 293 case ${wal_blocksize} in
 294   1) XLOG_BLCKSZ=1024;;
 295   2) XLOG_BLCKSZ=2048;;
 296   4) XLOG_BLCKSZ=4096;;
 297   8) XLOG_BLCKSZ=8192;;
 298  16) XLOG_BLCKSZ=16384;;
 299  32) XLOG_BLCKSZ=32768;;
 300  64) XLOG_BLCKSZ=65536;;
 301   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 302 esac
 303 AC_MSG_RESULT([${wal_blocksize}kB])
 304
 305 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 306  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 307  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 308  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 309  buffers, else direct I/O may fail.
 310
 311  Changing XLOG_BLCKSZ requires an initdb.
 312 ])
 313
 314 #
 315 # WAL segment size
 316 #
 317 AC_MSG_CHECKING([for WAL segment size])
 318 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 319              [wal_segsize=$withval],
 320              [wal_segsize=16])
 321 case ${wal_segsize} in
 322   1) ;;
 323   2) ;;
 324   4) ;;
 325   8) ;;
 326  16) ;;
 327  32) ;;
 328  64) ;;
 329   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 330 esac
 331 AC_MSG_RESULT([${wal_segsize}MB])
 332
 333 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 334  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 335  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 336  XLOG_BLCKSZ).
 337
 338  Changing XLOG_SEG_SIZE requires an initdb.
 339 ])
 340
 341 #
 342 # C compiler
 343 #
 344
 345 # For historical reasons you can also use --with-CC to specify the C compiler
 346 # to use, although the standard way to do this is to set the CC environment
 347 # variable.
 348 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 349
 350 case $template in
 351   aix) pgac_cc_list="gcc xlc";;
 352     *) pgac_cc_list="gcc cc";;
 353 esac
 354
 355 AC_PROG_CC([$pgac_cc_list])
 356
 357 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 358 # but has idiosyncrasies of its own.  We assume icc will define
 359 # __INTEL_COMPILER regardless of CFLAGS.
 360 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 361 choke me
 362 @%:@endif], [ICC=[yes]], [ICC=[no]])
 363
 364 # Check if it's Sun Studio compiler. We assume that
 365 # __SUNPRO_C will be defined for Sun Studio compilers
 366 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 367 choke me
 368 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 369
 370 AC_SUBST(SUN_STUDIO_CC)
 371
 372 unset CFLAGS
 373
 374 #
 375 # Read the template
 376 #
 377 . "$srcdir/src/template/$template" || exit
 378
 379 # CFLAGS are selected so:
 380 # If the user specifies something in the environment, that is used.
 381 # else:  If the template file set something, that is used.
 382 # else:  If coverage was enabled, don't set anything.
 383 # else:  If the compiler is GCC, then we use -O2.
 384 # else:  If the compiler is something else, then we use -O, unless debugging.
 385
 386 if test "$ac_env_CFLAGS_set" = set; then
 387   CFLAGS=$ac_env_CFLAGS_value
 388 elif test "${CFLAGS+set}" = set; then
 389   : # (keep what template set)
 390 elif test "$enable_coverage" = yes; then
 391   : # no optimization by default
 392 elif test "$GCC" = yes; then
 393   CFLAGS="-O2"
 394 else
 395   # if the user selected debug mode, don't use -O
 396   if test "$enable_debug" != yes; then
 397     CFLAGS="-O"
 398   fi
 399 fi
 400
 401 # set CFLAGS_VECTOR from the environment, if available
 402 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 403   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 404 fi
 405
 406 # Some versions of GCC support some additional useful warning flags.
 407 # Check whether they are supported, and add them to CFLAGS if so.
 408 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 409 # but has its own.  Also check other compiler-specific flags here.
 410
 411 if test "$GCC" = yes -a "$ICC" = no; then
 412   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 413   # These work in some but not all gcc versions
 414   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 415   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 416   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 417   # This was included in -Wall/-Wformat in older GCC versions
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 419   # Disable strict-aliasing rules; needed for gcc 3.3+
 420   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 421   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 422   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 423   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 424   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 425   # Optimization flags for specific files that benefit from vectorization
 426   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 427   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 428 elif test "$ICC" = yes; then
 429   # Intel's compiler has a bug/misoptimization in checking for
 430   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 431   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 432   # Make sure strict aliasing is off (though this is said to be the default)
 433   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 434 elif test "$PORTNAME" = "aix"; then
 435   # AIX's xlc has to have strict aliasing turned off too
 436   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 437 elif test "$PORTNAME" = "hpux"; then
 438   # On some versions of HP-UX, libm functions do not set errno by default.
 439   # Fix that by using +Olibmerrno if the compiler recognizes it.
 440   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 441 fi
 442
 443 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 444
 445 # supply -g if --enable-debug
 446 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 447   CFLAGS="$CFLAGS -g"
 448 fi
 449
 450 # enable code coverage if --enable-coverage
 451 if test "$enable_coverage" = yes; then
 452   if test "$GCC" = yes; then
 453     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 454   else
 455     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 456   fi
 457 fi
 458
 459 # enable profiling if --enable-profiling
 460 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 461   if test "$GCC" = yes; then
 462     AC_DEFINE([PROFILE_PID_DIR], 1,
 463            [Define to 1 to allow profiling output to be saved separately for each process.])
 464     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 465   else
 466     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 467   fi
 468 fi
 469
 470 # We already have this in Makefile.win32, but configure needs it too
 471 if test "$PORTNAME" = "win32"; then
 472   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 473 fi
 474
 475 # Check if the compiler still works with the template settings
 476 AC_MSG_CHECKING([whether the C compiler still works])
 477 AC_TRY_LINK([], [return 0;],
 478   [AC_MSG_RESULT(yes)],
 479   [AC_MSG_RESULT(no)
 480    AC_MSG_ERROR([cannot proceed])])
 481
 482 # Defend against gcc -ffast-math
 483 if test "$GCC" = yes; then
 484 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 485 choke me
 486 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 487 fi
 488
 489 AC_PROG_CPP
 490 AC_SUBST(GCC)
 491
 492
 493 #
 494 # Set up TAS assembly code if needed; the template file has now had its
 495 # chance to request this.
 496 #
 497 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 498
 499 if test "$need_tas" = yes ; then
 500   TAS=tas.o
 501 else
 502   TAS=""
 503 fi
 504 AC_SUBST(TAS)
 505
 506
 507 #
 508 # Automatic dependency tracking
 509 #
 510 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 511               [autodepend=yes])
 512 AC_SUBST(autodepend)
 513
 514
 515 #
 516 # Enable assert checks
 517 #
 518 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 519               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 520                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 521
 522
 523 #
 524 # Include directories
 525 #
 526 ac_save_IFS=$IFS
 527 IFS="${IFS}${PATH_SEPARATOR}"
 528 # SRCH_INC comes from the template file
 529 for dir in $with_includes $SRCH_INC; do
 530   if test -d "$dir"; then
 531     INCLUDES="$INCLUDES -I$dir"
 532   else
 533     AC_MSG_WARN([*** Include directory $dir does not exist.])
 534   fi
 535 done
 536 IFS=$ac_save_IFS
 537 AC_SUBST(INCLUDES)
 538
 539
 540 #
 541 # Library directories
 542 #
 543 ac_save_IFS=$IFS
 544 IFS="${IFS}${PATH_SEPARATOR}"
 545 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 546 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 547   if test -d "$dir"; then
 548     LIBDIRS="$LIBDIRS -L$dir"
 549   else
 550     AC_MSG_WARN([*** Library directory $dir does not exist.])
 551   fi
 552 done
 553 IFS=$ac_save_IFS
 554
 555 #
 556 # Enable thread-safe client libraries
 557 #
 558 AC_MSG_CHECKING([allow thread-safe client libraries])
 559 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 560 if test "$enable_thread_safety" = yes; then
 561   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 562           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 563 fi
 564 AC_MSG_RESULT([$enable_thread_safety])
 565 AC_SUBST(enable_thread_safety)
 566
 567 #
 568 # Optionally build Tcl modules (PL/Tcl)
 569 #
 570 AC_MSG_CHECKING([whether to build with Tcl])
 571 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 572 AC_MSG_RESULT([$with_tcl])
 573 AC_SUBST([with_tcl])
 574
 575 # We see if the path to the Tcl/Tk configuration scripts is specified.
 576 # This will override the use of tclsh to find the paths to search.
 577
 578 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 579
 580 #
 581 # Optionally build Perl modules (PL/Perl)
 582 #
 583 AC_MSG_CHECKING([whether to build Perl modules])
 584 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 585 AC_MSG_RESULT([$with_perl])
 586 AC_SUBST(with_perl)
 587
 588 #
 589 # Optionally build Python modules (PL/Python)
 590 #
 591 AC_MSG_CHECKING([whether to build Python modules])
 592 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 593 AC_MSG_RESULT([$with_python])
 594 AC_SUBST(with_python)
 595
 596 #
 597 # GSSAPI
 598 #
 599 AC_MSG_CHECKING([whether to build with GSSAPI support])
 600 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 601 [
 602   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 603   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 604 ])
 605 AC_MSG_RESULT([$with_gssapi])
 606
 607 #
 608 # Kerberos 5
 609 #
 610 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 611 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 612 [
 613   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 614   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 615 ])
 616 AC_MSG_RESULT([$with_krb5])
 617
 618
 619 AC_SUBST(krb_srvtab)
 620
 621
 622 #
 623 # Kerberos configuration parameters
 624 #
 625 PGAC_ARG_REQ(with, krb-srvnam,
 626              [NAME], [default service principal name in Kerberos [postgres]],
 627              [],
 628              [with_krb_srvnam="postgres"])
 629 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 630                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 631
 632
 633 #
 634 # PAM
 635 #
 636 AC_MSG_CHECKING([whether to build with PAM support])
 637 PGAC_ARG_BOOL(with, pam, no,
 638               [build with PAM support],
 639               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 640 AC_MSG_RESULT([$with_pam])
 641
 642
 643 #
 644 # LDAP
 645 #
 646 AC_MSG_CHECKING([whether to build with LDAP support])
 647 PGAC_ARG_BOOL(with, ldap, no,
 648               [build with LDAP support],
 649               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 650 AC_MSG_RESULT([$with_ldap])
 651
 652
 653 #
 654 # Bonjour
 655 #
 656 AC_MSG_CHECKING([whether to build with Bonjour support])
 657 PGAC_ARG_BOOL(with, bonjour, no,
 658               [build with Bonjour support],
 659               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 660 AC_MSG_RESULT([$with_bonjour])
 661
 662
 663 #
 664 # OpenSSL
 665 #
 666 AC_MSG_CHECKING([whether to build with OpenSSL support])
 667 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 668               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 669 AC_MSG_RESULT([$with_openssl])
 670 AC_SUBST(with_openssl)
 671
 672 #
 673 # SELinux
 674 #
 675 AC_MSG_CHECKING([whether to build with SELinux support])
 676 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 677 AC_SUBST(with_selinux)
 678 AC_MSG_RESULT([$with_selinux])
 679
 680 #
 681 # Readline
 682 #
 683 PGAC_ARG_BOOL(with, readline, yes,
 684               [do not use GNU Readline nor BSD Libedit for editing])
 685 # readline on MinGW has problems with backslashes in psql and other bugs.
 686 # This is particularly a problem with non-US code pages.
 687 # Therefore disable its use until we understand the cause. 2004-07-20
 688 if test "$PORTNAME" = "win32"; then
 689   if test "$with_readline" = yes; then
 690     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 691     with_readline=no
 692   fi
 693 fi
 694
 695
 696 #
 697 # Prefer libedit
 698 #
 699 PGAC_ARG_BOOL(with, libedit-preferred, no,
 700               [prefer BSD Libedit over GNU Readline])
 701
 702
 703 #
 704 # OSSP UUID library
 705 #
 706 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 707 AC_SUBST(with_ossp_uuid)
 708
 709
 710 #
 711 # XML
 712 #
 713 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 714               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 715
 716 if test "$with_libxml" = yes ; then
 717   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 718   if test -n "$XML2_CONFIG"; then
 719     for pgac_option in `$XML2_CONFIG --cflags`; do
 720       case $pgac_option in
 721         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 722       esac
 723     done
 724     for pgac_option in `$XML2_CONFIG --libs`; do
 725       case $pgac_option in
 726         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 727       esac
 728     done
 729   fi
 730 fi
 731
 732 AC_SUBST(with_libxml)
 733
 734 #
 735 # XSLT
 736 #
 737 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 738               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 739
 740
 741 AC_SUBST(with_libxslt)
 742
 743 #
 744 # tzdata
 745 #
 746 PGAC_ARG_REQ(with, system-tzdata,
 747              [DIR], [use system time zone data in DIR])
 748 AC_SUBST(with_system_tzdata)
 749
 750 #
 751 # Zlib
 752 #
 753 PGAC_ARG_BOOL(with, zlib, yes,
 754               [do not use Zlib])
 755 AC_SUBST(with_zlib)
 756
 757 #
 758 # Elf
 759 #
 760
 761 # Assume system is ELF if it predefines __ELF__ as 1,
 762 # otherwise believe host_os based default.
 763 case $host_os in
 764     freebsd1*|freebsd2*) elf=no;;
 765     freebsd3*|freebsd4*) elf=yes;;
 766 esac
 767
 768 AC_EGREP_CPP(yes,
 769 [#if __ELF__
 770   yes
 771 #endif
 772 ],
 773 [ELF_SYS=true],
 774 [if test "X$elf" = "Xyes" ; then
 775   ELF_SYS=true
 776 else
 777   ELF_SYS=
 778 fi])
 779 AC_SUBST(ELF_SYS)
 780
 781 #
 782 # Assignments
 783 #
 784
 785 CPPFLAGS="$CPPFLAGS $INCLUDES"
 786 LDFLAGS="$LDFLAGS $LIBDIRS"
 787
 788 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 789 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 790
 791 PGAC_PROG_LD
 792 AC_SUBST(LD)
 793 AC_SUBST(with_gnu_ld)
 794 case $host_os in sysv5*)
 795   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 796   [
 797     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 798     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 799     LDFLAGS=$pgac_save_LDFLAGS
 800   ])
 801   ld_R_works=$pgac_cv_prog_ld_R
 802   AC_SUBST(ld_R_works)
 803 esac
 804 AC_PROG_RANLIB
 805 PGAC_CHECK_STRIP
 806 AC_CHECK_TOOL(AR, ar, ar)
 807 if test "$PORTNAME" = "win32"; then
 808   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 809   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 810   AC_CHECK_TOOL(WINDRES, windres, windres)
 811 fi
 812
 813 AC_PROG_INSTALL
 814 # When Autoconf chooses install-sh as install program it tries to generate
 815 # a relative path to it in each makefile where it subsitutes it. This clashes
 816 # with our Makefile.global concept. This workaround helps.
 817 case $INSTALL in
 818   *install-sh*) install_bin='';;
 819   *) install_bin=$INSTALL;;
 820 esac
 821 AC_SUBST(install_bin)
 822
 823 AC_PATH_PROG(TAR, tar)
 824 AC_PROG_LN_S
 825 AC_PROG_AWK
 826 AC_PROG_MKDIR_P
 827 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 828 # a relative path to it in each makefile where it subsitutes it. This clashes
 829 # with our Makefile.global concept. This workaround helps.
 830 case $MKDIR_P in
 831   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 832 esac
 833
 834 PGAC_PATH_BISON
 835 PGAC_PATH_FLEX
 836
 837 PGAC_PATH_PERL
 838 if test "$with_perl" = yes; then
 839   if test -z "$PERL"; then
 840     AC_MSG_ERROR([Perl not found])
 841   fi
 842   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 843   PGAC_CHECK_PERL_EMBED_LDFLAGS
 844 fi
 845
 846 if test "$with_python" = yes; then
 847   PGAC_PATH_PYTHON
 848   PGAC_CHECK_PYTHON_EMBED_SETUP
 849 fi
 850
 851 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 852   AC_PATH_PROG(ZIC, zic)
 853   if test -z "$ZIC"; then
 854     AC_MSG_ERROR([
 855 When cross-compiling, either use the option --with-system-tzdata to use
 856 existing time-zone data, or set the environment variable ZIC to a zic
 857 program to use during the build.])
 858   fi
 859 fi
 860
 861
 862 ##
 863 ## Libraries
 864 ##
 865 ## Most libraries are included only if they demonstrably provide a function
 866 ## we need, but libm is an exception: always include it, because there are
 867 ## too many compilers that play cute optimization games that will break
 868 ## probes for standard functions such as pow().
 869 ##
 870
 871 AC_CHECK_LIB(m, main)
 872 AC_SEARCH_LIBS(setproctitle, util)
 873 AC_SEARCH_LIBS(dlopen, dl)
 874 AC_SEARCH_LIBS(socket, [socket wsock32])
 875 AC_SEARCH_LIBS(shl_load, dld)
 876 # We only use libld in port/dynloader/aix.c
 877 case $host_os in
 878      aix*)
 879         AC_SEARCH_LIBS(ldopen, ld)
 880         ;;
 881 esac
 882 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 883 AC_SEARCH_LIBS(crypt, crypt)
 884 AC_SEARCH_LIBS(shm_open, rt)
 885 AC_SEARCH_LIBS(shm_unlink, rt)
 886 # Solaris:
 887 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 888 # Required for thread_test.c on Solaris 2.5:
 889 # Other ports use it too (HP-UX) so test unconditionally
 890 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 891 # Cygwin:
 892 AC_SEARCH_LIBS(shmget, cygipc)
 893
 894 if test "$with_readline" = yes; then
 895   PGAC_CHECK_READLINE
 896   if test x"$pgac_cv_check_readline" = x"no"; then
 897     AC_MSG_ERROR([readline library not found
 898 If you have readline already installed, see config.log for details on the
 899 failure.  It is possible the compiler isn't looking in the proper directory.
 900 Use --without-readline to disable readline support.])
 901   fi
 902 fi
 903
 904 if test "$with_zlib" = yes; then
 905   AC_CHECK_LIB(z, inflate, [],
 906                [AC_MSG_ERROR([zlib library not found
 907 If you have zlib already installed, see config.log for details on the
 908 failure.  It is possible the compiler isn't looking in the proper directory.
 909 Use --without-zlib to disable zlib support.])])
 910 fi
 911
 912 if test "$enable_spinlocks" = yes; then
 913   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 914 else
 915   AC_MSG_WARN([
 916 *** Not using spinlocks will cause poor performance.])
 917 fi
 918
 919 if test "$with_gssapi" = yes ; then
 920   if test "$PORTNAME" != "win32"; then
 921     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 922                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 923   else
 924     LIBS="$LIBS -lgssapi32"
 925   fi
 926 fi
 927
 928 if test "$with_krb5" = yes ; then
 929   if test "$PORTNAME" != "win32"; then
 930      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 931                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 932      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 933                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 934   else
 935      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 936                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 937   fi
 938 fi
 939
 940 if test "$with_openssl" = yes ; then
 941   dnl Order matters!
 942   if test "$PORTNAME" != "win32"; then
 943      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 944      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 945   else
 946      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 947      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 948   fi
 949 fi
 950
 951 if test "$with_pam" = yes ; then
 952   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 953 fi
 954
 955 if test "$with_libxml" = yes ; then
 956   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 957 fi
 958
 959 if test "$with_libxslt" = yes ; then
 960   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 961 fi
 962
 963 # for contrib/sepgsql
 964 if test "$with_selinux" = yes; then
 965   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 966                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 967 fi
 968
 969 # for contrib/uuid-ossp
 970 if test "$with_ossp_uuid" = yes ; then
 971   AC_CHECK_LIB(ossp-uuid, uuid_export,
 972     [OSSP_UUID_LIBS="-lossp-uuid"],
 973     [AC_CHECK_LIB(uuid, uuid_export,
 974       [OSSP_UUID_LIBS="-luuid"],
 975       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 976 fi
 977 AC_SUBST(OSSP_UUID_LIBS)
 978
 979
 980 ##
 981 ## Header files
 982 ##
 983
 984 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 985 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 986
 987 # On BSD, test for net/if.h will fail unless sys/socket.h
 988 # is included first.
 989 AC_CHECK_HEADERS(net/if.h, [], [],
 990 [AC_INCLUDES_DEFAULT
 991 #ifdef HAVE_SYS_SOCKET_H
 992 #include <sys/socket.h>
 993 #endif
 994 ])
 995
 996 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
 997 # is included first.
 998 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 999 [AC_INCLUDES_DEFAULT
1000 #include <sys/param.h>
1001 ])
1002
1003 # At least on IRIX, test for netinet/tcp.h will fail unless
1004 # netinet/in.h is included first.
1005 AC_CHECK_HEADERS(netinet/in.h)
1006 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1007 [AC_INCLUDES_DEFAULT
1008 #ifdef HAVE_NETINET_IN_H
1009 #include <netinet/in.h>
1010 #endif
1011 ])
1012
1013 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1014   AC_CHECK_HEADERS(readline/readline.h, [],
1015         [AC_CHECK_HEADERS(readline.h, [],
1016                 [AC_MSG_ERROR([readline header not found
1017 If you have readline already installed, see config.log for details on the
1018 failure.  It is possible the compiler isn't looking in the proper directory.
1019 Use --without-readline to disable readline support.])])])
1020   AC_CHECK_HEADERS(readline/history.h, [],
1021         [AC_CHECK_HEADERS(history.h, [],
1022                 [AC_MSG_ERROR([history header not found
1023 If you have readline already installed, see config.log for details on the
1024 failure.  It is possible the compiler isn't looking in the proper directory.
1025 Use --without-readline to disable readline support.])])])
1026 fi
1027
1028 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1029 # Some installations of libedit usurp /usr/include/readline/, which seems
1030 # bad practice, since in combined installations readline will have its headers
1031 # there.  We might have to resort to AC_EGREP checks to make sure we found
1032 # the proper header...
1033   AC_CHECK_HEADERS(editline/readline.h, [],
1034         [AC_CHECK_HEADERS(readline.h, [],
1035                 [AC_CHECK_HEADERS(readline/readline.h, [],
1036                         [AC_MSG_ERROR([readline header not found
1037 If you have libedit already installed, see config.log for details on the
1038 failure.  It is possible the compiler isn't looking in the proper directory.
1039 Use --without-readline to disable libedit support.])])])])
1040 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1041 # not be there at all.  Hence, don't complain if not found.  We must check
1042 # though, since in yet other versions it is an independent header.
1043   AC_CHECK_HEADERS(editline/history.h, [],
1044         [AC_CHECK_HEADERS(history.h, [],
1045                 [AC_CHECK_HEADERS(readline/history.h)])])
1046 fi
1047
1048 if test "$with_zlib" = yes; then
1049   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1050 If you have zlib already installed, see config.log for details on the
1051 failure.  It is possible the compiler isn't looking in the proper directory.
1052 Use --without-zlib to disable zlib support.])])
1053 fi
1054
1055 if test "$with_gssapi" = yes ; then
1056   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1057         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1058 fi
1059
1060 if test "$with_krb5" = yes ; then
1061   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1062 fi
1063
1064 if test "$with_openssl" = yes ; then
1065   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1066   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1067 fi
1068
1069 if test "$with_pam" = yes ; then
1070   AC_CHECK_HEADERS(security/pam_appl.h, [],
1071                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1072                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1073 fi
1074
1075 if test "$with_libxml" = yes ; then
1076   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1077 fi
1078
1079 if test "$with_libxslt" = yes ; then
1080   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1081 fi
1082
1083 if test "$with_ldap" = yes ; then
1084   if test "$PORTNAME" != "win32"; then
1085      AC_CHECK_HEADERS(ldap.h, [],
1086                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1087   else
1088      AC_CHECK_HEADERS(winldap.h, [],
1089                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1090                       [AC_INCLUDES_DEFAULT
1091 #include <windows.h>
1092                       ])
1093   fi
1094 fi
1095
1096 if test "$with_bonjour" = yes ; then
1097   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1098 fi
1099
1100 # for contrib/uuid-ossp
1101 if test "$with_ossp_uuid" = yes ; then
1102   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1103     AC_CHECK_HEADERS(uuid.h, [],
1104       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1105 fi
1106
1107 if test "$PORTNAME" = "win32" ; then
1108    AC_CHECK_HEADERS(crtdefs.h)
1109 fi
1110
1111 ##
1112 ## Types, structures, compiler characteristics
1113 ##
1114
1115 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1116 AC_C_BIGENDIAN
1117 PGAC_C_INLINE
1118 AC_C_FLEXIBLE_ARRAY_MEMBER
1119 PGAC_C_SIGNED
1120 PGAC_C_FUNCNAME_SUPPORT
1121 PGAC_C_STATIC_ASSERT
1122 PGAC_C_TYPES_COMPATIBLE
1123 PGAC_C_BUILTIN_CONSTANT_P
1124 PGAC_C_BUILTIN_UNREACHABLE
1125 PGAC_C_VA_ARGS
1126 PGAC_STRUCT_TIMEZONE
1127 PGAC_UNION_SEMUN
1128 PGAC_STRUCT_SOCKADDR_UN
1129 PGAC_STRUCT_SOCKADDR_STORAGE
1130 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1131 PGAC_STRUCT_ADDRINFO
1132 AC_TYPE_INTPTR_T
1133 AC_TYPE_UINTPTR_T
1134 AC_TYPE_LONG_LONG_INT
1135
1136 PGAC_TYPE_LOCALE_T
1137
1138 AC_CHECK_TYPES([struct cmsgcred], [], [],
1139 [#include <sys/socket.h>
1140 #include <sys/param.h>
1141 #ifdef HAVE_SYS_UCRED_H
1142 #include <sys/ucred.h>
1143 #endif])
1144
1145 AC_CHECK_TYPES([struct option], [], [],
1146 [#ifdef HAVE_GETOPT_H
1147 #include <getopt.h>
1148 #endif])
1149
1150 if test "$with_zlib" = yes; then
1151   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1152   # did not).  While we could work around the lack of z_streamp, it
1153   # seems unwise to encourage people to use such old zlib versions...
1154   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1155 Use --without-zlib to disable zlib support.])],
1156                 [#include <zlib.h>])
1157 fi
1158
1159 if test "$with_krb5" = yes; then
1160 # Check for differences between MIT and Heimdal (KTH) releases
1161   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1162                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1163                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1164                                      [#include <krb5.h>])],
1165                    [#include <krb5.h>])
1166   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1167                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1168                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1169                                      [#include <krb5.h>])],
1170                    [#include <krb5.h>])
1171
1172 # Win32 requires headers to be loaded for __stdcall, so can't use
1173 # AC_CHECK_FUNCS here.
1174   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1175   AC_TRY_LINK([#include <krb5.h>],
1176               [krb5_free_unparsed_name(NULL,NULL);],
1177               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name.])
1178 AC_MSG_RESULT(yes)],
1179               [AC_MSG_RESULT(no)])
1180 fi
1181
1182 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1183 case $host_cpu in
1184   ppc*|powerpc*)
1185     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1186     AC_TRY_COMPILE([],
1187         [int a = 0; int *p = &a; int r;
1188          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1189         [pgac_cv_have_ppc_mutex_hint=yes],
1190         [pgac_cv_have_ppc_mutex_hint=no])
1191     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1192     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1193         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1194     fi
1195   ;;
1196 esac
1197
1198 # Check largefile support.  You might think this is a system service not a
1199 # compiler characteristic, but you'd be wrong.  We must check this before
1200 # probing existence of related functions such as fseeko, since the largefile
1201 # defines can affect what is generated for that.
1202 if test "$PORTNAME" != "win32"; then
1203    AC_SYS_LARGEFILE
1204 fi
1205
1206 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1207 AC_CHECK_SIZEOF([off_t])
1208
1209 # If we don't have largefile support, can't handle segsize >= 2GB.
1210 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1211    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1212 fi
1213
1214
1215 ##
1216 ## Functions, global variables
1217 ##
1218
1219 PGAC_VAR_INT_TIMEZONE
1220 AC_FUNC_ACCEPT_ARGTYPES
1221 PGAC_FUNC_GETTIMEOFDAY_1ARG
1222
1223 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1224 # symbols that that library has no business exposing to the world.  Pending
1225 # acquisition of a clue by those developers, ignore libedit (including its
1226 # possible alias of libreadline) while checking for everything else.
1227 LIBS_including_readline="$LIBS"
1228 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1229
1230 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1231
1232 AC_REPLACE_FUNCS(fseeko)
1233 case $host_os in
1234         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1235         # Mingw uses macros to access Win32 API calls
1236         netbsd*|mingw*)
1237                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1238                 ac_cv_func_fseeko=yes;;
1239         *)
1240                 AC_FUNC_FSEEKO;;
1241 esac
1242
1243 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1244 # by calling it, 2009-04-02
1245 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1246 if test "$PORTNAME" != "solaris"; then
1247 AC_CHECK_FUNCS(posix_fadvise)
1248 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1249 fi
1250
1251 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1252 AC_CHECK_DECLS([strlcat, strlcpy])
1253 # This is probably only present on Darwin, but may as well check always
1254 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1255
1256 HAVE_IPV6=no
1257 AC_CHECK_TYPE([struct sockaddr_in6],
1258         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1259          HAVE_IPV6=yes],
1260         [],
1261 [$ac_includes_default
1262 #include <netinet/in.h>])
1263 AC_SUBST(HAVE_IPV6)
1264
1265 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1266 [AC_TRY_LINK(
1267 [#include <machine/vmparam.h>
1268 #include <sys/exec.h>
1269 ],
1270 [PS_STRINGS->ps_nargvstr = 1;
1271 PS_STRINGS->ps_argvstr = "foo";],
1272 [pgac_cv_var_PS_STRINGS=yes],
1273 [pgac_cv_var_PS_STRINGS=no])])
1274 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1275   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1276 fi
1277
1278
1279 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1280 # is missing.  Yes, there are machines that have only one.  We may
1281 # also decide to use snprintf.c if snprintf() is present but does not
1282 # have all the features we need --- see below.
1283
1284 if test "$PORTNAME" = "win32"; then
1285   # Win32 gets snprintf.c built unconditionally.
1286   #
1287   # To properly translate all NLS languages strings, we must support the
1288   # *printf() %$ format, which allows *printf() arguments to be selected
1289   # by position in the translated string.
1290   #
1291   # libintl versions < 0.13 use the native *printf() functions, and Win32
1292   # *printf() doesn't understand %$, so we must use our /port versions,
1293   # which do understand %$. libintl versions >= 0.13 include their own
1294   # *printf versions on Win32.  The libintl 0.13 release note text is:
1295   #
1296   #   C format strings with positions, as they arise when a translator
1297   #   needs to reorder a sentence, are now supported on all platforms.
1298   #   On those few platforms (NetBSD and Woe32) for which the native
1299   #   printf()/fprintf()/... functions don't support such format
1300   #   strings, replacements are provided through <libintl.h>.
1301   #
1302   # We could use libintl >= 0.13's *printf() if we were sure that we had
1303   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1304   # to guarantee that, it is best to just use our own, so we are sure to
1305   # get %$ support. In include/port.h we disable the *printf() macros
1306   # that might have been defined by libintl.
1307   #
1308   # We do this unconditionally whether NLS is used or not so we are sure
1309   # that all Win32 libraries and binaries behave the same.
1310   pgac_need_repl_snprintf=yes
1311 else
1312   pgac_need_repl_snprintf=no
1313   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1314   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1315 fi
1316
1317
1318 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1319 # include/c.h will provide declarations.  Note this is a separate test
1320 # from whether the functions exist in the C library --- there are
1321 # systems that have the functions but don't bother to declare them :-(
1322
1323 AC_CHECK_DECLS([snprintf, vsnprintf])
1324
1325
1326 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1327 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1328 [AC_TRY_LINK([
1329 #include <math.h>
1330 double glob_double;
1331 ],
1332 [return isinf(glob_double) ? 0 : 1;],
1333 [ac_cv_func_isinf=yes],
1334 [ac_cv_func_isinf=no])])
1335
1336 if test $ac_cv_func_isinf = yes ; then
1337   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1338 else
1339   AC_LIBOBJ(isinf)
1340   # Look for a way to implement a substitute for isinf()
1341   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1342 fi
1343
1344 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1345
1346 case $host_os in
1347
1348         # Windows uses a specialised env handler
1349         # and doesn't need a replacement getpeereid because it doesn't use
1350         # Unix sockets.
1351         mingw*)
1352                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1353                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1354                 ac_cv_func_unsetenv=yes
1355                 ac_cv_func_getpeereid=yes;;
1356         *)
1357                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1358                 ;;
1359 esac
1360
1361 # System's version of getaddrinfo(), if any, may be used only if we found
1362 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1363 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1364 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1365 # because we want to use our own getaddrinfo.c on Windows anyway.)
1366 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1367   AC_REPLACE_FUNCS([getaddrinfo])
1368 else
1369   AC_LIBOBJ(getaddrinfo)
1370 fi
1371
1372 # Similarly, use system's getopt_long() only if system provides struct option.
1373 if test x"$ac_cv_type_struct_option" = xyes ; then
1374   AC_REPLACE_FUNCS([getopt_long])
1375 else
1376   AC_LIBOBJ(getopt_long)
1377 fi
1378
1379 # Solaris' getopt() doesn't do what we want for long options, so always use
1380 # our version on that platform.
1381 if test "$PORTNAME" = "solaris"; then
1382   AC_LIBOBJ(getopt)
1383 fi
1384
1385 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1386 # so always use our version on Windows.
1387 if test "$PORTNAME" = "win32"; then
1388   AC_LIBOBJ(getopt)
1389   AC_LIBOBJ(getopt_long)
1390 fi
1391
1392 # Win32 support
1393 if test "$PORTNAME" = "win32"; then
1394   AC_REPLACE_FUNCS(gettimeofday)
1395   AC_LIBOBJ(kill)
1396   AC_LIBOBJ(open)
1397   AC_LIBOBJ(win32env)
1398   AC_LIBOBJ(win32error)
1399   AC_LIBOBJ(win32setlocale)
1400   AC_DEFINE([HAVE_SYMLINK], 1,
1401             [Define to 1 if you have the `symlink' function.])
1402   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1403 #define WIN32_LEAN_AND_MEAN
1404 #include <windows.h>
1405 #include <string.h>
1406 #include <dbghelp.h>])
1407 fi
1408 if test x"$pgac_minidump_type" = x"yes" ; then
1409   AC_SUBST(have_win32_dbghelp,yes)
1410 else
1411   AC_SUBST(have_win32_dbghelp,no)
1412 fi
1413
1414 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1415 dnl (especially on GNU libc)
1416 dnl See also comments in c.h.
1417 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1418 [AC_TRY_LINK([#include <setjmp.h>],
1419             [sigjmp_buf x; sigsetjmp(x, 1);],
1420             [pgac_cv_func_sigsetjmp=yes],
1421             [pgac_cv_func_sigsetjmp=no])])
1422 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1423   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1424 fi
1425
1426 AC_DECL_SYS_SIGLIST
1427
1428 AC_CHECK_FUNC(syslog,
1429               [AC_CHECK_HEADER(syslog.h,
1430                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1431
1432 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1433 [AC_TRY_LINK([#include <unistd.h>],
1434   [extern int opterr; opterr = 1;],
1435   [pgac_cv_var_int_opterr=yes],
1436   [pgac_cv_var_int_opterr=no])])
1437 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1438   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1439 fi
1440
1441 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1442 [AC_TRY_LINK([#include <unistd.h>],
1443   [extern int optreset; optreset = 1;],
1444   [pgac_cv_var_int_optreset=yes],
1445   [pgac_cv_var_int_optreset=no])])
1446 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1447   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1448 fi
1449
1450 AC_CHECK_FUNCS([strtoll strtoq], [break])
1451 AC_CHECK_FUNCS([strtoull strtouq], [break])
1452
1453 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1454 [AC_TRY_LINK([],
1455   [int lock = 0;
1456    __sync_lock_test_and_set(&lock, 1);
1457    __sync_lock_release(&lock);],
1458   [pgac_cv_gcc_int_atomics="yes"],
1459   [pgac_cv_gcc_int_atomics="no"])])
1460 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1461   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1462 fi
1463
1464 # Lastly, restore full LIBS list and check for readline/libedit symbols
1465 LIBS="$LIBS_including_readline"
1466
1467 if test "$with_readline" = yes; then
1468   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1469   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1470   AC_CHECK_FUNCS([append_history history_truncate_file])
1471 fi
1472
1473
1474 #
1475 # Pthreads
1476 #
1477 # For each platform, we need to know about any special compile and link
1478 # libraries, and whether the normal C function names are thread-safe.
1479 # See the comment at the top of src/port/thread.c for more information.
1480 # WIN32 doesn't need the pthread tests;  it always uses threads
1481 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1482 ACX_PTHREAD     # set thread flags
1483
1484 # Some platforms use these, so just define them.  They can't hurt if they
1485 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1486 # enables 5-arg getpwuid_r, among other things.
1487 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1488
1489
1490 # At this point, we don't want to muck with the compiler name for threading.
1491 # Let's see who fails, perhaps AIX.  2004-04-23
1492 if test "$PTHREAD_CC" != "$CC"; then
1493 AC_MSG_ERROR([
1494 PostgreSQL does not support platforms that require a special compiler
1495 for thread safety;  use --disable-thread-safety to disable thread safety.])
1496 fi
1497
1498 # Check for *_r functions
1499 _CFLAGS="$CFLAGS"
1500 _LIBS="$LIBS"
1501 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1502 LIBS="$LIBS $PTHREAD_LIBS"
1503
1504 if test "$PORTNAME" != "win32"; then
1505 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1506 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1507 fi
1508
1509 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1510
1511 # Do test here with the proper thread flags
1512 PGAC_FUNC_GETPWUID_R_5ARG
1513 PGAC_FUNC_STRERROR_R_INT
1514
1515 CFLAGS="$_CFLAGS"
1516 LIBS="$_LIBS"
1517
1518 else
1519 # do not use values from template file
1520 PTHREAD_CFLAGS=
1521 PTHREAD_LIBS=
1522 fi
1523
1524 AC_SUBST(PTHREAD_CFLAGS)
1525 AC_SUBST(PTHREAD_LIBS)
1526
1527
1528 # We can test for libldap_r only after we know PTHREAD_LIBS
1529 if test "$with_ldap" = yes ; then
1530   _LIBS="$LIBS"
1531   if test "$PORTNAME" != "win32"; then
1532     AC_CHECK_LIB(ldap, ldap_bind, [],
1533                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1534                  [$EXTRA_LDAP_LIBS])
1535     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1536     if test "$enable_thread_safety" = yes; then
1537       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1538       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1539                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1540                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1541       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1542     else
1543       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1544     fi
1545   else
1546     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1547     LDAP_LIBS_FE="-lwldap32"
1548     LDAP_LIBS_BE="-lwldap32"
1549   fi
1550   LIBS="$_LIBS"
1551 fi
1552 AC_SUBST(LDAP_LIBS_FE)
1553 AC_SUBST(LDAP_LIBS_BE)
1554
1555
1556 # This test makes sure that run tests work at all.  Sometimes a shared
1557 # library is found by the linker, but the runtime linker can't find it.
1558 # This check should come after all modifications of compiler or linker
1559 # variables, and before any other run tests.
1560 AC_MSG_CHECKING([test program])
1561 AC_TRY_RUN([int main() { return 0; }],
1562 [AC_MSG_RESULT(ok)],
1563 [AC_MSG_RESULT(failed)
1564 AC_MSG_ERROR([[
1565 Could not execute a simple test program.  This may be a problem
1566 related to locating shared libraries.  Check the file 'config.log'
1567 for the exact reason.]])],
1568 [AC_MSG_RESULT([cross-compiling])])
1569
1570 # --------------------
1571 # Run tests below here
1572 # --------------------
1573
1574 # Force use of our snprintf if system's doesn't do arg control
1575 # See comment above at snprintf test for details.
1576 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1577   PGAC_FUNC_PRINTF_ARG_CONTROL
1578   if test $pgac_cv_printf_arg_control != yes ; then
1579     pgac_need_repl_snprintf=yes
1580   fi
1581 fi
1582
1583
1584 dnl Check to see if we have a working 64-bit integer type.
1585 dnl This breaks down into two steps:
1586 dnl (1) figure out if the compiler has a 64-bit int type with working
1587 dnl arithmetic, and if so
1588 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1589 dnl snprintf is the only library routine we really need for int8 support.)
1590 dnl It's entirely possible to have a compiler that handles a 64-bit type
1591 dnl when the C library doesn't; this is fairly likely when using gcc on
1592 dnl an older platform, for example.
1593 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1594 dnl we force our own version of snprintf() to be used instead.
1595 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1596
1597 dnl As of Postgres 8.4, we no longer support compilers without a working
1598 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1599
1600 PGAC_TYPE_64BIT_INT([long int])
1601
1602 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1603   pg_int64_type="long int"
1604 else
1605   PGAC_TYPE_64BIT_INT([long long int])
1606   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1607     pg_int64_type="long long int"
1608   else
1609     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1610   fi
1611 fi
1612
1613 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1614   [Define to the name of a signed 64-bit integer type.])
1615
1616 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1617
1618 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1619   AC_TRY_COMPILE([
1620 #define INT64CONST(x)  x##LL
1621 long long int foo = INT64CONST(0x1234567890123456);
1622 ],
1623         [],
1624         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1625         [])
1626 fi
1627
1628
1629 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1630 # we found we need to use "long long int", better check.  We cope with
1631 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1632 # work, fall back to our own snprintf emulation (which we know uses %lld).
1633
1634 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1635   if test $pgac_need_repl_snprintf = no; then
1636     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1637     if test "$LONG_LONG_INT_FORMAT" = ""; then
1638       # Force usage of our own snprintf, since system snprintf is broken
1639       pgac_need_repl_snprintf=yes
1640       LONG_LONG_INT_FORMAT='%lld'
1641     fi
1642   else
1643     # Here if we previously decided we needed to use our own snprintf
1644     LONG_LONG_INT_FORMAT='%lld'
1645   fi
1646   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1647   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1648   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1649 else
1650   # Here if we are not using 'long long int' at all
1651   INT64_FORMAT='"%ld"'
1652   UINT64_FORMAT='"%lu"'
1653 fi
1654
1655 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1656                    [Define to the appropriate snprintf format for 64-bit ints.])
1657
1658 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1659                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1660
1661 # Now we have checked all the reasons to replace snprintf
1662 if test $pgac_need_repl_snprintf = yes; then
1663   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1664   AC_LIBOBJ(snprintf)
1665 fi
1666
1667 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1668 AC_CHECK_SIZEOF([void *])
1669 AC_CHECK_SIZEOF([size_t])
1670 AC_CHECK_SIZEOF([long])
1671
1672 # Decide whether float4 is passed by value: user-selectable, enabled by default
1673 AC_MSG_CHECKING([whether to build with float4 passed by value])
1674 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1675               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1676                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1677                float4passbyval=true],
1678               [float4passbyval=false])
1679 AC_MSG_RESULT([$enable_float4_byval])
1680 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1681
1682 # Decide whether float8 is passed by value.
1683 # Note: this setting also controls int8 and related types such as timestamp.
1684 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1685 # If not, trying to select it is an error.
1686 AC_MSG_CHECKING([whether to build with float8 passed by value])
1687 if test $ac_cv_sizeof_void_p -ge 8 ; then
1688   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1689 else
1690   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1691   if test "$enable_float8_byval" = yes ; then
1692     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1693   fi
1694 fi
1695 if test "$enable_float8_byval" = yes ; then
1696   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1697             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1698   float8passbyval=true
1699 else
1700   float8passbyval=false
1701 fi
1702 AC_MSG_RESULT([$enable_float8_byval])
1703 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1704
1705 # Determine memory alignment requirements for the basic C data types.
1706
1707 AC_CHECK_ALIGNOF(short)
1708 AC_CHECK_ALIGNOF(int)
1709 AC_CHECK_ALIGNOF(long)
1710 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1711   AC_CHECK_ALIGNOF(long long int)
1712 fi
1713 AC_CHECK_ALIGNOF(double)
1714
1715 # Compute maximum alignment of any basic type.
1716 # We assume long's alignment is at least as strong as char, short, or int;
1717 # but we must check long long (if it exists) and double.
1718
1719 MAX_ALIGNOF=$ac_cv_alignof_long
1720 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1721   MAX_ALIGNOF=$ac_cv_alignof_double
1722 fi
1723 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1724   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1725 fi
1726 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1727
1728
1729 # Some platforms predefine the types int8, int16, etc.  Only check
1730 # a (hopefully) representative subset.
1731 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1732 [#include <stdio.h>])
1733
1734 # We also check for sig_atomic_t, which *should* be defined per ANSI
1735 # C, but is missing on some old platforms.
1736 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1737
1738
1739 if test "$PORTNAME" != "win32"
1740 then
1741 PGAC_FUNC_POSIX_SIGNALS
1742 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1743   AC_MSG_ERROR([
1744 Thread-safety requires POSIX signals, which are not supported by this
1745 operating system;  use --disable-thread-safety to disable thread safety.])
1746 fi
1747 fi
1748
1749
1750 # Select semaphore implementation type.
1751 if test "$PORTNAME" != "win32"; then
1752   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1753     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1754     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1755   else
1756     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1757       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1758       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1759     else
1760       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1761       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1762     fi
1763   fi
1764 else
1765   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1766   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1767 fi
1768
1769
1770 # Select shared-memory implementation type.
1771 if test "$PORTNAME" != "win32"; then
1772   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1773   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1774 else
1775   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1776   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1777 fi
1778
1779 # Select latch implementation type.
1780 if test "$PORTNAME" != "win32"; then
1781   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1782 else
1783   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1784 fi
1785
1786 # If not set in template file, set bytes to use libc memset()
1787 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1788   MEMSET_LOOP_LIMIT=1024
1789 fi
1790 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1791
1792
1793 if test "$enable_nls" = yes ; then
1794   PGAC_CHECK_GETTEXT
1795 fi
1796
1797 # Check for Tcl configuration script tclConfig.sh
1798 if test "$with_tcl" = yes; then
1799     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1800     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1801                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1802     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1803     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1804     ac_save_CPPFLAGS=$CPPFLAGS
1805     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1806     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1807     CPPFLAGS=$ac_save_CPPFLAGS
1808 fi
1809
1810 # check for <perl.h>
1811 if test "$with_perl" = yes; then
1812   ac_save_CPPFLAGS=$CPPFLAGS
1813   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1814   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1815                   [#include <EXTERN.h>])
1816   # While we're at it, check that we can link to libperl.
1817   # On most platforms, if perl.h is there then libperl.so will be too, but at
1818   # this writing Debian packages them separately.  There is no known reason to
1819   # waste cycles on separate probes for the Tcl or Python libraries, though.
1820   pgac_save_LIBS=$LIBS
1821   LIBS="$perl_embed_ldflags"
1822   AC_MSG_CHECKING([for libperl])
1823   AC_TRY_LINK([
1824 #include <EXTERN.h>
1825 #include <perl.h>
1826 ],  [perl_alloc();],
1827     [AC_MSG_RESULT(yes)],
1828     [AC_MSG_RESULT(no)
1829      AC_MSG_ERROR([libperl library is required for Perl])])
1830   LIBS=$pgac_save_LIBS
1831   CPPFLAGS=$ac_save_CPPFLAGS
1832 fi
1833
1834 # check for <Python.h>
1835 if test "$with_python" = yes; then
1836   ac_save_CPPFLAGS=$CPPFLAGS
1837   CPPFLAGS="$python_includespec $CPPFLAGS"
1838   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1839   CPPFLAGS=$ac_save_CPPFLAGS
1840 fi
1841
1842 #
1843 # Check for DocBook and tools
1844 #
1845 PGAC_PROG_NSGMLS
1846 PGAC_PROG_JADE
1847 PGAC_CHECK_DOCBOOK(4.2)
1848 PGAC_PATH_DOCBOOK_STYLESHEETS
1849 PGAC_PATH_COLLATEINDEX
1850 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1851 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1852
1853 # Thread testing
1854
1855 # We have to run the thread test near the end so we have all our symbols
1856 # defined.  Cross compiling throws a warning.
1857 #
1858 if test "$enable_thread_safety" = yes; then
1859 if test "$PORTNAME" != "win32"
1860 then
1861 AC_MSG_CHECKING([thread safety of required library functions])
1862
1863 _CFLAGS="$CFLAGS"
1864 _LIBS="$LIBS"
1865 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1866 LIBS="$LIBS $PTHREAD_LIBS"
1867 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1868   [AC_MSG_RESULT(yes)],
1869   [AC_MSG_RESULT(no)
1870   AC_MSG_ERROR([thread test program failed
1871 This platform is not thread-safe.  Check the file 'config.log' or compile
1872 and run src/test/thread/thread_test for the exact reason.
1873 Use --disable-thread-safety to disable thread safety.])],
1874   [AC_MSG_RESULT(maybe)
1875   AC_MSG_WARN([
1876 *** Skipping thread test program because of cross-compile build.
1877 *** Run the program in src/test/thread on the target machine.
1878 ])])
1879 CFLAGS="$_CFLAGS"
1880 LIBS="$_LIBS"
1881 else
1882 AC_MSG_WARN([*** skipping thread test on Win32])
1883 fi
1884 fi
1885
1886 # If compiler will take -Wl,--as-needed (or various platform-specific
1887 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1888 # trying to filter LIBS to the minimum for each executable.
1889 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1890 # libreadline; therefore we postpone testing it until we know what library
1891 # dependencies readline has.  The test code will try to link with $LIBS.
1892 if test "$with_readline" = yes; then
1893   link_test_func=readline
1894 else
1895   link_test_func=exit
1896 fi
1897
1898 if test "$PORTNAME" = "darwin"; then
1899   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1900 elif test "$PORTNAME" = "openbsd"; then
1901   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1902 else
1903   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1904 fi
1905
1906 # Create compiler version string
1907 if test x"$GCC" = x"yes" ; then
1908   cc_string=`${CC} --version | sed q`
1909   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1910 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1911   cc_string=`${CC} -V 2>&1 | sed q`
1912 else
1913   cc_string=$CC
1914 fi
1915
1916 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1917                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1918                    [A string containing the version number, platform, and C compiler])
1919
1920 # Supply a numeric version string for use by 3rd party add-ons
1921 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1922 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1923 tr '.' '        ' |
1924 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1925 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1926
1927
1928 # Begin output steps
1929
1930 AC_MSG_NOTICE([using compiler=$cc_string])
1931 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1932 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1933 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1934
1935 # prepare build tree if outside source tree
1936 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1937 # Note 2: /bin/pwd might be better than shell's built-in at getting
1938 #         a symlink-free name.
1939 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1940   vpath_build=no
1941 else
1942   vpath_build=yes
1943   if test "$no_create" != yes; then
1944     _AS_ECHO_N([preparing build tree... ])
1945     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1946     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1947       || AC_MSG_ERROR(failed)
1948     AC_MSG_RESULT(done)
1949   fi
1950 fi
1951 AC_SUBST(vpath_build)
1952
1953
1954 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1955
1956 AC_CONFIG_LINKS([
1957   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1958   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1959   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1960   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1961   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1962   src/include/pg_config_os.h:src/include/port/${template}.h
1963   src/Makefile.port:src/makefiles/Makefile.${template}
1964 ])
1965
1966 if test "$PORTNAME" = "win32"; then
1967 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1968 # Links sometimes fail undetected on Mingw -
1969 # so here we detect it and warn the user
1970 for FILE in $CONFIG_LINKS
1971  do
1972         # test -e works for symlinks in the MinGW console
1973         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1974  done
1975 ])
1976 fi
1977
1978 AC_CONFIG_HEADERS([src/include/pg_config.h],
1979 [
1980 # Update timestamp for pg_config.h (see Makefile.global)
1981 echo >src/include/stamp-h
1982 ])
1983
1984 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
1985 [
1986 # Update timestamp for pg_config_ext.h (see Makefile.global)
1987 echo >src/include/stamp-ext-h
1988 ])
1989
1990 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1991                   [echo >src/interfaces/ecpg/include/stamp-h])
1992
1993 AC_OUTPUT