granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl get an EGREP to use in the Makefiles
  63 AC_PROG_EGREP
  64 APACHE_SUBST(EGREP)
  65
  66 dnl ## Run configure for packages Apache uses
  67
  68 dnl shared library support for these packages doesn't currently
  69 dnl work on some platforms
  70
  71 AC_CANONICAL_SYSTEM
  72
  73 orig_prefix="$prefix"
  74
  75 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  76
  77 AC_ARG_WITH(included-apr,
  78 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  79
  80 if test "x$with_included_apr" = "xyes"; then
  81    apr_found=reconfig
  82 else
  83    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  84 fi
  85
  86 if test "$apr_found" = "no"; then
  87   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  88 fi
  89
  90 if test "$apr_found" = "reconfig"; then
  91   APR_SUBDIR_CONFIG(srclib/apr,
  92                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  93                     [--enable-layout=*|\'--enable-layout=*])
  94   dnl We must be the first to build and the last to be cleaned
  95   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  96   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  97
  98   dnl We have to find apr-N-config when we reconfigure APR.
  99   for majorver in 1 2; do
 100     test_apr_config="./srclib/apr/apr-${majorver}-config"
 101     if test -f "$test_apr_config"; then
 102       apr_config="$test_apr_config"
 103     fi
 104   done
 105 fi
 106
 107 APR_SETIFNULL(CC, `$apr_config --cc`)
 108 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 109 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 110 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 111 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 112 INTERNAL_CPPFLAGS=""
 113 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 114 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 115 APR_BINDIR=`$apr_config --bindir`
 116 APR_INCLUDEDIR=`$apr_config --includedir`
 117 APR_INCLUDES=`$apr_config --includes`
 118 APR_VERSION=`$apr_config --version`
 119 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 120 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 121
 122 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 123
 124 if test "x${apr_major_version}" = "x2"; then
 125    apu_found=obsolete
 126 elif test "x$with_included_apr" = "xyes"; then
 127    apu_found=reconfig
 128 else
 129    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 130    dnl isn't supported.
 131    ifdef([APR_FIND_APU], [
 132      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 133                   1, ${apr_major_version})
 134    ], [apu_found=no])
 135 fi
 136
 137 if test "$apu_found" = "no"; then
 138   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 139 fi
 140
 141 # Catch some misconfigurations:
 142 case ${apr_found}.${apu_found} in
 143 reconfig.yes)
 144   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 145   ;;
 146 yes.reconfig)
 147   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 148   ;;
 149 esac
 150
 151 if test "$apu_found" = "reconfig"; then
 152   APR_SUBDIR_CONFIG(srclib/apr-util,
 153                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 154                     [--enable-layout=*|\'--enable-layout=*])
 155   dnl We must be the last to build and the first to be cleaned
 156   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 157   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 158   dnl APR and APR-Util major versions must match
 159   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 160 fi
 161
 162 if test "$apu_found" = "obsolete"; then
 163   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 164 else
 165   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 166   APU_BINDIR=`$apu_config --bindir`
 167   APU_INCLUDEDIR=`$apu_config --includedir`
 168   APU_INCLUDES=`$apu_config --includes`
 169   APU_VERSION=`$apu_config --version`
 170   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 171 fi
 172
 173 dnl In case we picked up CC and CPP from APR, get that info into the
 174 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 175 dnl PCRE and for our config tests will be whatever PCRE determines.
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178
 179 dnl Try to get c99 support for variadic macros
 180 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 181
 182 if test "x${cache_file}" = "x/dev/null"; then
 183   # Likewise, ensure that CC and CPP are passed through to the pcre
 184   # configure script iff caching is disabled (the autoconf 2.5x default).
 185   export CC; export CPP
 186 fi
 187
 188 dnl Absolute source/build directory
 189 abs_srcdir=`(cd $srcdir && pwd)`
 190 abs_builddir=`pwd`
 191
 192 AC_ARG_WITH(pcre,
 193 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 194
 195 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 196 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 197    PCRE_CONFIG=$with_pcre/bin/pcre-config
 198 elif test -x "$with_pcre"; then
 199    PCRE_CONFIG=$with_pcre
 200 fi
 201
 202 if test "$PCRE_CONFIG" != "false"; then
 203   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 204     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 205   fi
 206   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 207   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 208   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 209 else
 210   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 211 fi
 212 APACHE_SUBST(PCRE_LIBS)
 213
 214 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 215
 216 dnl If the source dir is not equal to the build dir,
 217 dnl then we are running in VPATH mode.
 218
 219 APR_ADDTO(INCLUDES, [-I.])
 220
 221 if test "$abs_builddir" != "$abs_srcdir"; then
 222   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 223 fi
 224
 225 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 226
 227 # apr/apr-util --includes may pick up system paths for dependent
 228 # libraries, so ensure these are later in INCLUDES than local source
 229 # directories.
 230 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 231 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 232
 233 dnl Add in path to PCRE includes
 234 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 235
 236 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 237
 238 case $host in
 239   *os2*)
 240       # Use a custom made libtool replacement
 241       echo "using aplibtool"
 242       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 243       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 244       SH_LIBS="\$(ALL_LIBS)"
 245       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 246       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 247       MK_IMPLIB="emximp"
 248       other_targets="$other_targets os2core"
 249       INSTALL_PROG_FLAGS="-e .exe"
 250       SHLTCFLAGS=""
 251       LTCFLAGS=""
 252       ;;
 253   *)
 254       if test "x$LTFLAGS" = "x"; then
 255           LTFLAGS='--silent'
 256       fi
 257       my_libtool=`$apr_config --apr-libtool`
 258       LIBTOOL="$my_libtool \$(LTFLAGS)"
 259       libtoolversion=`$my_libtool --version`
 260       case $libtoolversion in
 261           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 262               SH_LIBTOOL='$(LIBTOOL)'
 263               SHLTCFLAGS="-prefer-pic"
 264               LTCFLAGS="-prefer-non-pic -static"
 265               ;;
 266           *)
 267               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 268               SHLTCFLAGS=""
 269               LTCFLAGS=""
 270               ;;
 271       esac
 272       ;;
 273 esac
 274 APACHE_SUBST(SHLTCFLAGS)
 275 APACHE_SUBST(LTCFLAGS)
 276
 277 case $host in
 278   *-apple-aux3*)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *os2-emx*)
 282       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 283       ;;
 284   *-linux-*)
 285       case `uname -r` in
 286         2.[[2-9]]* )
 287             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 288             ;;
 289         * )
 290             ;;
 291       esac
 292       ;;
 293   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 294       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 295       ;;
 296   *-solaris2*)
 297       dnl This is a hack -- we should be using AC_TRY_RUN instead
 298       ap_platform_runtime_link_flag="-R"
 299       dnl solaris 8 and above don't have a thundering herd
 300       dnl not sure about rev's before this one.
 301       case `uname -r` in
 302         5.[567]*)
 303             ;;
 304         * )
 305             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 306             ;;
 307       esac
 308       ;;
 309   *cygwin*)
 310       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 311       ;;
 312   *mingw32*)
 313       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 314       APR_SETIFNULL(ac_cv_func_times, [no])
 315       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 316       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 317       ;;
 318   *aix*)
 319       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 320       if test $aixver -ge 4320; then
 321         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 322       fi
 323       ;;
 324   *os390*)
 325       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 326       ;;
 327 esac
 328
 329 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 330
 331 dnl
 332 dnl Process command line arguments. This is done early in the process so the
 333 dnl user can get feedback quickly in case of an error.
 334 dnl
 335 dnl ### need to move some of the arguments "up here"
 336
 337 dnl ## Check for programs
 338
 339 AC_PATH_PROG(RM, rm)
 340 AC_PATH_PROG(PKGCONFIG, pkg-config)
 341 AC_PATH_PROG(RSYNC, rsync)
 342 AC_PROG_AWK
 343 AC_PROG_LN_S
 344 AC_CHECK_TOOL(RANLIB, ranlib, true)
 345 dnl AC_PATH_PROG(PERL_PATH, perl)
 346 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 347
 348 # Hard-coded install programs
 349 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 350 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 351 APACHE_SUBST(MKINSTALLDIRS)
 352 APACHE_SUBST(INSTALL)
 353
 354 dnl Various OS checks that apparently set required flags
 355 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 356 AC_USE_SYSTEM_EXTENSIONS
 357 ], [
 358 AC_AIX
 359 AC_MINIX
 360 ])
 361
 362 AC_ISC_POSIX
 363
 364 # Ensure that satisfactory versions of apr and apr-util are
 365 # found if external copies are configured.
 366 if test "${apr_found}" = "yes"; then
 367   # Require at least APR 1.3.x otherwise fail
 368   APACHE_CHECK_APxVER([apr], 1, 3)
 369 fi
 370
 371 if test "${apu_found}" = "yes"; then
 372   # Require at least APR-util 1.3.x otherwise fail
 373   if test "${apr_found}" = "yes"; then
 374     # we need to add the APR includes to CPPFLAGS
 375     apu_ckver_CPPFLAGS="$CPPFLAGS"
 376     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 377     APACHE_CHECK_APxVER([apu], 1, 3)
 378     CPPFLAGS="$apu_ckver_CPPFLAGS"
 379   else
 380     APACHE_CHECK_APxVER([apu], 1, 3)
 381   fi
 382 fi
 383
 384 dnl Check for what we can generate dependency files with
 385 APR_CHECK_DEPEND
 386
 387 dnl ## Check for libraries
 388
 389 dnl ## Check for header files
 390
 391 dnl I think these are just used all over the place, so just check for
 392 dnl them at the base of the tree. If some are specific to a single
 393 dnl directory, they should be moved (Comment #Spoon)
 394
 395 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 396 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 397 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 398
 399 AC_HEADER_STDC
 400 AC_CHECK_HEADERS( \
 401 string.h \
 402 limits.h \
 403 unistd.h \
 404 sys/socket.h \
 405 pwd.h \
 406 grp.h \
 407 strings.h \
 408 sys/prctl.h \
 409 sys/processor.h \
 410 sys/sem.h \
 411 sys/sdt.h
 412 )
 413 AC_HEADER_SYS_WAIT
 414
 415 dnl ## Check for typedefs, structures, and compiler characteristics.
 416
 417 AC_C_CONST
 418
 419 dnl ## Check for library functions
 420 dnl ## sqrt() only needed in support/ab.c
 421 saved_LIBS="$LIBS"
 422 LIBS=""
 423 AC_SEARCH_LIBS(sqrt, m)
 424 MATH_LIBS="$LIBS"
 425 APACHE_SUBST(MATH_LIBS)
 426 LIBS="$saved_LIBS"
 427
 428 saved_LIBS="$LIBS"
 429 LIBS=""
 430 AC_SEARCH_LIBS(crypt, crypt)
 431 CRYPT_LIBS="$LIBS"
 432 APACHE_SUBST(CRYPT_LIBS)
 433 LIBS="$saved_LIBS"
 434
 435 dnl See Comment #Spoon
 436
 437 AC_CHECK_FUNCS( \
 438 getpwnam \
 439 getgrnam \
 440 initgroups \
 441 bindprocessor \
 442 prctl \
 443 timegm \
 444 getpgid \
 445 fopen64
 446 )
 447
 448 dnl confirm that a void pointer is large enough to store a long integer
 449 APACHE_CHECK_VOID_PTR_LEN
 450
 451 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 452 [AC_TRY_RUN(#define _GNU_SOURCE
 453 #include <unistd.h>
 454 #include <sys/syscall.h>
 455 #include <sys/types.h>
 456 int main(int argc, char **argv) {
 457 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 458 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 459 if test "$ac_cv_gettid" = "yes"; then
 460     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 461 fi
 462
 463 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 464 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 465 [AC_TRY_COMPILE([#include <sys/types.h>
 466 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 467   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 468 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 469     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 470 fi
 471
 472 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 473
 474 case $host in
 475     *aix*)
 476         # for 32-bit builds, increase MAXDATA to allow lots of threads
 477         if test x$OBJECT_MODE != x64; then
 478             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 479         fi
 480         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 481         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 482         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 483         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 484         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 485         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 486         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 487         ;;
 488     *os390*)
 489         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 490         ;;
 491     *)
 492         OS_SPECIFIC_VARS=""
 493 esac
 494
 495 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 496         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 497         [PORT=80])
 498
 499 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 500         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 501         [SSLPORT=443])
 502
 503 DTRACE=true
 504 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 505 [
 506   enable_dtrace=$enableval
 507   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 508   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 509 ],
 510 [
 511   enable_dtrace=no
 512 ])
 513
 514 dnl Disabled dtrace build for now.
 515 enable_dtrace=no
 516
 517 case $host in
 518   *-solaris2*)
 519     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 520         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 521                   [Enable DTrace probes])
 522         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 523         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 524     fi
 525     ;;
 526 esac
 527
 528 APACHE_SUBST(DTRACE)
 529
 530 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 531 [
 532     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 533         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 534     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 535 ])dnl
 536
 537 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 538 [
 539     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 540               [Allow modules to run hook after a fatal exception])
 541 ])dnl
 542
 543 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 544 [
 545   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 546   if test "$GCC" = "yes"; then
 547     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 548     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 549     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 550     APACHE_ADD_GCC_CFLAG([-Wformat])
 551     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 552     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 553   elif test "$AIX_XLC" = "yes"; then
 554     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 555   fi
 556 ])dnl
 557
 558 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 559 [
 560   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 561   if test "$GCC" = "yes"; then
 562     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 563     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 564     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 565     APACHE_ADD_GCC_CFLAG([-Wformat])
 566     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 567     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 568   elif test "$AIX_XLC" = "yes"; then
 569     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 570   fi
 571 ])dnl
 572
 573 dnl Conditionally enable PIE support for GNU toolchains.
 574 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 575 if test "$enable_pie" = "yes"; then
 576    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 577      save_CFLAGS=$CFLAGS
 578      save_LDFLAGS=$LDFLAGS
 579      CFLAGS="$CFLAGS -fPIE"
 580      LDFLAGS="$LDFLAGS -pie"
 581      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 582       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 583      CFLAGS=$save_CFLAGS
 584      LDFLAGS=$save_LDFLAGS
 585    ])
 586    if test "$ap_cv_cc_pie" = "yes"; then
 587      PICFLAGS="-fPIE"
 588      PILDFLAGS="-pie"
 589    else
 590      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 591    fi
 592 fi
 593 AC_SUBST(PICFLAGS)
 594 AC_SUBST(PILDFLAGS)
 595
 596 prefix="$orig_prefix"
 597 APACHE_ENABLE_MODULES
 598
 599 dnl reading config stubs
 600 esyscmd(./build/config-stubs .)
 601
 602 APACHE_SUBST(progname)
 603 APACHE_SUBST(OS)
 604 APACHE_SUBST(OS_DIR)
 605 APACHE_SUBST(BUILTIN_LIBS)
 606 APACHE_SUBST(SHLIBPATH_VAR)
 607 APACHE_SUBST(OS_SPECIFIC_VARS)
 608
 609 PRE_SHARED_CMDS='echo ""'
 610 POST_SHARED_CMDS='echo ""'
 611
 612 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 613
 614 if test "$apache_need_shared" = "yes"; then
 615   if test -f $ac_aux_dir/ltconfig; then
 616     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 617   fi
 618   shared_build="shared-build"
 619 fi
 620
 621 dnl enable_so tells us if *any* modules can be built as DSOs
 622
 623 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 624   case $host in
 625     *-ibm-aix*)
 626       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 627       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 628       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 629       ;;
 630     *os390)
 631       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 632       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 633   esac
 634   MOD_SO_ENABLED=yes
 635 fi
 636 AC_SUBST(MOD_SO_ENABLED)
 637
 638 APACHE_SUBST(PRE_SHARED_CMDS)
 639 APACHE_SUBST(POST_SHARED_CMDS)
 640 APACHE_SUBST(shared_build)
 641
 642 AC_ARG_WITH(program-name,
 643 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 644   progname="$withval" ], [
 645   progname="httpd"] )
 646
 647 # SuExec parameters
 648 AC_ARG_WITH(suexec-bin,
 649 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 650   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 651 ] )
 652
 653 AC_ARG_WITH(suexec-caller,
 654 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 655   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 656
 657 AC_ARG_WITH(suexec-userdir,
 658 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 659   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 660
 661 AC_ARG_WITH(suexec-docroot,
 662 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 663   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 664
 665 AC_ARG_WITH(suexec-uidmin,
 666 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 667   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 668
 669 AC_ARG_WITH(suexec-gidmin,
 670 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 671   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 672
 673 AC_ARG_WITH(suexec-logfile,
 674 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 675   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 676
 677 AC_ARG_WITH(suexec-safepath,
 678 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 679   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 680
 681 AC_ARG_WITH(suexec-umask,
 682 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 683   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 684
 685 dnl APR should go after the other libs, so the right symbols can be picked up
 686 if test x${apu_found} != xobsolete; then
 687   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 688 fi
 689 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 690 APACHE_SUBST(AP_LIBS)
 691 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 692 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 693
 694 AC_DEFINE(AP_USING_AUTOCONF, 1,
 695                 [Using autoconf to configure Apache])
 696
 697 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 698     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 699               [This platform doesn't suffer from the thundering herd problem])
 700 fi
 701
 702 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 703     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 704               [Listening sockets are non-blocking when there are more than 1])
 705 fi
 706
 707 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 708
 709 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 710 [
 711   v4mapped=$enableval
 712 ],
 713 [
 714     case $host in
 715     *freebsd5*|*netbsd*|*openbsd*)
 716         v4mapped=no
 717         ;;
 718     *)
 719         v4mapped=yes
 720         ;;
 721     esac
 722     if ap_mpm_is_enabled winnt; then
 723         dnl WinNT MPM doesn't support this.
 724         v4mapped=no
 725     fi
 726 ])
 727
 728 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 729     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 730               [Allow IPv4 connections on IPv6 listening sockets])
 731 fi
 732
 733 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 734 [
 735   LOAD_ALL_MODULES=$enableval
 736 ],
 737 [
 738   LOAD_ALL_MODULES="no"
 739 ])
 740
 741 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 742 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 743 APACHE_FAST_OUTPUT(support/Makefile)
 744
 745 if test -d ./test; then
 746     APACHE_FAST_OUTPUT(test/Makefile)
 747 fi
 748
 749 dnl ## Finalize the variables
 750 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 751
 752 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 753 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 754 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 755 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 756 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 757 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 758
 759 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 760
 761 APACHE_GEN_CONFIG_VARS
 762
 763 dnl ## Build modules.c
 764 rm -f modules.c
 765 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 766
 767 APR_EXPAND_VAR(ap_prefix, $prefix)
 768 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 769         [Root directory of the Apache install area])
 770 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 771         [Location of the config file, relative to the Apache root directory])
 772 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 773         [Location of the MIME types config file, relative to the Apache root directory])
 774
 775 perlbin=`$ac_aux_dir/PrintPath perl`
 776 if test "x$perlbin" = "x"; then
 777     perlbin="/replace/with/path/to/perl/interpreter"
 778 fi
 779 AC_SUBST(perlbin)
 780
 781 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 782
 783 BSD_MAKEFILE=no
 784 ap_make_include=include
 785 ap_make_delimiter=' '
 786 case $host in
 787 *bsdi*)
 788     # Check whether they've installed GNU make
 789     if make --version > /dev/null 2>&1; then
 790         true
 791     else
 792         BSD_MAKEFILE=yes
 793         ap_make_include=.include
 794         ap_make_delimiter='"'
 795     fi
 796     ;;
 797 esac
 798 AC_SUBST(ap_make_include)
 799 AC_SUBST(ap_make_delimiter)
 800
 801 dnl Ensure that docs/conf is created.
 802 test -d docs/conf||$mkdir_p docs/conf
 803
 804 dnl Ensure that the httpd version is included
 805 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 806 AC_SUBST(HTTPD_VERSION)
 807
 808 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 809   APACHE_GEN_MAKEFILES
 810 ])