granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225
 226 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 227 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 228    PCRE_CONFIG=$with_pcre/bin/pcre-config
 229 elif test -x "$with_pcre"; then
 230    PCRE_CONFIG=$with_pcre
 231 fi
 232
 233 if test "$PCRE_CONFIG" != "false"; then
 234   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 235     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 236   fi
 237   case `$PCRE_CONFIG --version` in
 238   [[1-5].*])
 239     AC_MSG_ERROR([Need at least pcre version 6.7])
 240     ;;
 241   [6.[0-6]*])
 242     AC_MSG_ERROR([Need at least pcre version 6.7])
 243     ;;
 244   esac
 245   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 246   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 247   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 248   APR_ADDTO(HTTPD_LIBS, [\$(PCRE_LIBS)])
 249 else
 250   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 251 fi
 252 APACHE_SUBST(PCRE_LIBS)
 253
 254 AC_MSG_NOTICE([])
 255 AC_MSG_NOTICE([Configuring Apache httpd...])
 256 AC_MSG_NOTICE([])
 257
 258 dnl If the source dir is not equal to the build dir,
 259 dnl then we are running in VPATH mode.
 260
 261 APR_ADDTO(INCLUDES, [-I.])
 262
 263 if test "$abs_builddir" != "$abs_srcdir"; then
 264   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 265 fi
 266
 267 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 268
 269 # apr/apr-util --includes may pick up system paths for dependent
 270 # libraries, so ensure these are later in INCLUDES than local source
 271 # directories.
 272 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 273 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 274
 275 dnl Add in path to PCRE includes
 276 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 277
 278 save_CPPFLAGS="$CPPFLAGS"
 279 CPPFLAGS="$CPPFLAGS $PCRE_INCLUDES"
 280 AC_EGREP_CPP(yes,
 281 [
 282 #include <pcre.h>
 283 #ifdef PCRE_DUPNAMES
 284 yes
 285 #endif
 286 ],pcre_have_dupnames=yes,pcre_have_dupnames=no)
 287 if test "$pcre_have_dupnames" != "yes"; then
 288     AC_MSG_ERROR([pcre version does not support PCRE_DUPNAMES])
 289 fi
 290 CPPFLAGS="$save_CPPFLAGS"
 291
 292 AC_MSG_NOTICE([])
 293 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 294 AC_MSG_NOTICE([])
 295
 296 case $host in
 297   *os2*)
 298       # Use a custom made libtool replacement
 299       echo "using aplibtool"
 300       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 301       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 302       SH_LIBS="\$(ALL_LIBS)"
 303       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 304       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 305       MK_IMPLIB="emximp"
 306       other_targets="$other_targets os2core"
 307       INSTALL_PROG_FLAGS="-e .exe"
 308       SHLTCFLAGS=""
 309       LTCFLAGS=""
 310       ;;
 311   *)
 312       if test "x$LTFLAGS" = "x"; then
 313           LTFLAGS='--silent'
 314       fi
 315       my_libtool=`$apr_config --apr-libtool`
 316       LIBTOOL="$my_libtool \$(LTFLAGS)"
 317       libtoolversion=`$my_libtool --version`
 318       case $libtoolversion in
 319           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 320               SH_LIBTOOL='$(LIBTOOL)'
 321               SHLTCFLAGS="-prefer-pic"
 322               LTCFLAGS="-prefer-non-pic -static"
 323               ;;
 324           *)
 325               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 326               SHLTCFLAGS=""
 327               LTCFLAGS=""
 328               ;;
 329       esac
 330       ;;
 331 esac
 332 APACHE_SUBST(SHLTCFLAGS)
 333 APACHE_SUBST(LTCFLAGS)
 334
 335 case $host in
 336   *-apple-aux3*)
 337       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 338       ;;
 339   *os2-emx*)
 340       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 341       ;;
 342   *-linux-*)
 343       case `uname -r` in
 344         # Unserialized accept() was not recommended until Linux 2.2.
 345         [[01]].* | 2.[[01]]* )
 346             ;;
 347         * )
 348             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 349             ;;
 350       esac
 351       ;;
 352   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 353       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 354       ;;
 355   *-solaris2*)
 356       dnl This is a hack -- we should be using AC_TRY_RUN instead
 357       ap_platform_runtime_link_flag="-R"
 358       dnl solaris 8 and above don't have a thundering herd
 359       dnl not sure about rev's before this one.
 360       case `uname -r` in
 361         5.[567]*)
 362             ;;
 363         * )
 364             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 365             ;;
 366       esac
 367       ;;
 368   *cygwin*)
 369       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 370       ;;
 371   *mingw32*)
 372       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 373       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 374       APR_SETIFNULL(ac_cv_func_times, [no])
 375       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 376       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 377       ;;
 378   *aix*)
 379       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 380       if test $aixver -ge 4320; then
 381         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 382       fi
 383       ;;
 384   *os390*)
 385       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 386       ;;
 387 esac
 388
 389 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 390
 391 dnl
 392 dnl Process command line arguments. This is done early in the process so the
 393 dnl user can get feedback quickly in case of an error.
 394 dnl
 395 dnl ### need to move some of the arguments "up here"
 396
 397 dnl ## Check for programs
 398
 399 AC_PATH_PROG(RM, rm)
 400 AC_PATH_PROG(PKGCONFIG, pkg-config)
 401 AC_PATH_PROG(RSYNC, rsync)
 402 AC_PROG_AWK
 403 AC_PROG_LN_S
 404 AC_CHECK_TOOL(RANLIB, ranlib, true)
 405 dnl AC_PATH_PROG(PERL_PATH, perl)
 406 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 407
 408 # Hard-coded install programs
 409 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 410 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 411 APACHE_SUBST(MKINSTALLDIRS)
 412 APACHE_SUBST(INSTALL)
 413
 414 dnl Various OS checks that apparently set required flags
 415 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 416 AC_USE_SYSTEM_EXTENSIONS
 417 ], [
 418 AC_AIX
 419 AC_MINIX
 420 ])
 421
 422 AC_ISC_POSIX
 423
 424 # Ensure that satisfactory versions of apr and apr-util are
 425 # found if external copies are configured.
 426 if test "${apr_found}" = "yes"; then
 427   # Require at least APR 1.3.x otherwise fail
 428   APACHE_CHECK_APxVER([apr], 1, 3)
 429 fi
 430
 431 if test "${apu_found}" = "yes"; then
 432   # Require at least APR-util 1.3.x otherwise fail
 433   if test "${apr_found}" = "yes"; then
 434     # we need to add the APR includes to CPPFLAGS
 435     apu_ckver_CPPFLAGS="$CPPFLAGS"
 436     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 437     APACHE_CHECK_APxVER([apu], 1, 3)
 438     CPPFLAGS="$apu_ckver_CPPFLAGS"
 439   else
 440     APACHE_CHECK_APxVER([apu], 1, 3)
 441   fi
 442 fi
 443
 444 dnl Check for what we can generate dependency files with
 445 APR_CHECK_DEPEND
 446
 447 dnl ## Check for libraries
 448
 449 dnl ## Check for header files
 450
 451 dnl I think these are just used all over the place, so just check for
 452 dnl them at the base of the tree. If some are specific to a single
 453 dnl directory, they should be moved (Comment #Spoon)
 454
 455 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 456 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 457 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 458
 459 AC_HEADER_STDC
 460 AC_CHECK_HEADERS( \
 461 string.h \
 462 limits.h \
 463 unistd.h \
 464 sys/socket.h \
 465 pwd.h \
 466 grp.h \
 467 strings.h \
 468 sys/prctl.h \
 469 sys/processor.h \
 470 sys/sem.h \
 471 sys/sdt.h \
 472 sys/loadavg.h
 473 )
 474 AC_HEADER_SYS_WAIT
 475
 476 dnl ## Check for typedefs, structures, and compiler characteristics.
 477
 478 AC_C_CONST
 479
 480 dnl ## Check for library functions
 481 dnl ## sqrt() only needed in support/ab.c
 482 saved_LIBS="$LIBS"
 483 LIBS=""
 484 AC_SEARCH_LIBS(sqrt, m)
 485 MATH_LIBS="$LIBS"
 486 APACHE_SUBST(MATH_LIBS)
 487 LIBS="$saved_LIBS"
 488
 489 saved_LIBS="$LIBS"
 490 LIBS=""
 491 AC_SEARCH_LIBS(crypt, crypt)
 492 CRYPT_LIBS="$LIBS"
 493 APACHE_SUBST(CRYPT_LIBS)
 494 LIBS="$saved_LIBS"
 495
 496 dnl See Comment #Spoon
 497
 498 AC_CHECK_FUNCS( \
 499 getpwnam \
 500 getgrnam \
 501 initgroups \
 502 bindprocessor \
 503 prctl \
 504 timegm \
 505 getpgid \
 506 fopen64 \
 507 getloadavg
 508 )
 509
 510 dnl confirm that a void pointer is large enough to store a long integer
 511 APACHE_CHECK_VOID_PTR_LEN
 512
 513 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 514 [AC_TRY_RUN(#define _GNU_SOURCE
 515 #include <unistd.h>
 516 #include <sys/syscall.h>
 517 #include <sys/types.h>
 518 int main(int argc, char **argv) {
 519 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 520 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 521 if test "$ac_cv_gettid" = "yes"; then
 522     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 523 fi
 524
 525 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 526 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 527 [AC_TRY_COMPILE([#include <sys/types.h>
 528 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 529   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 530 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 531     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 532 fi
 533
 534 dnl Check for systemd support for listen.c's socket activation.
 535 case $host in
 536 *-linux-*)
 537       AC_CHECK_LIB(systemd-daemon, sd_notify, SYSTEMD_LIBS="-lsystemd-daemon")
 538       AC_CHECK_HEADERS(systemd/sd-daemon.h)
 539       if test "${ac_cv_header_systemd_sd_daemon_h}" = "no" || test -z "${SYSTEMD_LIBS}"; then
 540         AC_MSG_WARN([Your system does not support systemd.])
 541       else
 542         APR_ADDTO(HTTPD_LIBS, [$SYSTEMD_LIBS])
 543         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd is supported])
 544       fi
 545 esac
 546
 547 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 548
 549 case $host in
 550     *aix*)
 551         # for 32-bit builds, increase MAXDATA to allow lots of threads
 552         if test x$OBJECT_MODE != x64; then
 553             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 554         fi
 555         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 556         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 557         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 558         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 559         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 560         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 561         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 562         ;;
 563     *os390*)
 564         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 565         ;;
 566     *)
 567         OS_SPECIFIC_VARS=""
 568 esac
 569
 570 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 571         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 572         [PORT=80])
 573
 574 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 575         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 576         [SSLPORT=443])
 577
 578 DTRACE=true
 579 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 580 [
 581   enable_dtrace=$enableval
 582   if test "$enableval" = "yes"; then
 583     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 584     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 585   fi
 586 ],
 587 [
 588   enable_dtrace=no
 589 ])
 590
 591 dnl Disabled dtrace build for now.
 592 enable_dtrace=no
 593
 594 case $host in
 595   *-solaris2*)
 596     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 597         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 598                   [Enable DTrace probes])
 599         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 600         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 601     fi
 602     ;;
 603 esac
 604
 605 APACHE_SUBST(DTRACE)
 606
 607 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 608 [
 609     if test "$enableval" = "yes"; then
 610         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 611                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 612         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 613     fi
 614 ])dnl
 615
 616 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 617 [
 618     if test "$enableval" = "yes"; then
 619         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 620                   [Allow modules to run hook after a fatal exception])
 621     fi
 622 ])dnl
 623
 624 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 625 [
 626   LOAD_ALL_MODULES=$enableval
 627   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 628 ],
 629 [
 630   LOAD_ALL_MODULES="no"
 631 ])
 632
 633 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 634 [
 635   if test "$enableval" = "yes"; then
 636     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 637     if test "$GCC" = "yes"; then
 638       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 639       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 640       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 641       APACHE_ADD_GCC_CFLAG([-Wformat])
 642       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 643       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 644     elif test "$AIX_XLC" = "yes"; then
 645       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 646     fi
 647     if test "x$enable_load_all_modules" = "x"; then
 648       LOAD_ALL_MODULES=yes
 649       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 650     fi
 651     if test "x$enable_bucketeer" = "x"; then
 652       enable_bucketeer=yes
 653       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 654     fi
 655   fi
 656 ])dnl
 657
 658 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 659 [
 660   if test "$enableval" = "yes"; then
 661     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 662     if test "$GCC" = "yes"; then
 663       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 664       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 665       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 666       APACHE_ADD_GCC_CFLAG([-Wformat])
 667       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 668       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 669     elif test "$AIX_XLC" = "yes"; then
 670       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 671     fi
 672   fi
 673 ])dnl
 674
 675 dnl Conditionally enable PIE support for GNU toolchains.
 676 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 677 if test "$enable_pie" = "yes"; then
 678    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 679      save_CFLAGS=$CFLAGS
 680      save_LDFLAGS=$LDFLAGS
 681      CFLAGS="$CFLAGS -fPIE"
 682      LDFLAGS="$LDFLAGS -pie"
 683      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 684       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 685      CFLAGS=$save_CFLAGS
 686      LDFLAGS=$save_LDFLAGS
 687    ])
 688    if test "$ap_cv_cc_pie" = "yes"; then
 689      PICFLAGS="-fPIE"
 690      PILDFLAGS="-pie"
 691    else
 692      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 693    fi
 694 fi
 695 APACHE_SUBST(PICFLAGS)
 696 APACHE_SUBST(PILDFLAGS)
 697
 698 AC_ARG_WITH(valgrind,
 699   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 700                           (optionally: set path to valgrind headers) ],
 701   [ if test "$withval" != no; then
 702       if test "$withval" = yes; then
 703         withval=/usr/include/valgrind
 704       fi
 705       APR_ADDTO(CPPFLAGS, -I$withval)
 706       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 707       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 708         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 709         [AC_MSG_ERROR(valgrind headers not found) ]
 710       )
 711     fi ]
 712 )
 713
 714 prefix="$orig_prefix"
 715 APACHE_ENABLE_MODULES
 716
 717 dnl reading config stubs
 718 esyscmd(./build/config-stubs .)
 719
 720 APACHE_SUBST(progname)
 721 APACHE_SUBST(OS)
 722 APACHE_SUBST(OS_DIR)
 723 APACHE_SUBST(BUILTIN_LIBS)
 724 APACHE_SUBST(SHLIBPATH_VAR)
 725 APACHE_SUBST(OS_SPECIFIC_VARS)
 726 APACHE_SUBST(HTTPD_LIBS)
 727
 728 PRE_SHARED_CMDS='echo ""'
 729 POST_SHARED_CMDS='echo ""'
 730
 731 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 732
 733 if test "$apache_need_shared" = "yes"; then
 734   if test -f $ac_aux_dir/ltconfig; then
 735     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 736   fi
 737   shared_build="shared-build"
 738 fi
 739
 740 dnl enable_so tells us if *any* modules can be built as DSOs
 741
 742 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 743   case $host in
 744     *-ibm-aix*)
 745       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 746       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 747       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 748       ;;
 749     *os390)
 750       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 751       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 752   esac
 753   MOD_SO_ENABLED=yes
 754 fi
 755 AC_SUBST(MOD_SO_ENABLED)
 756
 757 APACHE_SUBST(PRE_SHARED_CMDS)
 758 APACHE_SUBST(POST_SHARED_CMDS)
 759 APACHE_SUBST(shared_build)
 760
 761 AC_ARG_WITH(program-name,
 762 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 763   progname="$withval" ], [
 764   progname="httpd"] )
 765
 766 # SuExec parameters
 767 AC_ARG_WITH(suexec-bin,
 768 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 769   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 770 ] )
 771
 772 AC_ARG_WITH(suexec-caller,
 773 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 774   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 775
 776 AC_ARG_WITH(suexec-userdir,
 777 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 778   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 779
 780 AC_ARG_WITH(suexec-docroot,
 781 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 782   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 783
 784 AC_ARG_WITH(suexec-uidmin,
 785 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 786   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 787
 788 AC_ARG_WITH(suexec-gidmin,
 789 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 790   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 791
 792 AC_ARG_WITH(suexec-logfile,
 793 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 794   if test "x$withval" = "xyes"; then
 795     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 796   elif test "x$withval" != "xno"; then
 797     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 798   fi
 799 ])
 800
 801 AC_ARG_WITH(suexec-syslog,
 802 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 803   if test $withval = "yes"; then
 804     if test "x${with_suexec_logfile}" != "xno"; then
 805       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 806       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 807     fi
 808     AC_CHECK_FUNCS([vsyslog], [], [
 809        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 810     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 811   fi
 812 ])
 813
 814
 815 AC_ARG_WITH(suexec-safepath,
 816 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 817   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 818
 819 AC_ARG_WITH(suexec-umask,
 820 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 821   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 822
 823 INSTALL_SUEXEC=setuid
 824 AC_ARG_ENABLE([suexec-capabilities],
 825 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 826   if test "$enableval" = "yes"; then
 827     INSTALL_SUEXEC=caps
 828     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 829               [Enable if suexec is installed with Linux capabilities, not setuid])
 830   fi
 831 ])
 832 APACHE_SUBST(INSTALL_SUEXEC)
 833
 834 dnl APR should go after the other libs, so the right symbols can be picked up
 835 if test x${apu_found} != xobsolete; then
 836   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 837 fi
 838 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 839 APACHE_SUBST(AP_LIBS)
 840 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 841 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 842
 843 AC_DEFINE(AP_USING_AUTOCONF, 1,
 844                 [Using autoconf to configure Apache])
 845
 846 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 847     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 848               [This platform doesn't suffer from the thundering herd problem])
 849 fi
 850
 851 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 852     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 853               [Listening sockets are non-blocking when there are more than 1])
 854 fi
 855
 856 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 857
 858 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 859 [
 860   v4mapped=$enableval
 861 ],
 862 [
 863     case $host in
 864     *freebsd[1234].*)
 865         v4mapped=yes
 866         ;;
 867     *freebsd*|*netbsd*|*openbsd*)
 868         v4mapped=no
 869         ;;
 870     *)
 871         v4mapped=yes
 872         ;;
 873     esac
 874     if ap_mpm_is_enabled winnt; then
 875         dnl WinNT MPM doesn't support this.
 876         v4mapped=no
 877     fi
 878 ])
 879
 880 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 881     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 882               [Allow IPv4 connections on IPv6 listening sockets])
 883 fi
 884
 885 AC_ARG_ENABLE(bsd-makefiles,APACHE_HELP_STRING(--enable-bsd-makefiles,use BSD Makefile syntax),
 886 [
 887   FORCE_BSD_MAKEFILE=$enableval
 888   AC_MSG_NOTICE([Setting "FORCE_BSD_MAKEFILE" to $FORCE_BSD_MAKEFILE])
 889 ],
 890 [
 891   FORCE_BSD_MAKEFILE="auto"
 892 ])
 893
 894 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 895 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 896 APACHE_FAST_OUTPUT(support/Makefile)
 897
 898 if test -d ./test; then
 899     APACHE_FAST_OUTPUT(test/Makefile)
 900 fi
 901
 902 dnl ## Finalize the variables
 903 AC_MSG_NOTICE([])
 904 AC_MSG_NOTICE([Restore user-defined environment settings...])
 905 AC_MSG_NOTICE([])
 906
 907 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 908 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 909 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 910 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 911 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 912 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 913
 914 AC_MSG_NOTICE([])
 915 AC_MSG_NOTICE([Construct makefiles and header files...])
 916 AC_MSG_NOTICE([])
 917
 918 APACHE_GEN_CONFIG_VARS
 919
 920 dnl ## Build modules.c
 921 rm -f modules.c
 922 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 923
 924 APR_EXPAND_VAR(ap_prefix, $prefix)
 925 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 926         [Root directory of the Apache install area])
 927 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 928         [Location of the config file, relative to the Apache root directory])
 929 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 930         [Location of the MIME types config file, relative to the Apache root directory])
 931
 932 perlbin=`$ac_aux_dir/PrintPath perl`
 933 if test "x$perlbin" = "x"; then
 934     perlbin="/replace/with/path/to/perl/interpreter"
 935 fi
 936 AC_SUBST(perlbin)
 937
 938 dnl If we are running on a BSD variant, see if we need to use the BSD .include syntax.
 939
 940 ap_make_include=include
 941 ap_make_ifdef=ifdef
 942 ap_make_else=else
 943 ap_make_endif=endif
 944 ap_make_delimiter=' '
 945 if test "x$FORCE_BSD_MAKEFILE" = "xno"; then
 946   BSD_MAKEFILE=no
 947 elif test "x$FORCE_BSD_MAKEFILE" = "xyes"; then
 948   BSD_MAKEFILE=yes
 949 else
 950   case $host in
 951   *bsd*)
 952       # Check whether they've installed GNU make
 953       if make --version > /dev/null 2>&1; then
 954           BSD_MAKEFILE=no
 955       else
 956           BSD_MAKEFILE=yes
 957       fi
 958       ;;
 959   *)
 960       BSD_MAKEFILE=no
 961       ;;
 962   esac
 963 fi
 964 if test "x$BSD_MAKEFILE" = "xyes"; then
 965   ap_make_include=.include
 966   ap_make_ifdef=.ifdef
 967   ap_make_else=.else
 968   ap_make_endif=.endif
 969   ap_make_delimiter='"'
 970 fi
 971 AC_MSG_NOTICE([using BSD Makefile syntax... $BSD_MAKEFILE])
 972
 973 AC_SUBST(ap_make_include)
 974 AC_SUBST(ap_make_ifdef)
 975 AC_SUBST(ap_make_else)
 976 AC_SUBST(ap_make_endif)
 977 AC_SUBST(ap_make_delimiter)
 978
 979 dnl Ensure that docs/conf is created.
 980 test -d docs/conf||$mkdir_p docs/conf
 981
 982 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 983   APACHE_GEN_MAKEFILES
 984 ])