granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.552 2008/02/24 05:21:54 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage (--enable-integer-datetimes)
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [  --disable-shared        do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [  --disable-rpath         do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [  --disable-spinlocks     do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [  --enable-debug          build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [  --enable-profiling      build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # DTrace
 208 #
 209 PGAC_ARG_BOOL(enable, dtrace, no,
 210               [  --enable-dtrace         build with DTrace support],
 211 [AC_DEFINE([ENABLE_DTRACE], 1,
 212            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 213 AC_CHECK_PROGS(DTRACE, dtrace)
 214 if test -z "$DTRACE"; then
 215   AC_MSG_ERROR([dtrace not found])
 216 fi
 217 AC_SUBST(DTRACEFLAGS)])
 218 AC_SUBST(enable_dtrace)
 219
 220 #
 221 # C compiler
 222 #
 223
 224 # For historical reasons you can also use --with-CC to specify the C compiler
 225 # to use, although the standard way to do this is to set the CC environment
 226 # variable.
 227 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 228
 229 case $template in
 230   aix) pgac_cc_list="gcc xlc";;
 231  irix) pgac_cc_list="cc";; # no gcc
 232     *) pgac_cc_list="gcc cc";;
 233 esac
 234
 235 AC_PROG_CC([$pgac_cc_list])
 236
 237 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 238 # but has idiosyncrasies of its own.  We assume icc will define
 239 # __INTEL_COMPILER regardless of CFLAGS.
 240 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 241 choke me
 242 @%:@endif], [ICC=[yes]], [ICC=[no]])
 243
 244 unset CFLAGS
 245
 246 #
 247 # Read the template
 248 #
 249 . "$srcdir/src/template/$template" || exit
 250
 251 # CFLAGS are selected so:
 252 # If the user specifies something in the environment, that is used.
 253 # else:  If the template file set something, that is used.
 254 # else:  If the compiler is GCC, then we use -O2.
 255 # else:  If the compiler is something else, then we use -0.
 256
 257 if test "$ac_env_CFLAGS_set" = set; then
 258   CFLAGS=$ac_env_CFLAGS_value
 259 elif test "${CFLAGS+set}" = set; then
 260   : # (keep what template set)
 261 elif test "$GCC" = yes; then
 262   CFLAGS="-O2"
 263 else
 264   # if the user selected debug mode, don't use -O
 265   if test "$enable_debug" != yes; then
 266     CFLAGS="-O"
 267   fi
 268 fi
 269
 270 # Some versions of GCC support some additional useful warning flags.
 271 # Check whether they are supported, and add them to CFLAGS if so.
 272 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 273
 274 if test "$GCC" = yes -a "$ICC" = no; then
 275   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 276   # These work in some but not all gcc versions
 277   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 278   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 279   # Disable strict-aliasing rules; needed for gcc 3.3+
 280   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 281 elif test "$ICC" = yes; then
 282   # Intel's compiler has a bug/misoptimization in checking for
 283   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 284   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 285   # Make sure strict aliasing is off (though this is said to be the default)
 286   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 287 elif test x"${CC}" = x"xlc"; then
 288   # AIX xlc has to have strict aliasing turned off too
 289   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 290 fi
 291
 292 # supply -g if --enable-debug
 293 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 294   CFLAGS="$CFLAGS -g"
 295 fi
 296
 297 # enable profiling if --enable-profiling
 298 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 299   if test "$GCC" = yes; then
 300     AC_DEFINE([PROFILE_PID_DIR], 1,
 301            [Define to 1 to allow profiling output to be saved separately for each process.])
 302     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 303   else
 304     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 305   fi
 306 fi
 307
 308 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 309
 310 # We already have this in Makefile.win32, but configure needs it too
 311 if test "$PORTNAME" = "win32"; then
 312   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 313 fi
 314
 315 # Check if the compiler still works with the template settings
 316 AC_MSG_CHECKING([whether the C compiler still works])
 317 AC_TRY_LINK([], [return 0;],
 318   [AC_MSG_RESULT(yes)],
 319   [AC_MSG_RESULT(no)
 320    AC_MSG_ERROR([cannot proceed])])
 321
 322 # Defend against gcc -ffast-math
 323 if test "$GCC" = yes; then
 324 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 325 choke me
 326 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 327 fi
 328
 329 AC_PROG_CPP
 330 AC_SUBST(GCC)
 331
 332 # Create compiler version string
 333 if test x"$GCC" = x"yes" ; then
 334   cc_string="GCC `${CC} --version | sed q`"
 335 else
 336   cc_string=$CC
 337 fi
 338 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 339                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 340                    [A string containing the version number, platform, and C compiler])
 341
 342
 343 #
 344 # Set up TAS assembly code if needed; the template file has now had its
 345 # chance to request this.
 346 #
 347 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 348
 349 if test "$need_tas" = yes ; then
 350   TAS=tas.o
 351 else
 352   TAS=""
 353 fi
 354 AC_SUBST(TAS)
 355
 356
 357 #
 358 # Automatic dependency tracking
 359 #
 360 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 361               [autodepend=yes])
 362 AC_SUBST(autodepend)
 363
 364
 365 #
 366 # Enable assert checks
 367 #
 368 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 369               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 370                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 371
 372
 373 #
 374 # Include directories
 375 #
 376 ac_save_IFS=$IFS
 377 IFS="${IFS}${PATH_SEPARATOR}"
 378 # SRCH_INC comes from the template file
 379 for dir in $with_includes $SRCH_INC; do
 380   if test -d "$dir"; then
 381     INCLUDES="$INCLUDES -I$dir"
 382   else
 383     AC_MSG_WARN([*** Include directory $dir does not exist.])
 384   fi
 385 done
 386 IFS=$ac_save_IFS
 387 AC_SUBST(INCLUDES)
 388
 389
 390 #
 391 # Library directories
 392 #
 393 ac_save_IFS=$IFS
 394 IFS="${IFS}${PATH_SEPARATOR}"
 395 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 396 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 397   if test -d "$dir"; then
 398     LIBDIRS="$LIBDIRS -L$dir"
 399   else
 400     AC_MSG_WARN([*** Library directory $dir does not exist.])
 401   fi
 402 done
 403 IFS=$ac_save_IFS
 404
 405 #
 406 # Enable thread-safe client libraries
 407 #
 408 AC_MSG_CHECKING([allow thread-safe client libraries])
 409 if test "$PORTNAME" != "win32"; then
 410 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 411 else
 412 # Win32 should always use threads
 413 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 414 fi
 415
 416 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 417 if test "$enable_thread_safety" = yes -o \
 418         "$enable_thread_safety_force" = yes; then
 419   enable_thread_safety="yes"    # for 'force'
 420   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 421           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 422 fi
 423 AC_MSG_RESULT([$enable_thread_safety])
 424 AC_SUBST(enable_thread_safety)
 425
 426 #
 427 # Optionally build Tcl modules (PL/Tcl)
 428 #
 429 AC_MSG_CHECKING([whether to build with Tcl])
 430 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 431 AC_MSG_RESULT([$with_tcl])
 432 AC_SUBST([with_tcl])
 433
 434 # We see if the path to the Tcl/Tk configuration scripts is specified.
 435 # This will override the use of tclsh to find the paths to search.
 436
 437 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 438
 439 #
 440 # Optionally build Perl modules (PL/Perl)
 441 #
 442 AC_MSG_CHECKING([whether to build Perl modules])
 443 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 444 AC_MSG_RESULT([$with_perl])
 445 AC_SUBST(with_perl)
 446
 447 #
 448 # Optionally build Python modules (PL/Python)
 449 #
 450 AC_MSG_CHECKING([whether to build Python modules])
 451 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 452 AC_MSG_RESULT([$with_python])
 453 AC_SUBST(with_python)
 454
 455 #
 456 # GSSAPI
 457 #
 458 AC_MSG_CHECKING([whether to build with GSSAPI support])
 459 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 460 [
 461   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 462   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 463 ])
 464 AC_MSG_RESULT([$with_gssapi])
 465 AC_SUBST(with_gssapi)
 466
 467 #
 468 # Kerberos 5
 469 #
 470 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 471 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 472 [
 473   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 474   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 475 ])
 476 AC_MSG_RESULT([$with_krb5])
 477 AC_SUBST(with_krb5)
 478
 479
 480 AC_SUBST(krb_srvtab)
 481
 482
 483 #
 484 # Kerberos configuration parameters
 485 #
 486 PGAC_ARG_REQ(with, krb-srvnam,
 487              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 488              [],
 489              [with_krb_srvnam="postgres"])
 490 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 491                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 492
 493
 494 #
 495 # PAM
 496 #
 497 AC_MSG_CHECKING([whether to build with PAM support])
 498 PGAC_ARG_BOOL(with, pam, no,
 499               [  --with-pam              build with PAM support],
 500               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 501 AC_MSG_RESULT([$with_pam])
 502 AC_SUBST(with_pam)
 503
 504
 505 #
 506 # LDAP
 507 #
 508 AC_MSG_CHECKING([whether to build with LDAP support])
 509 PGAC_ARG_BOOL(with, ldap, no,
 510               [  --with-ldap             build with LDAP support],
 511               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 512 AC_MSG_RESULT([$with_ldap])
 513 AC_SUBST(with_ldap)
 514
 515
 516 #
 517 # Bonjour
 518 #
 519 AC_MSG_CHECKING([whether to build with Bonjour support])
 520 PGAC_ARG_BOOL(with, bonjour, no,
 521               [  --with-bonjour          build with Bonjour support],
 522               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 523 AC_MSG_RESULT([$with_bonjour])
 524 AC_SUBST(with_bonjour)
 525
 526
 527 #
 528 # OpenSSL
 529 #
 530 AC_MSG_CHECKING([whether to build with OpenSSL support])
 531 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 532               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 533 AC_MSG_RESULT([$with_openssl])
 534 AC_SUBST(with_openssl)
 535
 536
 537 #
 538 # Readline
 539 #
 540 PGAC_ARG_BOOL(with, readline, yes,
 541               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 542 # readline on MinGW has problems with backslashes in psql and other bugs.
 543 # This is particularly a problem with non-US code pages.
 544 # Therefore disable its use until we understand the cause. 2004-07-20
 545 if test "$PORTNAME" = "win32"; then
 546   if test "$with_readline" = yes; then
 547     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 548     with_readline=no
 549   fi
 550 fi
 551
 552
 553 #
 554 # Prefer libedit
 555 #
 556 PGAC_ARG_BOOL(with, libedit-preferred, no,
 557               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 558
 559
 560 #
 561 # OSSP UUID library
 562 #
 563 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 564 AC_SUBST(with_ossp_uuid)
 565
 566
 567 #
 568 # XML
 569 #
 570 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 571               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 572
 573 if test "$with_libxml" = yes ; then
 574   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 575   if test -n "$XML2_CONFIG"; then
 576     for pgac_option in `$XML2_CONFIG --cflags`; do
 577       case $pgac_option in
 578         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 579       esac
 580     done
 581     for pgac_option in `$XML2_CONFIG --libs`; do
 582       case $pgac_option in
 583         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 584       esac
 585     done
 586   fi
 587 fi
 588
 589 AC_SUBST(with_libxml)
 590
 591 #
 592 # XSLT
 593 #
 594 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 595               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 596
 597
 598 AC_SUBST(with_libxslt)
 599
 600 #
 601 # tzdata
 602 #
 603 PGAC_ARG_REQ(with, system-tzdata,
 604              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 605 AC_SUBST(with_system_tzdata)
 606
 607 #
 608 # Zlib
 609 #
 610 PGAC_ARG_BOOL(with, zlib, yes,
 611               [  --without-zlib          do not use Zlib])
 612 AC_SUBST(with_zlib)
 613
 614 #
 615 # Elf
 616 #
 617
 618 # Assume system is ELF if it predefines __ELF__ as 1,
 619 # otherwise believe host_os based default.
 620 case $host_os in
 621     freebsd1*|freebsd2*) elf=no;;
 622     freebsd3*|freebsd4*) elf=yes;;
 623 esac
 624
 625 AC_EGREP_CPP(yes,
 626 [#if __ELF__
 627   yes
 628 #endif
 629 ],
 630 [ELF_SYS=true],
 631 [if test "X$elf" = "Xyes" ; then
 632   ELF_SYS=true
 633 else
 634   ELF_SYS=
 635 fi])
 636 AC_SUBST(ELF_SYS)
 637
 638 #
 639 # Assignments
 640 #
 641
 642 CPPFLAGS="$CPPFLAGS $INCLUDES"
 643 LDFLAGS="$LDFLAGS $LIBDIRS"
 644
 645 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 646 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 647
 648 AC_ARG_VAR(LDFLAGS_SL)
 649
 650 PGAC_PROG_LD
 651 AC_SUBST(LD)
 652 AC_SUBST(with_gnu_ld)
 653 case $host_os in sysv5*)
 654   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 655   [
 656     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 657     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 658     LDFLAGS=$pgac_save_LDFLAGS
 659   ])
 660   ld_R_works=$pgac_cv_prog_ld_R
 661   AC_SUBST(ld_R_works)
 662 esac
 663 AC_PROG_RANLIB
 664 PGAC_CHECK_STRIP
 665
 666 AC_PATH_PROG(TAR, tar)
 667 AC_PROG_LN_S
 668 AC_PROG_AWK
 669
 670 PGAC_PATH_YACC
 671 PGAC_PATH_FLEX
 672
 673 PGAC_PATH_PERL
 674 if test "$with_perl" = yes; then
 675   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 676   PGAC_CHECK_PERL_EMBED_LDFLAGS
 677 fi
 678
 679 if test "$with_python" = yes; then
 680   PGAC_PATH_PYTHON
 681   PGAC_CHECK_PYTHON_EMBED_SETUP
 682 fi
 683
 684 # Supply a numeric version string for use by 3rd party add-ons
 685 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 686 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 687 tr '.' '        ' |
 688 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 689 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 690
 691 ##
 692 ## Libraries
 693 ##
 694 ## Most libraries are included only if they demonstrably provide a function
 695 ## we need, but libm is an exception: always include it, because there are
 696 ## too many compilers that play cute optimization games that will break
 697 ## probes for standard functions such as pow().
 698 ##
 699
 700 AC_CHECK_LIB(m, main)
 701 AC_SEARCH_LIBS(setproctitle, util)
 702 AC_SEARCH_LIBS(dlopen, dl)
 703 AC_SEARCH_LIBS(socket, [socket wsock32])
 704 AC_SEARCH_LIBS(shl_load, dld)
 705 # We only use libld in port/dynloader/aix.c
 706 case $host_os in
 707      aix*)
 708         AC_SEARCH_LIBS(ldopen, ld)
 709         ;;
 710 esac
 711 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 712 AC_SEARCH_LIBS(crypt, crypt)
 713 # Solaris:
 714 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 715 # Cygwin:
 716 AC_SEARCH_LIBS(shmget, cygipc)
 717
 718 if test "$with_readline" = yes; then
 719   PGAC_CHECK_READLINE
 720   if test x"$pgac_cv_check_readline" = x"no"; then
 721     AC_MSG_ERROR([readline library not found
 722 If you have readline already installed, see config.log for details on the
 723 failure.  It is possible the compiler isn't looking in the proper directory.
 724 Use --without-readline to disable readline support.])
 725   fi
 726 fi
 727
 728 if test "$with_zlib" = yes; then
 729   AC_CHECK_LIB(z, inflate, [],
 730                [AC_MSG_ERROR([zlib library not found
 731 If you have zlib already installed, see config.log for details on the
 732 failure.  It is possible the compiler isn't looking in the proper directory.
 733 Use --without-zlib to disable zlib support.])])
 734 fi
 735
 736 if test "$enable_spinlocks" = yes; then
 737   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 738 else
 739   AC_MSG_WARN([
 740 *** Not using spinlocks will cause poor performance.])
 741 fi
 742
 743 if test "$with_gssapi" = yes ; then
 744   if test "$PORTNAME" != "win32"; then
 745     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 746                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 747   else
 748     LIBS="$LIBS -lgssapi32"
 749   fi
 750 fi
 751
 752 if test "$with_krb5" = yes ; then
 753   if test "$PORTNAME" != "win32"; then
 754      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 755                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 756      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 757                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 758   else
 759      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 760                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 761   fi
 762 fi
 763
 764 if test "$with_openssl" = yes ; then
 765   dnl Order matters!
 766   if test "$PORTNAME" != "win32"; then
 767      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 768      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 769   else
 770      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 771      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 772   fi
 773 fi
 774
 775 if test "$with_pam" = yes ; then
 776   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 777 fi
 778
 779 if test "$with_libxml" = yes ; then
 780   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 781 fi
 782
 783 if test "$with_libxslt" = yes ; then
 784   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 785 fi
 786
 787 # for contrib/uuid-ossp
 788 if test "$with_ossp_uuid" = yes ; then
 789   AC_CHECK_LIB(ossp-uuid, uuid_export,
 790     [OSSP_UUID_LIBS="-lossp-uuid"],
 791     [AC_CHECK_LIB(uuid, uuid_export,
 792       [OSSP_UUID_LIBS="-luuid"],
 793       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 794 fi
 795 AC_SUBST(OSSP_UUID_LIBS)
 796
 797
 798 ##
 799 ## Header files
 800 ##
 801
 802 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 803 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 804
 805 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 806 # netinet/in.h is included first.
 807 AC_CHECK_HEADERS(netinet/in.h)
 808 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 809 [AC_INCLUDES_DEFAULT
 810 #ifdef HAVE_NETINET_IN_H
 811 #include <netinet/in.h>
 812 #endif
 813 ])
 814
 815 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 816   AC_CHECK_HEADERS(readline/readline.h, [],
 817         [AC_CHECK_HEADERS(readline.h, [],
 818                 [AC_MSG_ERROR([readline header not found
 819 If you have readline already installed, see config.log for details on the
 820 failure.  It is possible the compiler isn't looking in the proper directory.
 821 Use --without-readline to disable readline support.])])])
 822   AC_CHECK_HEADERS(readline/history.h, [],
 823         [AC_CHECK_HEADERS(history.h, [],
 824                 [AC_MSG_ERROR([history header not found
 825 If you have readline already installed, see config.log for details on the
 826 failure.  It is possible the compiler isn't looking in the proper directory.
 827 Use --without-readline to disable readline support.])])])
 828 fi
 829
 830 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 831 # Some installations of libedit usurp /usr/include/readline/, which seems
 832 # bad practice, since in combined installations readline will have its headers
 833 # there.  We might have to resort to AC_EGREP checks to make sure we found
 834 # the proper header...
 835   AC_CHECK_HEADERS(editline/readline.h, [],
 836         [AC_CHECK_HEADERS(readline.h, [],
 837                 [AC_CHECK_HEADERS(readline/readline.h, [],
 838                         [AC_MSG_ERROR([readline header not found
 839 If you have libedit already installed, see config.log for details on the
 840 failure.  It is possible the compiler isn't looking in the proper directory.
 841 Use --without-readline to disable libedit support.])])])])
 842 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 843 # not be there at all.  Hence, don't complain if not found.  We must check
 844 # though, since in yet other versions it is an independent header.
 845   AC_CHECK_HEADERS(editline/history.h, [],
 846         [AC_CHECK_HEADERS(history.h, [],
 847                 [AC_CHECK_HEADERS(readline/history.h)])])
 848 fi
 849
 850 if test "$with_zlib" = yes; then
 851   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 852 If you have zlib already installed, see config.log for details on the
 853 failure.  It is possible the compiler isn't looking in the proper directory.
 854 Use --without-zlib to disable zlib support.])])
 855 fi
 856
 857 if test "$with_gssapi" = yes ; then
 858   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 859         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 860 fi
 861
 862 if test "$with_krb5" = yes ; then
 863   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 864 fi
 865
 866 if test "$with_openssl" = yes ; then
 867   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 868   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 869   AC_CHECK_FUNCS([ERR_set_mark])
 870 fi
 871
 872 if test "$with_pam" = yes ; then
 873   AC_CHECK_HEADERS(security/pam_appl.h, [],
 874                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 875                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 876 fi
 877
 878 if test "$with_libxml" = yes ; then
 879   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 880 fi
 881
 882 if test "$with_libxslt" = yes ; then
 883   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 884 fi
 885
 886 if test "$with_ldap" = yes ; then
 887   if test "$PORTNAME" != "win32"; then
 888      AC_CHECK_HEADERS(ldap.h, [],
 889                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 890   else
 891      AC_CHECK_HEADERS(winldap.h, [],
 892                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 893                       [AC_INCLUDES_DEFAULT
 894 #include <windows.h>
 895                       ])
 896   fi
 897 fi
 898
 899 if test "$with_bonjour" = yes ; then
 900   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 901 fi
 902
 903 # for contrib/uuid-ossp
 904 if test "$with_ossp_uuid" = yes ; then
 905   AC_CHECK_HEADERS(ossp/uuid.h, [], [
 906     AC_CHECK_HEADERS(uuid.h, [],
 907       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
 908 fi
 909
 910
 911 ##
 912 ## Types, structures, compiler characteristics
 913 ##
 914
 915 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 916 AC_C_BIGENDIAN
 917 AC_C_CONST
 918 AC_C_INLINE
 919 AC_C_STRINGIZE
 920 PGAC_C_SIGNED
 921 AC_C_VOLATILE
 922 PGAC_C_FUNCNAME_SUPPORT
 923 PGAC_STRUCT_TIMEZONE
 924 PGAC_UNION_SEMUN
 925 PGAC_STRUCT_SOCKADDR_UN
 926 PGAC_STRUCT_SOCKADDR_STORAGE
 927 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 928 PGAC_STRUCT_ADDRINFO
 929
 930 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 931 [#include <sys/param.h>
 932 #include <sys/types.h>
 933 #include <sys/socket.h>
 934 #include <sys/ucred.h>])
 935
 936 AC_CHECK_TYPES([struct option], [], [],
 937 [#ifdef HAVE_GETOPT_H
 938 #include <getopt.h>
 939 #endif])
 940
 941 if test "$with_zlib" = yes; then
 942   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 943   # did not).  While we could work around the lack of z_streamp, it
 944   # seems unwise to encourage people to use such old zlib versions...
 945   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 946 Use --without-zlib to disable zlib support.])],
 947                 [#include <zlib.h>])
 948 fi
 949
 950 if test "$with_krb5" = yes; then
 951 # Check for differences between MIT and Heimdal (KTH) releases
 952   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 953                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 954                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 955                                      [#include <krb5.h>])],
 956                    [#include <krb5.h>])
 957   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 958                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 959                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 960                                      [#include <krb5.h>])],
 961                    [#include <krb5.h>])
 962
 963 # Win32 requires headers to be loaded for __stdcall, so can't use
 964 # AC_CHECK_FUNCS here.
 965   AC_MSG_CHECKING(for krb5_free_unparsed_name)
 966   AC_TRY_LINK([#include <krb5.h>],
 967               [krb5_free_unparsed_name(NULL,NULL);],
 968               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
 969 AC_MSG_RESULT(yes)],
 970               [AC_MSG_RESULT(no)])
 971 fi
 972
 973
 974 ##
 975 ## Functions, global variables
 976 ##
 977
 978 PGAC_VAR_INT_TIMEZONE
 979 AC_FUNC_ACCEPT_ARGTYPES
 980 PGAC_FUNC_GETTIMEOFDAY_1ARG
 981
 982 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 983
 984 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 985 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 986 AC_CHECK_DECLS([strlcat, strlcpy])
 987 # This is probably only present on Darwin, but may as well check always
 988 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 989
 990 HAVE_IPV6=no
 991 AC_CHECK_TYPE([struct sockaddr_in6],
 992         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 993          HAVE_IPV6=yes],
 994         [],
 995 [$ac_includes_default
 996 #include <netinet/in.h>])
 997 AC_SUBST(HAVE_IPV6)
 998
 999 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1000 [AC_TRY_LINK(
1001 [#include <machine/vmparam.h>
1002 #include <sys/exec.h>
1003 ],
1004 [PS_STRINGS->ps_nargvstr = 1;
1005 PS_STRINGS->ps_argvstr = "foo";],
1006 [pgac_cv_var_PS_STRINGS=yes],
1007 [pgac_cv_var_PS_STRINGS=no])])
1008 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1009   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1010 fi
1011
1012
1013 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1014 # is missing.  Yes, there are machines that have only one.  We may
1015 # also decide to use snprintf.c if snprintf() is present but does not
1016 # have all the features we need --- see below.
1017
1018 if test "$PORTNAME" = "win32"; then
1019   # Win32 gets snprintf.c built unconditionally.
1020   #
1021   # To properly translate all NLS languages strings, we must support the
1022   # *printf() %$ format, which allows *printf() arguments to be selected
1023   # by position in the translated string.
1024   #
1025   # libintl versions < 0.13 use the native *printf() functions, and Win32
1026   # *printf() doesn't understand %$, so we must use our /port versions,
1027   # which do understand %$. libintl versions >= 0.13 include their own
1028   # *printf versions on Win32.  The libintl 0.13 release note text is:
1029   #
1030   #   C format strings with positions, as they arise when a translator
1031   #   needs to reorder a sentence, are now supported on all platforms.
1032   #   On those few platforms (NetBSD and Woe32) for which the native
1033   #   printf()/fprintf()/... functions don't support such format
1034   #   strings, replacements are provided through <libintl.h>.
1035   #
1036   # We could use libintl >= 0.13's *printf() if we were sure that we had
1037   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1038   # to guarantee that, it is best to just use our own, so we are sure to
1039   # get %$ support. In include/port.h we disable the *printf() macros
1040   # that might have been defined by libintl.
1041   #
1042   # We do this unconditionally whether NLS is used or not so we are sure
1043   # that all Win32 libraries and binaries behave the same.
1044   pgac_need_repl_snprintf=yes
1045 else
1046   pgac_need_repl_snprintf=no
1047   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1048   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1049 fi
1050
1051
1052 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1053 # include/c.h will provide declarations.  Note this is a separate test
1054 # from whether the functions exist in the C library --- there are
1055 # systems that have the functions but don't bother to declare them :-(
1056
1057 AC_CHECK_DECLS([snprintf, vsnprintf])
1058
1059
1060 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1061 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1062 [AC_TRY_LINK([
1063 #include <math.h>
1064 double glob_double;
1065 ],
1066 [return isinf(glob_double) ? 0 : 1;],
1067 [ac_cv_func_isinf=yes],
1068 [ac_cv_func_isinf=no])])
1069
1070 if test $ac_cv_func_isinf = yes ; then
1071   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1072 else
1073   AC_LIBOBJ(isinf)
1074   # Look for a way to implement a substitute for isinf()
1075   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1076 fi
1077
1078 # Some versions of libedit contain strlcpy(); so disregard that library while
1079 # checking for these standard libc functions.
1080 pgac_save_LIBS="$LIBS"
1081 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1082
1083 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1084
1085 LIBS="$pgac_save_LIBS"
1086
1087 # System's version of getaddrinfo(), if any, may be used only if we found
1088 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1089 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1090 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1091 # because we want to use our own getaddrinfo.c on Windows anyway.)
1092 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1093   AC_REPLACE_FUNCS([getaddrinfo])
1094 else
1095   AC_LIBOBJ(getaddrinfo)
1096 fi
1097
1098 # Similarly, use system's getopt_long() only if system provides struct option.
1099 # Solaris' getopt() doesn't do what we want for long options, so always use
1100 # our versions on that platform.
1101 if test "$PORTNAME" = "solaris"; then
1102   AC_LIBOBJ(getopt)
1103   AC_LIBOBJ(getopt_long)
1104 elif test x"$ac_cv_type_struct_option" = xyes ; then
1105   AC_REPLACE_FUNCS([getopt_long])
1106 else
1107   AC_LIBOBJ(getopt_long)
1108 fi
1109
1110 # Win32 support
1111 if test "$PORTNAME" = "win32"; then
1112 AC_REPLACE_FUNCS(gettimeofday)
1113 AC_LIBOBJ(kill)
1114 AC_LIBOBJ(open)
1115 AC_LIBOBJ(rand)
1116 AC_LIBOBJ(win32error)
1117 AC_DEFINE([HAVE_SYMLINK], 1,
1118           [Define to 1 if you have the `symlink' function.])
1119 fi
1120
1121 if test "$with_readline" = yes; then
1122   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1123   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1124   AC_CHECK_FUNCS([replace_history_entry])
1125 fi
1126
1127
1128 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1129 dnl (especially on GNU libc)
1130 dnl See also comments in c.h.
1131 AC_MSG_CHECKING(for sigsetjmp)
1132 AC_TRY_LINK([#include <setjmp.h>],
1133             [sigjmp_buf x; sigsetjmp(x, 1);],
1134             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1135 AC_MSG_RESULT(yes)],
1136             [AC_MSG_RESULT(no)])
1137
1138 AC_DECL_SYS_SIGLIST
1139
1140 AC_CHECK_FUNC(syslog,
1141               [AC_CHECK_HEADER(syslog.h,
1142                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1143
1144 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1145 [AC_TRY_LINK([#include <unistd.h>],
1146   [extern int optreset; optreset = 1;],
1147   [pgac_cv_var_int_optreset=yes],
1148   [pgac_cv_var_int_optreset=no])])
1149 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1150   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1151 fi
1152
1153 AC_CHECK_FUNCS([strtoll strtoq], [break])
1154 AC_CHECK_FUNCS([strtoull strtouq], [break])
1155
1156 # Check for one of atexit() or on_exit()
1157 AC_CHECK_FUNCS(atexit, [],
1158                [AC_CHECK_FUNCS(on_exit, [],
1159                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1160
1161 AC_REPLACE_FUNCS(fseeko)
1162 case $host_os in
1163         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1164         bsdi*|netbsd*)
1165                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1166                 ac_cv_func_fseeko=yes;;
1167         *)
1168                 AC_FUNC_FSEEKO;;
1169 esac
1170
1171
1172 #
1173 # Pthreads
1174 #
1175 # For each platform, we need to know about any special compile and link
1176 # libraries, and whether the normal C function names are thread-safe.
1177 # See the comment at the top of src/port/thread.c for more information.
1178 # WIN32 doesn't need the pthread tests;  it always uses threads
1179 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1180 ACX_PTHREAD     # set thread flags
1181
1182 # Some platforms use these, so just defineed them.  They can't hurt if they
1183 # are not supported.
1184 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1185
1186
1187 # At this point, we don't want to muck with the compiler name for threading.
1188 # Let's see who fails, perhaps AIX.  2004-04-23
1189 if test "$PTHREAD_CC" != "$CC"; then
1190 AC_MSG_ERROR([
1191 PostgreSQL does not support platforms that require a special compiler
1192 for thread safety.])
1193 fi
1194
1195 if test "$THREAD_SUPPORT" = no; then
1196 AC_MSG_ERROR([cannot enable threads on this platform
1197 This platform is known to not support thread-safe programs.  For details,
1198 compile and run src/bin/pg_thread_test.])
1199 fi
1200
1201 # Check for *_r functions
1202 _CFLAGS="$CFLAGS"
1203 _LIBS="$LIBS"
1204 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1205 LIBS="$LIBS $PTHREAD_LIBS"
1206
1207 if test "$PORTNAME" != "win32"; then
1208 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1209 fi
1210
1211 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1212
1213 # Do test here with the proper thread flags
1214 PGAC_FUNC_GETPWUID_R_5ARG
1215 PGAC_FUNC_STRERROR_R_INT
1216
1217 CFLAGS="$_CFLAGS"
1218 LIBS="$_LIBS"
1219
1220 else
1221 # do not use values from template file
1222 PTHREAD_CFLAGS=
1223 PTHREAD_LIBS=
1224 fi
1225
1226 AC_SUBST(PTHREAD_CFLAGS)
1227 AC_SUBST(PTHREAD_LIBS)
1228
1229
1230 # We can test for libldap_r only after we know PTHREAD_LIBS
1231 if test "$with_ldap" = yes ; then
1232   _LIBS="$LIBS"
1233   if test "$PORTNAME" != "win32"; then
1234     AC_CHECK_LIB(ldap, ldap_bind, [],
1235                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1236                  [$EXTRA_LDAP_LIBS])
1237     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1238     if test "$enable_thread_safety" = yes; then
1239       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1240       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1241                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1242                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1243       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1244     else
1245       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1246     fi
1247   else
1248     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1249     LDAP_LIBS_FE="-lwldap32"
1250     LDAP_LIBS_BE="-lwldap32"
1251   fi
1252   LIBS="$_LIBS"
1253 fi
1254 AC_SUBST(LDAP_LIBS_FE)
1255 AC_SUBST(LDAP_LIBS_BE)
1256
1257
1258 # This test makes sure that run tests work at all.  Sometimes a shared
1259 # library is found by the linker, but the runtime linker can't find it.
1260 # This check should come after all modifications of compiler or linker
1261 # variables, and before any other run tests.
1262 AC_MSG_CHECKING([test program])
1263 AC_TRY_RUN([int main() { return 0; }],
1264 [AC_MSG_RESULT(ok)],
1265 [AC_MSG_RESULT(failed)
1266 AC_MSG_ERROR([[
1267 Could not execute a simple test program.  This may be a problem
1268 related to locating shared libraries.  Check the file 'config.log'
1269 for the exact reason.]])],
1270 [AC_MSG_RESULT([cross-compiling])])
1271
1272 # --------------------
1273 # Run tests below here
1274 # --------------------
1275
1276 # Force use of our snprintf if system's doesn't do arg control
1277 # See comment above at snprintf test for details.
1278 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1279   PGAC_FUNC_PRINTF_ARG_CONTROL
1280   if test $pgac_cv_printf_arg_control != yes ; then
1281     pgac_need_repl_snprintf=yes
1282   fi
1283 fi
1284
1285
1286 dnl Check to see if we have a working 64-bit integer type.
1287 dnl This breaks down into two steps:
1288 dnl (1) figure out if the compiler has a 64-bit int type with working
1289 dnl arithmetic, and if so
1290 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1291 dnl snprintf is the only library routine we really need for int8 support.)
1292 dnl It's entirely possible to have a compiler that handles a 64-bit type
1293 dnl when the C library doesn't; this is fairly likely when using gcc on
1294 dnl an older platform, for example.
1295 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1296 dnl we force our own version of snprintf() to be used instead.
1297 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1298
1299 PGAC_TYPE_64BIT_INT([long int])
1300
1301 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1302   PGAC_TYPE_64BIT_INT([long long int])
1303 fi
1304
1305
1306 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1307
1308 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1309   AC_TRY_COMPILE([
1310 #define INT64CONST(x)  x##LL
1311 long long int foo = INT64CONST(0x1234567890123456);
1312 ],
1313         [],
1314         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1315         [])
1316 fi
1317
1318
1319 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1320 # we found we need to use "long long int", better check.  We cope with
1321 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1322 # work, fall back to our own snprintf emulation (which we know uses %lld).
1323
1324 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1325   if test $pgac_need_repl_snprintf = no; then
1326     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1327     if test "$LONG_LONG_INT_FORMAT" = ""; then
1328       # Force usage of our own snprintf, since system snprintf is broken
1329       pgac_need_repl_snprintf=yes
1330       LONG_LONG_INT_FORMAT='%lld'
1331     fi
1332   else
1333     # Here if we previously decided we needed to use our own snprintf
1334     LONG_LONG_INT_FORMAT='%lld'
1335   fi
1336   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1337   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1338   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1339 else
1340   # Here if we are not using 'long long int' at all
1341   INT64_FORMAT='"%ld"'
1342   UINT64_FORMAT='"%lu"'
1343 fi
1344
1345 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1346                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1347
1348 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1349                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1350
1351 # Now we have checked all the reasons to replace snprintf
1352 if test $pgac_need_repl_snprintf = yes; then
1353   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1354   AC_LIBOBJ(snprintf)
1355 fi
1356
1357 # Need a #define for the size of Datum (unsigned long)
1358 AC_CHECK_SIZEOF([unsigned long])
1359
1360 # And one for the size of size_t (enables tweaks for > 32bit address space)
1361 AC_CHECK_SIZEOF([size_t])
1362
1363 # Determine memory alignment requirements for the basic C data types.
1364
1365 AC_CHECK_ALIGNOF(short)
1366 AC_CHECK_ALIGNOF(int)
1367 AC_CHECK_ALIGNOF(long)
1368 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1369   AC_CHECK_ALIGNOF(long long int)
1370 fi
1371 AC_CHECK_ALIGNOF(double)
1372
1373 # Compute maximum alignment of any basic type.
1374 # We assume long's alignment is at least as strong as char, short, or int;
1375 # but we must check long long (if it exists) and double.
1376
1377 MAX_ALIGNOF=$ac_cv_alignof_long
1378 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1379   MAX_ALIGNOF=$ac_cv_alignof_double
1380 fi
1381 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1382   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1383 fi
1384 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1385
1386
1387 # Some platforms predefine the types int8, int16, etc.  Only check
1388 # a (hopefully) representative subset.
1389 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1390 [#include <stdio.h>
1391 #ifdef HAVE_SUPPORTDEFS_H
1392 #include <SupportDefs.h>
1393 #endif])
1394
1395 # We also check for sig_atomic_t, which *should* be defined per ANSI
1396 # C, but is missing on some old platforms.
1397 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1398
1399
1400 if test "$PORTNAME" != "win32"
1401 then
1402 PGAC_FUNC_POSIX_SIGNALS
1403 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1404   AC_MSG_ERROR([
1405 Thread-safety requires POSIX signals, which are not supported by this
1406 operating system.])
1407 fi
1408 fi
1409
1410 if test $ac_cv_func_fseeko = yes; then
1411 AC_SYS_LARGEFILE
1412 fi
1413
1414 # SunOS doesn't handle negative byte comparisons properly with +/- return
1415 AC_FUNC_MEMCMP
1416
1417
1418 # Select semaphore implementation type.
1419 if test "$PORTNAME" != "win32"; then
1420   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1421     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1422     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1423   else
1424     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1425       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1426       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1427     else
1428       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1429       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1430     fi
1431   fi
1432 else
1433   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1434   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1435 fi
1436
1437
1438 # Select shared-memory implementation type.
1439 if test "$PORTNAME" != "win32"; then
1440   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1441   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1442 else
1443   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1444   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1445 fi
1446
1447 # If not set in template file, set bytes to use libc memset()
1448 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1449   MEMSET_LOOP_LIMIT=1024
1450 fi
1451 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1452
1453
1454 if test "$enable_nls" = yes ; then
1455   PGAC_CHECK_GETTEXT
1456 fi
1457
1458 # Check for Tcl configuration script tclConfig.sh
1459 if test "$with_tcl" = yes; then
1460     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1461     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1462                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1463     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1464     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1465     ac_save_CPPFLAGS=$CPPFLAGS
1466     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1467     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1468     CPPFLAGS=$ac_save_CPPFLAGS
1469 fi
1470
1471 #
1472 # Check for DocBook and tools
1473 #
1474 PGAC_PROG_NSGMLS
1475 PGAC_PROG_JADE
1476 PGAC_CHECK_DOCBOOK(4.2)
1477 PGAC_PATH_DOCBOOK_STYLESHEETS
1478 PGAC_PATH_COLLATEINDEX
1479 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1480
1481 # Thread testing
1482
1483 # We have to run the thread test near the end so we have all our symbols
1484 # defined.  Cross compiling throws a warning.
1485 #
1486 if test "$enable_thread_safety_force" = yes; then
1487 if test "$PORTNAME" != "win32"
1488 then
1489   AC_MSG_WARN([
1490 *** Skipping thread test program.  --enable-thread-safety-force was used.
1491 *** Run the program in src/test/thread on the your machine and add proper
1492 *** locking function calls to your applications to guarantee thread safety.
1493 ])
1494 else
1495 AC_MSG_WARN([*** skipping thread test on Win32])
1496 fi
1497 elif test "$enable_thread_safety" = yes; then
1498 if test "$PORTNAME" != "win32"
1499 then
1500 AC_MSG_CHECKING([thread safety of required library functions])
1501
1502 _CFLAGS="$CFLAGS"
1503 _LIBS="$LIBS"
1504 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1505 LIBS="$LIBS $PTHREAD_LIBS"
1506 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1507   [AC_MSG_RESULT(yes)],
1508   [AC_MSG_RESULT(no)
1509   AC_MSG_ERROR([thread test program failed
1510 This platform is not thread-safe.  Check the file 'config.log'for the
1511 exact reason.
1512
1513 You can use the configure option --enable-thread-safety-force to force
1514 threads to be enabled.  But you must then run the program in
1515 src/test/thread and add locking function calls to your applications to
1516 guarantee thread safety.])],
1517   [AC_MSG_RESULT(maybe)
1518   AC_MSG_WARN([
1519 *** Skipping thread test program because of cross-compile build.
1520 *** Run the program in src/test/thread on the target machine.
1521 ])])
1522 CFLAGS="$_CFLAGS"
1523 LIBS="$_LIBS"
1524 else
1525 AC_MSG_WARN([*** skipping thread test on Win32])
1526 fi
1527 fi
1528
1529 # prepare build tree if outside source tree
1530 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1531 # Note 2: /bin/pwd might be better than shell's built-in at getting
1532 #         a symlink-free name.
1533 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1534   vpath_build=no
1535 else
1536   vpath_build=yes
1537   if test "$no_create" != yes; then
1538     _AS_ECHO_N([preparing build tree... ])
1539     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1540     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1541       || AC_MSG_ERROR(failed)
1542     AC_MSG_RESULT(done)
1543   fi
1544 fi
1545 AC_SUBST(vpath_build)
1546
1547
1548 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1549
1550 AC_CONFIG_LINKS([
1551   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1552   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1553   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1554   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1555   src/include/pg_config_os.h:src/include/port/${template}.h
1556   src/Makefile.port:src/makefiles/Makefile.${template}
1557 ])
1558
1559 if test "$PORTNAME" = "win32"; then
1560 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1561 # Links sometimes fail undetected on Mingw -
1562 # so here we detect it and warn the user
1563 for FILE in $CONFIG_LINKS
1564  do
1565         # test -e works for symlinks in the MinGW console
1566         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1567  done
1568 ])
1569 fi
1570
1571 AC_CONFIG_HEADERS([src/include/pg_config.h],
1572 [
1573 # Update timestamp for pg_config.h (see Makefile.global)
1574 echo >src/include/stamp-h
1575 ])
1576
1577 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1578
1579 AC_OUTPUT
1580
1581 # Warn about unknown options
1582 PGAC_ARG_CHECK