granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.5devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2015, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif], [ICC=[yes]], [ICC=[no]])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # CFLAGS we determined above will be added back at the end
 418 user_CFLAGS=$CFLAGS
 419 CFLAGS=""
 420
 421 # set CFLAGS_VECTOR from the environment, if available
 422 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 423   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 424 fi
 425
 426 # Some versions of GCC support some additional useful warning flags.
 427 # Check whether they are supported, and add them to CFLAGS if so.
 428 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 429 # but has its own.  Also check other compiler-specific flags here.
 430
 431 if test "$GCC" = yes -a "$ICC" = no; then
 432   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 433   # These work in some but not all gcc versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 436   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 437   # This was included in -Wall/-Wformat in older GCC versions
 438   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 439   # Disable strict-aliasing rules; needed for gcc 3.3+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 442   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 443   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 444   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 445   # Optimization flags for specific files that benefit from vectorization
 446   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 447   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 448   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 449   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 450   # test for the positive form and if that works, add the negative form
 451   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 452   if test -n "$NOT_THE_CFLAGS"; then
 453     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 454   fi
 455 elif test "$ICC" = yes; then
 456   # Intel's compiler has a bug/misoptimization in checking for
 457   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 458   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 459   # Make sure strict aliasing is off (though this is said to be the default)
 460   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 461 elif test "$PORTNAME" = "aix"; then
 462   # AIX's xlc has to have strict aliasing turned off too
 463   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 464 elif test "$PORTNAME" = "hpux"; then
 465   # On some versions of HP-UX, libm functions do not set errno by default.
 466   # Fix that by using +Olibmerrno if the compiler recognizes it.
 467   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 468 fi
 469
 470 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 471
 472 # supply -g if --enable-debug
 473 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 474   CFLAGS="$CFLAGS -g"
 475 fi
 476
 477 # enable code coverage if --enable-coverage
 478 if test "$enable_coverage" = yes; then
 479   if test "$GCC" = yes; then
 480     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 481   else
 482     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 483   fi
 484 fi
 485
 486 # enable profiling if --enable-profiling
 487 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 488   if test "$GCC" = yes; then
 489     AC_DEFINE([PROFILE_PID_DIR], 1,
 490            [Define to 1 to allow profiling output to be saved separately for each process.])
 491     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 492   else
 493     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 494   fi
 495 fi
 496
 497 # We already have this in Makefile.win32, but configure needs it too
 498 if test "$PORTNAME" = "win32"; then
 499   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 500 fi
 501
 502 # Now that we're done automatically adding stuff to CFLAGS, put back the
 503 # user-specified flags (if any) at the end.  This lets users override
 504 # the automatic additions.
 505 CFLAGS="$CFLAGS $user_CFLAGS"
 506
 507 # Check if the compiler still works with the final flag settings
 508 AC_MSG_CHECKING([whether the C compiler still works])
 509 AC_TRY_LINK([], [return 0;],
 510   [AC_MSG_RESULT(yes)],
 511   [AC_MSG_RESULT(no)
 512    AC_MSG_ERROR([cannot proceed])])
 513
 514 # Defend against gcc -ffast-math
 515 if test "$GCC" = yes; then
 516 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 517 choke me
 518 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 519 fi
 520
 521 AC_PROG_CPP
 522 AC_SUBST(GCC)
 523
 524
 525 #
 526 # Set up TAS assembly code if needed; the template file has now had its
 527 # chance to request this.
 528 #
 529 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 530
 531 if test "$need_tas" = yes ; then
 532   TAS=tas.o
 533 else
 534   TAS=""
 535 fi
 536 AC_SUBST(TAS)
 537
 538
 539 #
 540 # Automatic dependency tracking
 541 #
 542 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 543               [autodepend=yes])
 544 AC_SUBST(autodepend)
 545
 546
 547 #
 548 # Enable assert checks
 549 #
 550 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 551               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 552                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 553
 554
 555 #
 556 # Include directories
 557 #
 558 ac_save_IFS=$IFS
 559 IFS="${IFS}${PATH_SEPARATOR}"
 560 # SRCH_INC comes from the template file
 561 for dir in $with_includes $SRCH_INC; do
 562   if test -d "$dir"; then
 563     INCLUDES="$INCLUDES -I$dir"
 564   else
 565     AC_MSG_WARN([*** Include directory $dir does not exist.])
 566   fi
 567 done
 568 IFS=$ac_save_IFS
 569 AC_SUBST(INCLUDES)
 570
 571
 572 #
 573 # Library directories
 574 #
 575 ac_save_IFS=$IFS
 576 IFS="${IFS}${PATH_SEPARATOR}"
 577 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 578 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 579   if test -d "$dir"; then
 580     LIBDIRS="$LIBDIRS -L$dir"
 581   else
 582     AC_MSG_WARN([*** Library directory $dir does not exist.])
 583   fi
 584 done
 585 IFS=$ac_save_IFS
 586
 587 #
 588 # Enable thread-safe client libraries
 589 #
 590 AC_MSG_CHECKING([allow thread-safe client libraries])
 591 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 592 if test "$enable_thread_safety" = yes; then
 593   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 594           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 595 fi
 596 AC_MSG_RESULT([$enable_thread_safety])
 597 AC_SUBST(enable_thread_safety)
 598
 599 #
 600 # Optionally build Tcl modules (PL/Tcl)
 601 #
 602 AC_MSG_CHECKING([whether to build with Tcl])
 603 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 604 AC_MSG_RESULT([$with_tcl])
 605 AC_SUBST([with_tcl])
 606
 607 # We see if the path to the Tcl/Tk configuration scripts is specified.
 608 # This will override the use of tclsh to find the paths to search.
 609
 610 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 611
 612 #
 613 # Optionally build Perl modules (PL/Perl)
 614 #
 615 AC_MSG_CHECKING([whether to build Perl modules])
 616 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 617 AC_MSG_RESULT([$with_perl])
 618 AC_SUBST(with_perl)
 619
 620 #
 621 # Optionally build Python modules (PL/Python)
 622 #
 623 AC_MSG_CHECKING([whether to build Python modules])
 624 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 625 AC_MSG_RESULT([$with_python])
 626 AC_SUBST(with_python)
 627
 628 #
 629 # GSSAPI
 630 #
 631 AC_MSG_CHECKING([whether to build with GSSAPI support])
 632 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 633 [
 634   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 635   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 636 ])
 637 AC_MSG_RESULT([$with_gssapi])
 638
 639
 640 AC_SUBST(krb_srvtab)
 641
 642
 643 #
 644 # Kerberos configuration parameters
 645 #
 646 PGAC_ARG_REQ(with, krb-srvnam,
 647              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 648              [],
 649              [with_krb_srvnam="postgres"])
 650 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 651                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 652
 653
 654 #
 655 # PAM
 656 #
 657 AC_MSG_CHECKING([whether to build with PAM support])
 658 PGAC_ARG_BOOL(with, pam, no,
 659               [build with PAM support],
 660               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 661 AC_MSG_RESULT([$with_pam])
 662
 663
 664 #
 665 # LDAP
 666 #
 667 AC_MSG_CHECKING([whether to build with LDAP support])
 668 PGAC_ARG_BOOL(with, ldap, no,
 669               [build with LDAP support],
 670               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 671 AC_MSG_RESULT([$with_ldap])
 672
 673
 674 #
 675 # Bonjour
 676 #
 677 AC_MSG_CHECKING([whether to build with Bonjour support])
 678 PGAC_ARG_BOOL(with, bonjour, no,
 679               [build with Bonjour support],
 680               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 681 AC_MSG_RESULT([$with_bonjour])
 682
 683
 684 #
 685 # OpenSSL
 686 #
 687 AC_MSG_CHECKING([whether to build with OpenSSL support])
 688 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 689               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 690 AC_MSG_RESULT([$with_openssl])
 691 AC_SUBST(with_openssl)
 692
 693 #
 694 # SELinux
 695 #
 696 AC_MSG_CHECKING([whether to build with SELinux support])
 697 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 698 AC_SUBST(with_selinux)
 699 AC_MSG_RESULT([$with_selinux])
 700
 701 #
 702 # Readline
 703 #
 704 PGAC_ARG_BOOL(with, readline, yes,
 705               [do not use GNU Readline nor BSD Libedit for editing])
 706 # readline on MinGW has problems with backslashes in psql and other bugs.
 707 # This is particularly a problem with non-US code pages.
 708 # Therefore disable its use until we understand the cause. 2004-07-20
 709 if test "$PORTNAME" = "win32"; then
 710   if test "$with_readline" = yes; then
 711     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 712     with_readline=no
 713   fi
 714 fi
 715
 716
 717 #
 718 # Prefer libedit
 719 #
 720 PGAC_ARG_BOOL(with, libedit-preferred, no,
 721               [prefer BSD Libedit over GNU Readline])
 722
 723
 724 #
 725 # UUID library
 726 #
 727 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 728 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 729 # UUID library.  More than one of these might be present on a given platform,
 730 # so we make the user say which one she wants.
 731 #
 732 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 733 if test x"$with_uuid" = x"" ; then
 734   with_uuid=no
 735 fi
 736 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 737 if test "$with_ossp_uuid" = yes ; then
 738   with_uuid=ossp
 739 fi
 740
 741 if test "$with_uuid" = bsd ; then
 742   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 743   UUID_EXTRA_OBJS="md5.o sha1.o"
 744 elif test "$with_uuid" = e2fs ; then
 745   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 746   UUID_EXTRA_OBJS="md5.o sha1.o"
 747 elif test "$with_uuid" = ossp ; then
 748   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 749   UUID_EXTRA_OBJS=""
 750 elif test "$with_uuid" = no ; then
 751   UUID_EXTRA_OBJS=""
 752 else
 753   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 754 fi
 755 AC_SUBST(with_uuid)
 756 AC_SUBST(UUID_EXTRA_OBJS)
 757
 758
 759 #
 760 # XML
 761 #
 762 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 763               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 764
 765 if test "$with_libxml" = yes ; then
 766   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 767   if test -n "$XML2_CONFIG"; then
 768     for pgac_option in `$XML2_CONFIG --cflags`; do
 769       case $pgac_option in
 770         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 771       esac
 772     done
 773     for pgac_option in `$XML2_CONFIG --libs`; do
 774       case $pgac_option in
 775         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 776       esac
 777     done
 778   fi
 779 fi
 780
 781 AC_SUBST(with_libxml)
 782
 783 #
 784 # XSLT
 785 #
 786 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 787               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 788
 789
 790 AC_SUBST(with_libxslt)
 791
 792 #
 793 # tzdata
 794 #
 795 PGAC_ARG_REQ(with, system-tzdata,
 796              [DIR], [use system time zone data in DIR])
 797 AC_SUBST(with_system_tzdata)
 798
 799 #
 800 # Zlib
 801 #
 802 PGAC_ARG_BOOL(with, zlib, yes,
 803               [do not use Zlib])
 804 AC_SUBST(with_zlib)
 805
 806 #
 807 # Elf
 808 #
 809
 810 # Assume system is ELF if it predefines __ELF__ as 1,
 811 # otherwise believe host_os based default.
 812 case $host_os in
 813     freebsd1*|freebsd2*) elf=no;;
 814     freebsd3*|freebsd4*) elf=yes;;
 815 esac
 816
 817 AC_EGREP_CPP(yes,
 818 [#if __ELF__
 819   yes
 820 #endif
 821 ],
 822 [ELF_SYS=true],
 823 [if test "X$elf" = "Xyes" ; then
 824   ELF_SYS=true
 825 else
 826   ELF_SYS=
 827 fi])
 828 AC_SUBST(ELF_SYS)
 829
 830 #
 831 # Assignments
 832 #
 833
 834 CPPFLAGS="$CPPFLAGS $INCLUDES"
 835 LDFLAGS="$LDFLAGS $LIBDIRS"
 836
 837 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 838 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 839
 840 PGAC_PROG_LD
 841 AC_SUBST(LD)
 842 AC_SUBST(with_gnu_ld)
 843 case $host_os in sysv5*)
 844   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 845   [
 846     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 847     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 848     LDFLAGS=$pgac_save_LDFLAGS
 849   ])
 850   ld_R_works=$pgac_cv_prog_ld_R
 851   AC_SUBST(ld_R_works)
 852 esac
 853 AC_PROG_RANLIB
 854 PGAC_CHECK_STRIP
 855 AC_CHECK_TOOL(AR, ar, ar)
 856 if test "$PORTNAME" = "win32"; then
 857   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 858   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 859   AC_CHECK_TOOL(WINDRES, windres, windres)
 860 fi
 861
 862 AC_PROG_INSTALL
 863 # When Autoconf chooses install-sh as install program it tries to generate
 864 # a relative path to it in each makefile where it subsitutes it. This clashes
 865 # with our Makefile.global concept. This workaround helps.
 866 case $INSTALL in
 867   *install-sh*) install_bin='';;
 868   *) install_bin=$INSTALL;;
 869 esac
 870 AC_SUBST(install_bin)
 871
 872 AC_PATH_PROG(TAR, tar)
 873 AC_PROG_LN_S
 874 AC_PROG_AWK
 875 AC_PROG_MKDIR_P
 876 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 877 # a relative path to it in each makefile where it subsitutes it. This clashes
 878 # with our Makefile.global concept. This workaround helps.
 879 case $MKDIR_P in
 880   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 881 esac
 882
 883 PGAC_PATH_BISON
 884 PGAC_PATH_FLEX
 885
 886 PGAC_PATH_PERL
 887 if test "$with_perl" = yes; then
 888   if test -z "$PERL"; then
 889     AC_MSG_ERROR([Perl not found])
 890   fi
 891   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 892   PGAC_CHECK_PERL_EMBED_LDFLAGS
 893 fi
 894
 895 if test "$with_python" = yes; then
 896   PGAC_PATH_PYTHON
 897   PGAC_CHECK_PYTHON_EMBED_SETUP
 898 fi
 899
 900 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 901   AC_PATH_PROG(ZIC, zic)
 902   if test -z "$ZIC"; then
 903     AC_MSG_ERROR([
 904 When cross-compiling, either use the option --with-system-tzdata to use
 905 existing time-zone data, or set the environment variable ZIC to a zic
 906 program to use during the build.])
 907   fi
 908 fi
 909
 910
 911 ##
 912 ## Libraries
 913 ##
 914 ## Most libraries are included only if they demonstrably provide a function
 915 ## we need, but libm is an exception: always include it, because there are
 916 ## too many compilers that play cute optimization games that will break
 917 ## probes for standard functions such as pow().
 918 ##
 919
 920 AC_CHECK_LIB(m, main)
 921 AC_SEARCH_LIBS(setproctitle, util)
 922 AC_SEARCH_LIBS(dlopen, dl)
 923 AC_SEARCH_LIBS(socket, [socket ws2_32])
 924 AC_SEARCH_LIBS(shl_load, dld)
 925 # We only use libld in port/dynloader/aix.c
 926 case $host_os in
 927      aix*)
 928         AC_SEARCH_LIBS(ldopen, ld)
 929         ;;
 930 esac
 931 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 932 AC_SEARCH_LIBS(crypt, crypt)
 933 AC_SEARCH_LIBS(shm_open, rt)
 934 AC_SEARCH_LIBS(shm_unlink, rt)
 935 # Solaris:
 936 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 937 # Required for thread_test.c on Solaris 2.5:
 938 # Other ports use it too (HP-UX) so test unconditionally
 939 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 940 # Cygwin:
 941 AC_SEARCH_LIBS(shmget, cygipc)
 942
 943 if test "$with_readline" = yes; then
 944   PGAC_CHECK_READLINE
 945   if test x"$pgac_cv_check_readline" = x"no"; then
 946     AC_MSG_ERROR([readline library not found
 947 If you have readline already installed, see config.log for details on the
 948 failure.  It is possible the compiler isn't looking in the proper directory.
 949 Use --without-readline to disable readline support.])
 950   fi
 951 fi
 952
 953 if test "$with_zlib" = yes; then
 954   AC_CHECK_LIB(z, inflate, [],
 955                [AC_MSG_ERROR([zlib library not found
 956 If you have zlib already installed, see config.log for details on the
 957 failure.  It is possible the compiler isn't looking in the proper directory.
 958 Use --without-zlib to disable zlib support.])])
 959 fi
 960
 961 if test "$enable_spinlocks" = yes; then
 962   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 963 else
 964   AC_MSG_WARN([
 965 *** Not using spinlocks will cause poor performance.])
 966 fi
 967
 968 if test "$enable_atomics" = yes; then
 969   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
 970 else
 971   AC_MSG_WARN([
 972 *** Not using atomic operations will cause poor performance.])
 973 fi
 974
 975 if test "$with_gssapi" = yes ; then
 976   if test "$PORTNAME" != "win32"; then
 977     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 978                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 979   else
 980     LIBS="$LIBS -lgssapi32"
 981   fi
 982 fi
 983
 984 if test "$with_openssl" = yes ; then
 985   dnl Order matters!
 986   if test "$PORTNAME" != "win32"; then
 987      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 988      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 989   else
 990      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 991      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 992   fi
 993   AC_CHECK_FUNCS([SSL_get_current_compression])
 994 fi
 995
 996 if test "$with_pam" = yes ; then
 997   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 998 fi
 999
