granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(build/find_ldap.m4)
  20 sinclude(acinclude.m4)
  21
  22 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  23 dnl configure script to emit at least warnings when it comes across unknown
  24 dnl command line options. These versions also have the macro
  25 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  26 dnl We want to have this turned off here since our configure calls can
  27 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  28 dnl So avoid confusing the user by turning this off. See also PR 45221.
  29 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  30
  31 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  32 dnl by configure until it is too late.  Is that how it should be or not?
  33 dnl Something seems broken here.
  34 AC_PREFIX_DEFAULT(/usr/local/apache2)
  35
  36 dnl Get the layout here, so we can pass the required variables to apr
  37 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  38
  39 dnl reparse the configure arguments.
  40 APR_PARSE_ARGUMENTS
  41
  42 dnl export expanded and relative configure argument variables
  43 APACHE_EXPORT_ARGUMENTS
  44
  45 dnl Save user-defined environment settings for later restoration
  46 dnl
  47 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  51 APR_SAVE_THE_ENVIRONMENT(LIBS)
  52 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  53
  54 dnl Generate ./config.nice for reproducing runs of configure
  55 dnl
  56 APR_CONFIG_NICE(config.nice)
  57
  58 nl='
  59 '
  60 dnl Check that mkdir -p works
  61 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  62
  63 dnl ## Run configure for packages Apache uses
  64
  65 dnl shared library support for these packages doesn't currently
  66 dnl work on some platforms
  67
  68 AC_CANONICAL_SYSTEM
  69
  70 orig_prefix="$prefix"
  71
  72 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  73
  74 AC_ARG_WITH(included-apr,
  75 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  76
  77 if test "x$with_included_apr" = "xyes"; then
  78    apr_found=reconfig
  79 else
  80    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  81 fi
  82
  83 if test "$apr_found" = "no"; then
  84   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  85 fi
  86
  87 if test "$apr_found" = "reconfig"; then
  88   APR_SUBDIR_CONFIG(srclib/apr,
  89                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  90                     [--enable-layout=*|\'--enable-layout=*])
  91   dnl We must be the first to build and the last to be cleaned
  92   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  93   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  94
  95   dnl We have to find apr-N-config when we reconfigure APR.
  96   for majorver in 1 2; do
  97     test_apr_config="./srclib/apr/apr-${majorver}-config"
  98     if test -f "$test_apr_config"; then
  99       apr_config="$test_apr_config"
 100     fi
 101   done
 102 fi
 103
 104 APR_SETIFNULL(CC, `$apr_config --cc`)
 105 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 106 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 107 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 108 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 109 INTERNAL_CPPFLAGS=""
 110 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 111 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 112 APR_BINDIR=`$apr_config --bindir`
 113 APR_INCLUDEDIR=`$apr_config --includedir`
 114 APR_INCLUDES=`$apr_config --includes`
 115 APR_VERSION=`$apr_config --version`
 116 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 117 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 118
 119 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 120
 121 if test "x${apr_major_version}" = "x2"; then
 122    apu_found=obsolete
 123 elif test "x$with_included_apr" = "xyes"; then
 124    apu_found=reconfig
 125 else
 126    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 127    dnl isn't supported.
 128    ifdef([APR_FIND_APU], [
 129      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 130                   1, ${apr_major_version})
 131    ], [apu_found=no])
 132 fi
 133
 134 if test "$apu_found" = "no"; then
 135   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 136 fi
 137
 138 # Catch some misconfigurations:
 139 case ${apr_found}.${apu_found} in
 140 reconfig.yes)
 141   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 142   ;;
 143 yes.reconfig)
 144   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 145   ;;
 146 esac
 147
 148 if test "$apu_found" = "reconfig"; then
 149   APR_SUBDIR_CONFIG(srclib/apr-util,
 150                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 151                     [--enable-layout=*|\'--enable-layout=*])
 152   dnl We must be the last to build and the first to be cleaned
 153   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 154   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 155   dnl APR and APR-Util major versions must match
 156   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 157 fi
 158
 159 if test "$apu_found" = "obsolete"; then
 160   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 161 else
 162   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 163   APU_BINDIR=`$apu_config --bindir`
 164   APU_INCLUDEDIR=`$apu_config --includedir`
 165   APU_INCLUDES=`$apu_config --includes`
 166   APU_VERSION=`$apu_config --version`
 167   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 168 fi
 169
 170 dnl In case we picked up CC and CPP from APR, get that info into the
 171 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 172 dnl PCRE and for our config tests will be whatever PCRE determines.
 173 AC_PROG_CC
 174 AC_PROG_CPP
 175
 176 dnl Try to get c99 support for variadic macros
 177 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 178
 179 if test "x${cache_file}" = "x/dev/null"; then
 180   # Likewise, ensure that CC and CPP are passed through to the pcre
 181   # configure script iff caching is disabled (the autoconf 2.5x default).
 182   export CC; export CPP
 183 fi
 184
 185 dnl Absolute source/build directory
 186 abs_srcdir=`(cd $srcdir && pwd)`
 187 abs_builddir=`pwd`
 188
 189 AC_ARG_WITH(pcre,
 190 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 191
 192 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 193 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 194    PCRE_CONFIG=$with_pcre/bin/pcre-config
 195 elif test -x "$with_pcre"; then
 196    PCRE_CONFIG=$with_pcre
 197 fi
 198
 199 if test "$PCRE_CONFIG" != "false"; then
 200   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 201     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 202   fi
 203   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 204   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 205   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 206 else
 207   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 208 fi
 209 APACHE_SUBST(PCRE_LIBS)
 210
 211 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 212
 213 dnl If the source dir is not equal to the build dir,
 214 dnl then we are running in VPATH mode.
 215
 216 APR_ADDTO(INCLUDES, [-I.])
 217
 218 if test "$abs_builddir" != "$abs_srcdir"; then
 219   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 220 fi
 221
 222 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 223
 224 # apr/apr-util --includes may pick up system paths for dependent
 225 # libraries, so ensure these are later in INCLUDES than local source
 226 # directories.
 227 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 228 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 229
 230 dnl Add in path to PCRE includes
 231 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 232
 233 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 234
 235 case $host in
 236   *os2*)
 237       # Use a custom made libtool replacement
 238       echo "using aplibtool"
 239       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 240       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 241       SH_LIBS="\$(ALL_LIBS)"
 242       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 243       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 244       MK_IMPLIB="emximp"
 245       other_targets="$other_targets os2core"
 246       INSTALL_PROG_FLAGS="-e .exe"
 247       SHLTCFLAGS=""
 248       LTCFLAGS=""
 249       ;;
 250   *)
 251       if test "x$LTFLAGS" = "x"; then
 252           LTFLAGS='--silent'
 253       fi
 254       my_libtool=`$apr_config --apr-libtool`
 255       LIBTOOL="$my_libtool \$(LTFLAGS)"
 256       libtoolversion=`$my_libtool --version`
 257       case $libtoolversion in
 258           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 259               SH_LIBTOOL='$(LIBTOOL)'
 260               SHLTCFLAGS="-prefer-pic"
 261               LTCFLAGS="-prefer-non-pic -static"
 262               ;;
 263           *)
 264               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 265               SHLTCFLAGS=""
 266               LTCFLAGS=""
 267               ;;
 268       esac
 269       ;;
 270 esac
 271 APACHE_SUBST(SHLTCFLAGS)
 272 APACHE_SUBST(LTCFLAGS)
 273
 274 case $host in
 275   *-apple-aux3*)
 276       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 277       ;;
 278   *os2-emx*)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *-linux-*)
 282       case `uname -r` in
 283         2.[[2-9]]* )
 284             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 285             ;;
 286         * )
 287             ;;
 288       esac
 289       ;;
 290   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 291       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 292       ;;
 293   *-solaris2*)
 294       dnl This is a hack -- we should be using AC_TRY_RUN instead
 295       ap_platform_runtime_link_flag="-R"
 296       dnl solaris 8 and above don't have a thundering herd
 297       dnl not sure about rev's before this one.
 298       case `uname -r` in
 299         5.[567]*)
 300             ;;
 301         * )
 302             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 303             ;;
 304       esac
 305       ;;
 306   *cygwin*)
 307       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 308       ;;
 309   *mingw32*)
 310       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 311       APR_SETIFNULL(ac_cv_func_times, [no])
 312       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 313       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 314       ;;
 315   *aix*)
 316       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 317       if test $aixver -ge 4320; then
 318         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 319       fi
 320       ;;
 321   *os390*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324 esac
 325
 326 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 327
 328 dnl
 329 dnl Process command line arguments. This is done early in the process so the
 330 dnl user can get feedback quickly in case of an error.
 331 dnl
 332 dnl ### need to move some of the arguments "up here"
 333
 334 dnl ## Check for programs
 335
 336 AC_PATH_PROG(RM, rm)
 337 AC_PATH_PROG(PKGCONFIG, pkg-config)
 338 AC_PATH_PROG(RSYNC, rsync)
 339 AC_PROG_AWK
 340 AC_PROG_LN_S
 341 AC_CHECK_TOOL(RANLIB, ranlib, true)
 342 dnl AC_PATH_PROG(PERL_PATH, perl)
 343 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 344
 345 # Hard-coded install programs
 346 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 347 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 348 APACHE_SUBST(MKINSTALLDIRS)
 349 APACHE_SUBST(INSTALL)
 350
 351 dnl Various OS checks that apparently set required flags
 352 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 353 AC_USE_SYSTEM_EXTENSIONS
 354 ], [
 355 AC_AIX
 356 AC_MINIX
 357 ])
 358
 359 AC_ISC_POSIX
 360
 361 # Ensure that satisfactory versions of apr and apr-util are
 362 # found if external copies are configured.
 363 if test "${apr_found}" = "yes"; then
 364   # Require at least APR 1.3.x otherwise fail
 365   APACHE_CHECK_APxVER([apr], 1, 3)
 366 fi
 367
 368 if test "${apu_found}" = "yes"; then
 369   # Require at least APR-util 1.3.x otherwise fail
 370   if test "${apr_found}" = "yes"; then
 371     # we need to add the APR includes to CPPFLAGS
 372     apu_ckver_CPPFLAGS="$CPPFLAGS"
 373     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 374     APACHE_CHECK_APxVER([apu], 1, 3)
 375     CPPFLAGS="$apu_ckver_CPPFLAGS"
 376   else
 377     APACHE_CHECK_APxVER([apu], 1, 3)
 378   fi
 379 fi
 380
 381 dnl Check for what we can generate dependency files with
 382 APR_CHECK_DEPEND
 383
 384 dnl ## Check for libraries
 385
 386 dnl ## Check for header files
 387
 388 dnl I think these are just used all over the place, so just check for
 389 dnl them at the base of the tree. If some are specific to a single
 390 dnl directory, they should be moved (Comment #Spoon)
 391
 392 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 393 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 394 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 395
 396 AC_HEADER_STDC
 397 AC_CHECK_HEADERS( \
 398 string.h \
 399 limits.h \
 400 unistd.h \
 401 sys/socket.h \
 402 pwd.h \
 403 grp.h \
 404 strings.h \
 405 sys/prctl.h \
 406 sys/processor.h \
 407 sys/sem.h \
 408 sys/sdt.h
 409 )
 410 AC_HEADER_SYS_WAIT
 411
 412 dnl ## Check for typedefs, structures, and compiler characteristics.
 413
 414 AC_C_CONST
 415
 416 dnl ## Check for library functions
 417 dnl ## sqrt() only needed in support/ab.c
 418 saved_LIBS="$LIBS"
 419 LIBS=""
 420 AC_SEARCH_LIBS(sqrt, m)
 421 MATH_LIBS="$LIBS"
 422 APACHE_SUBST(MATH_LIBS)
 423 LIBS="$saved_LIBS"
 424
 425 saved_LIBS="$LIBS"
 426 LIBS=""
 427 AC_SEARCH_LIBS(crypt, crypt)
 428 CRYPT_LIBS="$LIBS"
 429 APACHE_SUBST(CRYPT_LIBS)
 430 LIBS="$saved_LIBS"
 431
 432 dnl See Comment #Spoon
 433
 434 AC_CHECK_FUNCS( \
 435 getpwnam \
 436 getgrnam \
 437 initgroups \
 438 bindprocessor \
 439 prctl \
 440 timegm \
 441 getpgid \
 442 fopen64
 443 )
 444
 445 dnl confirm that a void pointer is large enough to store a long integer
 446 APACHE_CHECK_VOID_PTR_LEN
 447
 448 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 449 [AC_TRY_RUN(#define _GNU_SOURCE
 450 #include <unistd.h>
 451 #include <sys/syscall.h>
 452 #include <sys/types.h>
 453 int main(int argc, char **argv) {
 454 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 455 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 456 if test "$ac_cv_gettid" = "yes"; then
 457     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 458 fi
 459
 460 dnl check for LDAP support, needed by modules/aaa and modules/ldap
 461 AP_FIND_LDAP
 462
 463 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 464 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 465 [AC_TRY_COMPILE([#include <sys/types.h>
 466 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 467   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 468 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 469     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 470 fi
 471
 472 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 473
 474 case $host in
 475     *aix*)
 476         # for 32-bit builds, increase MAXDATA to allow lots of threads
 477         if test x$OBJECT_MODE != x64; then
 478             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 479         fi
 480         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 481         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 482         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 483         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 484         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 485         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 486         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 487         ;;
 488     *os390*)
 489         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 490         ;;
 491     *)
 492         OS_SPECIFIC_VARS=""
 493 esac
 494
 495 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 496         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 497         [PORT=80])
 498
 499 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 500         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 501         [SSLPORT=443])
 502
 503 DTRACE=true
 504 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 505 [
 506   enable_dtrace=$enableval
 507   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 508   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 509 ],
 510 [
 511   enable_dtrace=no
 512 ])
 513
 514 dnl Disabled dtrace build for now.
 515 enable_dtrace=no
 516
 517 case $host in
 518   *-solaris2*)
 519     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 520         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 521                   [Enable DTrace probes])
 522         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 523         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 524     fi
 525     ;;
 526 esac
 527
 528 APACHE_SUBST(DTRACE)
 529
 530 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 531 [
 532     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 533         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 534     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 535 ])dnl
 536
 537 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 538 [
 539     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 540               [Allow modules to run hook after a fatal exception])
 541 ])dnl
 542
 543 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 544 [
 545   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 546   if test "$GCC" = "yes"; then
 547     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 548     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 549       save_CFLAGS=$CFLAGS
 550       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 551       AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo() { return 0; }])],
 552         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 553       CFLAGS=$save_CFLAGS
 554     ])
 555     if test "$ap_cv_cc_Wdas" = "yes"; then
 556       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 557     fi
 558   elif test "$AIX_XLC" = "yes"; then
 559     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 560   fi
 561 ])dnl
 562
 563 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 564 [
 565   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 566   if test "$GCC" = "yes"; then
 567     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 568     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 569       save_CFLAGS=$CFLAGS
 570       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 571       AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo() { return 0; }])],
 572         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 573       CFLAGS=$save_CFLAGS
 574     ])
 575     if test "$ap_cv_cc_Wdas" = "yes"; then
 576       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 577     fi
 578   elif test "$AIX_XLC" = "yes"; then
 579     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 580   fi
 581 ])dnl
 582
 583 dnl Conditionally enable PIE support for GNU toolchains.
 584 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 585 if test "$enable_pie" = "yes"; then
 586    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 587      save_CFLAGS=$CFLAGS
 588      save_LDFLAGS=$LDFLAGS
 589      CFLAGS="$CFLAGS -fPIE"
 590      LDFLAGS="$LDFLAGS -pie"
 591      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 592       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 593      CFLAGS=$save_CFLAGS
 594      LDFLAGS=$save_LDFLAGS
 595    ])
 596    if test "$ap_cv_cc_pie" = "yes"; then
 597      PICFLAGS="-fPIE"
 598      PILDFLAGS="-pie"
 599    else
 600      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 601    fi
 602 fi
 603 AC_SUBST(PICFLAGS)
 604 AC_SUBST(PILDFLAGS)
 605
 606 prefix="$orig_prefix"
 607 APACHE_ENABLE_MODULES
 608
 609 dnl reading config stubs
 610 esyscmd(./build/config-stubs .)
 611
 612 APACHE_SUBST(progname)
 613 APACHE_SUBST(OS)
 614 APACHE_SUBST(OS_DIR)
 615 APACHE_SUBST(BUILTIN_LIBS)
 616 APACHE_SUBST(SHLIBPATH_VAR)
 617 APACHE_SUBST(OS_SPECIFIC_VARS)
 618
 619 PRE_SHARED_CMDS='echo ""'
 620 POST_SHARED_CMDS='echo ""'
 621
 622 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 623
 624 if test "$apache_need_shared" = "yes"; then
 625   if test -f $ac_aux_dir/ltconfig; then
 626     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 627   fi
 628   shared_build="shared-build"
 629 fi
 630
 631 dnl enable_so tells us if *any* modules can be built as DSOs
 632
 633 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 634   case $host in
 635     *-ibm-aix*)
 636       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 637       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 638       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 639       ;;
 640     *os390)
 641       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 642       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 643   esac
 644   MOD_SO_ENABLED=yes
 645 fi
 646 AC_SUBST(MOD_SO_ENABLED)
 647
 648 APACHE_SUBST(PRE_SHARED_CMDS)
 649 APACHE_SUBST(POST_SHARED_CMDS)
 650 APACHE_SUBST(shared_build)
 651
 652 AC_ARG_WITH(program-name,
 653 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 654   progname="$withval" ], [
 655   progname="httpd"] )
 656
 657 # SuExec parameters
 658 AC_ARG_WITH(suexec-bin,
 659 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 660   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 661 ] )
 662
 663 AC_ARG_WITH(suexec-caller,
 664 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 665   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 666
 667 AC_ARG_WITH(suexec-userdir,
 668 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 669   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 670
 671 AC_ARG_WITH(suexec-docroot,
 672 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 673   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 674
 675 AC_ARG_WITH(suexec-uidmin,
 676 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 677   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 678
 679 AC_ARG_WITH(suexec-gidmin,
 680 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 681   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 682
 683 AC_ARG_WITH(suexec-logfile,
 684 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 685   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 686
 687 AC_ARG_WITH(suexec-safepath,
 688 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 689   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 690
 691 AC_ARG_WITH(suexec-umask,
 692 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 693   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 694
 695 dnl APR should go after the other libs, so the right symbols can be picked up
 696 if test x${apu_found} != xobsolete; then
 697   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 698 fi
 699 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 700 APACHE_SUBST(AP_LIBS)
 701 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 702 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 703
 704 AC_DEFINE(AP_USING_AUTOCONF, 1,
 705                 [Using autoconf to configure Apache])
 706
 707 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 708     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 709               [This platform doesn't suffer from the thundering herd problem])
 710 fi
 711
 712 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 713     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 714               [Listening sockets are non-blocking when there are more than 1])
 715 fi
 716
 717 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 718
 719 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 720 [
 721   v4mapped=$enableval
 722 ],
 723 [
 724     case $host in
 725     *freebsd5*|*netbsd*|*openbsd*)
 726         v4mapped=no
 727         ;;
 728     *)
 729         v4mapped=yes
 730         ;;
 731     esac
 732     if ap_mpm_is_enabled winnt; then
 733         dnl WinNT MPM doesn't support this.
 734         v4mapped=no
 735     fi
 736 ])
 737
 738 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 739     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 740               [Allow IPv4 connections on IPv6 listening sockets])
 741 fi
 742
 743 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 744 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 745 APACHE_FAST_OUTPUT(support/Makefile)
 746
 747 if test -d ./test; then
 748     APACHE_FAST_OUTPUT(test/Makefile)
 749 fi
 750
 751 dnl ## Finalize the variables
 752 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 753
 754 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 755 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 756 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 757 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 758 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 759 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 760
 761 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 762
 763 APACHE_GEN_CONFIG_VARS
 764
 765 dnl ## Build modules.c
 766 rm -f modules.c
 767 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 768
 769 APR_EXPAND_VAR(ap_prefix, $prefix)
 770 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 771         [Root directory of the Apache install area])
 772 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 773         [Location of the config file, relative to the Apache root directory])
 774 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 775         [Location of the MIME types config file, relative to the Apache root directory])
 776
 777 perlbin=`$ac_aux_dir/PrintPath perl`
 778 if test "x$perlbin" = "x"; then
 779     perlbin="/replace/with/path/to/perl/interpreter"
 780 fi
 781 AC_SUBST(perlbin)
 782
 783 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 784
 785 BSD_MAKEFILE=no
 786 ap_make_include=include
 787 ap_make_delimiter=' '
 788 case $host in
 789 *bsdi*)
 790     # Check whether they've installed GNU make
 791     if make --version > /dev/null 2>&1; then
 792         true
 793     else
 794         BSD_MAKEFILE=yes
 795         ap_make_include=.include
 796         ap_make_delimiter='"'
 797     fi
 798     ;;
 799 esac
 800 AC_SUBST(ap_make_include)
 801 AC_SUBST(ap_make_delimiter)
 802
 803 dnl Ensure that docs/conf is created.
 804 test -d docs/conf||$mkdir_p docs/conf
 805
 806 dnl Ensure that the httpd version is included
 807 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 808 AC_SUBST(HTTPD_VERSION)
 809
 810 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 811   APACHE_GEN_MAKEFILES
 812 ])