granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="$srcdir/srclib/apr/apr-${majorver}-config"
  97     if test -f $test_apr_config; then
  98       apr_config=$test_apr_config
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 124    dnl isn't supported.
 125    ifdef([APR_FIND_APU], [
 126      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 127                   1, ${apr_major_version})
 128    ], [apu_found=no])
 129 fi
 130
 131 if test "$apu_found" = "no"; then
 132   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 133 fi
 134
 135 # Catch some misconfigurations:
 136 case ${apr_found}.${apu_found} in
 137 reconfig.yes)
 138   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 139   ;;
 140 yes.reconfig)
 141   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 142   ;;
 143 esac
 144
 145 if test "$apu_found" = "reconfig"; then
 146   APR_SUBDIR_CONFIG(srclib/apr-util,
 147                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 148                     [--enable-layout=*|\'--enable-layout=*])
 149   dnl We must be the last to build and the first to be cleaned
 150   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 151   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 152   dnl APR and APR-Util major versions must match
 153   apu_config="${srcdir}/srclib/apr-util/apu-${apr_major_version}-config"
 154 fi
 155
 156 if test "$apu_found" = "obsolete"; then
 157   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 158 else
 159   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 160   APU_BINDIR=`$apu_config --bindir`
 161   APU_INCLUDEDIR=`$apu_config --includedir`
 162   APU_INCLUDES=`$apu_config --includes`
 163   APU_VERSION=`$apu_config --version`
 164   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 165 fi
 166
 167 dnl In case we picked up CC and CPP from APR, get that info into the
 168 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 169 dnl PCRE and for our config tests will be whatever PCRE determines.
 170 AC_PROG_CC
 171 AC_PROG_CPP
 172
 173 if test "x${cache_file}" = "x/dev/null"; then
 174   # Likewise, ensure that CC and CPP are passed through to the pcre
 175   # configure script iff caching is disabled (the autoconf 2.5x default).
 176   export CC; export CPP
 177 fi
 178
 179 dnl Absolute source/build directory
 180 abs_srcdir=`(cd $srcdir && pwd)`
 181 abs_builddir=`pwd`
 182
 183 AC_ARG_WITH(pcre,
 184 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 185
 186 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 187 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 188    PCRE_CONFIG=$with_pcre/bin/pcre-config
 189 elif test -x "$with_pcre"; then
 190    PCRE_CONFIG=$with_pcre
 191 fi
 192
 193 if test "$PCRE_CONFIG" != "false"; then
 194   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 195     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 196   fi
 197   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 198   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 199   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 200 else
 201   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 202 fi
 203 APACHE_SUBST(PCRE_LIBS)
 204
 205 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 206 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 207
 208 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 209
 210 dnl If the source dir is not equal to the build dir,
 211 dnl then we are running in VPATH mode.
 212
 213 APR_ADDTO(INCLUDES, [-I.])
 214
 215 if test "$abs_builddir" != "$abs_srcdir"; then
 216   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 217 fi
 218
 219 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/aaa -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/modules/session -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/core -I\$(top_srcdir)/modules/generators  -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 220
 221 # apr/apr-util --includes may pick up system paths for dependent
 222 # libraries, so ensure these are later in INCLUDES than local source
 223 # directories.
 224 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 225 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 226
 227 dnl Add in path to PCRE includes
 228 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 229
 230 if test "x$LTFLAGS" = "x"; then
 231     LTFLAGS='--silent'
 232 fi
 233 my_libtool=`$apr_config --apr-libtool`
 234 LIBTOOL="$my_libtool \$(LTFLAGS)"
 235 libtoolversion=`$my_libtool --version`
 236 case $libtoolversion in
 237     *1.[[45]]* | *[[2-9]].[[0-9]]*)
 238         SH_LIBTOOL='$(LIBTOOL)'
 239         SHLTCFLAGS="-prefer-pic"
 240         LTCFLAGS="-prefer-non-pic -static"
 241         ;;
 242     *)
 243         SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 244         SHLTCFLAGS=""
 245         LTCFLAGS=""
 246         ;;
 247 esac
 248 APACHE_SUBST(SHLTCFLAGS)
 249 APACHE_SUBST(LTCFLAGS)
 250
 251 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 252
 253 case $host in
 254   *-apple-aux3*)
 255       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 256       ;;
 257   *-linux-*)
 258       case `uname -r` in
 259         2.[[2-9]]* )
 260             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 261             ;;
 262         * )
 263             ;;
 264       esac
 265       ;;
 266   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 267       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 268       ;;
 269   *-solaris2*)
 270       dnl This is a hack -- we should be using AC_TRY_RUN instead
 271       ap_platform_runtime_link_flag="-R"
 272       dnl solaris 8 and above don't have a thundering herd
 273       dnl not sure about rev's before this one.
 274       case `uname -r` in
 275         5.[567]*)
 276             ;;
 277         * )
 278             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 279             ;;
 280       esac
 281       ;;
 282   *cygwin*)
 283       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 284       ;;
 285   *mingw32*)
 286       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 287       APR_SETIFNULL(ac_cv_func_times, [no])
 288       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 289       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 290       ;;
 291   *aix*)
 292       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 293       if test $aixver -ge 4320; then
 294         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 295       fi
 296       ;;
 297   *os390*)
 298       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 299       ;;
 300 esac
 301
 302 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 303
 304 dnl
 305 dnl Process command line arguments. This is done early in the process so the
 306 dnl user can get feedback quickly in case of an error.
 307 dnl
 308 dnl ### need to move some of the arguments "up here"
 309
 310 dnl ## Check for programs
 311
 312 AC_PATH_PROG(RM, rm)
 313 AC_PATH_PROG(PKGCONFIG, pkg-config)
 314 AC_PATH_PROG(RSYNC, rsync)
 315 AC_PROG_AWK
 316 AC_PROG_LN_S
 317 AC_CHECK_TOOL(RANLIB, ranlib, true)
 318 dnl AC_PATH_PROG(PERL_PATH, perl)
 319 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 320
 321 # Hard-coded install programs
 322 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 323 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 324 APACHE_SUBST(MKINSTALLDIRS)
 325 APACHE_SUBST(INSTALL)
 326
 327 dnl Various OS checks that apparently set required flags
 328 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 329 AC_USE_SYSTEM_EXTENSIONS
 330 ], [
 331 AC_AIX
 332 AC_MINIX
 333 ])
 334
 335 AC_ISC_POSIX
 336
 337 # Ensure that satisfactory versions of apr and apr-util are
 338 # found if external copies are configured.
 339 if test "${apr_found}" = "yes"; then
 340   # Require at least APR 1.3.x otherwise fail
 341   APACHE_CHECK_APxVER([apr], 1, 3)
 342 fi
 343
 344 if test "${apu_found}" = "yes"; then
 345   # Require at least APR-util 1.3.x otherwise fail
 346   APACHE_CHECK_APxVER([apu], 1, 3)
 347 fi
 348
 349 dnl Check for what we can generate dependency files with
 350 APR_CHECK_DEPEND
 351
 352 dnl ## Check for libraries
 353
 354 dnl ## Check for header files
 355
 356 dnl I think these are just used all over the place, so just check for
 357 dnl them at the base of the tree. If some are specific to a single
 358 dnl directory, they should be moved (Comment #Spoon)
 359
 360 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 361 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 362 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 363
 364 AC_HEADER_STDC
 365 AC_CHECK_HEADERS( \
 366 string.h \
 367 limits.h \
 368 unistd.h \
 369 sys/socket.h \
 370 pwd.h \
 371 grp.h \
 372 strings.h \
 373 sys/prctl.h \
 374 sys/processor.h \
 375 sys/sem.h \
 376 sys/sdt.h
 377 )
 378 AC_HEADER_SYS_WAIT
 379
 380 dnl ## Check for typedefs, structures, and compiler characteristics.
 381
 382 AC_C_CONST
 383
 384 dnl ## Check for library functions
 385 dnl ## sqrt() only needed in support/ab.c
 386 saved_LIBS="$LIBS"
 387 LIBS=""
 388 AC_SEARCH_LIBS(sqrt, m)
 389 MATH_LIBS="$LIBS"
 390 APACHE_SUBST(MATH_LIBS)
 391 LIBS="$saved_LIBS"
 392
 393 dnl See Comment #Spoon
 394
 395 AC_CHECK_FUNCS( \
 396 getpwnam \
 397 getgrnam \
 398 initgroups \
 399 bindprocessor \
 400 prctl \
 401 timegm \
 402 getpgid
 403 )
 404
 405 dnl confirm that a void pointer is large enough to store a long integer
 406 APACHE_CHECK_VOID_PTR_LEN
 407
 408 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 409 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 410 [AC_TRY_COMPILE([#include <sys/types.h>
 411 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 412   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 413 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 414     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 415 fi
 416
 417 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 418
 419 case $host in
 420     *aix*)
 421         # for 32-bit builds, increase MAXDATA to allow lots of threads
 422         if test x$OBJECT_MODE != x64; then
 423             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 424         fi
 425         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 426         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 427         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 428         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 429         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 430         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 431         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 432         ;;
 433     *os390*)
 434         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 435         ;;
 436     *)
 437         OS_SPECIFIC_VARS=""
 438 esac
 439
 440 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 441         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 442         [PORT=80])
 443
 444 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 445         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 446         [SSLPORT=443])
 447
 448 DTRACE=true
 449 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 450 [
 451   enable_dtrace=$enableval
 452   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 453   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 454 ],
 455 [
 456   enable_dtrace=no
 457 ])
 458
 459 dnl Disabled dtrace build for now.
 460 enable_dtrace=no
 461
 462 case $host in
 463   *-solaris2*)
 464     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 465         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 466                   [Enable DTrace probes])
 467         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 468         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 469     fi
 470     ;;
 471 esac
 472
 473 APACHE_SUBST(DTRACE)
 474
 475 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 476
 477 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 478 [
 479   v4mapped=$enableval
 480 ],
 481 [
 482     case $host in
 483     *freebsd5*|*netbsd*|*openbsd*)
 484         v4mapped=no
 485         ;;
 486     *)
 487         v4mapped=yes
 488         ;;
 489 esac
 490 ])
 491
 492 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 493     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 494               [Allow IPv4 connections on IPv6 listening sockets])
 495 fi
 496
 497 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 498 [
 499     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 500               [Allow modules to run hook after a fatal exception])
 501 ])dnl
 502
 503 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 504 [
 505   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 506 ])dnl
 507
 508 dnl Conditionally enable PIE support for GNU toolchains.
 509 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 510 if test "$enable_pie" = "yes"; then
 511    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 512      save_CFLAGS=$CFLAGS
 513      save_LDFLAGS=$LDFLAGS
 514      CFLAGS="$CFLAGS -fPIE"
 515      LDFLAGS="$LDFLAGS -pie"
 516      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 517       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 518      CFLAGS=$save_CFLAGS
 519      LDFLAGS=$save_LDFLAGS
 520    ])
 521    if test "$ap_cv_cc_pie" = "yes"; then
 522      PICFLAGS="-fPIE"
 523      PILDFLAGS="-pie"
 524    else
 525      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 526    fi
 527 fi
 528 AC_SUBST(PICFLAGS)
 529 AC_SUBST(PILDFLAGS)
 530
 531 prefix="$orig_prefix"
 532 APACHE_ENABLE_MODULES
 533
 534 dnl reading config stubs
 535 esyscmd(./build/config-stubs .)
 536
 537 APACHE_SUBST(progname)
 538 APACHE_SUBST(OS)
 539 APACHE_SUBST(OS_DIR)
 540 APACHE_SUBST(BUILTIN_LIBS)
 541 APACHE_SUBST(SHLIBPATH_VAR)
 542 APACHE_SUBST(OS_SPECIFIC_VARS)
 543
 544 PRE_SHARED_CMDS='echo ""'
 545 POST_SHARED_CMDS='echo ""'
 546
 547 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 548
 549 if test "$apache_need_shared" = "yes"; then
 550   if test -f $ac_aux_dir/ltconfig; then
 551     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 552   fi
 553   shared_build="shared-build"
 554 fi
 555
 556 dnl enable_so tells us if *any* modules can be built as DSOs
 557
 558 if test "$enable_so" = "yes"; then
 559   case $host in
 560     *-ibm-aix*)
 561       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 562       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 563       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 564       ;;
 565     *os390)
 566       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 567       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 568   esac
 569   MOD_SO_ENABLED=yes
 570 fi
 571 AC_SUBST(MOD_SO_ENABLED)
 572
 573 APACHE_SUBST(PRE_SHARED_CMDS)
 574 APACHE_SUBST(POST_SHARED_CMDS)
 575 APACHE_SUBST(shared_build)
 576
 577 AC_ARG_WITH(program-name,
 578 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 579   progname="$withval" ], [
 580   progname="httpd"] )
 581
 582 # SuExec parameters
 583 AC_ARG_WITH(suexec-bin,
 584 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 585   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 586 ] )
 587
 588 AC_ARG_WITH(suexec-caller,
 589 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 590   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 591
 592 AC_ARG_WITH(suexec-userdir,
 593 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 594   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 595
 596 AC_ARG_WITH(suexec-docroot,
 597 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 598   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 599
 600 AC_ARG_WITH(suexec-uidmin,
 601 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 602   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 603
 604 AC_ARG_WITH(suexec-gidmin,
 605 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 606   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 607
 608 AC_ARG_WITH(suexec-logfile,
 609 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 610   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 611
 612 AC_ARG_WITH(suexec-safepath,
 613 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 614   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 615
 616 AC_ARG_WITH(suexec-umask,
 617 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 618   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 619
 620 dnl APR should go after the other libs, so the right symbols can be picked up
 621 if test x${apu_found} != xobsolete; then
 622   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 623 fi
 624 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 625 APACHE_SUBST(AP_LIBS)
 626 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 627 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 628
 629 AC_DEFINE(AP_USING_AUTOCONF, 1,
 630                 [Using autoconf to configure Apache])
 631
 632 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 633     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 634               [This platform doesn't suffer from the thundering herd problem])
 635 fi
 636
 637 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 638     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 639               [Listening sockets are non-blocking when there are more than 1])
 640 fi
 641
 642
 643 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 644 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 645 APACHE_FAST_OUTPUT(support/Makefile)
 646
 647 if test -d ./test; then
 648     APACHE_FAST_OUTPUT(test/Makefile)
 649 fi
 650
 651 dnl ## Finalize the variables
 652 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 653
 654 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 655 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 656 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 657 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 658 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 659 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 660
 661 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 662
 663 APACHE_GEN_CONFIG_VARS
 664
 665 dnl ## Build modules.c
 666 rm -f modules.c
 667 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 668
 669 APR_EXPAND_VAR(ap_prefix, $prefix)
 670 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 671         [Root directory of the Apache install area])
 672 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 673         [Location of the config file, relative to the Apache root directory])
 674 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 675         [Location of the MIME types config file, relative to the Apache root directory])
 676
 677 perlbin=`$ac_aux_dir/PrintPath perl`
 678 if test "x$perlbin" = "x"; then
 679     perlbin="/replace/with/path/to/perl/interpreter"
 680 fi
 681 AC_SUBST(perlbin)
 682
 683 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 684
 685 BSD_MAKEFILE=no
 686 ap_make_include=include
 687 ap_make_delimiter=' '
 688 case $host in
 689 *bsdi*)
 690     # Check whether they've installed GNU make
 691     if make --version > /dev/null 2>&1; then
 692         true
 693     else
 694         BSD_MAKEFILE=yes
 695         ap_make_include=.include
 696         ap_make_delimiter='"'
 697     fi
 698     ;;
 699 esac
 700 AC_SUBST(ap_make_include)
 701 AC_SUBST(ap_make_delimiter)
 702
 703 dnl Ensure that docs/conf is created.
 704 test -d docs/conf||$mkdir_p docs/conf
 705
 706 dnl Ensure that the httpd version is included
 707 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 708 AC_SUBST(HTTPD_VERSION)
 709
 710 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 711   APACHE_GEN_MAKEFILES
 712 ])