granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc";;
 357     *) pgac_cc_list="gcc cc";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361
 362 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 363 # but has idiosyncrasies of its own.  We assume icc will define
 364 # __INTEL_COMPILER regardless of CFLAGS.
 365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 366 choke me
 367 @%:@endif])], [ICC=yes], [ICC=no])
 368
 369 # Check if it's Sun Studio compiler. We assume that
 370 # __SUNPRO_C will be defined for Sun Studio compilers
 371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 372 choke me
 373 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 374
 375 AC_SUBST(SUN_STUDIO_CC)
 376
 377 unset CFLAGS
 378
 379 #
 380 # Read the template
 381 #
 382 . "$srcdir/src/template/$template" || exit
 383
 384 # CFLAGS are selected so:
 385 # If the user specifies something in the environment, that is used.
 386 # else:  If the template file set something, that is used.
 387 # else:  If coverage was enabled, don't set anything.
 388 # else:  If the compiler is GCC, then we use -O2.
 389 # else:  If the compiler is something else, then we use -O, unless debugging.
 390
 391 if test "$ac_env_CFLAGS_set" = set; then
 392   CFLAGS=$ac_env_CFLAGS_value
 393 elif test "${CFLAGS+set}" = set; then
 394   : # (keep what template set)
 395 elif test "$enable_coverage" = yes; then
 396   : # no optimization by default
 397 elif test "$GCC" = yes; then
 398   CFLAGS="-O2"
 399 else
 400   # if the user selected debug mode, don't use -O
 401   if test "$enable_debug" != yes; then
 402     CFLAGS="-O"
 403   fi
 404 fi
 405
 406 # CFLAGS we determined above will be added back at the end
 407 user_CFLAGS=$CFLAGS
 408 CFLAGS=""
 409
 410 # set CFLAGS_VECTOR from the environment, if available
 411 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 412   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 413 fi
 414
 415 # Some versions of GCC support some additional useful warning flags.
 416 # Check whether they are supported, and add them to CFLAGS if so.
 417 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 418 # but has its own.  Also check other compiler-specific flags here.
 419
 420 if test "$GCC" = yes -a "$ICC" = no; then
 421   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 422   # These work in some but not all gcc versions
 423   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 424   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 425   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 426   # This was included in -Wall/-Wformat in older GCC versions
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 434   # Optimization flags for specific files that benefit from vectorization
 435   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 436   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 437   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 438   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 439   # test for the positive form and if that works, add the negative form
 440   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 441   if test -n "$NOT_THE_CFLAGS"; then
 442     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 443   fi
 444 elif test "$ICC" = yes; then
 445   # Intel's compiler has a bug/misoptimization in checking for
 446   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 447   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 448   # Make sure strict aliasing is off (though this is said to be the default)
 449   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 450 elif test "$PORTNAME" = "aix"; then
 451   # AIX's xlc has to have strict aliasing turned off too
 452   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 453   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 454 elif test "$PORTNAME" = "hpux"; then
 455   # On some versions of HP-UX, libm functions do not set errno by default.
 456   # Fix that by using +Olibmerrno if the compiler recognizes it.
 457   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 458 fi
 459
 460 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 461
 462 # supply -g if --enable-debug
 463 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 464   CFLAGS="$CFLAGS -g"
 465 fi
 466
 467 # enable code coverage if --enable-coverage
 468 if test "$enable_coverage" = yes; then
 469   if test "$GCC" = yes; then
 470     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 471   else
 472     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 473   fi
 474 fi
 475
 476 # enable profiling if --enable-profiling
 477 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 478   if test "$GCC" = yes; then
 479     AC_DEFINE([PROFILE_PID_DIR], 1,
 480            [Define to 1 to allow profiling output to be saved separately for each process.])
 481     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 482   else
 483     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # We already have this in Makefile.win32, but configure needs it too
 488 if test "$PORTNAME" = "win32"; then
 489   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 490 fi
 491
 492 # Now that we're done automatically adding stuff to CFLAGS, put back the
 493 # user-specified flags (if any) at the end.  This lets users override
 494 # the automatic additions.
 495 CFLAGS="$CFLAGS $user_CFLAGS"
 496
 497 # Check if the compiler still works with the final flag settings
 498 AC_MSG_CHECKING([whether the C compiler still works])
 499 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 500   [AC_MSG_RESULT(yes)],
 501   [AC_MSG_RESULT(no)
 502    AC_MSG_ERROR([cannot proceed])])
 503
 504 # Defend against gcc -ffast-math
 505 if test "$GCC" = yes; then
 506 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 507 choke me
 508 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 509 fi
 510
 511 AC_PROG_CPP
 512 AC_SUBST(GCC)
 513
 514
 515 #
 516 # Set up TAS assembly code if needed; the template file has now had its
 517 # chance to request this.
 518 #
 519 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 520
 521 if test "$need_tas" = yes ; then
 522   TAS=tas.o
 523 else
 524   TAS=""
 525 fi
 526 AC_SUBST(TAS)
 527
 528
 529 #
 530 # Automatic dependency tracking
 531 #
 532 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 533               [autodepend=yes])
 534 AC_SUBST(autodepend)
 535
 536
 537 #
 538 # Enable assert checks
 539 #
 540 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 541               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 542                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 543
 544
 545 #
 546 # Include directories
 547 #
 548 ac_save_IFS=$IFS
 549 IFS="${IFS}${PATH_SEPARATOR}"
 550 # SRCH_INC comes from the template file
 551 for dir in $with_includes $SRCH_INC; do
 552   if test -d "$dir"; then
 553     INCLUDES="$INCLUDES -I$dir"
 554   else
 555     AC_MSG_WARN([*** Include directory $dir does not exist.])
 556   fi
 557 done
 558 IFS=$ac_save_IFS
 559 AC_SUBST(INCLUDES)
 560
 561
 562 #
 563 # Library directories
 564 #
 565 ac_save_IFS=$IFS
 566 IFS="${IFS}${PATH_SEPARATOR}"
 567 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 568 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 569   if test -d "$dir"; then
 570     LIBDIRS="$LIBDIRS -L$dir"
 571   else
 572     AC_MSG_WARN([*** Library directory $dir does not exist.])
 573   fi
 574 done
 575 IFS=$ac_save_IFS
 576
 577 #
 578 # Enable thread-safe client libraries
 579 #
 580 AC_MSG_CHECKING([allow thread-safe client libraries])
 581 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 582 if test "$enable_thread_safety" = yes; then
 583   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 584           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 585 fi
 586 AC_MSG_RESULT([$enable_thread_safety])
 587 AC_SUBST(enable_thread_safety)
 588
 589 #
 590 # ICU
 591 #
 592 AC_MSG_CHECKING([whether to build with ICU support])
 593 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 594               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 595 AC_MSG_RESULT([$with_icu])
 596 AC_SUBST(with_icu)
 597
 598 if test "$with_icu" = yes; then
 599   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 600 fi
 601
 602 #
 603 # Optionally build Tcl modules (PL/Tcl)
 604 #
 605 AC_MSG_CHECKING([whether to build with Tcl])
 606 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 607 AC_MSG_RESULT([$with_tcl])
 608 AC_SUBST([with_tcl])
 609
 610 # We see if the path to the Tcl/Tk configuration scripts is specified.
 611 # This will override the use of tclsh to find the paths to search.
 612
 613 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 614
 615 #
 616 # Optionally build Perl modules (PL/Perl)
 617 #
 618 AC_MSG_CHECKING([whether to build Perl modules])
 619 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 620 AC_MSG_RESULT([$with_perl])
 621 AC_SUBST(with_perl)
 622
 623 #
 624 # Optionally build Python modules (PL/Python)
 625 #
 626 AC_MSG_CHECKING([whether to build Python modules])
 627 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 628 AC_MSG_RESULT([$with_python])
 629 AC_SUBST(with_python)
 630
 631 #
 632 # GSSAPI
 633 #
 634 AC_MSG_CHECKING([whether to build with GSSAPI support])
 635 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 636 [
 637   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 638   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 639 ])
 640 AC_MSG_RESULT([$with_gssapi])
 641
 642
 643 AC_SUBST(krb_srvtab)
 644
 645
 646 #
 647 # Kerberos configuration parameters
 648 #
 649 PGAC_ARG_REQ(with, krb-srvnam,
 650              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 651              [],
 652              [with_krb_srvnam="postgres"])
 653 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 654                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 655
 656
 657 #
 658 # PAM
 659 #
 660 AC_MSG_CHECKING([whether to build with PAM support])
 661 PGAC_ARG_BOOL(with, pam, no,
 662               [build with PAM support],
 663               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 664 AC_MSG_RESULT([$with_pam])
 665
 666
 667 #
 668 # BSD AUTH
 669 #
 670 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 671 PGAC_ARG_BOOL(with, bsd-auth, no,
 672               [build with BSD Authentication support],
 673               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 674 AC_MSG_RESULT([$with_bsd_auth])
 675
 676
 677 #
 678 # LDAP
 679 #
 680 AC_MSG_CHECKING([whether to build with LDAP support])
 681 PGAC_ARG_BOOL(with, ldap, no,
 682               [build with LDAP support],
 683               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 684 AC_MSG_RESULT([$with_ldap])
 685
 686
 687 #
 688 # Bonjour
 689 #
 690 AC_MSG_CHECKING([whether to build with Bonjour support])
 691 PGAC_ARG_BOOL(with, bonjour, no,
 692               [build with Bonjour support],
 693               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 694 AC_MSG_RESULT([$with_bonjour])
 695
 696
 697 #
 698 # OpenSSL
 699 #
 700 AC_MSG_CHECKING([whether to build with OpenSSL support])
 701 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 702               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 703 AC_MSG_RESULT([$with_openssl])
 704 AC_SUBST(with_openssl)
 705
 706 #
 707 # SELinux
 708 #
 709 AC_MSG_CHECKING([whether to build with SELinux support])
 710 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 711 AC_SUBST(with_selinux)
 712 AC_MSG_RESULT([$with_selinux])
 713
 714 #
 715 # Systemd
 716 #
 717 AC_MSG_CHECKING([whether to build with systemd support])
 718 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 719               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 720 AC_SUBST(with_systemd)
 721 AC_MSG_RESULT([$with_systemd])
 722
 723 #
 724 # Readline
 725 #
 726 PGAC_ARG_BOOL(with, readline, yes,
 727               [do not use GNU Readline nor BSD Libedit for editing])
 728 # readline on MinGW has problems with backslashes in psql and other bugs.
 729 # This is particularly a problem with non-US code pages.
 730 # Therefore disable its use until we understand the cause. 2004-07-20
 731 if test "$PORTNAME" = "win32"; then
 732   if test "$with_readline" = yes; then
 733     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 734     with_readline=no
 735   fi
 736 fi
 737
 738
 739 #
 740 # Prefer libedit
 741 #
 742 PGAC_ARG_BOOL(with, libedit-preferred, no,
 743               [prefer BSD Libedit over GNU Readline])
 744
 745
 746 #
 747 # UUID library
 748 #
 749 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 750 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 751 # UUID library.  More than one of these might be present on a given platform,
 752 # so we make the user say which one she wants.
 753 #
 754 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 755 if test x"$with_uuid" = x"" ; then
 756   with_uuid=no
 757 fi
 758 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 759 if test "$with_ossp_uuid" = yes ; then
 760   with_uuid=ossp
 761 fi
 762
 763 if test "$with_uuid" = bsd ; then
 764   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 765   UUID_EXTRA_OBJS="md5.o sha1.o"
 766 elif test "$with_uuid" = e2fs ; then
 767   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 768   UUID_EXTRA_OBJS="md5.o sha1.o"
 769 elif test "$with_uuid" = ossp ; then
 770   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 771   UUID_EXTRA_OBJS=""
 772 elif test "$with_uuid" = no ; then
 773   UUID_EXTRA_OBJS=""
 774 else
 775   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 776 fi
 777 AC_SUBST(with_uuid)
 778 AC_SUBST(UUID_EXTRA_OBJS)
 779
 780
 781 #
 782 # XML
 783 #
 784 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 785               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 786
 787 if test "$with_libxml" = yes ; then
 788   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 789   if test -n "$XML2_CONFIG"; then
 790     for pgac_option in `$XML2_CONFIG --cflags`; do
 791       case $pgac_option in
 792         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 793       esac
 794     done
 795     for pgac_option in `$XML2_CONFIG --libs`; do
 796       case $pgac_option in
 797         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 798       esac
 799     done
 800   fi
 801 fi
 802
 803 AC_SUBST(with_libxml)
 804
 805 #
 806 # XSLT
 807 #
 808 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 809               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 810
 811
 812 AC_SUBST(with_libxslt)
 813
 814 #
 815 # tzdata
 816 #
 817 PGAC_ARG_REQ(with, system-tzdata,
 818              [DIR], [use system time zone data in DIR])
 819 AC_SUBST(with_system_tzdata)
 820
 821 #
 822 # Zlib
 823 #
 824 PGAC_ARG_BOOL(with, zlib, yes,
 825               [do not use Zlib])
 826 AC_SUBST(with_zlib)
 827
 828 #
 829 # Elf
 830 #
 831
 832 # Assume system is ELF if it predefines __ELF__ as 1,
 833 # otherwise believe host_os based default.
 834 case $host_os in
 835     freebsd1*|freebsd2*) elf=no;;
 836     freebsd3*|freebsd4*) elf=yes;;
 837 esac
 838
 839 AC_EGREP_CPP(yes,
 840 [#if __ELF__
 841   yes
 842 #endif
 843 ],
 844 [ELF_SYS=true],
 845 [if test "X$elf" = "Xyes" ; then
 846   ELF_SYS=true
 847 else
 848   ELF_SYS=
 849 fi])
 850 AC_SUBST(ELF_SYS)
 851
 852 #
 853 # Assignments
 854 #
 855
 856 CPPFLAGS="$CPPFLAGS $INCLUDES"
 857 LDFLAGS="$LDFLAGS $LIBDIRS"
 858
 859 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 860 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 861
 862 PGAC_PROG_LD
 863 AC_SUBST(LD)
 864 AC_SUBST(with_gnu_ld)
 865 AC_PROG_RANLIB
 866 PGAC_CHECK_STRIP
 867 AC_CHECK_TOOL(AR, ar, ar)
 868 if test "$PORTNAME" = "win32"; then
 869   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 870   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 871   AC_CHECK_TOOL(WINDRES, windres, windres)
 872 fi
 873
 874 AC_PROG_INSTALL
 875 # When Autoconf chooses install-sh as install program it tries to generate
 876 # a relative path to it in each makefile where it substitutes it. This clashes
 877 # with our Makefile.global concept. This workaround helps.
 878 case $INSTALL in
 879   *install-sh*) install_bin='';;
 880   *) install_bin=$INSTALL;;
 881 esac
 882 AC_SUBST(install_bin)
 883
 884 PGAC_PATH_PROGS(TAR, tar)
 885 AC_PROG_LN_S
 886 AC_PROG_AWK
 887 AC_PROG_MKDIR_P
 888 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 889 # a relative path to it in each makefile where it substitutes it. This clashes
 890 # with our Makefile.global concept. This workaround helps.
 891 case $MKDIR_P in
 892   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 893 esac
 894
 895 PGAC_PATH_BISON
 896 PGAC_PATH_FLEX
 897
 898 PGAC_PATH_PERL
 899 if test "$with_perl" = yes; then
 900   if test -z "$PERL"; then
 901     AC_MSG_ERROR([Perl not found])
 902   fi
 903   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 904   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 905     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 906 You might have to rebuild your Perl installation.  Refer to the
 907 documentation for details.  Use --without-perl to disable building
 908 PL/Perl.])
 909   fi
 910   PGAC_CHECK_PERL_EMBED_CCFLAGS
 911   PGAC_CHECK_PERL_EMBED_LDFLAGS
 912 fi
 913
 914 if test "$with_python" = yes; then
 915   PGAC_PATH_PYTHON
 916   PGAC_CHECK_PYTHON_EMBED_SETUP
 917 fi
 918
 919 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 920   PGAC_PATH_PROGS(ZIC, zic)
 921   if test -z "$ZIC"; then
 922     AC_MSG_ERROR([
 923 When cross-compiling, either use the option --with-system-tzdata to use
 924 existing time-zone data, or set the environment variable ZIC to a zic
 925 program to use during the build.])
 926   fi
 927 fi
 928
 929 #
 930 # Pthreads
 931 #
 932 # For each platform, we need to know about any special compile and link
 933 # libraries, and whether the normal C function names are thread-safe.
 934 # See the comment at the top of src/port/thread.c for more information.
 935 # WIN32 doesn't need the pthread tests;  it always uses threads
 936 #
 937 # These tests are run before the library-tests, because linking with the
 938 # other libraries can pull in the pthread functions as a side-effect.  We
 939 # want to use the -pthread or similar flags directly, and not rely on
 940 # the side-effects of linking with some other library.
 941 #
 942 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 943 # invocation below is the first one in the script, and autoconf generates
 944 # additional code for that, which must not be inside the if-block. AS_IF
 945 # knows how to do that.
 946 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 947 [ # then
 948 AX_PTHREAD      # set thread flags
 949
 950 # Some platforms use these, so just define them.  They can't hurt if they
 951 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 952 # enables 5-arg getpwuid_r, among other things.
 953 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 954
 955 # Check for *_r functions
 956 _CFLAGS="$CFLAGS"
 957 _LIBS="$LIBS"
 958 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 959 LIBS="$LIBS $PTHREAD_LIBS"
 960
 961 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 962 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 963
 964 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 965
 966 # Do test here with the proper thread flags
 967 PGAC_FUNC_STRERROR_R_INT
 968
 969 CFLAGS="$_CFLAGS"
 970 LIBS="$_LIBS"
 971
 972 ], [ # else
 973 # do not use values from template file
 974 PTHREAD_CFLAGS=
 975 PTHREAD_LIBS=
 976 ]) # fi
 977
 978 AC_SUBST(PTHREAD_CFLAGS)
 979 AC_SUBST(PTHREAD_LIBS)
 980
 981
 982 ##
 983 ## Libraries
 984 ##
 985 ## Most libraries are included only if they demonstrably provide a function
 986 ## we need, but libm is an exception: always include it, because there are
 987 ## too many compilers that play cute optimization games that will break
 988 ## probes for standard functions such as pow().
 989 ##
 990
 991 AC_CHECK_LIB(m, main)
 992 AC_SEARCH_LIBS(setproctitle, util)
 993 AC_SEARCH_LIBS(dlopen, dl)
 994 AC_SEARCH_LIBS(socket, [socket ws2_32])
 995 AC_SEARCH_LIBS(shl_load, dld)
 996 # We only use libld in port/dynloader/aix.c
 997 case $host_os in
 998      aix*)
 999         AC_SEARCH_LIBS(ldopen, ld)
