granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="./srclib/apr/apr-${majorver}-config"
  97     if test -f "$test_apr_config"; then
  98       apr_config="$test_apr_config"
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 108 INTERNAL_CPPFLAGS=""
 109 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 110 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 111 APR_BINDIR=`$apr_config --bindir`
 112 APR_INCLUDEDIR=`$apr_config --includedir`
 113 APR_INCLUDES=`$apr_config --includes`
 114 APR_VERSION=`$apr_config --version`
 115 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 116 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 117
 118 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 119
 120 if test "x${apr_major_version}" = "x2"; then
 121    apu_found=obsolete
 122 elif test "x$with_included_apr" = "xyes"; then
 123    apu_found=reconfig
 124 else
 125    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 126    dnl isn't supported.
 127    ifdef([APR_FIND_APU], [
 128      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 129                   1, ${apr_major_version})
 130    ], [apu_found=no])
 131 fi
 132
 133 if test "$apu_found" = "no"; then
 134   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 135 fi
 136
 137 # Catch some misconfigurations:
 138 case ${apr_found}.${apu_found} in
 139 reconfig.yes)
 140   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 141   ;;
 142 yes.reconfig)
 143   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 144   ;;
 145 esac
 146
 147 if test "$apu_found" = "reconfig"; then
 148   APR_SUBDIR_CONFIG(srclib/apr-util,
 149                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 150                     [--enable-layout=*|\'--enable-layout=*])
 151   dnl We must be the last to build and the first to be cleaned
 152   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 153   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 154   dnl APR and APR-Util major versions must match
 155   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 156 fi
 157
 158 if test "$apu_found" = "obsolete"; then
 159   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 160 else
 161   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 162   APU_BINDIR=`$apu_config --bindir`
 163   APU_INCLUDEDIR=`$apu_config --includedir`
 164   APU_INCLUDES=`$apu_config --includes`
 165   APU_VERSION=`$apu_config --version`
 166   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 167 fi
 168
 169 dnl In case we picked up CC and CPP from APR, get that info into the
 170 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 171 dnl PCRE and for our config tests will be whatever PCRE determines.
 172 AC_PROG_CC
 173 AC_PROG_CPP
 174
 175 dnl Try to get c99 support for variadic macros
 176 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 177
 178 if test "x${cache_file}" = "x/dev/null"; then
 179   # Likewise, ensure that CC and CPP are passed through to the pcre
 180   # configure script iff caching is disabled (the autoconf 2.5x default).
 181   export CC; export CPP
 182 fi
 183
 184 dnl Absolute source/build directory
 185 abs_srcdir=`(cd $srcdir && pwd)`
 186 abs_builddir=`pwd`
 187
 188 AC_ARG_WITH(pcre,
 189 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 190
 191 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 192 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 193    PCRE_CONFIG=$with_pcre/bin/pcre-config
 194 elif test -x "$with_pcre"; then
 195    PCRE_CONFIG=$with_pcre
 196 fi
 197
 198 if test "$PCRE_CONFIG" != "false"; then
 199   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 200     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 201   fi
 202   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 203   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 204   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 205 else
 206   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 207 fi
 208 APACHE_SUBST(PCRE_LIBS)
 209
 210 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 211
 212 dnl If the source dir is not equal to the build dir,
 213 dnl then we are running in VPATH mode.
 214
 215 APR_ADDTO(INCLUDES, [-I.])
 216
 217 if test "$abs_builddir" != "$abs_srcdir"; then
 218   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 219 fi
 220
 221 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 222
 223 # apr/apr-util --includes may pick up system paths for dependent
 224 # libraries, so ensure these are later in INCLUDES than local source
 225 # directories.
 226 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 227 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 228
 229 dnl Add in path to PCRE includes
 230 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 231
 232 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 233
 234 case $host in
 235   *os2*)
 236       # Use a custom made libtool replacement
 237       echo "using aplibtool"
 238       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 239       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 240       SH_LIBS="\$(ALL_LIBS)"
 241       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 242       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 243       MK_IMPLIB="emximp"
 244       other_targets="$other_targets os2core"
 245       INSTALL_PROG_FLAGS="-e .exe"
 246       SHLTCFLAGS=""
 247       LTCFLAGS=""
 248       ;;
 249   *)
 250       if test "x$LTFLAGS" = "x"; then
 251           LTFLAGS='--silent'
 252       fi
 253       my_libtool=`$apr_config --apr-libtool`
 254       LIBTOOL="$my_libtool \$(LTFLAGS)"
 255       libtoolversion=`$my_libtool --version`
 256       case $libtoolversion in
 257           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 258               SH_LIBTOOL='$(LIBTOOL)'
 259               SHLTCFLAGS="-prefer-pic"
 260               LTCFLAGS="-prefer-non-pic -static"
 261               ;;
 262           *)
 263               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 264               SHLTCFLAGS=""
 265               LTCFLAGS=""
 266               ;;
 267       esac
 268       ;;
 269 esac
 270 APACHE_SUBST(SHLTCFLAGS)
 271 APACHE_SUBST(LTCFLAGS)
 272
 273 case $host in
 274   *-apple-aux3*)
 275       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 276       ;;
 277   *os2-emx*)
 278       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 279       ;;
 280   *-linux-*)
 281       case `uname -r` in
 282         2.[[2-9]]* )
 283             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 284             ;;
 285         * )
 286             ;;
 287       esac
 288       ;;
 289   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 290       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 291       ;;
 292   *-solaris2*)
 293       dnl This is a hack -- we should be using AC_TRY_RUN instead
 294       ap_platform_runtime_link_flag="-R"
 295       dnl solaris 8 and above don't have a thundering herd
 296       dnl not sure about rev's before this one.
 297       case `uname -r` in
 298         5.[567]*)
 299             ;;
 300         * )
 301             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 302             ;;
 303       esac
 304       ;;
 305   *cygwin*)
 306       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 307       ;;
 308   *mingw32*)
 309       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 310       APR_SETIFNULL(ac_cv_func_times, [no])
 311       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 312       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 313       ;;
 314   *aix*)
 315       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 316       if test $aixver -ge 4320; then
 317         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 318       fi
 319       ;;
 320   *os390*)
 321       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 322       ;;
 323 esac
 324
 325 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 326
 327 dnl
 328 dnl Process command line arguments. This is done early in the process so the
 329 dnl user can get feedback quickly in case of an error.
 330 dnl
 331 dnl ### need to move some of the arguments "up here"
 332
 333 dnl ## Check for programs
 334
 335 AC_PATH_PROG(RM, rm)
 336 AC_PATH_PROG(PKGCONFIG, pkg-config)
 337 AC_PATH_PROG(RSYNC, rsync)
 338 AC_PROG_AWK
 339 AC_PROG_LN_S
 340 AC_CHECK_TOOL(RANLIB, ranlib, true)
 341 dnl AC_PATH_PROG(PERL_PATH, perl)
 342 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 343
 344 # Hard-coded install programs
 345 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 346 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 347 APACHE_SUBST(MKINSTALLDIRS)
 348 APACHE_SUBST(INSTALL)
 349
 350 dnl Various OS checks that apparently set required flags
 351 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 352 AC_USE_SYSTEM_EXTENSIONS
 353 ], [
 354 AC_AIX
 355 AC_MINIX
 356 ])
 357
 358 AC_ISC_POSIX
 359
 360 # Ensure that satisfactory versions of apr and apr-util are
 361 # found if external copies are configured.
 362 if test "${apr_found}" = "yes"; then
 363   # Require at least APR 1.3.x otherwise fail
 364   APACHE_CHECK_APxVER([apr], 1, 3)
 365 fi
 366
 367 if test "${apu_found}" = "yes"; then
 368   # Require at least APR-util 1.3.x otherwise fail
 369   if test "${apr_found}" = "yes"; then
 370     # we need to add the APR includes to CPPFLAGS
 371     apu_ckver_CPPFLAGS="$CPPFLAGS"
 372     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 373     APACHE_CHECK_APxVER([apu], 1, 3)
 374     CPPFLAGS="$apu_ckver_CPPFLAGS"
 375   else
 376     APACHE_CHECK_APxVER([apu], 1, 3)
 377   fi
 378 fi
 379
 380 dnl Check for what we can generate dependency files with
 381 APR_CHECK_DEPEND
 382
 383 dnl ## Check for libraries
 384
 385 dnl ## Check for header files
 386
 387 dnl I think these are just used all over the place, so just check for
 388 dnl them at the base of the tree. If some are specific to a single
 389 dnl directory, they should be moved (Comment #Spoon)
 390
 391 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 392 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 393 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 394
 395 AC_HEADER_STDC
 396 AC_CHECK_HEADERS( \
 397 string.h \
 398 limits.h \
 399 unistd.h \
 400 sys/socket.h \
 401 pwd.h \
 402 grp.h \
 403 strings.h \
 404 sys/prctl.h \
 405 sys/processor.h \
 406 sys/sem.h \
 407 sys/sdt.h
 408 )
 409 AC_HEADER_SYS_WAIT
 410
 411 dnl ## Check for typedefs, structures, and compiler characteristics.
 412
 413 AC_C_CONST
 414
 415 dnl ## Check for library functions
 416 dnl ## sqrt() only needed in support/ab.c
 417 saved_LIBS="$LIBS"
 418 LIBS=""
 419 AC_SEARCH_LIBS(sqrt, m)
 420 MATH_LIBS="$LIBS"
 421 APACHE_SUBST(MATH_LIBS)
 422 LIBS="$saved_LIBS"
 423
 424 saved_LIBS="$LIBS"
 425 LIBS=""
 426 AC_SEARCH_LIBS(crypt, crypt)
 427 CRYPT_LIBS="$LIBS"
 428 APACHE_SUBST(CRYPT_LIBS)
 429 LIBS="$saved_LIBS"
 430
 431 dnl See Comment #Spoon
 432
 433 AC_CHECK_FUNCS( \
 434 getpwnam \
 435 getgrnam \
 436 initgroups \
 437 bindprocessor \
 438 prctl \
 439 timegm \
 440 getpgid \
 441 fopen64
 442 )
 443
 444 dnl confirm that a void pointer is large enough to store a long integer
 445 APACHE_CHECK_VOID_PTR_LEN
 446
 447 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 448 [AC_TRY_RUN(#define _GNU_SOURCE
 449 #include <unistd.h>
 450 #include <sys/syscall.h>
 451 #include <sys/types.h>
 452 int main(int argc, char **argv) {
 453 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 454 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 455 if test "$ac_cv_gettid" = "yes"; then
 456     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 457 fi
 458
 459 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 460 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 461 [AC_TRY_COMPILE([#include <sys/types.h>
 462 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 463   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 464 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 465     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 466 fi
 467
 468 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 469
 470 case $host in
 471     *aix*)
 472         # for 32-bit builds, increase MAXDATA to allow lots of threads
 473         if test x$OBJECT_MODE != x64; then
 474             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 475         fi
 476         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 477         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 478         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 479         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 480         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 481         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 482         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 483         ;;
 484     *os390*)
 485         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 486         ;;
 487     *)
 488         OS_SPECIFIC_VARS=""
 489 esac
 490
 491 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 492         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 493         [PORT=80])
 494
 495 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 496         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 497         [SSLPORT=443])
 498
 499 DTRACE=true
 500 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 501 [
 502   enable_dtrace=$enableval
 503   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 504   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 505 ],
 506 [
 507   enable_dtrace=no
 508 ])
 509
 510 dnl Disabled dtrace build for now.
 511 enable_dtrace=no
 512
 513 case $host in
 514   *-solaris2*)
 515     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 516         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 517                   [Enable DTrace probes])
 518         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 519         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 520     fi
 521     ;;
 522 esac
 523
 524 APACHE_SUBST(DTRACE)
 525
 526 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 527 [
 528     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 529         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 530     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 531 ])dnl
 532
 533 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 534 [
 535     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 536               [Allow modules to run hook after a fatal exception])
 537 ])dnl
 538
 539 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 540 [
 541   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 542   if test "$GCC" = "yes"; then
 543     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 544     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 545     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 546     APACHE_ADD_GCC_CFLAG([-Wformat])
 547     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 548     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 549   elif test "$AIX_XLC" = "yes"; then
 550     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 551   fi
 552 ])dnl
 553
 554 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 555 [
 556   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 557   if test "$GCC" = "yes"; then
 558     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 559     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 560     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 561     APACHE_ADD_GCC_CFLAG([-Wformat])
 562     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 563     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 564   elif test "$AIX_XLC" = "yes"; then
 565     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 566   fi
 567 ])dnl
 568
 569 dnl Conditionally enable PIE support for GNU toolchains.
 570 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 571 if test "$enable_pie" = "yes"; then
 572    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 573      save_CFLAGS=$CFLAGS
 574      save_LDFLAGS=$LDFLAGS
 575      CFLAGS="$CFLAGS -fPIE"
 576      LDFLAGS="$LDFLAGS -pie"
 577      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 578       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 579      CFLAGS=$save_CFLAGS
 580      LDFLAGS=$save_LDFLAGS
 581    ])
 582    if test "$ap_cv_cc_pie" = "yes"; then
 583      PICFLAGS="-fPIE"
 584      PILDFLAGS="-pie"
 585    else
 586      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 587    fi
 588 fi
 589 AC_SUBST(PICFLAGS)
 590 AC_SUBST(PILDFLAGS)
 591
 592 prefix="$orig_prefix"
 593 APACHE_ENABLE_MODULES
 594
 595 dnl reading config stubs
 596 esyscmd(./build/config-stubs .)
 597
 598 APACHE_SUBST(progname)
 599 APACHE_SUBST(OS)
 600 APACHE_SUBST(OS_DIR)
 601 APACHE_SUBST(BUILTIN_LIBS)
 602 APACHE_SUBST(SHLIBPATH_VAR)
 603 APACHE_SUBST(OS_SPECIFIC_VARS)
 604
 605 PRE_SHARED_CMDS='echo ""'
 606 POST_SHARED_CMDS='echo ""'
 607
 608 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 609
 610 if test "$apache_need_shared" = "yes"; then
 611   if test -f $ac_aux_dir/ltconfig; then
 612     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 613   fi
 614   shared_build="shared-build"
 615 fi
 616
 617 dnl enable_so tells us if *any* modules can be built as DSOs
 618
 619 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 620   case $host in
 621     *-ibm-aix*)
 622       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 623       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 624       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 625       ;;
 626     *os390)
 627       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 628       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 629   esac
 630   MOD_SO_ENABLED=yes
 631 fi
 632 AC_SUBST(MOD_SO_ENABLED)
 633
 634 APACHE_SUBST(PRE_SHARED_CMDS)
 635 APACHE_SUBST(POST_SHARED_CMDS)
 636 APACHE_SUBST(shared_build)
 637
 638 AC_ARG_WITH(program-name,
 639 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 640   progname="$withval" ], [
 641   progname="httpd"] )
 642
 643 # SuExec parameters
 644 AC_ARG_WITH(suexec-bin,
 645 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 646   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 647 ] )
 648
 649 AC_ARG_WITH(suexec-caller,
 650 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 651   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 652
 653 AC_ARG_WITH(suexec-userdir,
 654 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 655   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 656
 657 AC_ARG_WITH(suexec-docroot,
 658 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 659   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 660
 661 AC_ARG_WITH(suexec-uidmin,
 662 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 663   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 664
 665 AC_ARG_WITH(suexec-gidmin,
 666 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 667   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 668
 669 AC_ARG_WITH(suexec-logfile,
 670 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 671   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 672
 673 AC_ARG_WITH(suexec-safepath,
 674 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 675   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 676
 677 AC_ARG_WITH(suexec-umask,
 678 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 679   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 680
 681 dnl APR should go after the other libs, so the right symbols can be picked up
 682 if test x${apu_found} != xobsolete; then
 683   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 684 fi
 685 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 686 APACHE_SUBST(AP_LIBS)
 687 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 688 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 689
 690 AC_DEFINE(AP_USING_AUTOCONF, 1,
 691                 [Using autoconf to configure Apache])
 692
 693 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 694     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 695               [This platform doesn't suffer from the thundering herd problem])
 696 fi
 697
 698 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 699     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 700               [Listening sockets are non-blocking when there are more than 1])
 701 fi
 702
 703 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 704
 705 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 706 [
 707   v4mapped=$enableval
 708 ],
 709 [
 710     case $host in
 711     *freebsd5*|*netbsd*|*openbsd*)
 712         v4mapped=no
 713         ;;
 714     *)
 715         v4mapped=yes
 716         ;;
 717     esac
 718     if ap_mpm_is_enabled winnt; then
 719         dnl WinNT MPM doesn't support this.
 720         v4mapped=no
 721     fi
 722 ])
 723
 724 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 725     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 726               [Allow IPv4 connections on IPv6 listening sockets])
 727 fi
 728
 729 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 730 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 731 APACHE_FAST_OUTPUT(support/Makefile)
 732
 733 if test -d ./test; then
 734     APACHE_FAST_OUTPUT(test/Makefile)
 735 fi
 736
 737 dnl ## Finalize the variables
 738 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 739
 740 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 741 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 742 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 743 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 744 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 745 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 746
 747 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 748
 749 APACHE_GEN_CONFIG_VARS
 750
 751 dnl ## Build modules.c
 752 rm -f modules.c
 753 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 754
 755 APR_EXPAND_VAR(ap_prefix, $prefix)
 756 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 757         [Root directory of the Apache install area])
 758 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 759         [Location of the config file, relative to the Apache root directory])
 760 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 761         [Location of the MIME types config file, relative to the Apache root directory])
 762
 763 perlbin=`$ac_aux_dir/PrintPath perl`
 764 if test "x$perlbin" = "x"; then
 765     perlbin="/replace/with/path/to/perl/interpreter"
 766 fi
 767 AC_SUBST(perlbin)
 768
 769 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 770
 771 BSD_MAKEFILE=no
 772 ap_make_include=include
 773 ap_make_delimiter=' '
 774 case $host in
 775 *bsdi*)
 776     # Check whether they've installed GNU make
 777     if make --version > /dev/null 2>&1; then
 778         true
 779     else
 780         BSD_MAKEFILE=yes
 781         ap_make_include=.include
 782         ap_make_delimiter='"'
 783     fi
 784     ;;
 785 esac
 786 AC_SUBST(ap_make_include)
 787 AC_SUBST(ap_make_delimiter)
 788
 789 dnl Ensure that docs/conf is created.
 790 test -d docs/conf||$mkdir_p docs/conf
 791
 792 dnl Ensure that the httpd version is included
 793 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 794 AC_SUBST(HTTPD_VERSION)
 795
 796 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 797   APACHE_GEN_MAKEFILES
 798 ])