granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 # Only APR 1.x is supported.
  77 apr_version=1
  78
  79 if test "x$with_included_apr" = "xyes"; then
  80    apr_found=reconfig
  81    apr_config="$srcdir/srclib/apr/apr-${apr_version}-config"
  82 else
  83    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, ${apr_version})
  84 fi
  85
  86 if test "$apr_found" = "no"; then
  87   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  88 fi
  89
  90 if test "$apr_found" = "reconfig"; then
  91   APR_SUBDIR_CONFIG(srclib/apr,
  92                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  93                     [--enable-layout=*|\'--enable-layout=*])
  94   dnl We must be the first to build and the last to be cleaned
  95   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  96   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  97 fi
  98
  99 APR_SETIFNULL(CC, `$apr_config --cc`)
 100 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 101 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 102 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 103 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 104 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 105 APR_BINDIR=`$apr_config --bindir`
 106 APR_INCLUDEDIR=`$apr_config --includedir`
 107 APR_INCLUDES=`$apr_config --includes`
 108 APR_VERSION=`$apr_config --version`
 109 APR_CONFIG="$APR_BINDIR/apr-`echo ${APR_VERSION} | sed 's,\..*,,'`-config"
 110
 111 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 112
 113 # Only APR-util 1.x is supported.
 114 apu_version=1
 115
 116 if test "x$with_included_apr" = "xyes"; then
 117    apu_found=reconfig
 118    apu_config="${srcdir}/srclib/apr-util/apu-${apu_version}-config"
 119 else
 120    APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1, ${apu_version})
 121 fi
 122
 123 if test "$apu_found" = "no"; then
 124   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 125 fi
 126
 127 # Catch some misconfigurations:
 128 case ${apr_found}.${apu_found} in
 129 reconfig.yes)
 130   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 131   ;;
 132 yes.reconfig)
 133   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 134   ;;
 135 esac
 136
 137 if test "$apu_found" = "reconfig"; then
 138   APR_SUBDIR_CONFIG(srclib/apr-util,
 139                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 140                     [--enable-layout=*|\'--enable-layout=*])
 141   dnl We must be the last to build and the first to be cleaned
 142   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 143   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 144 fi
 145
 146 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 147 APU_BINDIR=`$apu_config --bindir`
 148 APU_INCLUDEDIR=`$apu_config --includedir`
 149 APU_INCLUDES=`$apu_config --includes`
 150 APU_VERSION=`$apu_config --version`
 151 APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 152
 153 dnl In case we picked up CC and CPP from APR, get that info into the
 154 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 155 dnl PCRE and for our config tests will be whatever PCRE determines.
 156 AC_PROG_CC
 157 AC_PROG_CPP
 158
 159 if test "x${cache_file}" = "x/dev/null"; then
 160   # Likewise, ensure that CC and CPP are passed through to the pcre
 161   # configure script iff caching is disabled (the autoconf 2.5x default).
 162   export CC; export CPP
 163 fi
 164
 165 dnl Absolute source/build directory
 166 abs_srcdir=`(cd $srcdir && pwd)`
 167 abs_builddir=`pwd`
 168
 169 AC_ARG_WITH(pcre,
 170 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 171
 172 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 173 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 174    PCRE_CONFIG=$with_pcre/bin/pcre-config
 175 elif test -x "$with_pcre"; then
 176    PCRE_CONFIG=$with_pcre
 177 fi
 178
 179 if test "$PCRE_CONFIG" != "false"; then
 180   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 181     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 182   fi
 183   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 184   APR_ADDTO(CFLAGS, [`$PCRE_CONFIG --cflags`])
 185   APR_ADDTO(LIBS, [`$PCRE_CONFIG --libs`])
 186 else
 187   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 188 fi
 189
 190 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 191
 192 dnl If the source dir is not equal to the build dir,
 193 dnl then we are running in VPATH mode.
 194
 195 APR_ADDTO(INCLUDES, [-I.])
 196
 197 if test "$abs_builddir" != "$abs_srcdir"; then
 198   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 199 fi
 200
 201 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/aaa -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/modules/session -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 202
 203 # apr/apr-util --includes may pick up system paths for dependent
 204 # libraries, so ensure these are later in INCLUDES than local source
 205 # directories.
 206 APR_ADDTO(INCLUDES, `$apr_config --includes`)
 207 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 208
 209 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 210
 211 case $host in
 212   *os2*)
 213       # Use a custom made libtool replacement
 214       echo "using aplibtool"
 215       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 216       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 217       SH_LIBS="\$(ALL_LIBS)"
 218       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 219       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 220       MK_IMPLIB="emximp"
 221       other_targets="$other_targets os2core"
 222       INSTALL_PROG_FLAGS="-e .exe"
 223       SHLTCFLAGS=""
 224       LTCFLAGS=""
 225       ;;
 226   *)
 227       if test "x$LTFLAGS" = "x"; then
 228           LTFLAGS='--silent'
 229       fi
 230       my_libtool=`$apr_config --apr-libtool`
 231       LIBTOOL="$my_libtool \$(LTFLAGS)"
 232       libtoolversion=`$my_libtool --version`
 233       case $libtoolversion in
 234           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 235               SH_LIBTOOL='$(LIBTOOL)'
 236               SHLTCFLAGS="-prefer-pic"
 237               LTCFLAGS="-prefer-non-pic -static"
 238               ;;
 239           *)
 240               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 241               SHLTCFLAGS=""
 242               LTCFLAGS=""
 243               ;;
 244       esac
 245       ;;
 246 esac
 247 APACHE_SUBST(SHLTCFLAGS)
 248 APACHE_SUBST(LTCFLAGS)
 249
 250 case $host in
 251   *-apple-aux3*)
 252       APR_SETVAR(APACHE_MPM, [prefork])
 253       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 254       ;;
 255   *-beos*)
 256       APR_SETVAR(APACHE_MPM, [beos])
 257       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 258       ;;
 259   *os2-emx*)
 260       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 261       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 262       ;;
 263   *-linux-*)
 264       case `uname -r` in
 265         2.[[2-9]]* )
 266             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 267             ;;
 268         * )
 269             ;;
 270       esac
 271       ;;
 272   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 273       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 274       ;;
 275   *-solaris2*)
 276       dnl This is a hack -- we should be using AC_TRY_RUN instead
 277       ap_platform_runtime_link_flag="-R"
 278       dnl solaris 8 and above don't have a thundering herd
 279       dnl not sure about rev's before this one.
 280       case `uname -r` in
 281         5.[567]*)
 282             ;;
 283         * )
 284             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 285             ;;
 286       esac
 287       ;;
 288   *cygwin*)
 289       APR_SETVAR(APACHE_MPM, [prefork])
 290       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 291       ;;
 292   *mingw32*)
 293       APR_SETVAR(APACHE_MPM, [winnt])
 294       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 295       APR_SETIFNULL(ac_cv_func_times, [no])
 296       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 297       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 298       ;;
 299   *aix*)
 300       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 301       if test $aixver -ge 4320; then
 302         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 303       fi
 304       ;;
 305   *os390*)
 306       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 307       ;;
 308 esac
 309
 310 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 311
 312 dnl
 313 dnl Process command line arguments. This is done early in the process so the
 314 dnl user can get feedback quickly in case of an error.
 315 dnl
 316 dnl ### need to move some of the arguments "up here"
 317
 318 dnl ## Check for programs
 319
 320 AC_PATH_PROG(RM, rm)
 321 AC_PATH_PROG(PKGCONFIG, pkg-config)
 322 AC_PATH_PROG(RSYNC, rsync)
 323 AC_PROG_AWK
 324 AC_PROG_LN_S
 325 AC_CHECK_TOOL(RANLIB, ranlib, true)
 326 dnl AC_PATH_PROG(PERL_PATH, perl)
 327 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 328
 329 # Hard-coded install programs
 330 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 331 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 332 APACHE_SUBST(MKINSTALLDIRS)
 333 APACHE_SUBST(INSTALL)
 334
 335 dnl Various OS checks that apparently set required flags
 336 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 337 AC_USE_SYSTEM_EXTENSIONS
 338 ], [
 339 AC_AIX
 340 AC_MINIX
 341 ])
 342
 343 AC_ISC_POSIX
 344
 345 # Ensure that satisfactory versions of apr and apr-util are
 346 # found if external copies are configured.
 347 if test "${apr_found}" = "yes"; then
 348   # Require APR 1.3.x otherwise fail
 349   APACHE_CHECK_APxVER([apr], 1, 3)
 350 fi
 351
 352 if test "${apu_found}" = "yes"; then
 353   # Require APR-util 1.3.x otherwise fail
 354   APACHE_CHECK_APxVER([apu], 1, 3)
 355 fi
 356
 357 dnl Check for what we can generate dependency files with
 358 APR_CHECK_DEPEND
 359
 360 dnl ## Check for libraries
 361
 362 dnl ## Check for header files
 363
 364 dnl I think these are just used all over the place, so just check for
 365 dnl them at the base of the tree. If some are specific to a single
 366 dnl directory, they should be moved (Comment #Spoon)
 367
 368 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 369 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 370 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 371
 372 AC_HEADER_STDC
 373 AC_CHECK_HEADERS( \
 374 string.h \
 375 limits.h \
 376 unistd.h \
 377 sys/socket.h \
 378 pwd.h \
 379 grp.h \
 380 strings.h \
 381 sys/prctl.h \
 382 sys/processor.h \
 383 sys/sem.h \
 384 sys/sdt.h
 385 )
 386 AC_HEADER_SYS_WAIT
 387
 388 dnl ## Check for typedefs, structures, and compiler characteristics.
 389
 390 AC_C_CONST
 391
 392 dnl ## Check for library functions
 393 AC_SEARCH_LIBS(sqrt, m)
 394
 395 dnl See Comment #Spoon
 396
 397 AC_CHECK_FUNCS( \
 398 getpwnam \
 399 getgrnam \
 400 initgroups \
 401 bindprocessor \
 402 prctl \
 403 timegm \
 404 getpgid
 405 )
 406
 407 dnl confirm that a void pointer is large enough to store a long integer
 408 APACHE_CHECK_VOID_PTR_LEN
 409
 410 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 411 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 412 [AC_TRY_COMPILE([#include <sys/types.h>
 413 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 414   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 415 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 416     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 417 fi
 418
 419 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 420
 421 case $host in
 422     *aix*)
 423         # for 32-bit builds, increase MAXDATA to allow lots of threads
 424         if test x$OBJECT_MODE != x64; then
 425             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 426         fi
 427         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 428         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 429         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 430         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 431         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 432         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 433         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 434         ;;
 435     *os390*)
 436         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 437         ;;
 438     *)
 439         OS_SPECIFIC_VARS=""
 440 esac
 441
 442 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 443         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 444         [PORT=80])
 445
 446 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 447         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 448         [SSLPORT=443])
 449
 450 DTRACE=true
 451 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 452 [
 453   enable_dtrace=$enableval
 454   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 455   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 456 ],
 457 [
 458   enable_dtrace=no
 459 ])
 460
 461 dnl Disabled dtrace build for now.
 462 enable_dtrace=no
 463
 464 case $host in
 465   *-solaris2*)
 466     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 467         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 468                   [Enable DTrace probes])
 469         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 470         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 471     fi
 472     ;;
 473 esac
 474
 475 APACHE_SUBST(DTRACE)
 476
 477 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 478
 479 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 480 [
 481   v4mapped=$enableval
 482 ],
 483 [
 484     case $host in
 485     *freebsd5*|*netbsd*|*openbsd*)
 486         v4mapped=no
 487         ;;
 488     *)
 489         v4mapped=yes
 490         ;;
 491 esac
 492 ])
 493
 494 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 495     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 496               [Allow IPv4 connections on IPv6 listening sockets])
 497 fi
 498
 499 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 500 [
 501     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 502               [Allow modules to run hook after a fatal exception])
 503 ])dnl
 504
 505 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 506 [
 507   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 508 ])dnl
 509
 510 dnl Conditionally enable PIE support for GNU toolchains.
 511 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 512 if test "$enable_pie" = "yes"; then
 513    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 514      save_CFLAGS=$CFLAGS
 515      save_LDFLAGS=$LDFLAGS
 516      CFLAGS="$CFLAGS -fPIE"
 517      LDFLAGS="$LDFLAGS -pie"
 518      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 519       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 520      CFLAGS=$save_CFLAGS
 521      LDFLAGS=$save_LDFLAGS
 522    ])
 523    if test "$ap_cv_cc_pie" = "yes"; then
 524      PICFLAGS="-fPIE"
 525      PILDFLAGS="-pie"
 526    else
 527      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 528    fi
 529 fi
 530 AC_SUBST(PICFLAGS)
 531 AC_SUBST(PILDFLAGS)
 532
 533 prefix="$orig_prefix"
 534 APACHE_ENABLE_MODULES
 535
 536 dnl reading config stubs
 537 esyscmd(./build/config-stubs .)
 538
 539 APACHE_SUBST(progname)
 540 APACHE_SUBST(MPM_LIB)
 541 APACHE_SUBST(OS)
 542 APACHE_SUBST(OS_DIR)
 543 APACHE_SUBST(BUILTIN_LIBS)
 544 APACHE_SUBST(SHLIBPATH_VAR)
 545 APACHE_SUBST(OS_SPECIFIC_VARS)
 546
 547 PRE_SHARED_CMDS='echo ""'
 548 POST_SHARED_CMDS='echo ""'
 549
 550 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 551
 552 if test "$apache_need_shared" = "yes"; then
 553   if test -f $ac_aux_dir/ltconfig; then
 554     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 555   fi
 556   shared_build="shared-build"
 557 fi
 558
 559 dnl enable_so tells us if *any* modules can be built as DSOs
 560
 561 if test "$enable_so" = "yes"; then
 562   case $host in
 563     *-ibm-aix*)
 564       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 565       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 566       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 567       ;;
 568     *beos)
 569       SH_LDFLAGS='$(top_builddir)/_APP_'
 570       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 571       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 572       ;;
 573     *os390)
 574       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 575       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 576   esac
 577   MOD_SO_ENABLED=yes
 578 fi
 579 AC_SUBST(MOD_SO_ENABLED)
 580
 581 APACHE_SUBST(PRE_SHARED_CMDS)
 582 APACHE_SUBST(POST_SHARED_CMDS)
 583 APACHE_SUBST(shared_build)
 584
 585 AC_ARG_WITH(program-name,
 586 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 587   progname="$withval" ], [
 588   progname="httpd"] )
 589
 590 # SuExec parameters
 591 AC_ARG_WITH(suexec-bin,
 592 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 593   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 594 ] )
 595
 596 AC_ARG_WITH(suexec-caller,
 597 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 598   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 599
 600 AC_ARG_WITH(suexec-userdir,
 601 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 602   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 603
 604 AC_ARG_WITH(suexec-docroot,
 605 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 606   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 607
 608 AC_ARG_WITH(suexec-uidmin,
 609 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 610   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 611
 612 AC_ARG_WITH(suexec-gidmin,
 613 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 614   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 615
 616 AC_ARG_WITH(suexec-logfile,
 617 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 618   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 619
 620 AC_ARG_WITH(suexec-safepath,
 621 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 622   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 623
 624 AC_ARG_WITH(suexec-umask,
 625 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 626   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 627
 628 dnl APR should go after the other libs, so the right symbols can be picked up
 629 AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 630 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 631 APACHE_SUBST(AP_LIBS)
 632 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 633 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 634
 635 AC_DEFINE(AP_USING_AUTOCONF, 1,
 636                 [Using autoconf to configure Apache])
 637
 638 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 639     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 640               [This platform doesn't suffer from the thundering herd problem])
 641 fi
 642
 643 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 644     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 645               [Listening sockets are non-blocking when there are more than 1])
 646 fi
 647
 648
 649 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 650 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 651 APACHE_FAST_OUTPUT(support/Makefile)
 652
 653 if test -d ./test; then
 654     APACHE_FAST_OUTPUT(test/Makefile)
 655 fi
 656
 657 dnl ## Finalize the variables
 658 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 659
 660 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 661 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 662 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 663 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 664 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 665 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 666
 667 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 668
 669 APACHE_GEN_CONFIG_VARS
 670
 671 dnl ## Build modules.c
 672 rm -f modules.c
 673 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 674
 675 APR_EXPAND_VAR(ap_prefix, $prefix)
 676 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 677         [Root directory of the Apache install area])
 678 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 679         [Location of the config file, relative to the Apache root directory])
 680 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 681         [Location of the MIME types config file, relative to the Apache root directory])
 682 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 683         [Location of the source for the current MPM])
 684
 685 perlbin=`$ac_aux_dir/PrintPath perl`
 686 if test "x$perlbin" = "x"; then
 687     perlbin="/replace/with/path/to/perl/interpreter"
 688 fi
 689 AC_SUBST(perlbin)
 690
 691 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 692
 693 BSD_MAKEFILE=no
 694 ap_make_include=include
 695 ap_make_delimiter=' '
 696 case $host in
 697 *bsdi*)
 698     # Check whether they've installed GNU make
 699     if make --version > /dev/null 2>&1; then
 700         true
 701     else
 702         BSD_MAKEFILE=yes
 703         ap_make_include=.include
 704         ap_make_delimiter='"'
 705     fi
 706     ;;
 707 esac
 708 AC_SUBST(ap_make_include)
 709 AC_SUBST(ap_make_delimiter)
 710
 711 dnl Ensure that docs/conf is created.
 712 test -d docs/conf||$mkdir_p docs/conf
 713
 714 dnl Ensure that the httpd version is included
 715 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 716 AC_SUBST(HTTPD_VERSION)
 717
 718 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 719   APACHE_GEN_MAKEFILES
 720 ])
 721
 722 case $MPM_SUBDIR_NAME in
 723 *experimental*)
 724     echo ""
 725     echo ""
 726     echo "============================================================"
 727     echo "    WARNING: THE '${APACHE_MPM}' MPM IS EXPERIMENTAL"
 728     echo "============================================================"
 729     echo " The selected MPM might not be fully functional!"
 730     echo ""
 731     echo " Development of this MPM is not complete. Do not use this"
 732     echo " MPM unless you are a programmer willing to help fix it."
 733     echo ""
 734     echo " If you are looking for a stable server, you should not use"
 735     echo " the '${APACHE_MPM}' MPM until it is moved out of experimental."
 736     echo "============================================================"
 737     echo ""
 738     echo ""
 739     ;;
 740 esac