1000 if test "$with_libxml" = yes ; then
1001   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1002 fi
1003
1004 if test "$with_libxslt" = yes ; then
1005   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1006 fi
1007
1008 # for contrib/sepgsql
1009 if test "$with_selinux" = yes; then
1010   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1011                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1012 fi
1013
1014 # for contrib/uuid-ossp
1015 if test "$with_uuid" = bsd ; then
1016   # On BSD, the UUID functions are in libc
1017   AC_CHECK_FUNC(uuid_to_string,
1018     [UUID_LIBS=""],
1019     [AC_MSG_ERROR([BSD UUID functions are not present])])
1020 elif test "$with_uuid" = e2fs ; then
1021   # On OS X, the UUID functions are in libc
1022   AC_CHECK_FUNC(uuid_generate,
1023     [UUID_LIBS=""],
1024     [AC_CHECK_LIB(uuid, uuid_generate,
1025       [UUID_LIBS="-luuid"],
1026       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1027 elif test "$with_uuid" = ossp ; then
1028   AC_CHECK_LIB(ossp-uuid, uuid_export,
1029     [UUID_LIBS="-lossp-uuid"],
1030     [AC_CHECK_LIB(uuid, uuid_export,
1031       [UUID_LIBS="-luuid"],
1032       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1033 fi
1034 AC_SUBST(UUID_LIBS)
1035
1036
1037 ##
1038 ## Header files
1039 ##
1040
1041 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1042 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1043
1044 # On BSD, test for net/if.h will fail unless sys/socket.h
1045 # is included first.
1046 AC_CHECK_HEADERS(net/if.h, [], [],
1047 [AC_INCLUDES_DEFAULT
1048 #ifdef HAVE_SYS_SOCKET_H
1049 #include <sys/socket.h>
1050 #endif
1051 ])
1052
1053 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1054 # is included first.
1055 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1056 [AC_INCLUDES_DEFAULT
1057 #include <sys/param.h>
1058 ])
1059
1060 # At least on IRIX, test for netinet/tcp.h will fail unless
1061 # netinet/in.h is included first.
1062 AC_CHECK_HEADERS(netinet/in.h)
1063 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1064 [AC_INCLUDES_DEFAULT
1065 #ifdef HAVE_NETINET_IN_H
1066 #include <netinet/in.h>
1067 #endif
1068 ])
1069
1070 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1071   AC_CHECK_HEADERS(readline/readline.h, [],
1072         [AC_CHECK_HEADERS(readline.h, [],
1073                 [AC_MSG_ERROR([readline header not found
1074 If you have readline already installed, see config.log for details on the
1075 failure.  It is possible the compiler isn't looking in the proper directory.
1076 Use --without-readline to disable readline support.])])])
1077   AC_CHECK_HEADERS(readline/history.h, [],
1078         [AC_CHECK_HEADERS(history.h, [],
1079                 [AC_MSG_ERROR([history header not found
1080 If you have readline already installed, see config.log for details on the
1081 failure.  It is possible the compiler isn't looking in the proper directory.
1082 Use --without-readline to disable readline support.])])])
1083 fi
1084
1085 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1086 # Some installations of libedit usurp /usr/include/readline/, which seems
1087 # bad practice, since in combined installations readline will have its headers
1088 # there.  We might have to resort to AC_EGREP checks to make sure we found
1089 # the proper header...
1090   AC_CHECK_HEADERS(editline/readline.h, [],
1091         [AC_CHECK_HEADERS(readline.h, [],
1092                 [AC_CHECK_HEADERS(readline/readline.h, [],
1093                         [AC_MSG_ERROR([readline header not found
1094 If you have libedit already installed, see config.log for details on the
1095 failure.  It is possible the compiler isn't looking in the proper directory.
1096 Use --without-readline to disable libedit support.])])])])
1097 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1098 # not be there at all.  Hence, don't complain if not found.  We must check
1099 # though, since in yet other versions it is an independent header.
1100   AC_CHECK_HEADERS(editline/history.h, [],
1101         [AC_CHECK_HEADERS(history.h, [],
1102                 [AC_CHECK_HEADERS(readline/history.h)])])
1103 fi
1104
1105 if test "$with_zlib" = yes; then
1106   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1107 If you have zlib already installed, see config.log for details on the
1108 failure.  It is possible the compiler isn't looking in the proper directory.
1109 Use --without-zlib to disable zlib support.])])
1110 fi
1111
1112 if test "$with_gssapi" = yes ; then
1113   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1114         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1115 fi
1116
1117 if test "$with_openssl" = yes ; then
1118   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1119   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1120 fi
1121
1122 if test "$with_pam" = yes ; then
1123   AC_CHECK_HEADERS(security/pam_appl.h, [],
1124                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1125                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1126 fi
1127
1128 if test "$with_libxml" = yes ; then
1129   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1130 fi
1131
1132 if test "$with_libxslt" = yes ; then
1133   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1134 fi
1135
1136 if test "$with_ldap" = yes ; then
1137   if test "$PORTNAME" != "win32"; then
1138      AC_CHECK_HEADERS(ldap.h, [],
1139                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1140      PGAC_LDAP_SAFE
1141   else
1142      AC_CHECK_HEADERS(winldap.h, [],
1143                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1144                       [AC_INCLUDES_DEFAULT
1145 #include <windows.h>
1146                       ])
1147   fi
1148 fi
1149
1150 if test "$with_bonjour" = yes ; then
1151   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1152 fi
1153
1154 # for contrib/uuid-ossp
1155 if test "$with_uuid" = bsd ; then
1156   AC_CHECK_HEADERS(uuid.h,
1157     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1158       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1159     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1160 elif test "$with_uuid" = e2fs ; then
1161   AC_CHECK_HEADERS(uuid/uuid.h,
1162     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1163       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1164     [AC_CHECK_HEADERS(uuid.h,
1165       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1166         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1167       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1168 elif test "$with_uuid" = ossp ; then
1169   AC_CHECK_HEADERS(ossp/uuid.h,
1170     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1171       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1172     [AC_CHECK_HEADERS(uuid.h,
1173       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1174         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1175       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1176 fi
1177
1178 if test "$PORTNAME" = "win32" ; then
1179    AC_CHECK_HEADERS(crtdefs.h)
1180 fi
1181
1182 ##
1183 ## Types, structures, compiler characteristics
1184 ##
1185
1186 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1187 AC_C_BIGENDIAN
1188 PGAC_C_INLINE
1189 PGAC_PRINTF_ARCHETYPE
1190 AC_C_FLEXIBLE_ARRAY_MEMBER
1191 PGAC_C_SIGNED
1192 PGAC_C_FUNCNAME_SUPPORT
1193 PGAC_C_STATIC_ASSERT
1194 PGAC_C_TYPES_COMPATIBLE
1195 PGAC_C_BUILTIN_BSWAP32
1196 PGAC_C_BUILTIN_CONSTANT_P
1197 PGAC_C_BUILTIN_UNREACHABLE
1198 PGAC_C_VA_ARGS
1199 PGAC_STRUCT_TIMEZONE
1200 PGAC_UNION_SEMUN
1201 PGAC_STRUCT_SOCKADDR_UN
1202 PGAC_STRUCT_SOCKADDR_STORAGE
1203 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1204 PGAC_STRUCT_ADDRINFO
1205 AC_TYPE_INTPTR_T
1206 AC_TYPE_UINTPTR_T
1207 AC_TYPE_LONG_LONG_INT
1208
1209 PGAC_TYPE_LOCALE_T
1210
1211 AC_CHECK_TYPES([struct cmsgcred], [], [],
1212 [#include <sys/socket.h>
1213 #include <sys/param.h>
1214 #ifdef HAVE_SYS_UCRED_H
1215 #include <sys/ucred.h>
1216 #endif])
1217
1218 AC_CHECK_TYPES([struct option], [], [],
1219 [#ifdef HAVE_GETOPT_H
1220 #include <getopt.h>
1221 #endif])
1222
1223 if test "$with_zlib" = yes; then
1224   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1225   # did not).  While we could work around the lack of z_streamp, it
1226   # seems unwise to encourage people to use such old zlib versions...
1227   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1228 Use --without-zlib to disable zlib support.])],
1229                 [#include <zlib.h>])
1230 fi
1231
1232 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1233 case $host_cpu in
1234   ppc*|powerpc*)
1235     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1236     AC_TRY_COMPILE([],
1237         [int a = 0; int *p = &a; int r;
1238          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1239         [pgac_cv_have_ppc_mutex_hint=yes],
1240         [pgac_cv_have_ppc_mutex_hint=no])
1241     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1242     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1243         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1244     fi
1245   ;;
1246 esac
1247
1248 # Check largefile support.  You might think this is a system service not a
1249 # compiler characteristic, but you'd be wrong.  We must check this before
1250 # probing existence of related functions such as fseeko, since the largefile
1251 # defines can affect what is generated for that.
1252 if test "$PORTNAME" != "win32"; then
1253    AC_SYS_LARGEFILE
1254    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1255    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1256    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1257    dnl versions where the feature actually works, it's on by default anyway.
1258    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1259 fi
1260
1261 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1262 AC_CHECK_SIZEOF([off_t])
1263
1264 # If we don't have largefile support, can't handle segsize >= 2GB.
1265 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1266    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1267 fi
1268
1269
1270 ##
1271 ## Functions, global variables
1272 ##
1273
1274 PGAC_VAR_INT_TIMEZONE
1275 AC_FUNC_ACCEPT_ARGTYPES
1276 PGAC_FUNC_GETTIMEOFDAY_1ARG
1277
1278 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1279 # symbols that that library has no business exposing to the world.  Pending
1280 # acquisition of a clue by those developers, ignore libedit (including its
1281 # possible alias of libreadline) while checking for everything else.
1282 LIBS_including_readline="$LIBS"
1283 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1284
1285 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1286
1287 AC_REPLACE_FUNCS(fseeko)
1288 case $host_os in
1289         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1290         # Mingw uses macros to access Win32 API calls
1291         netbsd*|mingw*)
1292                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1293                 ac_cv_func_fseeko=yes;;
1294         *)
1295                 AC_FUNC_FSEEKO;;
1296 esac
1297
1298 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1299 # by calling it, 2009-04-02
1300 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1301 if test "$PORTNAME" != "solaris"; then
1302 AC_CHECK_FUNCS(posix_fadvise)
1303 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1304 fi
1305
1306 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1307 AC_CHECK_DECLS([strlcat, strlcpy])
1308 # This is probably only present on Darwin, but may as well check always
1309 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1310
1311 HAVE_IPV6=no
1312 AC_CHECK_TYPE([struct sockaddr_in6],
1313         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1314          HAVE_IPV6=yes],
1315         [],
1316 [$ac_includes_default
1317 #include <netinet/in.h>])
1318 AC_SUBST(HAVE_IPV6)
1319
1320 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1321 [AC_TRY_LINK(
1322 [#include <machine/vmparam.h>
1323 #include <sys/exec.h>
1324 ],
1325 [PS_STRINGS->ps_nargvstr = 1;
1326 PS_STRINGS->ps_argvstr = "foo";],
1327 [pgac_cv_var_PS_STRINGS=yes],
1328 [pgac_cv_var_PS_STRINGS=no])])
1329 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1330   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1331 fi
1332
1333
1334 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1335 # is missing.  Yes, there are machines that have only one.  We may
1336 # also decide to use snprintf.c if snprintf() is present but does not
1337 # have all the features we need --- see below.
1338
1339 if test "$PORTNAME" = "win32"; then
1340   # Win32 gets snprintf.c built unconditionally.
1341   #
1342   # To properly translate all NLS languages strings, we must support the
1343   # *printf() %$ format, which allows *printf() arguments to be selected
1344   # by position in the translated string.
1345   #
1346   # libintl versions < 0.13 use the native *printf() functions, and Win32
1347   # *printf() doesn't understand %$, so we must use our /port versions,
1348   # which do understand %$. libintl versions >= 0.13 include their own
1349   # *printf versions on Win32.  The libintl 0.13 release note text is:
1350   #
1351   #   C format strings with positions, as they arise when a translator
1352   #   needs to reorder a sentence, are now supported on all platforms.
1353   #   On those few platforms (NetBSD and Woe32) for which the native
1354   #   printf()/fprintf()/... functions don't support such format
1355   #   strings, replacements are provided through <libintl.h>.
1356   #
1357   # We could use libintl >= 0.13's *printf() if we were sure that we had
1358   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1359   # to guarantee that, it is best to just use our own, so we are sure to
1360   # get %$ support. In include/port.h we disable the *printf() macros
1361   # that might have been defined by libintl.
1362   #
1363   # We do this unconditionally whether NLS is used or not so we are sure
1364   # that all Win32 libraries and binaries behave the same.
1365   pgac_need_repl_snprintf=yes
1366 else
1367   pgac_need_repl_snprintf=no
1368   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1369   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1370 fi
1371
1372
1373 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1374 # include/c.h will provide declarations.  Note this is a separate test
1375 # from whether the functions exist in the C library --- there are
1376 # systems that have the functions but don't bother to declare them :-(
1377
1378 AC_CHECK_DECLS([snprintf, vsnprintf])
1379
1380
1381 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1382 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1383 [AC_TRY_LINK([
1384 #include <math.h>
1385 double glob_double;
1386 ],
1387 [return isinf(glob_double) ? 0 : 1;],
1388 [ac_cv_func_isinf=yes],
1389 [ac_cv_func_isinf=no])])
1390
1391 if test $ac_cv_func_isinf = yes ; then
1392   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1393 else
1394   AC_LIBOBJ(isinf)
1395   # Look for a way to implement a substitute for isinf()
1396   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1397 fi
1398
1399 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1400
1401 case $host_os in
1402
1403         # Windows uses a specialised env handler
1404         # and doesn't need a replacement getpeereid because it doesn't use
1405         # Unix sockets.
1406         mingw*)
1407                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1408                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1409                 ac_cv_func_unsetenv=yes
1410                 ac_cv_func_getpeereid=yes;;
1411         *)
1412                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1413                 ;;
1414 esac
1415
1416 # System's version of getaddrinfo(), if any, may be used only if we found
1417 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1418 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1419 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1420    test "$PORTNAME" != "win32"; then
1421   AC_REPLACE_FUNCS([getaddrinfo])
1422 else
1423   AC_LIBOBJ(getaddrinfo)
1424 fi
1425
1426 # Similarly, use system's getopt_long() only if system provides struct option.
1427 if test x"$ac_cv_type_struct_option" = xyes ; then
1428   AC_REPLACE_FUNCS([getopt_long])
1429 else
1430   AC_LIBOBJ(getopt_long)
1431 fi
1432
1433 # Solaris' getopt() doesn't do what we want for long options, so always use
1434 # our version on that platform.
1435 if test "$PORTNAME" = "solaris"; then
1436   AC_LIBOBJ(getopt)
1437 fi
1438
1439 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1440 # so always use our version on Windows.
1441 if test "$PORTNAME" = "win32"; then
1442   AC_LIBOBJ(getopt)
1443   AC_LIBOBJ(getopt_long)
1444 fi
1445
1446 # Win32 (really MinGW) support
1447 if test "$PORTNAME" = "win32"; then
1448   AC_REPLACE_FUNCS(gettimeofday)
1449   AC_LIBOBJ(dirmod)
1450   AC_LIBOBJ(kill)
1451   AC_LIBOBJ(open)
1452   AC_LIBOBJ(system)
1453   AC_LIBOBJ(win32env)
1454   AC_LIBOBJ(win32error)
1455   AC_LIBOBJ(win32setlocale)
1456   AC_DEFINE([HAVE_SYMLINK], 1,
1457             [Define to 1 if you have the `symlink' function.])
1458   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1459 #define WIN32_LEAN_AND_MEAN
1460 #include <windows.h>
1461 #include <string.h>
1462 #include <dbghelp.h>])
1463 fi
1464 if test x"$pgac_minidump_type" = x"yes" ; then
1465   AC_SUBST(have_win32_dbghelp,yes)
1466 else
1467   AC_SUBST(have_win32_dbghelp,no)
1468 fi
1469
1470 # Cygwin needs only a bit of that
1471 if test "$PORTNAME" = "cygwin"; then
1472   AC_LIBOBJ(dirmod)
1473 fi
1474
1475 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1476 dnl (especially on GNU libc)
1477 dnl See also comments in c.h.
1478 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1479 [AC_TRY_LINK([#include <setjmp.h>],
1480             [sigjmp_buf x; sigsetjmp(x, 1);],
1481             [pgac_cv_func_sigsetjmp=yes],
1482             [pgac_cv_func_sigsetjmp=no])])
1483 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1484   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1485 fi
1486
1487 AC_DECL_SYS_SIGLIST
1488
1489 AC_CHECK_FUNC(syslog,
1490               [AC_CHECK_HEADER(syslog.h,
1491                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1492
1493 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1494 [AC_TRY_LINK([#include <unistd.h>],
1495   [extern int opterr; opterr = 1;],
1496   [pgac_cv_var_int_opterr=yes],
1497   [pgac_cv_var_int_opterr=no])])
1498 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1499   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1500 fi
1501
1502 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1503 [AC_TRY_LINK([#include <unistd.h>],
1504   [extern int optreset; optreset = 1;],
1505   [pgac_cv_var_int_optreset=yes],
1506   [pgac_cv_var_int_optreset=no])])
1507 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1508   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1509 fi
1510
1511 AC_CHECK_FUNCS([strtoll strtoq], [break])
1512 AC_CHECK_FUNCS([strtoull strtouq], [break])
1513
1514 # Lastly, restore full LIBS list and check for readline/libedit symbols
1515 LIBS="$LIBS_including_readline"
1516
1517 if test "$with_readline" = yes; then
1518   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1519   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1520   AC_CHECK_FUNCS([append_history history_truncate_file])
1521 fi
1522
1523
1524 #
1525 # Pthreads
1526 #
1527 # For each platform, we need to know about any special compile and link
1528 # libraries, and whether the normal C function names are thread-safe.
1529 # See the comment at the top of src/port/thread.c for more information.
1530 # WIN32 doesn't need the pthread tests;  it always uses threads
1531 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1532 ACX_PTHREAD     # set thread flags
1533
1534 # Some platforms use these, so just define them.  They can't hurt if they
1535 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1536 # enables 5-arg getpwuid_r, among other things.
1537 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1538
1539 # Check for *_r functions
1540 _CFLAGS="$CFLAGS"
1541 _LIBS="$LIBS"
1542 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1543 LIBS="$LIBS $PTHREAD_LIBS"
1544
1545 if test "$PORTNAME" != "win32"; then
1546 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1547 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1548 fi
1549
1550 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1551
1552 # Do test here with the proper thread flags
1553 PGAC_FUNC_STRERROR_R_INT
1554
1555 CFLAGS="$_CFLAGS"
1556 LIBS="$_LIBS"
1557
1558 else
1559 # do not use values from template file
1560 PTHREAD_CFLAGS=
1561 PTHREAD_LIBS=
1562 fi
1563
1564 AC_SUBST(PTHREAD_CFLAGS)
1565 AC_SUBST(PTHREAD_LIBS)
1566
1567
1568 # We can test for libldap_r only after we know PTHREAD_LIBS
1569 if test "$with_ldap" = yes ; then
1570   _LIBS="$LIBS"
1571   if test "$PORTNAME" != "win32"; then
1572     AC_CHECK_LIB(ldap, ldap_bind, [],
1573                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1574                  [$EXTRA_LDAP_LIBS])
1575     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1576     if test "$enable_thread_safety" = yes; then
1577       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1578       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1579                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1580                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1581       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1582     else
1583       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1584     fi
1585   else
1586     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1587     LDAP_LIBS_FE="-lwldap32"
1588     LDAP_LIBS_BE="-lwldap32"
1589   fi
1590   LIBS="$_LIBS"
1591 fi
1592 AC_SUBST(LDAP_LIBS_FE)
1593 AC_SUBST(LDAP_LIBS_BE)
1594
1595
1596 # This test makes sure that run tests work at all.  Sometimes a shared
1597 # library is found by the linker, but the runtime linker can't find it.
1598 # This check should come after all modifications of compiler or linker
1599 # variables, and before any other run tests.
1600 AC_MSG_CHECKING([test program])
1601 AC_TRY_RUN([int main() { return 0; }],
1602 [AC_MSG_RESULT(ok)],
1603 [AC_MSG_RESULT(failed)
1604 AC_MSG_ERROR([[
1605 Could not execute a simple test program.  This may be a problem
1606 related to locating shared libraries.  Check the file 'config.log'
1607 for the exact reason.]])],
1608 [AC_MSG_RESULT([cross-compiling])])
1609
1610 # --------------------
1611 # Run tests below here
1612 # --------------------
1613
1614 # Force use of our snprintf if system's doesn't do arg control
1615 # See comment above at snprintf test for details.
1616 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1617   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1618   if test $pgac_cv_snprintf_arg_control != yes ; then
1619     pgac_need_repl_snprintf=yes
1620   fi
1621 fi
1622
1623
1624 dnl Check to see if we have a working 64-bit integer type.
1625 dnl This breaks down into two steps:
1626 dnl (1) figure out if the compiler has a 64-bit int type with working
1627 dnl arithmetic, and if so
1628 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1629 dnl snprintf is the only library routine we really need for int8 support.)
1630 dnl It's entirely possible to have a compiler that handles a 64-bit type
1631 dnl when the C library doesn't; this is fairly likely when using gcc on
1632 dnl an older platform, for example.
1633 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1634 dnl we force our own version of snprintf() to be used instead.
1635 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1636
1637 dnl As of Postgres 8.4, we no longer support compilers without a working
1638 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1639
1640 PGAC_TYPE_64BIT_INT([long int])
1641
1642 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1643   pg_int64_type="long int"
1644 else
1645   PGAC_TYPE_64BIT_INT([long long int])
1646   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1647     pg_int64_type="long long int"
1648   else
1649     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1650   fi
1651 fi
1652
1653 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1654   [Define to the name of a signed 64-bit integer type.])
1655
1656 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1657
1658 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1659   AC_TRY_COMPILE([
1660 #define INT64CONST(x)  x##LL
1661 long long int foo = INT64CONST(0x1234567890123456);
1662 ],
1663         [],
1664         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1665         [])
1666 fi
1667
1668
1669 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1670 # we found we need to use "long long int", better check.  We cope with
1671 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1672 # work, fall back to our own snprintf emulation (which we know uses %lld).
1673
1674 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1675   if test $pgac_need_repl_snprintf = no; then
1676     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1677     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1678       # Force usage of our own snprintf, since system snprintf is broken
1679       pgac_need_repl_snprintf=yes
1680       LONG_LONG_INT_MODIFIER='ll'
1681     fi
1682   else
1683     # Here if we previously decided we needed to use our own snprintf
1684     LONG_LONG_INT_MODIFIER='ll'
1685   fi
1686 else
1687   # Here if we are not using 'long long int' at all
1688   LONG_LONG_INT_MODIFIER='l'
1689 fi
1690
1691 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1692
1693 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1694                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1695
1696 # Also force use of our snprintf if the system's doesn't support the %z flag.
1697 if test "$pgac_need_repl_snprintf" = no; then
1698   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1699   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1700     pgac_need_repl_snprintf=yes
1701   fi
1702 fi
1703
1704 # Now we have checked all the reasons to replace snprintf
1705 if test $pgac_need_repl_snprintf = yes; then
1706   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1707   AC_LIBOBJ(snprintf)
1708 fi
1709
1710 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1711 AC_CHECK_SIZEOF([void *])
1712 AC_CHECK_SIZEOF([size_t])
1713 AC_CHECK_SIZEOF([long])
1714
1715 # Decide whether float4 is passed by value: user-selectable, enabled by default
1716 AC_MSG_CHECKING([whether to build with float4 passed by value])
1717 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1718               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1719                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1720                float4passbyval=true],
1721               [float4passbyval=false])
1722 AC_MSG_RESULT([$enable_float4_byval])
1723 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1724
1725 # Decide whether float8 is passed by value.
1726 # Note: this setting also controls int8 and related types such as timestamp.
1727 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1728 # If not, trying to select it is an error.
1729 AC_MSG_CHECKING([whether to build with float8 passed by value])
1730 if test $ac_cv_sizeof_void_p -ge 8 ; then
1731   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1732 else
1733   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1734   if test "$enable_float8_byval" = yes ; then
1735     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1736   fi
1737 fi
1738 if test "$enable_float8_byval" = yes ; then
1739   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1740             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1741   float8passbyval=true
1742 else
1743   float8passbyval=false
1744 fi
1745 AC_MSG_RESULT([$enable_float8_byval])
1746 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1747
1748 # Determine memory alignment requirements for the basic C data types.
1749
1750 AC_CHECK_ALIGNOF(short)
1751 AC_CHECK_ALIGNOF(int)
1752 AC_CHECK_ALIGNOF(long)
1753 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1754   AC_CHECK_ALIGNOF(long long int)
1755 fi
1756 AC_CHECK_ALIGNOF(double)
1757
1758 # Compute maximum alignment of any basic type.
1759 # We assume long's alignment is at least as strong as char, short, or int;
1760 # but we must check long long (if it exists) and double.
1761
1762 MAX_ALIGNOF=$ac_cv_alignof_long
1763 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1764   MAX_ALIGNOF=$ac_cv_alignof_double
1765 fi
1766 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1767   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1768 fi
1769 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1770
1771
1772 # Some platforms predefine the types int8, int16, etc.  Only check
1773 # a (hopefully) representative subset.
1774 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1775 [#include <stdio.h>])
1776
1777 # We also check for sig_atomic_t, which *should* be defined per ANSI
1778 # C, but is missing on some old platforms.
1779 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1780
1781 # Check for extensions offering the integer scalar type __int128.
1782 PGAC_TYPE_128BIT_INT
1783
1784 # Check for various atomic operations now that we have checked how to declare
1785 # 64bit integers.
1786 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1787 PGAC_HAVE_GCC__SYNC_INT32_TAS
1788 PGAC_HAVE_GCC__SYNC_INT32_CAS
1789 PGAC_HAVE_GCC__SYNC_INT64_CAS
1790 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1791 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1792
1793 if test "$PORTNAME" != "win32"
1794 then
1795 PGAC_FUNC_POSIX_SIGNALS
1796 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1797   AC_MSG_ERROR([
1798 Thread-safety requires POSIX signals, which are not supported by this
1799 operating system;  use --disable-thread-safety to disable thread safety.])
1800 fi
1801 fi
1802
1803
1804 # Select semaphore implementation type.
1805 if test "$PORTNAME" != "win32"; then
1806   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1807     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1808     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1809   else
1810     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1811       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1812       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1813     else
1814       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1815       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1816     fi
1817   fi
1818 else
1819   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1820   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1821 fi
1822
1823
1824 # Select shared-memory implementation type.
1825 if test "$PORTNAME" != "win32"; then
1826   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1827   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1828 else
1829   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1830   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1831 fi
1832
1833 # Select latch implementation type.
1834 if test "$PORTNAME" != "win32"; then
1835   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1836 else
1837   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1838 fi
1839
1840 # If not set in template file, set bytes to use libc memset()
1841 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1842   MEMSET_LOOP_LIMIT=1024
1843 fi
1844 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1845
1846
1847 if test "$enable_nls" = yes ; then
1848   PGAC_CHECK_GETTEXT
1849 fi
1850
1851 # Check for Tcl configuration script tclConfig.sh
1852 if test "$with_tcl" = yes; then
1853     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1854     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1855                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1856     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1857     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1858     ac_save_CPPFLAGS=$CPPFLAGS
1859     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1860     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1861     CPPFLAGS=$ac_save_CPPFLAGS
1862 fi
1863
1864 # check for <perl.h>
1865 if test "$with_perl" = yes; then
1866   ac_save_CPPFLAGS=$CPPFLAGS
1867   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1868   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1869                   [#include <EXTERN.h>])
1870   # While we're at it, check that we can link to libperl.
1871   # On most platforms, if perl.h is there then libperl.so will be too, but at
1872   # this writing Debian packages them separately.  There is no known reason to
1873   # waste cycles on separate probes for the Tcl or Python libraries, though.
1874   pgac_save_LIBS=$LIBS
1875   LIBS="$perl_embed_ldflags"
1876   AC_MSG_CHECKING([for libperl])
1877   AC_TRY_LINK([
1878 #include <EXTERN.h>
1879 #include <perl.h>
1880 ],  [perl_alloc();],
1881     [AC_MSG_RESULT(yes)],
1882     [AC_MSG_RESULT(no)
1883      AC_MSG_ERROR([libperl library is required for Perl])])
1884   LIBS=$pgac_save_LIBS
1885   CPPFLAGS=$ac_save_CPPFLAGS
1886 fi
1887
1888 # check for <Python.h>
1889 if test "$with_python" = yes; then
1890   ac_save_CPPFLAGS=$CPPFLAGS
1891   CPPFLAGS="$python_includespec $CPPFLAGS"
1892   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1893   CPPFLAGS=$ac_save_CPPFLAGS
1894 fi
1895
1896 #
1897 # Check for DocBook and tools
1898 #
1899 PGAC_PROG_NSGMLS
1900 PGAC_PROG_JADE
1901 PGAC_CHECK_DOCBOOK(4.2)
1902 PGAC_PATH_DOCBOOK_STYLESHEETS
1903 PGAC_PATH_COLLATEINDEX
1904 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
1905 AC_CHECK_PROGS(XMLLINT, xmllint)
1906 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1907 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1908
1909 #
1910 # Check for test tools
1911 #
1912 if test "$enable_tap_tests" = yes; then
1913   AC_CHECK_PROGS(PROVE, prove)
1914   if test -z "$PROVE"; then
1915     AC_MSG_ERROR([prove not found])
1916   fi
1917   if test -z "$PERL"; then
1918     AC_MSG_ERROR([Perl not found])
1919   fi
1920 fi
1921
1922 # Thread testing
1923
1924 # We have to run the thread test near the end so we have all our symbols
1925 # defined.  Cross compiling throws a warning.
1926 #
1927 if test "$enable_thread_safety" = yes; then
1928 if test "$PORTNAME" != "win32"
1929 then
1930 AC_MSG_CHECKING([thread safety of required library functions])
1931
1932 _CFLAGS="$CFLAGS"
1933 _LIBS="$LIBS"
1934 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1935 LIBS="$LIBS $PTHREAD_LIBS"
1936 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1937   [AC_MSG_RESULT(yes)],
1938   [AC_MSG_RESULT(no)
1939   AC_MSG_ERROR([thread test program failed
1940 This platform is not thread-safe.  Check the file 'config.log' or compile
1941 and run src/test/thread/thread_test for the exact reason.
1942 Use --disable-thread-safety to disable thread safety.])],
1943   [AC_MSG_RESULT(maybe)
1944   AC_MSG_WARN([
1945 *** Skipping thread test program because of cross-compile build.
1946 *** Run the program in src/test/thread on the target machine.
1947 ])])
1948 CFLAGS="$_CFLAGS"
1949 LIBS="$_LIBS"
1950 else
1951 AC_MSG_WARN([*** skipping thread test on Win32])
1952 fi
1953 fi
1954
1955 # If compiler will take -Wl,--as-needed (or various platform-specific
1956 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1957 # trying to filter LIBS to the minimum for each executable.
1958 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1959 # libreadline; therefore we postpone testing it until we know what library
1960 # dependencies readline has.  The test code will try to link with $LIBS.
1961 if test "$with_readline" = yes; then
1962   link_test_func=readline
1963 else
1964   link_test_func=exit
1965 fi
1966
1967 if test "$PORTNAME" = "darwin"; then
1968   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1969 elif test "$PORTNAME" = "openbsd"; then
1970   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1971 else
1972   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1973 fi
1974
1975 # Create compiler version string
1976 if test x"$GCC" = x"yes" ; then
1977   cc_string=`${CC} --version | sed q`
1978   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1979 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1980   cc_string=`${CC} -V 2>&1 | sed q`
1981 else
1982   cc_string=$CC
1983 fi
1984
1985 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1986                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1987                    [A string containing the version number, platform, and C compiler])
1988
1989 # Supply a numeric version string for use by 3rd party add-ons
1990 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1991 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1992 tr '.' '        ' |
1993 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1994 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1995
1996
1997 # Begin output steps
1998
1999 AC_MSG_NOTICE([using compiler=$cc_string])
2000 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2001 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2002 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2003
2004 # prepare build tree if outside source tree
2005 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2006 # Note 2: /bin/pwd might be better than shell's built-in at getting
2007 #         a symlink-free name.
2008 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2009   vpath_build=no
2010 else
2011   vpath_build=yes
2012   if test "$no_create" != yes; then
2013     _AS_ECHO_N([preparing build tree... ])
2014     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2015     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2016       || AC_MSG_ERROR(failed)
2017     AC_MSG_RESULT(done)
2018   fi
2019 fi
2020 AC_SUBST(vpath_build)
2021
2022
2023 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2024
2025 AC_CONFIG_LINKS([
2026   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2027   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2028   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2029   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2030   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2031   src/include/pg_config_os.h:src/include/port/${template}.h
2032   src/Makefile.port:src/makefiles/Makefile.${template}
2033 ])
2034
2035 if test "$PORTNAME" = "win32"; then
2036 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2037 # Links sometimes fail undetected on Mingw -
2038 # so here we detect it and warn the user
2039 for FILE in $CONFIG_LINKS
2040  do
2041         # test -e works for symlinks in the MinGW console
2042         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2043  done
2044 ])
2045 fi
2046
2047 AC_CONFIG_HEADERS([src/include/pg_config.h],
2048 [
2049 # Update timestamp for pg_config.h (see Makefile.global)
2050 echo >src/include/stamp-h
2051 ])
2052
2053 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2054 [
2055 # Update timestamp for pg_config_ext.h (see Makefile.global)
2056 echo >src/include/stamp-ext-h
2057 ])
2058
2059 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2060                   [echo >src/interfaces/ecpg/include/stamp-h])
2061
2062 AC_OUTPUT