granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [13devel], [pgsql-bugs@lists.postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2019, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@lists.postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # --enable-debug adds -g to compiler flags
 198 #
 199 PGAC_ARG_BOOL(enable, debug, no,
 200               [build with debugging symbols (-g)])
 201 AC_SUBST(enable_debug)
 202
 203 #
 204 # --enable-profiling enables gcc profiling
 205 #
 206 PGAC_ARG_BOOL(enable, profiling, no,
 207               [build with profiling enabled ])
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [PGAC_PATH_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 PGAC_PATH_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 PGAC_PATH_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [PGAC_PATH_PROGS(DTRACE, dtrace)
 234 if test -z "$DTRACE"; then
 235   AC_MSG_ERROR([dtrace not found])
 236 fi
 237 AC_SUBST(DTRACEFLAGS)])
 238 AC_SUBST(enable_dtrace)
 239
 240 #
 241 # TAP tests
 242 #
 243 PGAC_ARG_BOOL(enable, tap-tests, no,
 244               [enable TAP tests (requires Perl and IPC::Run)])
 245 AC_SUBST(enable_tap_tests)
 246
 247 #
 248 # Block size
 249 #
 250 AC_MSG_CHECKING([for block size])
 251 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 252              [blocksize=$withval],
 253              [blocksize=8])
 254 case ${blocksize} in
 255   1) BLCKSZ=1024;;
 256   2) BLCKSZ=2048;;
 257   4) BLCKSZ=4096;;
 258   8) BLCKSZ=8192;;
 259  16) BLCKSZ=16384;;
 260  32) BLCKSZ=32768;;
 261   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 262 esac
 263 AC_MSG_RESULT([${blocksize}kB])
 264
 265 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 266  Size of a disk block --- this also limits the size of a tuple.  You
 267  can set it bigger if you need bigger tuples (although TOAST should
 268  reduce the need to have large tuples, since fields can be spread
 269  across multiple tuples).
 270
 271  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 272  is currently 2^15 (32768).  This is determined by the 15-bit widths
 273  of the lp_off and lp_len fields in ItemIdData (see
 274  include/storage/itemid.h).
 275
 276  Changing BLCKSZ requires an initdb.
 277 ])
 278
 279 #
 280 # Relation segment size
 281 #
 282 AC_MSG_CHECKING([for segment size])
 283 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 284              [segsize=$withval],
 285              [segsize=1])
 286 # this expression is set up to avoid unnecessary integer overflow
 287 # blocksize is already guaranteed to be a factor of 1024
 288 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 289 test $? -eq 0 || exit 1
 290 AC_MSG_RESULT([${segsize}GB])
 291
 292 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 293  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 294  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 295  relations bigger than that are divided into multiple files.
 296
 297  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 298  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 299  have large file support enabled.  By default, we make the limit 1 GB
 300  to avoid any possible integer-overflow problems within the OS.
 301  A limit smaller than necessary only means we divide a large
 302  relation into more chunks than necessary, so it seems best to err
 303  in the direction of a small limit.
 304
 305  A power-of-2 value is recommended to save a few cycles in md.c,
 306  but is not absolutely required.
 307
 308  Changing RELSEG_SIZE requires an initdb.
 309 ])
 310
 311 #
 312 # WAL block size
 313 #
 314 AC_MSG_CHECKING([for WAL block size])
 315 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 316              [wal_blocksize=$withval],
 317              [wal_blocksize=8])
 318 case ${wal_blocksize} in
 319   1) XLOG_BLCKSZ=1024;;
 320   2) XLOG_BLCKSZ=2048;;
 321   4) XLOG_BLCKSZ=4096;;
 322   8) XLOG_BLCKSZ=8192;;
 323  16) XLOG_BLCKSZ=16384;;
 324  32) XLOG_BLCKSZ=32768;;
 325  64) XLOG_BLCKSZ=65536;;
 326   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 327 esac
 328 AC_MSG_RESULT([${wal_blocksize}kB])
 329
 330 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 331  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 332  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 333  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 334  buffers, else direct I/O may fail.
 335
 336  Changing XLOG_BLCKSZ requires an initdb.
 337 ])
 338
 339 #
 340 # C compiler
 341 #
 342
 343 # For historical reasons you can also use --with-CC to specify the C compiler
 344 # to use, although the standard way to do this is to set the CC environment
 345 # variable.
 346 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 347
 348 case $template in
 349   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 350     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 351 esac
 352
 353 AC_PROG_CC([$pgac_cc_list])
 354 AC_PROG_CC_C99()
 355
 356 # Error out if the compiler does not support C99, as the codebase
 357 # relies on that.
 358 if test "$ac_cv_prog_cc_c99" = no; then
 359     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 360 fi
 361
 362 AC_PROG_CXX([$pgac_cxx_list])
 363
 364 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 365 # but has idiosyncrasies of its own.  We assume icc will define
 366 # __INTEL_COMPILER regardless of CFLAGS.
 367 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 368 choke me
 369 @%:@endif])], [ICC=yes], [ICC=no])
 370
 371 # Check if it's Sun Studio compiler. We assume that
 372 # __SUNPRO_C will be defined for Sun Studio compilers
 373 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 374 choke me
 375 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 376
 377 AC_SUBST(SUN_STUDIO_CC)
 378
 379
 380 #
 381 # LLVM
 382 #
 383 # Checked early because subsequent tests depend on it.
 384 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 385               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 386 AC_SUBST(with_llvm)
 387 dnl must use AS_IF here, else AC_REQUIRES inside PGAC_LLVM_SUPPORT malfunctions
 388 AS_IF([test "$with_llvm" = yes], [
 389   PGAC_LLVM_SUPPORT()
 390 ]) # fi
 391
 392
 393 unset CFLAGS
 394 unset CXXFLAGS
 395
 396 #
 397 # Read the template
 398 #
 399 . "$srcdir/src/template/$template" || exit
 400
 401 # C[XX]FLAGS are selected so:
 402 # If the user specifies something in the environment, that is used.
 403 # else:  If the template file set something, that is used.
 404 # else:  If coverage was enabled, don't set anything.
 405 # else:  If the compiler is GCC, then we use -O2.
 406 # else:  If the compiler is something else, then we use -O, unless debugging.
 407
 408 if test "$ac_env_CFLAGS_set" = set; then
 409   CFLAGS=$ac_env_CFLAGS_value
 410 elif test "${CFLAGS+set}" = set; then
 411   : # (keep what template set)
 412 elif test "$enable_coverage" = yes; then
 413   : # no optimization by default
 414 elif test "$GCC" = yes; then
 415   CFLAGS="-O2"
 416 else
 417   # if the user selected debug mode, don't use -O
 418   if test "$enable_debug" != yes; then
 419     CFLAGS="-O"
 420   fi
 421 fi
 422
 423 if test "$ac_env_CXXFLAGS_set" = set; then
 424   CXXFLAGS=$ac_env_CXXFLAGS_value
 425 elif test "${CXXFLAGS+set}" = set; then
 426   : # (keep what template set)
 427 elif test "$enable_coverage" = yes; then
 428   : # no optimization by default
 429 elif test "$GCC" = yes; then
 430   CXXFLAGS="-O2"
 431 else
 432   # if the user selected debug mode, don't use -O
 433   if test "$enable_debug" != yes; then
 434     CXXFLAGS="-O"
 435   fi
 436 fi
 437
 438 # When generating bitcode (for inlining) we always want to use -O2
 439 # even when --enable-debug is specified. The bitcode it's not going to
 440 # be used for line-by-line debugging, and JIT inlining doesn't work
 441 # without at least -O1 (otherwise clang will emit 'noinline'
 442 # attributes everywhere), which is bad for testing.  Still allow the
 443 # environment to override if done explicitly.
 444 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 445   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 446 else
 447   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 448 fi
 449 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 450   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 451 else
 452   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 453 fi
 454
 455 # C[XX]FLAGS we determined above will be added back at the end
 456 user_CFLAGS=$CFLAGS
 457 CFLAGS=""
 458 user_CXXFLAGS=$CXXFLAGS
 459 CXXFLAGS=""
 460 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 461 BITCODE_CFLAGS=""
 462 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 463 BITCODE_CXXFLAGS=""
 464
 465 # set CFLAGS_VECTOR from the environment, if available
 466 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 467   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 468 fi
 469
 470 # Some versions of GCC support some additional useful warning flags.
 471 # Check whether they are supported, and add them to CFLAGS if so.
 472 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 473 # but has its own.  Also check other compiler-specific flags here.
 474
 475 if test "$GCC" = yes -a "$ICC" = no; then
 476   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 477   CXXFLAGS="-Wall -Wpointer-arith"
 478   # These work in some but not all gcc versions
 479   save_CFLAGS=$CFLAGS
 480   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 481   # -Wdeclaration-after-statement isn't applicable for C++.  Specific C files
 482   # disable it, so AC_SUBST the negative form.
 483   PERMIT_DECLARATION_AFTER_STATEMENT=
 484   if test x"$save_CFLAGS" != x"$CFLAGS"; then
 485     PERMIT_DECLARATION_AFTER_STATEMENT=-Wno-declaration-after-statement
 486   fi
 487   AC_SUBST(PERMIT_DECLARATION_AFTER_STATEMENT)
 488   # Really don't want VLAs to be used in our dialect of C
 489   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 490   # -Wvla is not applicable for C++
 491   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 493   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 494   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 495   # This was included in -Wall/-Wformat in older GCC versions
 496   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 497   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 498   # Disable strict-aliasing rules; needed for gcc 3.3+
 499   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 500   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 501   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 502   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 503   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 504   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 505   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 506   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 507   # Optimization flags for specific files that benefit from vectorization
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 509   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 510   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 511   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 512   # test for the positive form and if that works, add the negative form
 513   NOT_THE_CFLAGS=""
 514   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 515   if test -n "$NOT_THE_CFLAGS"; then
 516     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 517   fi
 518   # Similarly disable useless truncation warnings from gcc 8+
 519   NOT_THE_CFLAGS=""
 520   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 521   if test -n "$NOT_THE_CFLAGS"; then
 522     CFLAGS="$CFLAGS -Wno-format-truncation"
 523   fi
 524   NOT_THE_CFLAGS=""
 525   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 526   if test -n "$NOT_THE_CFLAGS"; then
 527     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 528   fi
 529 elif test "$ICC" = yes; then
 530   # Intel's compiler has a bug/misoptimization in checking for
 531   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 532   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 533   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 534   # Make sure strict aliasing is off (though this is said to be the default)
 535   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 536   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 537 elif test "$PORTNAME" = "aix"; then
 538   # AIX's xlc has to have strict aliasing turned off too
 539   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 541   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 542   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 543 elif test "$PORTNAME" = "hpux"; then
 544   # On some versions of HP-UX, libm functions do not set errno by default.
 545   # Fix that by using +Olibmerrno if the compiler recognizes it.
 546   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 547   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 548 fi
 549
 550 AC_SUBST(CFLAGS_VECTOR)
 551
 552 # Determine flags used to emit bitcode for JIT inlining. Need to test
 553 # for behaviour changing compiler flags, to keep compatibility with
 554 # compiler used for normal postgres code.
 555 if test "$with_llvm" = yes ; then
 556   CLANGXX="$CLANG -xc++"
 557
 558   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 560   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 562   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 563   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 564 fi
 565
 566 # supply -g if --enable-debug
 567 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 568   CFLAGS="$CFLAGS -g"
 569 fi
 570
 571 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 572   CXXFLAGS="$CXXFLAGS -g"
 573 fi
 574
 575 # enable code coverage if --enable-coverage
 576 if test "$enable_coverage" = yes; then
 577   if test "$GCC" = yes; then
 578     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 579     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 580   else
 581     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 582   fi
 583 fi
 584
 585 # enable profiling if --enable-profiling
 586 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 587   if test "$GCC" = yes; then
 588     AC_DEFINE([PROFILE_PID_DIR], 1,
 589            [Define to 1 to allow profiling output to be saved separately for each process.])
 590     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 592   else
 593     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 594   fi
 595 fi
 596
 597 # We already have this in Makefile.win32, but configure needs it too
 598 if test "$PORTNAME" = "win32"; then
 599   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 600 fi
 601
 602 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 603 # user-specified flags (if any) at the end.  This lets users override
 604 # the automatic additions.
 605 CFLAGS="$CFLAGS $user_CFLAGS"
 606 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 607 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 608 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 609
 610 AC_SUBST(BITCODE_CFLAGS)
 611 AC_SUBST(BITCODE_CXXFLAGS)
 612
 613 # The template file must set up CFLAGS_SL; we don't support user override
 614 AC_SUBST(CFLAGS_SL)
 615
 616 # Check if the compiler still works with the final flag settings
 617 # (note, we're not checking that for CXX, which is optional)
 618 AC_MSG_CHECKING([whether the C compiler still works])
 619 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 620   [AC_MSG_RESULT(yes)],
 621   [AC_MSG_RESULT(no)
 622    AC_MSG_ERROR([cannot proceed])])
 623
 624 # Defend against gcc -ffast-math
 625 if test "$GCC" = yes; then
 626 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 627 choke me
 628 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 629 fi
 630
 631 # Defend against clang being used on x86-32 without SSE2 enabled.  As current
 632 # versions of clang do not understand -fexcess-precision=standard, the use of
 633 # x87 floating point operations leads to problems like isinf possibly returning
 634 # false for a value that is infinite when converted from the 80bit register to
 635 # the 8byte memory representation.
 636 #
 637 # Only perform the test if the compiler doesn't understand
 638 # -fexcess-precision=standard, that way a potentially fixed compiler will work
 639 # automatically.
 640 if test "$pgac_cv_prog_CC_cflags__fexcess_precision_standard" = no; then
 641 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 642 @%:@if defined(__clang__) && defined(__i386__) && !defined(__SSE2_MATH__)
 643 choke me
 644 @%:@endif
 645 ])], [],
 646 [AC_MSG_ERROR([Compiling PostgreSQL with clang, on 32bit x86, requires SSE2 support. Use -msse2 or use gcc.])])
 647 fi
 648
 649 AC_PROG_CPP
 650 AC_SUBST(GCC)
 651
 652
 653 #
 654 # Set up TAS assembly code if needed; the template file has now had its
 655 # chance to request this.
 656 #
 657 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 658
 659 if test "$need_tas" = yes ; then
 660   TAS=tas.o
 661 else
 662   TAS=""
 663 fi
 664 AC_SUBST(TAS)
 665
 666
 667 #
 668 # Automatic dependency tracking
 669 #
 670 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 671               [autodepend=yes])
 672 AC_SUBST(autodepend)
 673
 674
 675 #
 676 # Enable assert checks
 677 #
 678 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 679               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 680                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 681
 682
 683 #
 684 # Include directories
 685 #
 686 ac_save_IFS=$IFS
 687 IFS="${IFS}${PATH_SEPARATOR}"
 688 # SRCH_INC comes from the template file
 689 for dir in $with_includes $SRCH_INC; do
 690   if test -d "$dir"; then
 691     INCLUDES="$INCLUDES -I$dir"
 692   else
 693     AC_MSG_WARN([*** Include directory $dir does not exist.])
 694   fi
 695 done
 696 IFS=$ac_save_IFS
 697 AC_SUBST(INCLUDES)
 698
 699
 700 #
 701 # Library directories
 702 #
 703 ac_save_IFS=$IFS
 704 IFS="${IFS}${PATH_SEPARATOR}"
 705 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 706 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 707   if test -d "$dir"; then
 708     LIBDIRS="$LIBDIRS -L$dir"
 709   else
 710     AC_MSG_WARN([*** Library directory $dir does not exist.])
 711   fi
 712 done
 713 IFS=$ac_save_IFS
 714
 715 #
 716 # Enable thread-safe client libraries
 717 #
 718 AC_MSG_CHECKING([allow thread-safe client libraries])
 719 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 720 if test "$enable_thread_safety" = yes; then
 721   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 722           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 723 fi
 724 AC_MSG_RESULT([$enable_thread_safety])
 725 AC_SUBST(enable_thread_safety)
 726
 727 #
 728 # ICU
 729 #
 730 AC_MSG_CHECKING([whether to build with ICU support])
 731 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 732               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 733 AC_MSG_RESULT([$with_icu])
 734 AC_SUBST(with_icu)
 735
 736 if test "$with_icu" = yes; then
 737   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 738 fi
 739
 740 #
 741 # Optionally build Tcl modules (PL/Tcl)
 742 #
 743 AC_MSG_CHECKING([whether to build with Tcl])
 744 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 745 AC_MSG_RESULT([$with_tcl])
 746 AC_SUBST([with_tcl])
 747
 748 # We see if the path to the Tcl/Tk configuration scripts is specified.
 749 # This will override the use of tclsh to find the paths to search.
 750
 751 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 752
 753 #
 754 # Optionally build Perl modules (PL/Perl)
 755 #
 756 AC_MSG_CHECKING([whether to build Perl modules])
 757 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 758 AC_MSG_RESULT([$with_perl])
 759 AC_SUBST(with_perl)
 760
 761 #
 762 # Optionally build Python modules (PL/Python)
 763 #
 764 AC_MSG_CHECKING([whether to build Python modules])
 765 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 766 AC_MSG_RESULT([$with_python])
 767 AC_SUBST(with_python)
 768
 769 #
 770 # GSSAPI
 771 #
 772 AC_MSG_CHECKING([whether to build with GSSAPI support])
 773 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 774 [
 775   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 776   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 777 ])
 778 AC_MSG_RESULT([$with_gssapi])
 779 AC_SUBST(with_gssapi)
 780
 781
 782 AC_SUBST(krb_srvtab)
 783
 784
 785 #
 786 # Kerberos configuration parameters
 787 #
 788 PGAC_ARG_REQ(with, krb-srvnam,
 789              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 790              [],
 791              [with_krb_srvnam="postgres"])
 792 AC_SUBST(with_krb_srvnam)
 793 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 794                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 795
 796
 797 #
 798 # PAM
 799 #
 800 AC_MSG_CHECKING([whether to build with PAM support])
 801 PGAC_ARG_BOOL(with, pam, no,
 802               [build with PAM support],
 803               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 804 AC_MSG_RESULT([$with_pam])
 805
 806
 807 #
 808 # BSD AUTH
 809 #
 810 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 811 PGAC_ARG_BOOL(with, bsd-auth, no,
 812               [build with BSD Authentication support],
 813               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 814 AC_MSG_RESULT([$with_bsd_auth])
 815
 816
 817 #
 818 # LDAP
 819 #
 820 AC_MSG_CHECKING([whether to build with LDAP support])
 821 PGAC_ARG_BOOL(with, ldap, no,
 822               [build with LDAP support],
 823               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 824 AC_MSG_RESULT([$with_ldap])
 825 AC_SUBST(with_ldap)
 826
 827
 828 #
 829 # Bonjour
 830 #
 831 AC_MSG_CHECKING([whether to build with Bonjour support])
 832 PGAC_ARG_BOOL(with, bonjour, no,
 833               [build with Bonjour support],
 834               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 835 AC_MSG_RESULT([$with_bonjour])
 836
 837
 838 #
 839 # OpenSSL
 840 #
 841 AC_MSG_CHECKING([whether to build with OpenSSL support])
 842 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 843               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 844 AC_MSG_RESULT([$with_openssl])
 845 AC_SUBST(with_openssl)
 846
 847 #
 848 # SELinux
 849 #
 850 AC_MSG_CHECKING([whether to build with SELinux support])
 851 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 852 AC_SUBST(with_selinux)
 853 AC_MSG_RESULT([$with_selinux])
 854
 855 #
 856 # Systemd
 857 #
 858 AC_MSG_CHECKING([whether to build with systemd support])
 859 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 860               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 861 AC_SUBST(with_systemd)
 862 AC_MSG_RESULT([$with_systemd])
 863
 864 #
 865 # Readline
 866 #
 867 PGAC_ARG_BOOL(with, readline, yes,
 868               [do not use GNU Readline nor BSD Libedit for editing])
 869 # readline on MinGW has problems with backslashes in psql and other bugs.
 870 # This is particularly a problem with non-US code pages.
 871 # Therefore disable its use until we understand the cause. 2004-07-20
 872 if test "$PORTNAME" = "win32"; then
 873   if test "$with_readline" = yes; then
 874     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 875     with_readline=no
 876   fi
 877 fi
 878
 879
 880 #
 881 # Prefer libedit
 882 #
 883 PGAC_ARG_BOOL(with, libedit-preferred, no,
 884               [prefer BSD Libedit over GNU Readline])
 885
 886
 887 #
 888 # UUID library
 889 #
 890 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 891 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 892 # UUID library.  More than one of these might be present on a given platform,
 893 # so we make the user say which one she wants.
 894 #
 895 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 896 if test x"$with_uuid" = x"" ; then
 897   with_uuid=no
 898 fi
 899 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 900 if test "$with_ossp_uuid" = yes ; then
 901   with_uuid=ossp
 902 fi
 903
 904 if test "$with_uuid" = bsd ; then
 905   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 906   UUID_EXTRA_OBJS="md5.o sha1.o"
 907 elif test "$with_uuid" = e2fs ; then
 908   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 909   UUID_EXTRA_OBJS="md5.o sha1.o"
 910 elif test "$with_uuid" = ossp ; then
 911   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 912   UUID_EXTRA_OBJS=""
 913 elif test "$with_uuid" = no ; then
 914   UUID_EXTRA_OBJS=""
 915 else
 916   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 917 fi
 918 AC_SUBST(with_uuid)
 919 AC_SUBST(UUID_EXTRA_OBJS)
 920
 921
 922 #
 923 # XML
 924 #
 925 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 926               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 927
 928 if test "$with_libxml" = yes ; then
 929   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 930   AC_ARG_VAR(XML2_CONFIG, [path to xml2-config utility])dnl
 931   if test -n "$XML2_CONFIG"; then
 932     for pgac_option in `$XML2_CONFIG --cflags`; do
 933       case $pgac_option in
 934         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 935       esac
 936     done
 937     for pgac_option in `$XML2_CONFIG --libs`; do
 938       case $pgac_option in
 939         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 940       esac
 941     done
 942   fi
 943 fi
 944
 945 AC_SUBST(with_libxml)
 946
 947 #
 948 # XSLT
 949 #
 950 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 951               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 952
 953
 954 AC_SUBST(with_libxslt)
 955
 956 #
 957 # tzdata
 958 #
 959 PGAC_ARG_REQ(with, system-tzdata,
 960              [DIR], [use system time zone data in DIR])
 961 AC_SUBST(with_system_tzdata)
 962
 963 #
 964 # Zlib
 965 #
 966 PGAC_ARG_BOOL(with, zlib, yes,
 967               [do not use Zlib])
 968 AC_SUBST(with_zlib)
 969
 970 #
 971 # Assignments
 972 #
 973
 974 CPPFLAGS="$CPPFLAGS $INCLUDES"
 975 LDFLAGS="$LDFLAGS $LIBDIRS"
 976
 977 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 978 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 979
 980 PGAC_PROG_LD
 981 AC_SUBST(LD)
 982 AC_SUBST(with_gnu_ld)
 983 AC_PROG_RANLIB
 984 PGAC_CHECK_STRIP
 985 AC_CHECK_TOOL(AR, ar, ar)
 986 if test "$PORTNAME" = "win32"; then
 987   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 988   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 989   AC_CHECK_TOOL(WINDRES, windres, windres)
 990 fi
 991
 992 AC_PROG_INSTALL
 993 # When Autoconf chooses install-sh as install program it tries to generate
 994 # a relative path to it in each makefile where it substitutes it. This clashes
 995 # with our Makefile.global concept. This workaround helps.
 996 case $INSTALL in
 997   *install-sh*) install_bin='';;
 998   *) install_bin=$INSTALL;;
 999 esac
1000 AC_SUBST(install_bin)
1001
1002 PGAC_PATH_PROGS(TAR, tar)
1003 AC_PROG_LN_S
1004 AC_PROG_MKDIR_P
1005 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1006 # a relative path to it in each makefile where it substitutes it. This clashes
1007 # with our Makefile.global concept. This workaround helps.
1008 case $MKDIR_P in
1009   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1010 esac
1011
1012 PGAC_PATH_BISON
1013 PGAC_PATH_FLEX
1014
1015 PGAC_PATH_PERL
1016 if test "$with_perl" = yes; then
1017   if test -z "$PERL"; then
1018     AC_MSG_ERROR([Perl not found])
1019   fi
1020   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1021   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1022     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1023 You might have to rebuild your Perl installation.  Refer to the
1024 documentation for details.  Use --without-perl to disable building
1025 PL/Perl.])
1026   fi
1027   # On most platforms, archlibexp is also where the Perl include files live ...
1028   perl_includespec="-I$perl_archlibexp/CORE"
1029   # ... but on newer macOS versions, we must use -iwithsysroot to look
1030   # under $PG_SYSROOT
1031   if test \! -f "$perl_archlibexp/CORE/perl.h" ; then
1032     if test -f "$PG_SYSROOT$perl_archlibexp/CORE/perl.h" ; then
1033       perl_includespec="-iwithsysroot $perl_archlibexp/CORE"
1034     fi
1035   fi
1036   AC_SUBST(perl_includespec)dnl
1037   PGAC_CHECK_PERL_EMBED_CCFLAGS
1038   PGAC_CHECK_PERL_EMBED_LDFLAGS
1039 fi
1040
1041 if test "$with_python" = yes; then
1042   PGAC_PATH_PYTHON
1043   PGAC_CHECK_PYTHON_EMBED_SETUP
1044 fi
1045
1046 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1047   PGAC_PATH_PROGS(ZIC, zic)
1048   if test -z "$ZIC"; then
1049     AC_MSG_ERROR([
1050 When cross-compiling, either use the option --with-system-tzdata to use
1051 existing time-zone data, or set the environment variable ZIC to a zic
1052 program to use during the build.])
1053   fi
1054 fi
1055
1056 #
1057 # Pthreads
1058 #
1059 # For each platform, we need to know about any special compile and link
1060 # libraries, and whether the normal C function names are thread-safe.
1061 # See the comment at the top of src/port/thread.c for more information.
1062 # WIN32 doesn't need the pthread tests;  it always uses threads
1063 #
1064 # These tests are run before the library-tests, because linking with the
1065 # other libraries can pull in the pthread functions as a side-effect.  We
1066 # want to use the -pthread or similar flags directly, and not rely on
1067 # the side-effects of linking with some other library.
1068
1069 dnl note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1070 dnl invocation below is the first one in the script, and autoconf generates
1071 dnl additional code for that, which must not be inside the if-block. AS_IF
1072 dnl knows how to do that.
1073 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1074 [ # then
1075 AX_PTHREAD      # set thread flags
1076
1077 # Some platforms use these, so just define them.  They can't hurt if they
1078 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1079 # enables 5-arg getpwuid_r, among other things.
1080 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1081
1082 # Check for *_r functions
1083 _CFLAGS="$CFLAGS"
1084 _LIBS="$LIBS"
1085 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1086 LIBS="$LIBS $PTHREAD_LIBS"
1087
1088 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1089 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1090
1091 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1092
1093 # Do test here with the proper thread flags
1094 PGAC_FUNC_STRERROR_R_INT
1095
1096 CFLAGS="$_CFLAGS"
1097 LIBS="$_LIBS"
1098
1099 ], [ # else
1100 # do not use values from template file
1101 PTHREAD_CFLAGS=
1102 PTHREAD_LIBS=
1103 ]) # fi
1104
1105 AC_SUBST(PTHREAD_CFLAGS)
1106 AC_SUBST(PTHREAD_LIBS)
1107
1108
1109 ##
1110 ## Libraries
1111 ##
1112 ## Most libraries are included only if they demonstrably provide a function
1113 ## we need, but libm is an exception: always include it, because there are
1114 ## too many compilers that play cute optimization games that will break
1115 ## probes for standard functions such as pow().
1116 ##
1117
1118 AC_CHECK_LIB(m, main)
1119 AC_SEARCH_LIBS(setproctitle, util)
1120 AC_SEARCH_LIBS(dlopen, dl)
1121 AC_SEARCH_LIBS(socket, [socket ws2_32])
1122 AC_SEARCH_LIBS(shl_load, dld)
1123 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1124 AC_SEARCH_LIBS(shm_open, rt)
1125 AC_SEARCH_LIBS(shm_unlink, rt)
1126 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1127 # Solaris:
1128 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1129 # Required for thread_test.c on Solaris
1130 AC_SEARCH_LIBS(sched_yield, rt)
1131 # Required for thread_test.c on Solaris 2.5:
1132 # Other ports use it too (HP-UX) so test unconditionally
1133 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1134 # Cygwin:
1135 AC_SEARCH_LIBS(shmget, cygipc)
1136
1137 if test "$with_readline" = yes; then
1138   PGAC_CHECK_READLINE
1139   if test x"$pgac_cv_check_readline" = x"no"; then
1140     AC_MSG_ERROR([readline library not found
1141 If you have readline already installed, see config.log for details on the
1142 failure.  It is possible the compiler isn't looking in the proper directory.
1143 Use --without-readline to disable readline support.])
1144   fi
1145 fi
1146
1147 if test "$with_zlib" = yes; then
1148   AC_CHECK_LIB(z, inflate, [],
1149                [AC_MSG_ERROR([zlib library not found
1150 If you have zlib already installed, see config.log for details on the
1151 failure.  It is possible the compiler isn't looking in the proper directory.
1152 Use --without-zlib to disable zlib support.])])
1153 fi
1154
1155 if test "$enable_spinlocks" = yes; then
1156   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1157 else
1158   AC_MSG_WARN([
1159 *** Not using spinlocks will cause poor performance.])
1160 fi
1161
1162 if test "$enable_atomics" = yes; then
1163   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1164 else
1165   AC_MSG_WARN([
1166 *** Not using atomic operations will cause poor performance.])
1167 fi
1168
1169 if test "$with_gssapi" = yes ; then
1170   if test "$PORTNAME" != "win32"; then
1171     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1172                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1173   else
1174     LIBS="$LIBS -lgssapi32"
1175   fi
1176 fi
1177
1178 if test "$with_openssl" = yes ; then
1179   dnl Order matters!
1180   if test "$PORTNAME" != "win32"; then
1181      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1182      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1183   else
1184      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1185      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1186   fi
1187   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1188   # Functions introduced in OpenSSL 1.1.0. We used to check for
1189   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1190   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1191   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1192   # functions.
1193   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data])
1194   # OpenSSL versions before 1.1.0 required setting callback functions, for
1195   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1196   # function was removed.
1197   AC_CHECK_FUNCS([CRYPTO_lock])
1198 fi
1199
1200 if test "$with_pam" = yes ; then
1201   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1202 fi
1203
1204 if test "$with_libxml" = yes ; then
1205   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1206 fi
1207
1208 if test "$with_libxslt" = yes ; then
1209   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1210 fi
1211
1212 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1213 if test "$with_ldap" = yes ; then
1214   _LIBS="$LIBS"
1215   if test "$PORTNAME" != "win32"; then
1216     AC_CHECK_LIB(ldap, ldap_bind, [],
1217                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1218                  [$EXTRA_LDAP_LIBS])
1219     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1220     if test "$enable_thread_safety" = yes; then
1221       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1222       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1223                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1224                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1225       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1226     else
1227       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1228     fi
1229     AC_CHECK_FUNCS([ldap_initialize])
1230   else
1231     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1232     LDAP_LIBS_FE="-lwldap32"
1233     LDAP_LIBS_BE="-lwldap32"
1234   fi
1235   LIBS="$_LIBS"
1236 fi
1237 AC_SUBST(LDAP_LIBS_FE)
1238 AC_SUBST(LDAP_LIBS_BE)
1239
1240 # for contrib/sepgsql
1241 if test "$with_selinux" = yes; then
1242   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1243                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1244 fi
1245
1246 # for contrib/uuid-ossp
1247 if test "$with_uuid" = bsd ; then
1248   # On BSD, the UUID functions are in libc
1249   AC_CHECK_FUNC(uuid_to_string,
1250     [UUID_LIBS=""],
1251     [AC_MSG_ERROR([BSD UUID functions are not present])])
1252 elif test "$with_uuid" = e2fs ; then
1253   # On macOS, the UUID functions are in libc
1254   AC_CHECK_FUNC(uuid_generate,
1255     [UUID_LIBS=""],
1256     [AC_CHECK_LIB(uuid, uuid_generate,
1257       [UUID_LIBS="-luuid"],
1258       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1259 elif test "$with_uuid" = ossp ; then
1260   AC_CHECK_LIB(ossp-uuid, uuid_export,
1261     [UUID_LIBS="-lossp-uuid"],
1262     [AC_CHECK_LIB(uuid, uuid_export,
1263       [UUID_LIBS="-luuid"],
1264       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1265 fi
1266 AC_SUBST(UUID_LIBS)
1267
1268
1269 ##
1270 ## Header files
1271 ##
1272
1273 AC_HEADER_STDBOOL
1274
1275 AC_CHECK_HEADERS(m4_normalize([
1276         atomic.h
1277         copyfile.h
1278         fp_class.h
1279         getopt.h
1280         ieeefp.h
1281         ifaddrs.h
1282         langinfo.h
1283         mbarrier.h
1284         poll.h
1285         sys/epoll.h
1286         sys/ipc.h
1287         sys/prctl.h
1288         sys/procctl.h
1289         sys/pstat.h
1290         sys/resource.h
1291         sys/select.h
1292         sys/sem.h
1293         sys/shm.h
1294         sys/sockio.h
1295         sys/tas.h
1296         sys/un.h
1297         termios.h
1298         ucred.h
1299         utime.h
1300         wchar.h
1301         wctype.h
1302 ]))
1303
1304 # On BSD, test for net/if.h will fail unless sys/socket.h
1305 # is included first.
1306 AC_CHECK_HEADERS(net/if.h, [], [],
1307 [AC_INCLUDES_DEFAULT
1308 #include <sys/socket.h>
1309 ])
1310
1311 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1312 # is included first.
1313 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1314 [AC_INCLUDES_DEFAULT
1315 #include <sys/param.h>
1316 ])
1317
1318 # At least on IRIX, test for netinet/tcp.h will fail unless
1319 # netinet/in.h is included first.
1320 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1321 [AC_INCLUDES_DEFAULT
1322 #include <netinet/in.h>
1323 ])
1324
1325 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1326   AC_CHECK_HEADERS(readline/readline.h, [],
1327         [AC_CHECK_HEADERS(readline.h, [],
1328                 [AC_MSG_ERROR([readline header not found
1329 If you have readline already installed, see config.log for details on the
1330 failure.  It is possible the compiler isn't looking in the proper directory.
1331 Use --without-readline to disable readline support.])])])
1332   AC_CHECK_HEADERS(readline/history.h, [],
1333         [AC_CHECK_HEADERS(history.h, [],
1334                 [AC_MSG_ERROR([history header not found
1335 If you have readline already installed, see config.log for details on the
1336 failure.  It is possible the compiler isn't looking in the proper directory.
1337 Use --without-readline to disable readline support.])])])
1338 fi
1339
1340 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1341 # Some installations of libedit usurp /usr/include/readline/, which seems
1342 # bad practice, since in combined installations readline will have its headers
1343 # there.  We might have to resort to AC_EGREP checks to make sure we found
1344 # the proper header...
1345   AC_CHECK_HEADERS(editline/readline.h, [],
1346         [AC_CHECK_HEADERS(readline.h, [],
1347                 [AC_CHECK_HEADERS(readline/readline.h, [],
1348                         [AC_MSG_ERROR([readline header not found
1349 If you have libedit already installed, see config.log for details on the
1350 failure.  It is possible the compiler isn't looking in the proper directory.
1351 Use --without-readline to disable libedit support.])])])])
1352 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1353 # not be there at all.  Hence, don't complain if not found.  We must check
1354 # though, since in yet other versions it is an independent header.
1355   AC_CHECK_HEADERS(editline/history.h, [],
1356         [AC_CHECK_HEADERS(history.h, [],
1357                 [AC_CHECK_HEADERS(readline/history.h)])])
1358 fi
1359
1360 if test "$with_zlib" = yes; then
1361   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1362 If you have zlib already installed, see config.log for details on the
1363 failure.  It is possible the compiler isn't looking in the proper directory.
1364 Use --without-zlib to disable zlib support.])])
1365 fi
1366
1367 if test "$with_gssapi" = yes ; then
1368   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1369         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1370 fi
1371
1372 if test "$with_openssl" = yes ; then
1373   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1374   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1375 fi
1376
1377 if test "$with_pam" = yes ; then
1378   AC_CHECK_HEADERS(security/pam_appl.h, [],
1379                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1380                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1381 fi
1382
1383 if test "$with_bsd_auth" = yes ; then
1384   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1385 fi
1386
1387 if test "$with_systemd" = yes ; then
1388   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1389 fi
1390
1391 if test "$with_libxml" = yes ; then
1392   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1393 fi
1394
1395 if test "$with_libxslt" = yes ; then
1396   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1397 fi
1398
1399 if test "$with_ldap" = yes ; then
1400   if test "$PORTNAME" != "win32"; then
1401      AC_CHECK_HEADERS(ldap.h, [],
1402                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1403      PGAC_LDAP_SAFE
1404   else
1405      AC_CHECK_HEADERS(winldap.h, [],
1406                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1407                       [AC_INCLUDES_DEFAULT
1408 #include <windows.h>
1409                       ])
1410   fi
1411 fi
1412
1413 if test "$with_bonjour" = yes ; then
1414   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1415 dnl At some point we might add something like
1416 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1417 dnl but right now, what that would mainly accomplish is to encourage
1418 dnl people to try to use the avahi implementation, which does not work.
1419 dnl If you want to use Apple's own Bonjour code on another platform,
1420 dnl just add -ldns_sd to LIBS manually.
1421 fi
1422
1423 # for contrib/uuid-ossp
1424 if test "$with_uuid" = bsd ; then
1425   AC_CHECK_HEADERS(uuid.h,
1426     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1427       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1428     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1429 elif test "$with_uuid" = e2fs ; then
1430   AC_CHECK_HEADERS(uuid/uuid.h,
1431     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1432       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1433     [AC_CHECK_HEADERS(uuid.h,
1434       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1435         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1436       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1437 elif test "$with_uuid" = ossp ; then
1438   AC_CHECK_HEADERS(ossp/uuid.h,
1439     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1440       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1441     [AC_CHECK_HEADERS(uuid.h,
1442       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1443         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1444       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1445 fi
1446
1447 if test "$PORTNAME" = "win32" ; then
1448    AC_CHECK_HEADERS(crtdefs.h)
1449 fi
1450
1451 ##
1452 ## Types, structures, compiler characteristics
1453 ##
1454
1455 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1456 AC_C_BIGENDIAN
1457 AC_C_INLINE
1458 PGAC_PRINTF_ARCHETYPE
1459 AC_C_FLEXIBLE_ARRAY_MEMBER
1460 PGAC_C_SIGNED
1461 PGAC_C_FUNCNAME_SUPPORT
1462 PGAC_C_STATIC_ASSERT
1463 PGAC_C_TYPEOF
1464 PGAC_C_TYPES_COMPATIBLE
1465 PGAC_C_BUILTIN_CONSTANT_P
1466 PGAC_C_BUILTIN_UNREACHABLE
1467 PGAC_C_COMPUTED_GOTO
1468 PGAC_STRUCT_TIMEZONE
1469 PGAC_UNION_SEMUN
1470 PGAC_STRUCT_SOCKADDR_UN
1471 PGAC_STRUCT_SOCKADDR_STORAGE
1472 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1473 PGAC_STRUCT_ADDRINFO
1474 AC_TYPE_INTPTR_T
1475 AC_TYPE_UINTPTR_T
1476 AC_TYPE_LONG_LONG_INT
1477
1478 PGAC_TYPE_LOCALE_T
1479
1480 # MSVC doesn't cope well with defining restrict to __restrict, the
1481 # spelling it understands, because it conflicts with
1482 # __declspec(restrict). Therefore we define pg_restrict to the
1483 # appropriate definition, which presumably won't conflict.
1484 #
1485 # Allow platforms with buggy compilers to force restrict to not be
1486 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1487 # template.
1488 AC_C_RESTRICT
1489 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1490   pg_restrict=""
1491 else
1492   pg_restrict="$ac_cv_c_restrict"
1493 fi
1494 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1495 [Define to keyword to use for C99 restrict support, or to nothing if not
1496 supported])
1497
1498 AC_CHECK_TYPES([struct cmsgcred], [], [],
1499 [#include <sys/socket.h>
1500 #include <sys/param.h>
1501 #ifdef HAVE_SYS_UCRED_H
1502 #include <sys/ucred.h>
1503 #endif])
1504
1505 AC_CHECK_TYPES([struct option], [], [],
1506 [#ifdef HAVE_GETOPT_H
1507 #include <getopt.h>
1508 #endif])
1509
1510 if test "$with_zlib" = yes; then
1511   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1512   # did not).  While we could work around the lack of z_streamp, it
1513   # seems unwise to encourage people to use such old zlib versions...
1514   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1515 Use --without-zlib to disable zlib support.])],
1516                 [#include <zlib.h>])
1517 fi
1518
1519 case $host_cpu in
1520   x86_64)
1521     # On x86_64, check if we can compile a popcntq instruction
1522     AC_CACHE_CHECK([whether assembler supports x86_64 popcntq],
1523                    [pgac_cv_have_x86_64_popcntq],
1524     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1525         [long long x = 1; long long r;
1526          __asm__ __volatile__ (" popcntq %1,%0\n" : "=q"(r) : "rm"(x));])],
1527         [pgac_cv_have_x86_64_popcntq=yes],
1528         [pgac_cv_have_x86_64_popcntq=no])])
1529     if test x"$pgac_cv_have_x86_64_popcntq" = xyes ; then
1530         AC_DEFINE(HAVE_X86_64_POPCNTQ, 1, [Define to 1 if the assembler supports X86_64's POPCNTQ instruction.])
1531     fi
1532   ;;
1533   ppc*|powerpc*)
1534     # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1535     AC_CACHE_CHECK([whether assembler supports lwarx hint bit],
1536                    [pgac_cv_have_ppc_mutex_hint],
1537     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1538         [int a = 0; int *p = &a; int r;
1539          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1540         [pgac_cv_have_ppc_mutex_hint=yes],
1541         [pgac_cv_have_ppc_mutex_hint=no])])
1542     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1543         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1544     fi
1545     # Check if compiler accepts "i"(x) when __builtin_constant_p(x).
1546     AC_CACHE_CHECK([whether __builtin_constant_p(x) implies "i"(x) acceptance],
1547                    [pgac_cv_have_i_constraint__builtin_constant_p],
1548     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1549     [static inline int
1550      addi(int ra, int si)
1551      {
1552          int res = 0;
1553          if (__builtin_constant_p(si))
1554              __asm__ __volatile__(
1555                  " addi %0,%1,%2\n" : "=r"(res) : "b"(ra), "i"(si));
1556          return res;
1557      }
1558      int test_adds(int x) { return addi(3, x) + addi(x, 5); }], [])],
1559     [pgac_cv_have_i_constraint__builtin_constant_p=yes],
1560     [pgac_cv_have_i_constraint__builtin_constant_p=no])])
1561     if test x"$pgac_cv_have_i_constraint__builtin_constant_p" = xyes ; then
1562       AC_DEFINE(HAVE_I_CONSTRAINT__BUILTIN_CONSTANT_P, 1,
1563                 [Define to 1 if __builtin_constant_p(x) implies "i"(x) acceptance.])
1564     fi
1565   ;;
1566 esac
1567
1568 # Check largefile support.  You might think this is a system service not a
1569 # compiler characteristic, but you'd be wrong.  We must check this before
1570 # probing existence of related functions such as fseeko, since the largefile
1571 # defines can affect what is generated for that.
1572 if test "$PORTNAME" != "win32"; then
1573    AC_SYS_LARGEFILE
1574    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1575    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1576    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1577    dnl versions where the feature actually works, it's on by default anyway.
1578    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1579 fi
1580
1581 dnl Check for largefile support (must be after AC_SYS_LARGEFILE)
1582 AC_CHECK_SIZEOF([off_t])
1583
1584 # If we don't have largefile support, can't handle segsize >= 2GB.
1585 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1586    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1587 fi
1588
1589 AC_CHECK_SIZEOF([bool], [],
1590 [#ifdef HAVE_STDBOOL_H
1591 #include <stdbool.h>
1592 #endif])
1593
1594
1595 ##
1596 ## Functions, global variables
1597 ##
1598
1599 PGAC_VAR_INT_TIMEZONE
1600 AC_FUNC_ACCEPT_ARGTYPES
1601 PGAC_FUNC_GETTIMEOFDAY_1ARG
1602 PGAC_FUNC_WCSTOMBS_L
1603
1604 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1605 # symbols that that library has no business exposing to the world.  Pending
1606 # acquisition of a clue by those developers, ignore libedit (including its
1607 # possible alias of libreadline) while checking for everything else.
1608 LIBS_including_readline="$LIBS"
1609 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1610
1611 AC_CHECK_FUNCS(m4_normalize([
1612         cbrt
1613         clock_gettime
1614         copyfile
1615         fdatasync
1616         getifaddrs
1617         getpeerucred
1618         getrlimit
1619         mbstowcs_l
1620         memset_s
1621         memmove
1622         poll
1623         posix_fallocate
1624         ppoll
1625         pstat
1626         pthread_is_threaded_np
1627         readlink
1628         setproctitle
1629         setproctitle_fast
1630         setsid
1631         shm_open
1632         strchrnul
1633         strsignal
1634         symlink
1635         sync_file_range
1636         uselocale
1637         utime
1638         utimes
1639         wcstombs_l
1640 ]))
1641
1642 # These typically are compiler builtins, for which AC_CHECK_FUNCS fails.
1643 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap16], [int x])
1644 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap32], [int x])
1645 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap64], [long int x])
1646 # We assume that we needn't test all widths of these explicitly:
1647 PGAC_CHECK_BUILTIN_FUNC([__builtin_clz], [unsigned int x])
1648 PGAC_CHECK_BUILTIN_FUNC([__builtin_ctz], [unsigned int x])
1649 PGAC_CHECK_BUILTIN_FUNC([__builtin_popcount], [unsigned int x])
1650
1651 AC_REPLACE_FUNCS(fseeko)
1652 case $host_os in
1653         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1654         # Mingw uses macros to access Win32 API calls
1655         netbsd*|mingw*)
1656                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1657                 ac_cv_func_fseeko=yes;;
1658         *)
1659                 AC_FUNC_FSEEKO;;
1660 esac
1661
1662 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1663 # by calling it, 2009-04-02
1664 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1665 dnl must use AS_IF here, else AC_REQUIRES inside AC_CHECK_DECLS malfunctions
1666 AS_IF([test "$PORTNAME" != "solaris"], [
1667 AC_CHECK_FUNCS(posix_fadvise)
1668 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1669 ]) # fi
1670
1671 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1672 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1673 # This is probably only present on macOS, but may as well check always
1674 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1675
1676 AC_CHECK_DECLS([RTLD_GLOBAL, RTLD_NOW], [], [], [#include <dlfcn.h>])
1677
1678 AC_CHECK_TYPE([struct sockaddr_in6],
1679         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])],
1680         [],
1681 [$ac_includes_default
1682 #include <netinet/in.h>])
1683
1684 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1685 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1686 [#include <machine/vmparam.h>
1687 #include <sys/exec.h>
1688 ],
1689 [PS_STRINGS->ps_nargvstr = 1;
1690 PS_STRINGS->ps_argvstr = "foo";])],
1691 [pgac_cv_var_PS_STRINGS=yes],
1692 [pgac_cv_var_PS_STRINGS=no])])
1693 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1694   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1695 fi
1696
1697
1698 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1699 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1700 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1701 #include <math.h>
1702 double glob_double;
1703 ],
1704 [return isinf(glob_double) ? 0 : 1;])],
1705 [ac_cv_func_isinf=yes],
1706 [ac_cv_func_isinf=no])])
1707
1708 if test $ac_cv_func_isinf = yes ; then
1709   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1710 else
1711   AC_LIBOBJ(isinf)
1712   # Look for a way to implement a substitute for isinf()
1713   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1714 fi
1715
1716 AC_REPLACE_FUNCS(m4_normalize([
1717         dlopen
1718         explicit_bzero
1719         fls
1720         getopt
1721         getrusage
1722         inet_aton
1723         mkdtemp
1724         pread
1725         pwrite
1726         random
1727         rint
1728         srandom
1729         strlcat
1730         strlcpy
1731         strnlen
1732         strtof
1733 ]))
1734
1735 case $host_os in
1736         # Cygwin and (apparently, based on test results) Mingw both
1737         # have a broken strtof(), so substitute the same replacement
1738         # code we use with VS2013. That's not a perfect fix, since
1739         # (unlike with VS2013) it doesn't avoid double-rounding, but
1740         # we have no better options. To get that, though, we have to
1741         # force the file to be compiled despite HAVE_STRTOF.
1742         mingw*|cygwin*)
1743                 AC_LIBOBJ([strtof])
1744                 AC_MSG_NOTICE([On $host_os we will use our strtof wrapper.])
1745         ;;
1746 esac
1747
1748 case $host_os in
1749
1750         # Windows uses a specialised env handler
1751         # and doesn't need a replacement getpeereid because it doesn't use
1752         # Unix sockets.
1753         mingw*)
1754                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1755                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1756                 ac_cv_func_unsetenv=yes
1757                 ac_cv_func_getpeereid=yes;;
1758         *)
1759                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1760                 ;;
1761 esac
1762
1763 # System's version of getaddrinfo(), if any, may be used only if we found
1764 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1765 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1766 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1767    test "$PORTNAME" != "win32"; then
1768   AC_REPLACE_FUNCS([getaddrinfo])
1769 else
1770   AC_LIBOBJ(getaddrinfo)
1771 fi
1772
1773 # Similarly, use system's getopt_long() only if system provides struct option.
1774 if test x"$ac_cv_type_struct_option" = xyes ; then
1775   AC_REPLACE_FUNCS([getopt_long])
1776 else
1777   AC_LIBOBJ(getopt_long)
1778 fi
1779
1780 # On OpenBSD and Solaris, getopt() doesn't do what we want for long options
1781 # (i.e., allow '-' as a flag character), so use our version on those platforms.
1782 if test "$PORTNAME" = "openbsd" -o "$PORTNAME" = "solaris"; then
1783   AC_LIBOBJ(getopt)
1784 fi
1785
1786 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1787 # so always use our version on Windows.
1788 if test "$PORTNAME" = "win32"; then
1789   AC_LIBOBJ(getopt)
1790   AC_LIBOBJ(getopt_long)
1791 fi
1792
1793 # Win32 (really MinGW) support
1794 if test "$PORTNAME" = "win32"; then
1795   AC_CHECK_FUNCS(_configthreadlocale)
1796   AC_REPLACE_FUNCS(gettimeofday)
1797   AC_LIBOBJ(dirmod)
1798   AC_LIBOBJ(kill)
1799   AC_LIBOBJ(open)
1800   AC_LIBOBJ(system)
1801   AC_LIBOBJ(win32env)
1802   AC_LIBOBJ(win32error)
1803   AC_LIBOBJ(win32security)
1804   AC_LIBOBJ(win32setlocale)
1805   AC_DEFINE([HAVE_SYMLINK], 1,
1806             [Define to 1 if you have the `symlink' function.])
1807   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1808 #define WIN32_LEAN_AND_MEAN
1809 #include <windows.h>
1810 #include <string.h>
1811 #include <dbghelp.h>])
1812 fi
1813 if test x"$pgac_minidump_type" = x"yes" ; then
1814   AC_SUBST(have_win32_dbghelp,yes)
1815 else
1816   AC_SUBST(have_win32_dbghelp,no)
1817 fi
1818
1819 # Cygwin needs only a bit of that
1820 if test "$PORTNAME" = "cygwin"; then
1821   AC_LIBOBJ(dirmod)
1822 fi
1823
1824 AC_CHECK_FUNC(syslog,
1825               [AC_CHECK_HEADER(syslog.h,
1826                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1827
1828 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1829 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1830   [extern int opterr; opterr = 1;])],
1831   [pgac_cv_var_int_opterr=yes],
1832   [pgac_cv_var_int_opterr=no])])
1833 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1834   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1835 fi
1836
1837 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1838 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1839   [extern int optreset; optreset = 1;])],
1840   [pgac_cv_var_int_optreset=yes],
1841   [pgac_cv_var_int_optreset=no])])
1842 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1843   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1844 fi
1845
1846 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1847 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1848 # strto[u]ll may exist but not be declared
1849 AC_CHECK_DECLS([strtoll, strtoull])
1850
1851 if test "$with_icu" = yes; then
1852   ac_save_CPPFLAGS=$CPPFLAGS
1853   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1854
1855   # Verify we have ICU's header files
1856   AC_CHECK_HEADER(unicode/ucol.h, [],
1857         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1858
1859   CPPFLAGS=$ac_save_CPPFLAGS
1860 fi
1861
1862 if test "$with_llvm" = yes; then
1863   PGAC_CHECK_LLVM_FUNCTIONS()
1864 fi
1865
1866 # Lastly, restore full LIBS list and check for readline/libedit symbols
1867 LIBS="$LIBS_including_readline"
1868
1869 if test "$with_readline" = yes; then
1870   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1871   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1872   AC_CHECK_FUNCS([append_history history_truncate_file])
1873 fi
1874
1875
1876 # This test makes sure that run tests work at all.  Sometimes a shared
1877 # library is found by the linker, but the runtime linker can't find it.
1878 # This check should come after all modifications of compiler or linker
1879 # variables, and before any other run tests.
1880 AC_MSG_CHECKING([test program])
1881 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1882 [AC_MSG_RESULT(ok)],
1883 [AC_MSG_RESULT(failed)
1884 AC_MSG_ERROR([[
1885 Could not execute a simple test program.  This may be a problem
1886 related to locating shared libraries.  Check the file 'config.log'
1887 for the exact reason.]])],
1888 [AC_MSG_RESULT([cross-compiling])])
1889
1890 # --------------------
1891 # Run tests below here
1892 # --------------------
1893
1894 dnl Check to see if we have a working 64-bit integer type.
1895 dnl Since Postgres 8.4, we no longer support compilers without a working
1896 dnl 64-bit type; but we have to determine whether that type is called
1897 dnl "long int" or "long long int".
1898
1899 PGAC_TYPE_64BIT_INT([long int])
1900
1901 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1902   pg_int64_type="long int"
1903 else
1904   PGAC_TYPE_64BIT_INT([long long int])
1905   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1906     pg_int64_type="long long int"
1907   else
1908     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1909   fi
1910 fi
1911
1912 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1913   [Define to the name of a signed 64-bit integer type.])
1914
1915 # Select the printf length modifier that goes with that, too.
1916 if test x"$pg_int64_type" = x"long long int" ; then
1917   INT64_MODIFIER='"ll"'
1918 else
1919   INT64_MODIFIER='"l"'
1920 fi
1921
1922 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1923                    [Define to the appropriate printf length modifier for 64-bit ints.])
1924
1925 # has to be down here, rather than with the other builtins, because
1926 # the test uses PG_INT64_TYPE.
1927 PGAC_C_BUILTIN_OP_OVERFLOW
1928
1929 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1930 AC_CHECK_SIZEOF([void *])
1931 AC_CHECK_SIZEOF([size_t])
1932 AC_CHECK_SIZEOF([long])
1933
1934 # Decide whether float4 is passed by value: user-selectable, enabled by default
1935 AC_MSG_CHECKING([whether to build with float4 passed by value])
1936 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1937               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1938                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1939                float4passbyval=true],
1940               [float4passbyval=false])
1941 AC_MSG_RESULT([$enable_float4_byval])
1942 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1943
1944 # Decide whether float8 is passed by value.
1945 # Note: this setting also controls int8 and related types such as timestamp.
1946 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1947 # If not, trying to select it is an error.
1948 AC_MSG_CHECKING([whether to build with float8 passed by value])
1949 if test $ac_cv_sizeof_void_p -ge 8 ; then
1950   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1951 else
1952   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1953   if test "$enable_float8_byval" = yes ; then
1954     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1955   fi
1956 fi
1957 if test "$enable_float8_byval" = yes ; then
1958   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1959             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1960   float8passbyval=true
1961 else
1962   float8passbyval=false
1963 fi
1964 AC_MSG_RESULT([$enable_float8_byval])
1965 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1966
1967 # Determine memory alignment requirements for the basic C data types.
1968
1969 AC_CHECK_ALIGNOF(short)
1970 AC_CHECK_ALIGNOF(int)
1971 AC_CHECK_ALIGNOF(long)
1972 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1973   AC_CHECK_ALIGNOF(long long int)
1974 fi
1975 AC_CHECK_ALIGNOF(double)
1976
1977 # Compute maximum alignment of any basic type.
1978 # We assume long's alignment is at least as strong as char, short, or int;
1979 # but we must check long long (if it is being used for int64) and double.
1980 # Note that we intentionally do not consider any types wider than 64 bits,
1981 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1982 # for disk and memory space.
1983
1984 MAX_ALIGNOF=$ac_cv_alignof_long
1985 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1986   MAX_ALIGNOF=$ac_cv_alignof_double
1987 fi
1988 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1989   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1990 fi
1991 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1992
1993
1994 # Some platforms predefine the types int8, int16, etc.  Only check
1995 # a (hopefully) representative subset.
1996 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1997 [#include <stdio.h>])
1998
1999 # Some compilers offer a 128-bit integer scalar type.
2000 PGAC_TYPE_128BIT_INT
2001
2002 # Check for various atomic operations now that we have checked how to declare
2003 # 64bit integers.
2004 PGAC_HAVE_GCC__SYNC_CHAR_TAS
2005 PGAC_HAVE_GCC__SYNC_INT32_TAS
2006 PGAC_HAVE_GCC__SYNC_INT32_CAS
2007 PGAC_HAVE_GCC__SYNC_INT64_CAS
2008 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
2009 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
2010
2011
2012 # Check for x86 cpuid instruction
2013 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
2014 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
2015   [[unsigned int exx[4] = {0, 0, 0, 0};
2016   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
2017   ]])],
2018   [pgac_cv__get_cpuid="yes"],
2019   [pgac_cv__get_cpuid="no"])])
2020 if test x"$pgac_cv__get_cpuid" = x"yes"; then
2021   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
2022 fi
2023
2024 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
2025 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
2026   [[unsigned int exx[4] = {0, 0, 0, 0};
2027   __get_cpuid(exx[0], 1);
2028   ]])],
2029   [pgac_cv__cpuid="yes"],
2030   [pgac_cv__cpuid="no"])])
2031 if test x"$pgac_cv__cpuid" = x"yes"; then
2032   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
2033 fi
2034
2035 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
2036 #
2037 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
2038 # with the default compiler flags. If not, check if adding the -msse4.2
2039 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
2040 PGAC_SSE42_CRC32_INTRINSICS([])
2041 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
2042   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
2043 fi
2044 AC_SUBST(CFLAGS_SSE42)
2045
2046 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2047 # define __SSE4_2__ in that case.
2048 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2049 #ifndef __SSE4_2__
2050 #error __SSE4_2__ not defined
2051 #endif
2052 ])], [SSE4_2_TARGETED=1])
2053
2054 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2055 #
2056 # First check if __crc32c* intrinsics can be used with the default compiler
2057 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2058 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2059 PGAC_ARMV8_CRC32C_INTRINSICS([])
2060 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2061   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2062 fi
2063 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2064
2065 # Select CRC-32C implementation.
2066 #
2067 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2068 # use the special CRC instructions for calculating CRC-32C. If we're not
2069 # targeting such a processor, but we can nevertheless produce code that uses
2070 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2071 # implementations and select which one to use at runtime, depending on whether
2072 # SSE 4.2 is supported by the processor we're running on.
2073 #
2074 # Similarly, if we are targeting an ARM processor that has the CRC
2075 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2076 # we're not targeting such a processor, but can nevertheless produce code that
2077 # uses the CRC instructions, compile both, and select at runtime.
2078 #
2079 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2080 # in the template or configure command line.
2081 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2082   # Use Intel SSE 4.2 if available.
2083   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2084     USE_SSE42_CRC32C=1
2085   else
2086     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2087     # the runtime check.
2088     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2089       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2090     else
2091       # Use ARM CRC Extension if available.
2092       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2093         USE_ARMV8_CRC32C=1
2094       else
2095         # ARM CRC Extension, with runtime check?
2096         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2097           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2098         else
2099           # fall back to slicing-by-8 algorithm, which doesn't require any
2100           # special CPU support.
2101           USE_SLICING_BY_8_CRC32C=1
2102         fi
2103       fi
2104     fi
2105   fi
2106 fi
2107
2108 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2109 AC_MSG_CHECKING([which CRC-32C implementation to use])
2110 if test x"$USE_SSE42_CRC32C" = x"1"; then
2111   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2112   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2113   AC_MSG_RESULT(SSE 4.2)
2114 else
2115   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2116     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2117     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2118     AC_MSG_RESULT(SSE 4.2 with runtime check)
2119   else
2120     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2121       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2122       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2123       AC_MSG_RESULT(ARMv8 CRC instructions)
2124     else
2125       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2126         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2127         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2128         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2129       else
2130         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2131         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2132         AC_MSG_RESULT(slicing-by-8)
2133       fi
2134     fi
2135   fi
2136 fi
2137 AC_SUBST(PG_CRC32C_OBJS)
2138
2139
2140 # Select semaphore implementation type.
2141 if test "$PORTNAME" != "win32"; then
2142   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2143     # Need sem_open for this
2144     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2145   fi
2146   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2147     # Need sem_init for this
2148     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2149   fi
2150   AC_MSG_CHECKING([which semaphore API to use])
2151   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2152     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2153     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2154     sematype="named POSIX"
2155   else
2156     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2157       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2158       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2159       sematype="unnamed POSIX"
2160     else
2161       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2162       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2163       sematype="System V"
2164     fi
2165   fi
2166   AC_MSG_RESULT([$sematype])
2167 else
2168   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2169   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2170 fi
2171
2172
2173 # Select shared-memory implementation type.
2174 if test "$PORTNAME" != "win32"; then
2175   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2176   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2177 else
2178   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2179   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2180 fi
2181
2182 # Select random number source
2183 #
2184 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2185 # in the template or configure command line.
2186
2187 # If not selected manually, try to select a source automatically.
2188 if test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2189   if test x"$with_openssl" = x"yes" ; then
2190     USE_OPENSSL_RANDOM=1
2191   elif test "$PORTNAME" = "win32" ; then
2192     USE_WIN32_RANDOM=1
2193   else
2194     AC_CHECK_FILE([/dev/urandom], [], [])
2195
2196     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2197       USE_DEV_URANDOM=1
2198     fi
2199   fi
2200 fi
2201
2202 AC_MSG_CHECKING([which random number source to use])
2203 if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2204   AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2205   AC_MSG_RESULT([OpenSSL])
2206 elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2207   AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2208   AC_MSG_RESULT([Windows native])
2209 elif test x"$USE_DEV_URANDOM" = x"1" ; then
2210   AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2211   AC_MSG_RESULT([/dev/urandom])
2212 else
2213   AC_MSG_ERROR([
2214 no source of strong random numbers was found
2215 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers.])
2216 fi
2217
2218 # If not set in template file, set bytes to use libc memset()
2219 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2220   MEMSET_LOOP_LIMIT=1024
2221 fi
2222 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2223
2224
2225 if test "$enable_nls" = yes ; then
2226   PGAC_CHECK_GETTEXT
2227 fi
2228
2229 # Check for Tcl configuration script tclConfig.sh
2230 if test "$with_tcl" = yes; then
2231     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2232     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2233                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2234     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2235     if test "$TCL_SHARED_BUILD" != 1; then
2236       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2237 Use --without-tcl to disable building PL/Tcl.])
2238     fi
2239     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2240     ac_save_CPPFLAGS=$CPPFLAGS
2241     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2242     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2243     CPPFLAGS=$ac_save_CPPFLAGS
2244 fi
2245
2246 # check for <perl.h>
2247 if test "$with_perl" = yes; then
2248   ac_save_CPPFLAGS=$CPPFLAGS
2249   CPPFLAGS="$CPPFLAGS $perl_includespec"
2250   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2251                   [#include <EXTERN.h>])
2252   # While we're at it, check that we can link to libperl.
2253   # On most platforms, if perl.h is there then libperl.so will be too, but at
2254   # this writing Debian packages them separately.  There is no known reason to
2255   # waste cycles on separate probes for the Tcl or Python libraries, though.
2256   # On some Red Hat platforms, the link attempt can fail if we don't use
2257   # CFLAGS_SL while building the test program.
2258   ac_save_CFLAGS=$CFLAGS
2259   CFLAGS="$CFLAGS $CFLAGS_SL"
2260   pgac_save_LIBS=$LIBS
2261   LIBS="$perl_embed_ldflags"
2262   AC_MSG_CHECKING([for libperl])
2263   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2264 #include <EXTERN.h>
2265 #include <perl.h>
2266 ],  [perl_alloc();])],
2267     [AC_MSG_RESULT(yes)],
2268     [AC_MSG_RESULT(no)
2269      AC_MSG_ERROR([libperl library is required for Perl])])
2270   LIBS=$pgac_save_LIBS
2271   CFLAGS=$ac_save_CFLAGS
2272   CPPFLAGS=$ac_save_CPPFLAGS
2273 fi
2274
2275 # check for <Python.h>
2276 if test "$with_python" = yes; then
2277   ac_save_CPPFLAGS=$CPPFLAGS
2278   CPPFLAGS="$python_includespec $CPPFLAGS"
2279   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2280   CPPFLAGS=$ac_save_CPPFLAGS
2281 fi
2282
2283 #
2284 # Check for DocBook and tools
2285 #
2286 PGAC_PATH_XMLLINT
2287 PGAC_CHECK_DOCBOOK(4.5)
2288 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2289 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2290 PGAC_PATH_PROGS(FOP, fop)
2291
2292 #
2293 # Check for test tools
2294 #
2295 if test "$enable_tap_tests" = yes; then
2296   # Check for necessary modules, unless user has specified the "prove" to use;
2297   # in that case it's her responsibility to have a working configuration.
2298   # (prove might be part of a different Perl installation than perl, eg on
2299   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2300   if test -z "$PROVE"; then
2301     # Test::More and Time::HiRes are supposed to be part of core Perl,
2302     # but some distros omit them in a minimal installation.
2303     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2304       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2305   fi
2306   # Now make sure we know where prove is
2307   PGAC_PATH_PROGS(PROVE, prove)
2308   if test -z "$PROVE"; then
2309     AC_MSG_ERROR([prove not found])
2310   fi
2311 fi
2312
2313 # Thread testing
2314
2315 # We have to run the thread test near the end so we have all our symbols
2316 # defined.  Cross compiling throws a warning.
2317 #
2318 if test "$enable_thread_safety" = yes; then
2319 if test "$PORTNAME" != "win32"
2320 then
2321 AC_MSG_CHECKING([thread safety of required library functions])
2322
2323 _CFLAGS="$CFLAGS"
2324 _LIBS="$LIBS"
2325 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2326 LIBS="$LIBS $PTHREAD_LIBS"
2327 AC_RUN_IFELSE(
2328   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2329   [AC_MSG_RESULT(yes)],
2330   [AC_MSG_RESULT(no)
2331   AC_MSG_ERROR([thread test program failed
2332 This platform is not thread-safe.  Check the file 'config.log' or compile
2333 and run src/test/thread/thread_test for the exact reason.
2334 Use --disable-thread-safety to disable thread safety.])],
2335   [AC_MSG_RESULT(maybe)
2336   AC_MSG_WARN([
2337 *** Skipping thread test program because of cross-compile build.
2338 *** Run the program in src/test/thread on the target machine.
2339 ])])
2340 CFLAGS="$_CFLAGS"
2341 LIBS="$_LIBS"
2342 else
2343 AC_MSG_WARN([*** skipping thread test on Win32])
2344 fi
2345 fi
2346
2347 # If compiler will take -Wl,--as-needed (or various platform-specific
2348 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2349 # trying to filter LIBS to the minimum for each executable.
2350 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2351 # libreadline; therefore we postpone testing it until we know what library
2352 # dependencies readline has.  The test code will try to link with $LIBS.
2353 if test "$with_readline" = yes; then
2354   link_test_func=readline
2355 else
2356   link_test_func=exit
2357 fi
2358
2359 if test "$PORTNAME" = "darwin"; then
2360   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2361 elif test "$PORTNAME" = "openbsd"; then
2362   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2363 else
2364   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2365 fi
2366
2367 # Create compiler version string
2368 if test x"$GCC" = x"yes" ; then
2369   cc_string=`${CC} --version | sed q`
2370   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2371 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2372   cc_string=`${CC} -V 2>&1 | sed q`
2373 else
2374   cc_string=$CC
2375 fi
2376
2377 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2378                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2379                    [A string containing the version number, platform, and C compiler])
2380
2381 # Supply a numeric version string for use by 3rd party add-ons
2382 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2383 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2384 tr '.' '        ' |
2385 $AWK '{printf "%d%04d", $1, $2}'`"]
2386 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2387 AC_SUBST(PG_VERSION_NUM)
2388
2389 # If we are inserting PG_SYSROOT into CPPFLAGS, do so symbolically not
2390 # literally, so that it's possible to override it at build time using
2391 # a command like "make ... PG_SYSROOT=path".  This has to be done after
2392 # we've finished all configure checks that depend on CPPFLAGS.
2393 if test x"$PG_SYSROOT" != x; then
2394   CPPFLAGS=`echo "$CPPFLAGS" | sed -e "s| $PG_SYSROOT | \\\$(PG_SYSROOT) |"`
2395 fi
2396 AC_SUBST(PG_SYSROOT)
2397
2398
2399 # Begin output steps
2400
2401 AC_MSG_NOTICE([using compiler=$cc_string])
2402 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2403 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2404 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2405 # Currently only used when LLVM is used
2406 if test "$with_llvm" = yes ; then
2407    AC_MSG_NOTICE([using CXX=$CXX])
2408    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2409    AC_MSG_NOTICE([using CLANG=$CLANG])
2410    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2411    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2412 fi
2413
2414 # prepare build tree if outside source tree
2415 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2416 # Note 2: /bin/pwd might be better than shell's built-in at getting
2417 #         a symlink-free name.
2418 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2419   vpath_build=no
2420 else
2421   vpath_build=yes
2422   if test "$no_create" != yes; then
2423     _AS_ECHO_N([preparing build tree... ])
2424     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2425     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2426       || AC_MSG_ERROR(failed)
2427     AC_MSG_RESULT(done)
2428   fi
2429 fi
2430 AC_SUBST(vpath_build)
2431
2432
2433 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2434
2435 AC_CONFIG_LINKS([
2436   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2437   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2438   src/include/pg_config_os.h:src/include/port/${template}.h
2439   src/Makefile.port:src/makefiles/Makefile.${template}
2440 ])
2441
2442 if test "$PORTNAME" = "win32"; then
2443 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2444 # Links sometimes fail undetected on Mingw -
2445 # so here we detect it and warn the user
2446 for FILE in $CONFIG_LINKS
2447  do
2448         # test -e works for symlinks in the MinGW console
2449         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2450  done
2451 ])
2452 fi
2453
2454 AC_CONFIG_HEADERS([src/include/pg_config.h],
2455 [
2456 # Update timestamp for pg_config.h (see Makefile.global)
2457 echo >src/include/stamp-h
2458 ])
2459
2460 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2461 [
2462 # Update timestamp for pg_config_ext.h (see Makefile.global)
2463 echo >src/include/stamp-ext-h
2464 ])
2465
2466 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2467                   [echo >src/interfaces/ecpg/include/stamp-h])
2468
2469 AC_OUTPUT