granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  84
  85 AC_ARG_WITH(included-apr,
  86 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  87
  88 if test "x$with_included_apr" = "xyes"; then
  89   apr_found=reconfig
  90   if test ! -d srclib/apr; then
  91     AC_MSG_ERROR([Bundled APR requested but not found at srclib/apr. Download and unpack the corresponding httpd-${HTTPD_VERSION}-deps package over this one.])
  92   fi
  93 else
  94   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  95 fi
  96
  97 if test "$apr_found" = "no"; then
  98   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  99 fi
 100
 101 if test "$apr_found" = "reconfig"; then
 102   APR_SUBDIR_CONFIG(srclib/apr,
 103                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 104                     [--enable-layout=*|\'--enable-layout=*])
 105   dnl We must be the first to build and the last to be cleaned
 106   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 107   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 108
 109   dnl We have to find apr-N-config when we reconfigure APR.
 110   for majorver in 1 2; do
 111     test_apr_config="./srclib/apr/apr-${majorver}-config"
 112     if test -f "$test_apr_config"; then
 113       apr_config="$test_apr_config"
 114     fi
 115   done
 116 fi
 117
 118 APR_SETIFNULL(CC, `$apr_config --cc`)
 119 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 120 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 121 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 122 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 123 INTERNAL_CPPFLAGS=""
 124 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 125 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 126 APR_BINDIR=`$apr_config --bindir`
 127 APR_INCLUDEDIR=`$apr_config --includedir`
 128 APR_INCLUDES=`$apr_config --includes`
 129 APR_VERSION=`$apr_config --version`
 130 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 131 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 132
 133 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 134
 135 if test "x${apr_major_version}" = "x2"; then
 136   apu_found=obsolete
 137 elif test "x$with_included_apr" = "xyes"; then
 138   apu_found=reconfig
 139   if test ! -d srclib/apr-util; then
 140     AC_MSG_ERROR([Bundled APR-Util requested but not found at srclib/apr-util. Download and unpack the corresponding httpd-${HTTPD_VERSION}-deps package over this one.])
 141   fi
 142 else
 143    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 144    dnl isn't supported.
 145    ifdef([APR_FIND_APU], [
 146      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 147                   1, ${apr_major_version})
 148    ], [apu_found=no])
 149 fi
 150
 151 if test "$apu_found" = "no"; then
 152   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 153 fi
 154
 155 # Catch some misconfigurations:
 156 case ${apr_found}.${apu_found} in
 157 reconfig.yes)
 158   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 159   ;;
 160 yes.reconfig)
 161   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 162   ;;
 163 esac
 164
 165 if test "$apu_found" = "reconfig"; then
 166   APR_SUBDIR_CONFIG(srclib/apr-util,
 167                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 168                     [--enable-layout=*|\'--enable-layout=*])
 169   dnl We must be the last to build and the first to be cleaned
 170   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 171   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 172   dnl APR and APR-Util major versions must match
 173   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 174 fi
 175
 176 if test "$apu_found" = "obsolete"; then
 177   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 178 else
 179   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 180   APU_BINDIR=`$apu_config --bindir`
 181   APU_INCLUDEDIR=`$apu_config --includedir`
 182   APU_INCLUDES=`$apu_config --includes`
 183   APU_VERSION=`$apu_config --version`
 184   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 185 fi
 186
 187 dnl In case we picked up CC and CPP from APR, get that info into the
 188 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 189 dnl PCRE and for our config tests will be whatever PCRE determines.
 190 AC_PROG_CC
 191 AC_PROG_CPP
 192
 193 dnl Try to get c99 support for variadic macros
 194 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 195
 196 if test "x${cache_file}" = "x/dev/null"; then
 197   # Likewise, ensure that CC and CPP are passed through to the pcre
 198   # configure script iff caching is disabled (the autoconf 2.5x default).
 199   export CC; export CPP
 200 fi
 201
 202 AC_ARG_WITH(pcre,
 203 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 204
 205 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 206 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 207    PCRE_CONFIG=$with_pcre/bin/pcre-config
 208 elif test -x "$with_pcre"; then
 209    PCRE_CONFIG=$with_pcre
 210 fi
 211
 212 if test "$PCRE_CONFIG" != "false"; then
 213   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 214     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 215   fi
 216   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 217   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 218   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 219 else
 220   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 221 fi
 222 APACHE_SUBST(PCRE_LIBS)
 223
 224 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 225
 226 dnl If the source dir is not equal to the build dir,
 227 dnl then we are running in VPATH mode.
 228
 229 APR_ADDTO(INCLUDES, [-I.])
 230
 231 if test "$abs_builddir" != "$abs_srcdir"; then
 232   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 233 fi
 234
 235 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 236
 237 # apr/apr-util --includes may pick up system paths for dependent
 238 # libraries, so ensure these are later in INCLUDES than local source
 239 # directories.
 240 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 241 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 242
 243 dnl Add in path to PCRE includes
 244 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 245
 246 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 247
 248 case $host in
 249   *os2*)
 250       # Use a custom made libtool replacement
 251       echo "using aplibtool"
 252       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 253       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 254       SH_LIBS="\$(ALL_LIBS)"
 255       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 256       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 257       MK_IMPLIB="emximp"
 258       other_targets="$other_targets os2core"
 259       INSTALL_PROG_FLAGS="-e .exe"
 260       SHLTCFLAGS=""
 261       LTCFLAGS=""
 262       ;;
 263   *)
 264       if test "x$LTFLAGS" = "x"; then
 265           LTFLAGS='--silent'
 266       fi
 267       my_libtool=`$apr_config --apr-libtool`
 268       LIBTOOL="$my_libtool \$(LTFLAGS)"
 269       libtoolversion=`$my_libtool --version`
 270       case $libtoolversion in
 271           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 272               SH_LIBTOOL='$(LIBTOOL)'
 273               SHLTCFLAGS="-prefer-pic"
 274               LTCFLAGS="-prefer-non-pic -static"
 275               ;;
 276           *)
 277               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 278               SHLTCFLAGS=""
 279               LTCFLAGS=""
 280               ;;
 281       esac
 282       ;;
 283 esac
 284 APACHE_SUBST(SHLTCFLAGS)
 285 APACHE_SUBST(LTCFLAGS)
 286
 287 case $host in
 288   *-apple-aux3*)
 289       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 290       ;;
 291   *os2-emx*)
 292       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 293       ;;
 294   *-linux-*)
 295       case `uname -r` in
 296         2.[[2-9]]* )
 297             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 298             ;;
 299         * )
 300             ;;
 301       esac
 302       ;;
 303   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 304       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 305       ;;
 306   *-solaris2*)
 307       dnl This is a hack -- we should be using AC_TRY_RUN instead
 308       ap_platform_runtime_link_flag="-R"
 309       dnl solaris 8 and above don't have a thundering herd
 310       dnl not sure about rev's before this one.
 311       case `uname -r` in
 312         5.[567]*)
 313             ;;
 314         * )
 315             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 316             ;;
 317       esac
 318       ;;
 319   *cygwin*)
 320       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 321       ;;
 322   *mingw32*)
 323       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 324       APR_SETIFNULL(ac_cv_func_times, [no])
 325       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 326       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 327       ;;
 328   *aix*)
 329       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 330       if test $aixver -ge 4320; then
 331         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 332       fi
 333       ;;
 334   *os390*)
 335       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 336       ;;
 337 esac
 338
 339 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 340
 341 dnl
 342 dnl Process command line arguments. This is done early in the process so the
 343 dnl user can get feedback quickly in case of an error.
 344 dnl
 345 dnl ### need to move some of the arguments "up here"
 346
 347 dnl ## Check for programs
 348
 349 AC_PATH_PROG(RM, rm)
 350 AC_PATH_PROG(PKGCONFIG, pkg-config)
 351 AC_PATH_PROG(RSYNC, rsync)
 352 AC_PROG_AWK
 353 AC_PROG_LN_S
 354 AC_CHECK_TOOL(RANLIB, ranlib, true)
 355 dnl AC_PATH_PROG(PERL_PATH, perl)
 356 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 357
 358 # Hard-coded install programs
 359 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 360 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 361 APACHE_SUBST(MKINSTALLDIRS)
 362 APACHE_SUBST(INSTALL)
 363
 364 dnl Various OS checks that apparently set required flags
 365 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 366 AC_USE_SYSTEM_EXTENSIONS
 367 ], [
 368 AC_AIX
 369 AC_MINIX
 370 ])
 371
 372 AC_ISC_POSIX
 373
 374 # Ensure that satisfactory versions of apr and apr-util are
 375 # found if external copies are configured.
 376 if test "${apr_found}" = "yes"; then
 377   # Require at least APR 1.3.x otherwise fail
 378   APACHE_CHECK_APxVER([apr], 1, 3)
 379 fi
 380
 381 if test "${apu_found}" = "yes"; then
 382   # Require at least APR-util 1.3.x otherwise fail
 383   if test "${apr_found}" = "yes"; then
 384     # we need to add the APR includes to CPPFLAGS
 385     apu_ckver_CPPFLAGS="$CPPFLAGS"
 386     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 387     APACHE_CHECK_APxVER([apu], 1, 3)
 388     CPPFLAGS="$apu_ckver_CPPFLAGS"
 389   else
 390     APACHE_CHECK_APxVER([apu], 1, 3)
 391   fi
 392 fi
 393
 394 dnl Check for what we can generate dependency files with
 395 APR_CHECK_DEPEND
 396
 397 dnl ## Check for libraries
 398
 399 dnl ## Check for header files
 400
 401 dnl I think these are just used all over the place, so just check for
 402 dnl them at the base of the tree. If some are specific to a single
 403 dnl directory, they should be moved (Comment #Spoon)
 404
 405 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 406 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 407 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 408
 409 AC_HEADER_STDC
 410 AC_CHECK_HEADERS( \
 411 string.h \
 412 limits.h \
 413 unistd.h \
 414 sys/socket.h \
 415 pwd.h \
 416 grp.h \
 417 strings.h \
 418 sys/prctl.h \
 419 sys/processor.h \
 420 sys/sem.h \
 421 sys/sdt.h
 422 )
 423 AC_HEADER_SYS_WAIT
 424
 425 dnl ## Check for typedefs, structures, and compiler characteristics.
 426
 427 AC_C_CONST
 428
 429 dnl ## Check for library functions
 430 dnl ## sqrt() only needed in support/ab.c
 431 saved_LIBS="$LIBS"
 432 LIBS=""
 433 AC_SEARCH_LIBS(sqrt, m)
 434 MATH_LIBS="$LIBS"
 435 APACHE_SUBST(MATH_LIBS)
 436 LIBS="$saved_LIBS"
 437
 438 saved_LIBS="$LIBS"
 439 LIBS=""
 440 AC_SEARCH_LIBS(crypt, crypt)
 441 CRYPT_LIBS="$LIBS"
 442 APACHE_SUBST(CRYPT_LIBS)
 443 LIBS="$saved_LIBS"
 444
 445 dnl See Comment #Spoon
 446
 447 AC_CHECK_FUNCS( \
 448 getpwnam \
 449 getgrnam \
 450 initgroups \
 451 bindprocessor \
 452 prctl \
 453 timegm \
 454 getpgid \
 455 fopen64
 456 )
 457
 458 dnl confirm that a void pointer is large enough to store a long integer
 459 APACHE_CHECK_VOID_PTR_LEN
 460
 461 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 462 [AC_TRY_RUN(#define _GNU_SOURCE
 463 #include <unistd.h>
 464 #include <sys/syscall.h>
 465 #include <sys/types.h>
 466 int main(int argc, char **argv) {
 467 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 468 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 469 if test "$ac_cv_gettid" = "yes"; then
 470     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 471 fi
 472
 473 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 474 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 475 [AC_TRY_COMPILE([#include <sys/types.h>
 476 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 477   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 478 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 479     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 480 fi
 481
 482 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 483
 484 case $host in
 485     *aix*)
 486         # for 32-bit builds, increase MAXDATA to allow lots of threads
 487         if test x$OBJECT_MODE != x64; then
 488             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 489         fi
 490         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 491         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 492         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 493         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 494         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 495         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 496         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 497         ;;
 498     *os390*)
 499         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 500         ;;
 501     *)
 502         OS_SPECIFIC_VARS=""
 503 esac
 504
 505 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 506         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 507         [PORT=80])
 508
 509 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 510         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 511         [SSLPORT=443])
 512
 513 DTRACE=true
 514 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 515 [
 516   enable_dtrace=$enableval
 517   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 518   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 519 ],
 520 [
 521   enable_dtrace=no
 522 ])
 523
 524 dnl Disabled dtrace build for now.
 525 enable_dtrace=no
 526
 527 case $host in
 528   *-solaris2*)
 529     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 530         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 531                   [Enable DTrace probes])
 532         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 533         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 534     fi
 535     ;;
 536 esac
 537
 538 APACHE_SUBST(DTRACE)
 539
 540 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 541 [
 542     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 543         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 544     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 545 ])dnl
 546
 547 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 548 [
 549     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 550               [Allow modules to run hook after a fatal exception])
 551 ])dnl
 552
 553 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 554 [
 555   LOAD_ALL_MODULES=$enableval
 556   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 557 ],
 558 [
 559   LOAD_ALL_MODULES="no"
 560 ])
 561
 562 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 563 [
 564   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 565   if test "$GCC" = "yes"; then
 566     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 567     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 568     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 569     APACHE_ADD_GCC_CFLAG([-Wformat])
 570     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 571     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 572   elif test "$AIX_XLC" = "yes"; then
 573     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 574   fi
 575   if test "x$enable_load_all_modules" = "x"; then
 576     LOAD_ALL_MODULES=yes
 577     AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 578   fi
 579 ])dnl
 580
 581 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 582 [
 583   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 584   if test "$GCC" = "yes"; then
 585     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 586     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 587     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 588     APACHE_ADD_GCC_CFLAG([-Wformat])
 589     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 590     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 591   elif test "$AIX_XLC" = "yes"; then
 592     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 593   fi
 594 ])dnl
 595
 596 dnl Conditionally enable PIE support for GNU toolchains.
 597 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 598 if test "$enable_pie" = "yes"; then
 599    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 600      save_CFLAGS=$CFLAGS
 601      save_LDFLAGS=$LDFLAGS
 602      CFLAGS="$CFLAGS -fPIE"
 603      LDFLAGS="$LDFLAGS -pie"
 604      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 605       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 606      CFLAGS=$save_CFLAGS
 607      LDFLAGS=$save_LDFLAGS
 608    ])
 609    if test "$ap_cv_cc_pie" = "yes"; then
 610      PICFLAGS="-fPIE"
 611      PILDFLAGS="-pie"
 612    else
 613      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 614    fi
 615 fi
 616 AC_SUBST(PICFLAGS)
 617 AC_SUBST(PILDFLAGS)
 618
 619 prefix="$orig_prefix"
 620 APACHE_ENABLE_MODULES
 621
 622 dnl reading config stubs
 623 esyscmd(./build/config-stubs .)
 624
 625 APACHE_SUBST(progname)
 626 APACHE_SUBST(OS)
 627 APACHE_SUBST(OS_DIR)
 628 APACHE_SUBST(BUILTIN_LIBS)
 629 APACHE_SUBST(SHLIBPATH_VAR)
 630 APACHE_SUBST(OS_SPECIFIC_VARS)
 631
 632 PRE_SHARED_CMDS='echo ""'
 633 POST_SHARED_CMDS='echo ""'
 634
 635 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 636
 637 if test "$apache_need_shared" = "yes"; then
 638   if test -f $ac_aux_dir/ltconfig; then
 639     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 640   fi
 641   shared_build="shared-build"
 642 fi
 643
 644 dnl enable_so tells us if *any* modules can be built as DSOs
 645
 646 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 647   case $host in
 648     *-ibm-aix*)
 649       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 650       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 651       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 652       ;;
 653     *os390)
 654       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 655       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 656   esac
 657   MOD_SO_ENABLED=yes
 658 fi
 659 AC_SUBST(MOD_SO_ENABLED)
 660
 661 APACHE_SUBST(PRE_SHARED_CMDS)
 662 APACHE_SUBST(POST_SHARED_CMDS)
 663 APACHE_SUBST(shared_build)
 664
 665 AC_ARG_WITH(program-name,
 666 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 667   progname="$withval" ], [
 668   progname="httpd"] )
 669
 670 # SuExec parameters
 671 AC_ARG_WITH(suexec-bin,
 672 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 673   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 674 ] )
 675
 676 AC_ARG_WITH(suexec-caller,
 677 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 678   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 679
 680 AC_ARG_WITH(suexec-userdir,
 681 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 682   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 683
 684 AC_ARG_WITH(suexec-docroot,
 685 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 686   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 687
 688 AC_ARG_WITH(suexec-uidmin,
 689 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 690   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 691
 692 AC_ARG_WITH(suexec-gidmin,
 693 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 694   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 695
 696 AC_ARG_WITH(suexec-logfile,
 697 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 698   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 699
 700 AC_ARG_WITH(suexec-safepath,
 701 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 702   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 703
 704 AC_ARG_WITH(suexec-umask,
 705 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 706   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 707
 708 dnl APR should go after the other libs, so the right symbols can be picked up
 709 if test x${apu_found} != xobsolete; then
 710   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 711 fi
 712 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 713 APACHE_SUBST(AP_LIBS)
 714 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 715 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 716
 717 AC_DEFINE(AP_USING_AUTOCONF, 1,
 718                 [Using autoconf to configure Apache])
 719
 720 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 721     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 722               [This platform doesn't suffer from the thundering herd problem])
 723 fi
 724
 725 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 726     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 727               [Listening sockets are non-blocking when there are more than 1])
 728 fi
 729
 730 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 731
 732 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 733 [
 734   v4mapped=$enableval
 735 ],
 736 [
 737     case $host in
 738     *freebsd5*|*netbsd*|*openbsd*)
 739         v4mapped=no
 740         ;;
 741     *)
 742         v4mapped=yes
 743         ;;
 744     esac
 745     if ap_mpm_is_enabled winnt; then
 746         dnl WinNT MPM doesn't support this.
 747         v4mapped=no
 748     fi
 749 ])
 750
 751 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 752     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 753               [Allow IPv4 connections on IPv6 listening sockets])
 754 fi
 755
 756 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 757 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 758 APACHE_FAST_OUTPUT(support/Makefile)
 759
 760 if test -d ./test; then
 761     APACHE_FAST_OUTPUT(test/Makefile)
 762 fi
 763
 764 dnl ## Finalize the variables
 765 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 766
 767 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 768 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 769 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 770 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 771 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 772 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 773
 774 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 775
 776 APACHE_GEN_CONFIG_VARS
 777
 778 dnl ## Build modules.c
 779 rm -f modules.c
 780 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 781
 782 APR_EXPAND_VAR(ap_prefix, $prefix)
 783 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 784         [Root directory of the Apache install area])
 785 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 786         [Location of the config file, relative to the Apache root directory])
 787 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 788         [Location of the MIME types config file, relative to the Apache root directory])
 789
 790 perlbin=`$ac_aux_dir/PrintPath perl`
 791 if test "x$perlbin" = "x"; then
 792     perlbin="/replace/with/path/to/perl/interpreter"
 793 fi
 794 AC_SUBST(perlbin)
 795
 796 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 797
 798 BSD_MAKEFILE=no
 799 ap_make_include=include
 800 ap_make_delimiter=' '
 801 case $host in
 802 *bsdi*)
 803     # Check whether they've installed GNU make
 804     if make --version > /dev/null 2>&1; then
 805         true
 806     else
 807         BSD_MAKEFILE=yes
 808         ap_make_include=.include
 809         ap_make_delimiter='"'
 810     fi
 811     ;;
 812 esac
 813 AC_SUBST(ap_make_include)
 814 AC_SUBST(ap_make_delimiter)
 815
 816 dnl Ensure that docs/conf is created.
 817 test -d docs/conf||$mkdir_p docs/conf
 818
 819 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 820   APACHE_GEN_MAKEFILES
 821 ])