1000         ;;
1001 esac
1002 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1003 AC_SEARCH_LIBS(crypt, crypt)
1004 AC_SEARCH_LIBS(shm_open, rt)
1005 AC_SEARCH_LIBS(shm_unlink, rt)
1006 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1007 # Solaris:
1008 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1009 # Required for thread_test.c on Solaris
1010 AC_SEARCH_LIBS(sched_yield, rt)
1011 # Required for thread_test.c on Solaris 2.5:
1012 # Other ports use it too (HP-UX) so test unconditionally
1013 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1014 # Cygwin:
1015 AC_SEARCH_LIBS(shmget, cygipc)
1016
1017 if test "$with_readline" = yes; then
1018   PGAC_CHECK_READLINE
1019   if test x"$pgac_cv_check_readline" = x"no"; then
1020     AC_MSG_ERROR([readline library not found
1021 If you have readline already installed, see config.log for details on the
1022 failure.  It is possible the compiler isn't looking in the proper directory.
1023 Use --without-readline to disable readline support.])
1024   fi
1025 fi
1026
1027 if test "$with_zlib" = yes; then
1028   AC_CHECK_LIB(z, inflate, [],
1029                [AC_MSG_ERROR([zlib library not found
1030 If you have zlib already installed, see config.log for details on the
1031 failure.  It is possible the compiler isn't looking in the proper directory.
1032 Use --without-zlib to disable zlib support.])])
1033 fi
1034
1035 if test "$enable_spinlocks" = yes; then
1036   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1037 else
1038   AC_MSG_WARN([
1039 *** Not using spinlocks will cause poor performance.])
1040 fi
1041
1042 if test "$enable_atomics" = yes; then
1043   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1044 else
1045   AC_MSG_WARN([
1046 *** Not using atomic operations will cause poor performance.])
1047 fi
1048
1049 if test "$with_gssapi" = yes ; then
1050   if test "$PORTNAME" != "win32"; then
1051     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1052                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1053   else
1054     LIBS="$LIBS -lgssapi32"
1055   fi
1056 fi
1057
1058 if test "$with_openssl" = yes ; then
1059   dnl Order matters!
1060   if test "$PORTNAME" != "win32"; then
1061      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1062      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1063   else
1064      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1065      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1066   fi
1067   AC_CHECK_FUNCS([SSL_get_current_compression X509_get_signature_nid])
1068   # Functions introduced in OpenSSL 1.1.0. We used to check for
1069   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1070   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1071   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1072   # functions.
1073   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1074   # OpenSSL versions before 1.1.0 required setting callback functions, for
1075   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1076   # function was removed.
1077   AC_CHECK_FUNCS([CRYPTO_lock])
1078 fi
1079
1080 if test "$with_pam" = yes ; then
1081   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1082 fi
1083
1084 if test "$with_libxml" = yes ; then
1085   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1086 fi
1087
1088 if test "$with_libxslt" = yes ; then
1089   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1090 fi
1091
1092 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1093 if test "$with_ldap" = yes ; then
1094   _LIBS="$LIBS"
1095   if test "$PORTNAME" != "win32"; then
1096     AC_CHECK_LIB(ldap, ldap_bind, [],
1097                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1098                  [$EXTRA_LDAP_LIBS])
1099     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1100     if test "$enable_thread_safety" = yes; then
1101       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1102       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1103                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1104                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1105       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1106     else
1107       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1108     fi
1109     AC_CHECK_FUNCS([ldap_initialize])
1110   else
1111     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1112     LDAP_LIBS_FE="-lwldap32"
1113     LDAP_LIBS_BE="-lwldap32"
1114   fi
1115   LIBS="$_LIBS"
1116 fi
1117 AC_SUBST(LDAP_LIBS_FE)
1118 AC_SUBST(LDAP_LIBS_BE)
1119
1120 # for contrib/sepgsql
1121 if test "$with_selinux" = yes; then
1122   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1123                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1124 fi
1125
1126 # for contrib/uuid-ossp
1127 if test "$with_uuid" = bsd ; then
1128   # On BSD, the UUID functions are in libc
1129   AC_CHECK_FUNC(uuid_to_string,
1130     [UUID_LIBS=""],
1131     [AC_MSG_ERROR([BSD UUID functions are not present])])
1132 elif test "$with_uuid" = e2fs ; then
1133   # On macOS, the UUID functions are in libc
1134   AC_CHECK_FUNC(uuid_generate,
1135     [UUID_LIBS=""],
1136     [AC_CHECK_LIB(uuid, uuid_generate,
1137       [UUID_LIBS="-luuid"],
1138       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1139 elif test "$with_uuid" = ossp ; then
1140   AC_CHECK_LIB(ossp-uuid, uuid_export,
1141     [UUID_LIBS="-lossp-uuid"],
1142     [AC_CHECK_LIB(uuid, uuid_export,
1143       [UUID_LIBS="-luuid"],
1144       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1145 fi
1146 AC_SUBST(UUID_LIBS)
1147
1148
1149 ##
1150 ## Header files
1151 ##
1152
1153 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1154
1155 # On BSD, test for net/if.h will fail unless sys/socket.h
1156 # is included first.
1157 AC_CHECK_HEADERS(net/if.h, [], [],
1158 [AC_INCLUDES_DEFAULT
1159 #include <sys/socket.h>
1160 ])
1161
1162 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1163 # is included first.
1164 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1165 [AC_INCLUDES_DEFAULT
1166 #include <sys/param.h>
1167 ])
1168
1169 # At least on IRIX, test for netinet/tcp.h will fail unless
1170 # netinet/in.h is included first.
1171 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1172 [AC_INCLUDES_DEFAULT
1173 #include <netinet/in.h>
1174 ])
1175
1176 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1177   AC_CHECK_HEADERS(readline/readline.h, [],
1178         [AC_CHECK_HEADERS(readline.h, [],
1179                 [AC_MSG_ERROR([readline header not found
1180 If you have readline already installed, see config.log for details on the
1181 failure.  It is possible the compiler isn't looking in the proper directory.
1182 Use --without-readline to disable readline support.])])])
1183   AC_CHECK_HEADERS(readline/history.h, [],
1184         [AC_CHECK_HEADERS(history.h, [],
1185                 [AC_MSG_ERROR([history header not found
1186 If you have readline already installed, see config.log for details on the
1187 failure.  It is possible the compiler isn't looking in the proper directory.
1188 Use --without-readline to disable readline support.])])])
1189 fi
1190
1191 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1192 # Some installations of libedit usurp /usr/include/readline/, which seems
1193 # bad practice, since in combined installations readline will have its headers
1194 # there.  We might have to resort to AC_EGREP checks to make sure we found
1195 # the proper header...
1196   AC_CHECK_HEADERS(editline/readline.h, [],
1197         [AC_CHECK_HEADERS(readline.h, [],
1198                 [AC_CHECK_HEADERS(readline/readline.h, [],
1199                         [AC_MSG_ERROR([readline header not found
1200 If you have libedit already installed, see config.log for details on the
1201 failure.  It is possible the compiler isn't looking in the proper directory.
1202 Use --without-readline to disable libedit support.])])])])
1203 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1204 # not be there at all.  Hence, don't complain if not found.  We must check
1205 # though, since in yet other versions it is an independent header.
1206   AC_CHECK_HEADERS(editline/history.h, [],
1207         [AC_CHECK_HEADERS(history.h, [],
1208                 [AC_CHECK_HEADERS(readline/history.h)])])
1209 fi
1210
1211 if test "$with_zlib" = yes; then
1212   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1213 If you have zlib already installed, see config.log for details on the
1214 failure.  It is possible the compiler isn't looking in the proper directory.
1215 Use --without-zlib to disable zlib support.])])
1216 fi
1217
1218 if test "$with_gssapi" = yes ; then
1219   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1220         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1221 fi
1222
1223 if test "$with_openssl" = yes ; then
1224   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1225   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1226 fi
1227
1228 if test "$with_pam" = yes ; then
1229   AC_CHECK_HEADERS(security/pam_appl.h, [],
1230                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1231                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1232 fi
1233
1234 if test "$with_bsd_auth" = yes ; then
1235   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1236 fi
1237
1238 if test "$with_systemd" = yes ; then
1239   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1240 fi
1241
1242 if test "$with_libxml" = yes ; then
1243   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1244 fi
1245
1246 if test "$with_libxslt" = yes ; then
1247   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1248 fi
1249
1250 if test "$with_ldap" = yes ; then
1251   if test "$PORTNAME" != "win32"; then
1252      AC_CHECK_HEADERS(ldap.h, [],
1253                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1254      PGAC_LDAP_SAFE
1255   else
1256      AC_CHECK_HEADERS(winldap.h, [],
1257                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1258                       [AC_INCLUDES_DEFAULT
1259 #include <windows.h>
1260                       ])
1261   fi
1262 fi
1263
1264 if test "$with_bonjour" = yes ; then
1265   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1266 dnl At some point we might add something like
1267 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1268 dnl but right now, what that would mainly accomplish is to encourage
1269 dnl people to try to use the avahi implementation, which does not work.
1270 dnl If you want to use Apple's own Bonjour code on another platform,
1271 dnl just add -ldns_sd to LIBS manually.
1272 fi
1273
1274 # for contrib/uuid-ossp
1275 if test "$with_uuid" = bsd ; then
1276   AC_CHECK_HEADERS(uuid.h,
1277     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1278       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1279     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1280 elif test "$with_uuid" = e2fs ; then
1281   AC_CHECK_HEADERS(uuid/uuid.h,
1282     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1283       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1284     [AC_CHECK_HEADERS(uuid.h,
1285       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1286         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1287       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1288 elif test "$with_uuid" = ossp ; then
1289   AC_CHECK_HEADERS(ossp/uuid.h,
1290     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1291       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1292     [AC_CHECK_HEADERS(uuid.h,
1293       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1294         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1295       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1296 fi
1297
1298 if test "$PORTNAME" = "win32" ; then
1299    AC_CHECK_HEADERS(crtdefs.h)
1300 fi
1301
1302 ##
1303 ## Types, structures, compiler characteristics
1304 ##
1305
1306 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1307 AC_C_BIGENDIAN
1308 AC_C_INLINE
1309 PGAC_PRINTF_ARCHETYPE
1310 AC_C_FLEXIBLE_ARRAY_MEMBER
1311 PGAC_C_SIGNED
1312 PGAC_C_FUNCNAME_SUPPORT
1313 PGAC_C_STATIC_ASSERT
1314 PGAC_C_TYPEOF
1315 PGAC_C_TYPES_COMPATIBLE
1316 PGAC_C_BUILTIN_BSWAP16
1317 PGAC_C_BUILTIN_BSWAP32
1318 PGAC_C_BUILTIN_BSWAP64
1319 PGAC_C_BUILTIN_CONSTANT_P
1320 PGAC_C_BUILTIN_UNREACHABLE
1321 PGAC_C_COMPUTED_GOTO
1322 PGAC_C_VA_ARGS
1323 PGAC_STRUCT_TIMEZONE
1324 PGAC_UNION_SEMUN
1325 PGAC_STRUCT_SOCKADDR_UN
1326 PGAC_STRUCT_SOCKADDR_STORAGE
1327 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1328 PGAC_STRUCT_ADDRINFO
1329 AC_TYPE_INTPTR_T
1330 AC_TYPE_UINTPTR_T
1331 AC_TYPE_LONG_LONG_INT
1332
1333 PGAC_TYPE_LOCALE_T
1334
1335 # MSVC doesn't cope well with defining restrict to __restrict, the
1336 # spelling it understands, because it conflicts with
1337 # __declspec(restrict). Therefore we define pg_restrict to the
1338 # appropriate definition, which presumably won't conflict.
1339 #
1340 # Allow platforms with buggy compilers to force restrict to not be
1341 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1342 # template.
1343 AC_C_RESTRICT
1344 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1345   pg_restrict=""
1346 else
1347   pg_restrict="$ac_cv_c_restrict"
1348 fi
1349 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1350 [Define to keyword to use for C99 restrict support, or to nothing if not
1351 supported])
1352
1353 AC_CHECK_TYPES([struct cmsgcred], [], [],
1354 [#include <sys/socket.h>
1355 #include <sys/param.h>
1356 #ifdef HAVE_SYS_UCRED_H
1357 #include <sys/ucred.h>
1358 #endif])
1359
1360 AC_CHECK_TYPES([struct option], [], [],
1361 [#ifdef HAVE_GETOPT_H
1362 #include <getopt.h>
1363 #endif])
1364
1365 if test "$with_zlib" = yes; then
1366   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1367   # did not).  While we could work around the lack of z_streamp, it
1368   # seems unwise to encourage people to use such old zlib versions...
1369   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1370 Use --without-zlib to disable zlib support.])],
1371                 [#include <zlib.h>])
1372 fi
1373
1374 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1375 case $host_cpu in
1376   ppc*|powerpc*)
1377     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1378     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1379         [int a = 0; int *p = &a; int r;
1380          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1381         [pgac_cv_have_ppc_mutex_hint=yes],
1382         [pgac_cv_have_ppc_mutex_hint=no])
1383     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1384     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1385         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1386     fi
1387   ;;
1388 esac
1389
1390 # Check largefile support.  You might think this is a system service not a
1391 # compiler characteristic, but you'd be wrong.  We must check this before
1392 # probing existence of related functions such as fseeko, since the largefile
1393 # defines can affect what is generated for that.
1394 if test "$PORTNAME" != "win32"; then
1395    AC_SYS_LARGEFILE
1396    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1397    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1398    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1399    dnl versions where the feature actually works, it's on by default anyway.
1400    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1401 fi
1402
1403 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1404 AC_CHECK_SIZEOF([off_t])
1405
1406 # If we don't have largefile support, can't handle segsize >= 2GB.
1407 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1408    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1409 fi
1410
1411
1412 ##
1413 ## Functions, global variables
1414 ##
1415
1416 PGAC_VAR_INT_TIMEZONE
1417 AC_FUNC_ACCEPT_ARGTYPES
1418 PGAC_FUNC_GETTIMEOFDAY_1ARG
1419 PGAC_FUNC_WCSTOMBS_L
1420
1421 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1422 # symbols that that library has no business exposing to the world.  Pending
1423 # acquisition of a clue by those developers, ignore libedit (including its
1424 # possible alias of libreadline) while checking for everything else.
1425 LIBS_including_readline="$LIBS"
1426 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1427
1428 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1429
1430 AC_REPLACE_FUNCS(fseeko)
1431 case $host_os in
1432         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1433         # Mingw uses macros to access Win32 API calls
1434         netbsd*|mingw*)
1435                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1436                 ac_cv_func_fseeko=yes;;
1437         *)
1438                 AC_FUNC_FSEEKO;;
1439 esac
1440
1441 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1442 # by calling it, 2009-04-02
1443 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1444 if test "$PORTNAME" != "solaris"; then
1445 AC_CHECK_FUNCS(posix_fadvise)
1446 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1447 fi
1448
1449 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1450 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1451 # This is probably only present on macOS, but may as well check always
1452 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1453
1454 HAVE_IPV6=no
1455 AC_CHECK_TYPE([struct sockaddr_in6],
1456         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1457          HAVE_IPV6=yes],
1458         [],
1459 [$ac_includes_default
1460 #include <netinet/in.h>])
1461 AC_SUBST(HAVE_IPV6)
1462
1463 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1464 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1465 [#include <machine/vmparam.h>
1466 #include <sys/exec.h>
1467 ],
1468 [PS_STRINGS->ps_nargvstr = 1;
1469 PS_STRINGS->ps_argvstr = "foo";])],
1470 [pgac_cv_var_PS_STRINGS=yes],
1471 [pgac_cv_var_PS_STRINGS=no])])
1472 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1473   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1474 fi
1475
1476
1477 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1478 # is missing.  Yes, there are machines that have only one.  We may
1479 # also decide to use snprintf.c if snprintf() is present but does not
1480 # have all the features we need --- see below.
1481
1482 if test "$PORTNAME" = "win32"; then
1483   # Win32 gets snprintf.c built unconditionally.
1484   #
1485   # To properly translate all NLS languages strings, we must support the
1486   # *printf() %$ format, which allows *printf() arguments to be selected
1487   # by position in the translated string.
1488   #
1489   # libintl versions < 0.13 use the native *printf() functions, and Win32
1490   # *printf() doesn't understand %$, so we must use our /port versions,
1491   # which do understand %$. libintl versions >= 0.13 include their own
1492   # *printf versions on Win32.  The libintl 0.13 release note text is:
1493   #
1494   #   C format strings with positions, as they arise when a translator
1495   #   needs to reorder a sentence, are now supported on all platforms.
1496   #   On those few platforms (NetBSD and Woe32) for which the native
1497   #   printf()/fprintf()/... functions don't support such format
1498   #   strings, replacements are provided through <libintl.h>.
1499   #
1500   # We could use libintl >= 0.13's *printf() if we were sure that we had
1501   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1502   # to guarantee that, it is best to just use our own, so we are sure to
1503   # get %$ support. In include/port.h we disable the *printf() macros
1504   # that might have been defined by libintl.
1505   #
1506   # We do this unconditionally whether NLS is used or not so we are sure
1507   # that all Win32 libraries and binaries behave the same.
1508   pgac_need_repl_snprintf=yes
1509 else
1510   pgac_need_repl_snprintf=no
1511   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1512   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1513 fi
1514
1515
1516 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1517 # include/c.h will provide declarations.  Note this is a separate test
1518 # from whether the functions exist in the C library --- there are
1519 # systems that have the functions but don't bother to declare them :-(
1520
1521 AC_CHECK_DECLS([snprintf, vsnprintf])
1522
1523
1524 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1525 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1526 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1527 #include <math.h>
1528 double glob_double;
1529 ],
1530 [return isinf(glob_double) ? 0 : 1;])],
1531 [ac_cv_func_isinf=yes],
1532 [ac_cv_func_isinf=no])])
1533
1534 if test $ac_cv_func_isinf = yes ; then
1535   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1536 else
1537   AC_LIBOBJ(isinf)
1538   # Look for a way to implement a substitute for isinf()
1539   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1540 fi
1541
1542 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1543
1544 case $host_os in
1545
1546         # Windows uses a specialised env handler
1547         # and doesn't need a replacement getpeereid because it doesn't use
1548         # Unix sockets.
1549         mingw*)
1550                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1551                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1552                 ac_cv_func_unsetenv=yes
1553                 ac_cv_func_getpeereid=yes;;
1554         *)
1555                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1556                 ;;
1557 esac
1558
1559 # System's version of getaddrinfo(), if any, may be used only if we found
1560 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1561 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1562 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1563    test "$PORTNAME" != "win32"; then
1564   AC_REPLACE_FUNCS([getaddrinfo])
1565 else
1566   AC_LIBOBJ(getaddrinfo)
1567 fi
1568
1569 # Similarly, use system's getopt_long() only if system provides struct option.
1570 if test x"$ac_cv_type_struct_option" = xyes ; then
1571   AC_REPLACE_FUNCS([getopt_long])
1572 else
1573   AC_LIBOBJ(getopt_long)
1574 fi
1575
1576 # Solaris' getopt() doesn't do what we want for long options, so always use
1577 # our version on that platform.
1578 if test "$PORTNAME" = "solaris"; then
1579   AC_LIBOBJ(getopt)
1580 fi
1581
1582 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1583 # so always use our version on Windows.
1584 if test "$PORTNAME" = "win32"; then
1585   AC_LIBOBJ(getopt)
1586   AC_LIBOBJ(getopt_long)
1587 fi
1588
1589 # Win32 (really MinGW) support
1590 if test "$PORTNAME" = "win32"; then
1591   AC_REPLACE_FUNCS(gettimeofday)
1592   AC_LIBOBJ(dirmod)
1593   AC_LIBOBJ(kill)
1594   AC_LIBOBJ(open)
1595   AC_LIBOBJ(system)
1596   AC_LIBOBJ(win32env)
1597   AC_LIBOBJ(win32error)
1598   AC_LIBOBJ(win32security)
1599   AC_LIBOBJ(win32setlocale)
1600   AC_DEFINE([HAVE_SYMLINK], 1,
1601             [Define to 1 if you have the `symlink' function.])
1602   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1603 #define WIN32_LEAN_AND_MEAN
1604 #include <windows.h>
1605 #include <string.h>
1606 #include <dbghelp.h>])
1607 fi
1608 if test x"$pgac_minidump_type" = x"yes" ; then
1609   AC_SUBST(have_win32_dbghelp,yes)
1610 else
1611   AC_SUBST(have_win32_dbghelp,no)
1612 fi
1613
1614 # Cygwin needs only a bit of that
1615 if test "$PORTNAME" = "cygwin"; then
1616   AC_LIBOBJ(dirmod)
1617 fi
1618
1619 AC_CHECK_DECLS([sys_siglist], [], [],
1620 [#include <signal.h>
1621 /* NetBSD declares sys_siglist in unistd.h.  */
1622 #ifdef HAVE_UNISTD_H
1623 # include <unistd.h>
1624 #endif
1625 ])
1626
1627 AC_CHECK_FUNC(syslog,
1628               [AC_CHECK_HEADER(syslog.h,
1629                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1630
1631 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1632 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1633   [extern int opterr; opterr = 1;])],
1634   [pgac_cv_var_int_opterr=yes],
1635   [pgac_cv_var_int_opterr=no])])
1636 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1637   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1638 fi
1639
1640 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1641 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1642   [extern int optreset; optreset = 1;])],
1643   [pgac_cv_var_int_optreset=yes],
1644   [pgac_cv_var_int_optreset=no])])
1645 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1646   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1647 fi
1648
1649 AC_CHECK_FUNCS([strtoll strtoq], [break])
1650 AC_CHECK_FUNCS([strtoull strtouq], [break])
1651
1652 if test "$with_icu" = yes; then
1653   ac_save_CPPFLAGS=$CPPFLAGS
1654   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1655
1656   # Verify we have ICU's header files
1657   AC_CHECK_HEADER(unicode/ucol.h, [],
1658         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1659
1660   CPPFLAGS=$ac_save_CPPFLAGS
1661 fi
1662
1663 # Lastly, restore full LIBS list and check for readline/libedit symbols
1664 LIBS="$LIBS_including_readline"
1665
1666 if test "$with_readline" = yes; then
1667   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1668   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1669   AC_CHECK_FUNCS([append_history history_truncate_file])
1670 fi
1671
1672
1673 # This test makes sure that run tests work at all.  Sometimes a shared
1674 # library is found by the linker, but the runtime linker can't find it.
1675 # This check should come after all modifications of compiler or linker
1676 # variables, and before any other run tests.
1677 AC_MSG_CHECKING([test program])
1678 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1679 [AC_MSG_RESULT(ok)],
1680 [AC_MSG_RESULT(failed)
1681 AC_MSG_ERROR([[
1682 Could not execute a simple test program.  This may be a problem
1683 related to locating shared libraries.  Check the file 'config.log'
1684 for the exact reason.]])],
1685 [AC_MSG_RESULT([cross-compiling])])
1686
1687 # --------------------
1688 # Run tests below here
1689 # --------------------
1690
1691 # Force use of our snprintf if system's doesn't do arg control
1692 # See comment above at snprintf test for details.
1693 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1694   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1695   if test $pgac_cv_snprintf_arg_control != yes ; then
1696     pgac_need_repl_snprintf=yes
1697   fi
1698 fi
1699
1700
1701 dnl Check to see if we have a working 64-bit integer type.
1702 dnl This breaks down into two steps:
1703 dnl (1) figure out if the compiler has a 64-bit int type with working
1704 dnl arithmetic, and if so
1705 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1706 dnl snprintf is the only library routine we really need for int8 support.)
1707 dnl It's entirely possible to have a compiler that handles a 64-bit type
1708 dnl when the C library doesn't; this is fairly likely when using gcc on
1709 dnl an older platform, for example.
1710 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1711 dnl we force our own version of snprintf() to be used instead.
1712 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1713
1714 dnl As of Postgres 8.4, we no longer support compilers without a working
1715 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1716
1717 PGAC_TYPE_64BIT_INT([long int])
1718
1719 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1720   pg_int64_type="long int"
1721 else
1722   PGAC_TYPE_64BIT_INT([long long int])
1723   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1724     pg_int64_type="long long int"
1725   else
1726     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1727   fi
1728 fi
1729
1730 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1731   [Define to the name of a signed 64-bit integer type.])
1732
1733 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1734 # we found we need to use "long long int", better check.  We cope with
1735 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1736 # work, fall back to our own snprintf emulation (which we know uses %lld).
1737
1738 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1739   if test $pgac_need_repl_snprintf = no; then
1740     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1741     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1742       # Force usage of our own snprintf, since system snprintf is broken
1743       pgac_need_repl_snprintf=yes
1744       LONG_LONG_INT_MODIFIER='ll'
1745     fi
1746   else
1747     # Here if we previously decided we needed to use our own snprintf
1748     LONG_LONG_INT_MODIFIER='ll'
1749   fi
1750 else
1751   # Here if we are not using 'long long int' at all
1752   LONG_LONG_INT_MODIFIER='l'
1753 fi
1754
1755 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1756
1757 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1758                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1759
1760 # Also force use of our snprintf if the system's doesn't support the %z flag.
1761 if test "$pgac_need_repl_snprintf" = no; then
1762   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1763   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1764     pgac_need_repl_snprintf=yes
1765   fi
1766 fi
1767
1768 # Now we have checked all the reasons to replace snprintf
1769 if test $pgac_need_repl_snprintf = yes; then
1770   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1771   AC_LIBOBJ(snprintf)
1772 fi
1773
1774 # has to be down here, rather than with the other builtins, because
1775 # the test uses PG_INT64_TYPE.
1776 PGAC_C_BUILTIN_OP_OVERFLOW
1777
1778 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1779 AC_CHECK_SIZEOF([void *])
1780 AC_CHECK_SIZEOF([size_t])
1781 AC_CHECK_SIZEOF([long])
1782
1783 # Decide whether float4 is passed by value: user-selectable, enabled by default
1784 AC_MSG_CHECKING([whether to build with float4 passed by value])
1785 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1786               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1787                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1788                float4passbyval=true],
1789               [float4passbyval=false])
1790 AC_MSG_RESULT([$enable_float4_byval])
1791 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1792
1793 # Decide whether float8 is passed by value.
1794 # Note: this setting also controls int8 and related types such as timestamp.
1795 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1796 # If not, trying to select it is an error.
1797 AC_MSG_CHECKING([whether to build with float8 passed by value])
1798 if test $ac_cv_sizeof_void_p -ge 8 ; then
1799   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1800 else
1801   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1802   if test "$enable_float8_byval" = yes ; then
1803     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1804   fi
1805 fi
1806 if test "$enable_float8_byval" = yes ; then
1807   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1808             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1809   float8passbyval=true
1810 else
1811   float8passbyval=false
1812 fi
1813 AC_MSG_RESULT([$enable_float8_byval])
1814 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1815
1816 # Determine memory alignment requirements for the basic C data types.
1817
1818 AC_CHECK_ALIGNOF(short)
1819 AC_CHECK_ALIGNOF(int)
1820 AC_CHECK_ALIGNOF(long)
1821 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1822   AC_CHECK_ALIGNOF(long long int)
1823 fi
1824 AC_CHECK_ALIGNOF(double)
1825
1826 # Compute maximum alignment of any basic type.
1827 # We assume long's alignment is at least as strong as char, short, or int;
1828 # but we must check long long (if it is being used for int64) and double.
1829 # Note that we intentionally do not consider any types wider than 64 bits,
1830 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1831 # for disk and memory space.
1832
1833 MAX_ALIGNOF=$ac_cv_alignof_long
1834 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1835   MAX_ALIGNOF=$ac_cv_alignof_double
1836 fi
1837 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1838   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1839 fi
1840 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1841
1842
1843 # Some platforms predefine the types int8, int16, etc.  Only check
1844 # a (hopefully) representative subset.
1845 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1846 [#include <stdio.h>])
1847
1848 # Some compilers offer a 128-bit integer scalar type.
1849 PGAC_TYPE_128BIT_INT
1850
1851 # Check for various atomic operations now that we have checked how to declare
1852 # 64bit integers.
1853 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1854 PGAC_HAVE_GCC__SYNC_INT32_TAS
1855 PGAC_HAVE_GCC__SYNC_INT32_CAS
1856 PGAC_HAVE_GCC__SYNC_INT64_CAS
1857 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1858 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1859
1860
1861 # Check for x86 cpuid instruction
1862 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1863 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1864   [[unsigned int exx[4] = {0, 0, 0, 0};
1865   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1866   ]])],
1867   [pgac_cv__get_cpuid="yes"],
1868   [pgac_cv__get_cpuid="no"])])
1869 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1870   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1871 fi
1872
1873 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1874 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1875   [[unsigned int exx[4] = {0, 0, 0, 0};
1876   __get_cpuid(exx[0], 1);
1877   ]])],
1878   [pgac_cv__cpuid="yes"],
1879   [pgac_cv__cpuid="no"])])
1880 if test x"$pgac_cv__cpuid" = x"yes"; then
1881   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1882 fi
1883
1884 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1885 #
1886 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1887 # with the default compiler flags. If not, check if adding the -msse4.2
1888 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1889 PGAC_SSE42_CRC32_INTRINSICS([])
1890 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1891   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1892 fi
1893 AC_SUBST(CFLAGS_SSE42)
1894
1895 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1896 # define __SSE4_2__ in that case.
1897 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1898 #ifndef __SSE4_2__
1899 #error __SSE4_2__ not defined
1900 #endif
1901 ])], [SSE4_2_TARGETED=1])
1902
1903 # Select CRC-32C implementation.
1904 #
1905 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1906 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1907 # a processor, but we can nevertheless produce code that uses the SSE
1908 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1909 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1910 # by the processor we're running on.
1911 #
1912 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1913 # in the template or configure command line.
1914 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1915   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1916     USE_SSE42_CRC32C=1
1917   else
1918     # the CPUID instruction is needed for the runtime check.
1919     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1920       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1921     else
1922       # fall back to slicing-by-8 algorithm which doesn't require any special
1923       # CPU support.
1924       USE_SLICING_BY_8_CRC32C=1
1925     fi
1926   fi
1927 fi
1928
1929 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1930 AC_MSG_CHECKING([which CRC-32C implementation to use])
1931 if test x"$USE_SSE42_CRC32C" = x"1"; then
1932   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1933   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1934   AC_MSG_RESULT(SSE 4.2)
1935 else
1936   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1937     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1938     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1939     AC_MSG_RESULT(SSE 4.2 with runtime check)
1940   else
1941     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1942     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1943     AC_MSG_RESULT(slicing-by-8)
1944   fi
1945 fi
1946 AC_SUBST(PG_CRC32C_OBJS)
1947
1948
1949 # Select semaphore implementation type.
1950 if test "$PORTNAME" != "win32"; then
1951   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1952     # Need sem_open for this
1953     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1954   fi
1955   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1956     # Need sem_init for this
1957     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1958   fi
1959   AC_MSG_CHECKING([which semaphore API to use])
1960   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1961     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1962     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1963     sematype="named POSIX"
1964   else
1965     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1966       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1967       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1968       sematype="unnamed POSIX"
1969     else
1970       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1971       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1972       sematype="System V"
1973     fi
1974   fi
1975   AC_MSG_RESULT([$sematype])
1976 else
1977   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1978   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1979 fi
1980
1981
1982 # Select shared-memory implementation type.
1983 if test "$PORTNAME" != "win32"; then
1984   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1985   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1986 else
1987   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1988   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1989 fi
1990
1991 # Select random number source
1992 #
1993 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
1994 # in the template or configure command line.
1995
1996 # If not selected manually, try to select a source automatically.
1997 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
1998   if test x"$with_openssl" = x"yes" ; then
1999     USE_OPENSSL_RANDOM=1
2000   elif test "$PORTNAME" = "win32" ; then
2001     USE_WIN32_RANDOM=1
2002   else
2003     AC_CHECK_FILE([/dev/urandom], [], [])
2004
2005     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2006       USE_DEV_URANDOM=1
2007     fi
2008   fi
2009 fi
2010
2011 AC_MSG_CHECKING([which random number source to use])
2012 if test "$enable_strong_random" = yes ; then
2013   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2014     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2015     AC_MSG_RESULT([OpenSSL])
2016   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2017     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2018     AC_MSG_RESULT([Windows native])
2019   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2020     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2021     AC_MSG_RESULT([/dev/urandom])
2022   else
2023     AC_MSG_ERROR([
2024 no source of strong random numbers was found
2025 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2026 for authentication protocols. You can use --disable-strong-random to use a
2027 built-in pseudo random number generator, but that may be insecure.])
2028   fi
2029   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2030 else
2031     AC_MSG_RESULT([weak builtin PRNG])
2032     AC_MSG_WARN([
2033 *** Not using a strong random number source may be insecure.])
2034 fi
2035
2036 # If not set in template file, set bytes to use libc memset()
2037 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2038   MEMSET_LOOP_LIMIT=1024
2039 fi
2040 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2041
2042
2043 if test "$enable_nls" = yes ; then
2044   PGAC_CHECK_GETTEXT
2045 fi
2046
2047 # Check for Tcl configuration script tclConfig.sh
2048 if test "$with_tcl" = yes; then
2049     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2050     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2051                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2052     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2053     if test "$TCL_SHARED_BUILD" != 1; then
2054       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2055 Use --without-tcl to disable building PL/Tcl.])
2056     fi
2057     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2058     ac_save_CPPFLAGS=$CPPFLAGS
2059     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2060     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2061     CPPFLAGS=$ac_save_CPPFLAGS
2062 fi
2063
2064 # check for <perl.h>
2065 if test "$with_perl" = yes; then
2066   ac_save_CPPFLAGS=$CPPFLAGS
2067   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2068   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2069                   [#include <EXTERN.h>])
2070   # While we're at it, check that we can link to libperl.
2071   # On most platforms, if perl.h is there then libperl.so will be too, but at
2072   # this writing Debian packages them separately.  There is no known reason to
2073   # waste cycles on separate probes for the Tcl or Python libraries, though.
2074   pgac_save_LIBS=$LIBS
2075   LIBS="$perl_embed_ldflags"
2076   AC_MSG_CHECKING([for libperl])
2077   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2078 #include <EXTERN.h>
2079 #include <perl.h>
2080 ],  [perl_alloc();])],
2081     [AC_MSG_RESULT(yes)],
2082     [AC_MSG_RESULT(no)
2083      AC_MSG_ERROR([libperl library is required for Perl])])
2084   LIBS=$pgac_save_LIBS
2085   CPPFLAGS=$ac_save_CPPFLAGS
2086 fi
2087
2088 # check for <Python.h>
2089 if test "$with_python" = yes; then
2090   ac_save_CPPFLAGS=$CPPFLAGS
2091   CPPFLAGS="$python_includespec $CPPFLAGS"
2092   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2093   CPPFLAGS=$ac_save_CPPFLAGS
2094 fi
2095
2096 #
2097 # Check for DocBook and tools
2098 #
2099 PGAC_PATH_XMLLINT
2100 PGAC_CHECK_DOCBOOK(4.2)
2101 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2102 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2103 PGAC_PATH_PROGS(FOP, fop)
2104
2105 #
2106 # Check for test tools
2107 #
2108 if test "$enable_tap_tests" = yes; then
2109   # Check for necessary modules, unless user has specified the "prove" to use;
2110   # in that case it's her responsibility to have a working configuration.
2111   # (prove might be part of a different Perl installation than perl, eg on
2112   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2113   if test -z "$PROVE"; then
2114     AX_PROG_PERL_MODULES(IPC::Run, ,
2115       AC_MSG_ERROR([Perl module IPC::Run is required to run TAP tests]))
2116   fi
2117   # Now make sure we know where prove is
2118   PGAC_PATH_PROGS(PROVE, prove)
2119   if test -z "$PROVE"; then
2120     AC_MSG_ERROR([prove not found])
2121   fi
2122 fi
2123
2124 # Thread testing
2125
2126 # We have to run the thread test near the end so we have all our symbols
2127 # defined.  Cross compiling throws a warning.
2128 #
2129 if test "$enable_thread_safety" = yes; then
2130 if test "$PORTNAME" != "win32"
2131 then
2132 AC_MSG_CHECKING([thread safety of required library functions])
2133
2134 _CFLAGS="$CFLAGS"
2135 _LIBS="$LIBS"
2136 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2137 LIBS="$LIBS $PTHREAD_LIBS"
2138 AC_RUN_IFELSE(
2139   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2140   [AC_MSG_RESULT(yes)],
2141   [AC_MSG_RESULT(no)
2142   AC_MSG_ERROR([thread test program failed
2143 This platform is not thread-safe.  Check the file 'config.log' or compile
2144 and run src/test/thread/thread_test for the exact reason.
2145 Use --disable-thread-safety to disable thread safety.])],
2146   [AC_MSG_RESULT(maybe)
2147   AC_MSG_WARN([
2148 *** Skipping thread test program because of cross-compile build.
2149 *** Run the program in src/test/thread on the target machine.
2150 ])])
2151 CFLAGS="$_CFLAGS"
2152 LIBS="$_LIBS"
2153 else
2154 AC_MSG_WARN([*** skipping thread test on Win32])
2155 fi
2156 fi
2157
2158 # If compiler will take -Wl,--as-needed (or various platform-specific
2159 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2160 # trying to filter LIBS to the minimum for each executable.
2161 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2162 # libreadline; therefore we postpone testing it until we know what library
2163 # dependencies readline has.  The test code will try to link with $LIBS.
2164 if test "$with_readline" = yes; then
2165   link_test_func=readline
2166 else
2167   link_test_func=exit
2168 fi
2169
2170 if test "$PORTNAME" = "darwin"; then
2171   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2172 elif test "$PORTNAME" = "openbsd"; then
2173   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2174 else
2175   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2176 fi
2177
2178 # Create compiler version string
2179 if test x"$GCC" = x"yes" ; then
2180   cc_string=`${CC} --version | sed q`
2181   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2182 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2183   cc_string=`${CC} -V 2>&1 | sed q`
2184 else
2185   cc_string=$CC
2186 fi
2187
2188 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2189                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2190                    [A string containing the version number, platform, and C compiler])
2191
2192 # Supply a numeric version string for use by 3rd party add-ons
2193 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2194 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2195 tr '.' '        ' |
2196 $AWK '{printf "%d%04d", $1, $2}'`"]
2197 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2198 AC_SUBST(PG_VERSION_NUM)
2199
2200
2201 # Begin output steps
2202
2203 AC_MSG_NOTICE([using compiler=$cc_string])
2204 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2205 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2206 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2207
2208 # prepare build tree if outside source tree
2209 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2210 # Note 2: /bin/pwd might be better than shell's built-in at getting
2211 #         a symlink-free name.
2212 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2213   vpath_build=no
2214 else
2215   vpath_build=yes
2216   if test "$no_create" != yes; then
2217     _AS_ECHO_N([preparing build tree... ])
2218     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2219     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2220       || AC_MSG_ERROR(failed)
2221     AC_MSG_RESULT(done)
2222   fi
2223 fi
2224 AC_SUBST(vpath_build)
2225
2226
2227 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2228
2229 AC_CONFIG_LINKS([
2230   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2231   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2232   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2233   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2234   src/include/pg_config_os.h:src/include/port/${template}.h
2235   src/Makefile.port:src/makefiles/Makefile.${template}
2236 ])
2237
2238 if test "$PORTNAME" = "win32"; then
2239 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2240 # Links sometimes fail undetected on Mingw -
2241 # so here we detect it and warn the user
2242 for FILE in $CONFIG_LINKS
2243  do
2244         # test -e works for symlinks in the MinGW console
2245         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2246  done
2247 ])
2248 fi
2249
2250 AC_CONFIG_HEADERS([src/include/pg_config.h],
2251 [
2252 # Update timestamp for pg_config.h (see Makefile.global)
2253 echo >src/include/stamp-h
2254 ])
2255
2256 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2257 [
2258 # Update timestamp for pg_config_ext.h (see Makefile.global)
2259 echo >src/include/stamp-ext-h
2260 ])
2261
2262 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2263                   [echo >src/interfaces/ecpg/include/stamp-h])
2264
2265 AC_OUTPUT