granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.236 2003/02/14 14:05:00 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=win ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      qnx*) template=qnx4 ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-ports@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Pick right test-and-set (TAS) code.  Most platforms have inline
 107 # assembler code in src/include/storage/s_lock.h, so we just use
 108 # a dummy file here.
 109 case $host in
 110   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 111   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 112   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 113   *)                need_tas=no;  tas_file=dummy.s ;;
 114 esac
 115 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 116
 117 if test "$need_tas" = yes ; then
 118   TAS=tas.o
 119 fi
 120 AC_SUBST(TAS)
 121
 122
 123
 124 ##
 125 ## Command line options
 126 ##
 127
 128
 129 #
 130 # Add non-standard directories to the include path
 131 #
 132 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 133
 134
 135 #
 136 # Add non-standard directories to the library search path
 137 #
 138 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 139              [LIBRARY_DIRS=$withval])
 140
 141 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 142              [LIBRARY_DIRS=$withval])
 143
 144
 145 #
 146 # 64-bit integer date/time storage (--enable-integer-datetimes)
 147 #
 148 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 149 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 150               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 151                          [Set to 1 if you want integer date/time support (--enable-integer-datetimes)])])
 152 AC_MSG_RESULT([$enable_integer_datetimes])
 153
 154
 155 # Character set recode (--enable-recode)
 156 #
 157 AC_MSG_CHECKING([whether to build with recode support])
 158 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable single-byte recode support],
 159               [AC_DEFINE([CYR_RECODE], 1,
 160                          [Set to 1 if you want single-byte recode support (--enable-recode)])])
 161 AC_MSG_RESULT([$enable_recode])
 162
 163
 164 #
 165 # NLS
 166 #
 167 AC_MSG_CHECKING([whether NLS is wanted])
 168 PGAC_ARG_OPTARG(enable, nls,
 169                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 170                 [],
 171                 [WANTED_LANGUAGES=$enableval],
 172                 [AC_DEFINE(ENABLE_NLS, 1,
 173                            [Define to 1 if you want National Language Support (--enable-nls)])])
 174 AC_MSG_RESULT([$enable_nls])
 175 AC_SUBST(enable_nls)
 176 AC_SUBST(WANTED_LANGUAGES)
 177
 178 #
 179 # Default port number (--with-pgport), default 5432
 180 #
 181 AC_MSG_CHECKING([for default port number])
 182 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 183              [default_port=$withval],
 184              [default_port=5432])
 185 AC_MSG_RESULT([$default_port])
 186 # Need both of these because some places want an integer and some a string
 187 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 188 [The default TCP port number on which the server listens and to which
 189 clients will try to connect to.  This can be overridden at run-time,
 190 but it's convenient if your clients have the right default compiled in.
 191 (--with-pgport=PORTNUM)])
 192 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 193                    [Default TCP port number as string constant])
 194 AC_SUBST(default_port)
 195
 196 #
 197 # Maximum number of allowed connections (--with-maxbackends), default 32
 198 #
 199 AC_MSG_CHECKING([for default soft limit on number of connections])
 200 PGAC_ARG_REQ(with, maxbackends, [  --with-maxbackends=N    set default maximum number of connections [32]],
 201              [],
 202              [with_maxbackends=32])
 203 AC_MSG_RESULT([$with_maxbackends])
 204 AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
 205                    [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
 206
 207
 208 #
 209 # Option to disable shared libraries
 210 #
 211 PGAC_ARG_BOOL(enable, shared, yes,
 212               [  --disable-shared        do not build shared libraries])
 213 AC_SUBST(enable_shared)
 214
 215 #
 216 # '-rpath'-like feature can be disabled
 217 #
 218 PGAC_ARG_BOOL(enable, rpath, yes,
 219               [  --disable-rpath         do not embed shared library search path in executables])
 220 AC_SUBST(enable_rpath)
 221
 222
 223 #
 224 # --enable-debug adds -g to compiler flags
 225 #
 226 PGAC_ARG_BOOL(enable, debug, no,
 227               [  --enable-debug          build with debugging symbols (-g)])
 228 AC_SUBST(enable_debug)
 229
 230 #
 231 # C compiler
 232 #
 233
 234 # For historical reasons you can also use --with-CC to specify the C compiler
 235 # to use, although the standard way to do this is to set the CC environment
 236 # variable.
 237 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 238
 239 case $template in
 240   aix) pgac_cc_list="gcc xlc";;
 241  irix) pgac_cc_list="cc";; # no gcc
 242     *) pgac_cc_list="gcc cc";;
 243 esac
 244
 245 AC_PROG_CC([$pgac_cc_list])
 246 # Read the template
 247 . "$srcdir/src/template/$template" || exit
 248
 249 if test "$ac_env_CFLAGS_set" = set; then
 250   CFLAGS=$ac_env_CFLAGS_value
 251 fi
 252 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 253   CFLAGS="$CFLAGS -g"
 254 fi
 255 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 256
 257 # Check if the compiler still works with the template settings
 258 AC_MSG_CHECKING([whether the C compiler still works])
 259 AC_TRY_LINK([], [return 0;],
 260   [AC_MSG_RESULT(yes)],
 261   [AC_MSG_RESULT(no)
 262    AC_MSG_ERROR([cannot proceed])])
 263
 264 # Defend against gcc -ffastmath
 265 if test "$GCC" = yes; then
 266 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 267 choke me
 268 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 269 fi
 270
 271 AC_PROG_CPP
 272 AC_SUBST(GCC)
 273
 274 # Create compiler version string
 275 if test x"$GCC" = x"yes" ; then
 276   cc_string="GCC `${CC} --version | sed q`"
 277 else
 278   cc_string=$CC
 279 fi
 280 AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
 281
 282
 283 #
 284 # Automatic dependency tracking
 285 #
 286 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 287               [autodepend=yes])
 288 AC_SUBST(autodepend)
 289
 290
 291 #
 292 # Enable assert checks
 293 #
 294 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 295               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 296                          [Define to 1 to build with assertion checks])])
 297
 298
 299 #
 300 # Include directories
 301 #
 302 ac_save_IFS=$IFS
 303 IFS="${IFS}:"
 304 # SRCH_INC comes from the template file
 305 for dir in $with_includes $SRCH_INC; do
 306   if test -d "$dir"; then
 307     INCLUDES="$INCLUDES -I$dir"
 308   else
 309     AC_MSG_WARN([*** Include directory $dir does not exist.])
 310   fi
 311 done
 312 IFS=$ac_save_IFS
 313 AC_SUBST(INCLUDES)
 314
 315
 316 #
 317 # Library directories
 318 #
 319 ac_save_IFS=$IFS
 320 IFS="${IFS}:"
 321 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 322 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 323   if test -d "$dir"; then
 324     LIBDIRS="$LIBDIRS -L$dir"
 325   else
 326     AC_MSG_WARN([*** Library directory $dir does not exist.])
 327   fi
 328 done
 329 IFS=$ac_save_IFS
 330
 331
 332 #
 333 # Tcl/Tk
 334 #
 335 AC_MSG_CHECKING([whether to build with Tcl])
 336 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 337 AC_MSG_RESULT([$with_tcl])
 338 AC_SUBST([with_tcl])
 339
 340 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 341 AC_MSG_CHECKING([whether to build with Tk])
 342 if test "$with_tcl" = yes; then
 343   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 344 else
 345   with_tk=no
 346 fi
 347 AC_MSG_RESULT([$with_tk])
 348 AC_SUBST([with_tk])
 349
 350
 351 # We see if the path to the Tcl/Tk configuration scripts is specified.
 352 # This will override the use of tclsh to find the paths to search.
 353
 354 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 355
 356 # We see if the path to the Tk configuration scripts is specified.
 357 # This will override the use of tclsh to find the paths to search.
 358
 359 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 360
 361 #
 362 # Optionally build Perl modules (PL/Perl)
 363 #
 364 AC_MSG_CHECKING([whether to build Perl modules])
 365 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 366 AC_MSG_RESULT([$with_perl])
 367 AC_SUBST(with_perl)
 368
 369 #
 370 # Optionally build Python interface module
 371 #
 372 AC_MSG_CHECKING([whether to build Python modules])
 373 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 374 AC_MSG_RESULT([$with_python])
 375 AC_SUBST(with_python)
 376
 377 #
 378 # Optionally build the Java/JDBC tools
 379 #
 380 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 381 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 382 [AC_MSG_RESULT(yes)
 383 PGAC_PATH_ANT
 384 if test -z "$ANT"; then
 385   AC_MSG_ERROR([Ant is required to build Java components
 386 If you have Ant already installed, see config.log for details on the failure.])
 387 fi
 388 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 389   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 390 fi],
 391 [AC_MSG_RESULT(no)])
 392 AC_SUBST(with_java)
 393
 394 dnl A note on the Kerberos and OpenSSL options:
 395 dnl
 396 dnl The user can give an argument to the option in order the specify
 397 dnl the base path of the respective installation (what he specified
 398 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 399 dnl then we take the path where the package installs by default. This
 400 dnl way the user doesn't have to use redundant --with-includes and
 401 dnl --with-libraries options, but he can still use them if the layout
 402 dnl is non-standard.
 403
 404 #
 405 # Kerberos 4
 406 #
 407 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 408 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 409                 [krb4_prefix=/usr/athena],
 410                 [krb4_prefix=$withval],
 411 [
 412   AC_MSG_RESULT(yes)
 413   AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
 414
 415   if test -d "$krb4_prefix/include"; then
 416     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 417   fi
 418   if test -d "$krb4_prefix/lib"; then
 419     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 420   fi
 421
 422   krb_srvtab="/etc/srvtab"
 423 ],
 424 [AC_MSG_RESULT(no)])
 425
 426 AC_SUBST(with_krb4)
 427
 428
 429 #
 430 # Kerberos 5
 431 #
 432 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 433 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 434               [krb5_prefix=/usr/athena],
 435               [krb5_prefix=$withval],
 436 [
 437   AC_MSG_RESULT([yes])
 438   AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
 439
 440   if test -d "$krb5_prefix/include"; then
 441     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 442   fi
 443   if test -d "$krb5_prefix/lib"; then
 444     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 445   fi
 446
 447   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 448 ],
 449 [AC_MSG_RESULT(no)])
 450
 451 AC_SUBST(with_krb5)
 452
 453
 454 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 455 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 456   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 457 fi
 458
 459 AC_SUBST(krb_srvtab)
 460
 461
 462 #
 463 # Kerberos configuration parameters
 464 #
 465 PGAC_ARG_REQ(with, krb-srvnam,
 466              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 467              [],
 468              [with_krb_srvnam="postgres"])
 469 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 470                    [The name of the PostgreSQL service principal in Kerberos])
 471
 472
 473 #
 474 # PAM
 475 #
 476 AC_MSG_CHECKING([whether to build with PAM support])
 477 PGAC_ARG_BOOL(with, pam, no,
 478               [  --with-pam              build with PAM support],
 479               [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
 480 AC_MSG_RESULT([$with_pam])
 481 AC_SUBST(with_pam)
 482
 483
 484 #
 485 # OpenSSL
 486 #
 487 PGAC_ARG_OPTARG(with, openssl,
 488                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 489                 [openssl_prefix=/usr/local/ssl],
 490                 [openssl_prefix=$withval],
 491 [
 492   AC_MSG_RESULT([building with OpenSSL support])
 493   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
 494
 495   if test -d "${openssl_prefix}/include" ; then
 496     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 497   fi
 498   if test -d "${openssl_prefix}/lib" ; then
 499     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 500   fi
 501 ])
 502
 503 AC_SUBST(with_openssl)
 504
 505
 506 #
 507 # Readline
 508 #
 509 PGAC_ARG_BOOL(with, readline, yes,
 510               [  --without-readline      do not use Readline])
 511
 512 #
 513 # Zlib
 514 #
 515 PGAC_ARG_BOOL(with, zlib, yes,
 516               [  --without-zlib          do not use Zlib])
 517
 518
 519
 520 # Assume system is ELF if it predefines __ELF__ as 1,
 521 # otherwise believe host_os based default.
 522 case $host_os in
 523     freebsd1*|freebsd2*) elf=no;;
 524     freebsd3*|freebsd4*) elf=yes;;
 525 esac
 526
 527 AC_EGREP_CPP(yes,
 528 [#if __ELF__
 529   yes
 530 #endif
 531 ],
 532 [ELF_SYS=true],
 533 [if test "X$elf" = "Xyes" ; then
 534   ELF_SYS=true
 535 else
 536   ELF_SYS=
 537 fi])
 538 AC_SUBST(ELF_SYS)
 539
 540
 541
 542 CPPFLAGS="$CPPFLAGS $INCLUDES"
 543 LDFLAGS="$LDFLAGS $LIBDIRS"
 544
 545 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 546 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 547
 548
 549 AC_PROG_AWK
 550 PGAC_PATH_FLEX
 551 AC_PROG_LN_S
 552 AC_PROG_LD
 553 AC_SUBST(LD)
 554 AC_SUBST(with_gnu_ld)
 555 case $host_os in sysv5*)
 556   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 557   [
 558     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 559     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 560     LDFLAGS=$pgac_save_LDFLAGS
 561   ])
 562   ld_R_works=$pgac_cv_prog_ld_R
 563   AC_SUBST(ld_R_works)
 564 esac
 565 AC_PROG_RANLIB
 566 AC_CHECK_PROGS(LORDER, lorder)
 567 AC_PATH_PROG(TAR, tar)
 568 PGAC_CHECK_STRIP
 569
 570 AC_CHECK_PROGS(YACC, ['bison -y'])
 571 if test -z "$YACC"; then
 572   AC_MSG_WARN([
 573 *** Without Bison you will not be able to build PostgreSQL from CVS or
 574 *** change any of the parser definition files.  You can obtain Bison from
 575 *** a GNU mirror site.  (If you are using the official distribution of
 576 *** PostgreSQL then you do not need to worry about this because the Bison
 577 *** output is pre-generated.)  To use a different yacc program (possible,
 578 *** but not recommended), set the environment variable YACC before running
 579 *** 'configure'.])
 580 fi
 581 AC_SUBST(YFLAGS)
 582
 583 PGAC_PATH_PERL
 584 if test "$with_perl" = yes; then
 585   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 586   PGAC_CHECK_PERL_EMBED_LDFLAGS
 587 fi
 588
 589 if test "$with_python" = yes; then
 590   PGAC_PATH_PYTHON
 591   PGAC_CHECK_PYTHON_MODULE_SETUP
 592   PGAC_CHECK_PYTHON_EMBED_SETUP
 593 fi
 594
 595
 596 ##
 597 ## Libraries
 598 ##
 599
 600 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 601 then
 602         AC_CHECK_LIB(bsd,      main)
 603 fi
 604 AC_CHECK_LIB(util,     setproctitle)
 605 AC_CHECK_LIB(m,        main)
 606 AC_CHECK_LIB(dl,       main)
 607 AC_CHECK_LIB(nsl,      main)
 608 AC_CHECK_LIB(socket,   main)
 609 AC_CHECK_LIB(ipc,      main)
 610 AC_CHECK_LIB(IPC,      main)
 611 AC_CHECK_LIB(lc,       main)
 612 AC_CHECK_LIB(dld,      main)
 613 AC_CHECK_LIB(ld,       main)
 614 AC_CHECK_LIB(compat,   main)
 615 AC_CHECK_LIB(BSD,      main)
 616 AC_CHECK_LIB(gen,      main)
 617 AC_CHECK_LIB(PW,       main)
 618 AC_CHECK_LIB(resolv,   main)
 619 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 620 # QNX:
 621 AC_CHECK_LIB(unix, main)
 622 AC_SEARCH_LIBS(crypt,  crypt)
 623 # BeOS:
 624 AC_CHECK_LIB(bind, __inet_ntoa)
 625 # Solaris:
 626 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 627 # Cygwin:
 628 AC_CHECK_LIB(cygipc, shmget)
 629
 630 if test "$with_readline" = yes; then
 631   PGAC_CHECK_READLINE
 632   if test x"$pgac_cv_check_readline" = x"no"; then
 633     AC_MSG_ERROR([readline library not found
 634 If you have readline already installed, see config.log for details on the
 635 failure.  It is possible the compiler isn't looking in the proper directory.
 636 Use --without-readline to disable readline support.])
 637   fi
 638 fi
 639
 640 if test "$with_zlib" = yes; then
 641   AC_CHECK_LIB(z, inflate, [],
 642                [AC_MSG_ERROR([zlib library not found
 643 If you have zlib already installed, see config.log for details on the
 644 failure.  It is possible the compiler isn't looking in the proper directory.
 645 Use --without-zlib to disable zlib support.])])
 646 fi
 647
 648 if test "$with_krb4" = yes ; then
 649   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 650   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 651 fi
 652
 653 if test "$with_krb5" = yes ; then
 654   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 655                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 656   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 657                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 658   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 659                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 660 fi
 661
 662 if test "$with_openssl" = yes ; then
 663   dnl Order matters!
 664   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 665   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 666 fi
 667
 668 if test "$with_pam" = yes ; then
 669   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 670 fi
 671
 672
 673 ##
 674 ## Header files
 675 ##
 676
 677 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 678 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 679
 680 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 681 # netinet/in.h is included first.
 682 AC_CHECK_HEADERS(netinet/in.h)
 683 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 684 [AC_INCLUDES_DEFAULT
 685 #ifdef HAVE_NETINET_IN_H
 686 #include <netinet/in.h>
 687 #endif
 688 ])
 689
 690 if test "$with_readline" = yes; then
 691   AC_CHECK_HEADERS(readline/readline.h, [],
 692                    [AC_CHECK_HEADERS(readline.h, [],
 693                                      [AC_MSG_ERROR([readline header not found
 694 If you have readline already installed, see config.log for details on the
 695 failure.  It is possible the compiler isn't looking in the proper directory.
 696 Use --without-readline to disable readline support.])])])
 697   AC_CHECK_HEADERS(readline/history.h, [],
 698                    [AC_CHECK_HEADERS(history.h, [],
 699                                      [AC_MSG_ERROR([history header not found
 700 If you have readline already installed, see config.log for details on the
 701 failure.  It is possible the compiler isn't looking in the proper directory.
 702 Use --without-readline to disable readline support.])])])
 703 fi
 704
 705 if test "$with_zlib" = yes; then
 706   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 707 If you have zlib already installed, see config.log for details on the
 708 failure.  It is possible the compiler isn't looking in the proper directory.
 709 Use --without-zlib to disable zlib support.])])
 710 fi
 711
 712 if test "$with_krb4" = yes ; then
 713   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 714 fi
 715
 716 if test "$with_krb5" = yes ; then
 717   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 718   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 719 fi
 720
 721 if test "$with_openssl" = yes ; then
 722   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 723   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 724 fi
 725
 726 if test "$with_pam" = yes ; then
 727   AC_CHECK_HEADERS(security/pam_appl.h, [],
 728                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 729                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 730 fi
 731
 732
 733 ##
 734 ## Types, structures, compiler characteristics
 735 ##
 736
 737 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 738 AC_C_CONST
 739 AC_C_INLINE
 740 AC_C_STRINGIZE
 741 PGAC_C_SIGNED
 742 AC_C_VOLATILE
 743 AC_STRUCT_TIMEZONE
 744 PGAC_UNION_SEMUN
 745 PGAC_STRUCT_SOCKADDR_UN
 746
 747 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 748 [#include <sys/param.h>
 749 #include <sys/socket.h>
 750 #include <sys/ucred.h>])
 751
 752 if test "$with_zlib" = yes; then
 753   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 754   # did not).  While we could work around the lack of z_streamp, it
 755   # seems unwise to encourage people to use such old zlib versions...
 756   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 757 Use --without-zlib to disable zlib support.])],
 758                 [#include <zlib.h>])
 759 fi
 760
 761 if test "$with_krb5" = yes; then
 762 # Check for differences between MIT and Heimdal (KTH) releases
 763   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 764                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 765                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 766                                      [#include <krb5.h>])],
 767                    [#include <krb5.h>])
 768   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 769                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 770                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 771                                      [#include <krb5.h>])],
 772                    [#include <krb5.h>])
 773 fi
 774
 775
 776 ##
 777 ## Functions, global variables
 778 ##
 779
 780 PGAC_VAR_INT_TIMEZONE
 781 AC_FUNC_ACCEPT_ARGTYPES
 782 PGAC_FUNC_GETTIMEOFDAY_1ARG
 783
 784 # SunOS doesn't handle negative byte comparisons properly with +/- return
 785 AC_FUNC_MEMCMP
 786
 787 AC_CHECK_FUNCS([cbrt fcvt getpeereid memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync utime utimes])
 788
 789 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 790
 791 # This exports HAVE_IPV6 to both C files and Makefiles
 792 AC_CHECK_FUNC(getaddrinfo,
 793              [AC_CHECK_TYPE(struct sockaddr_in6,
 794                             [HAVE_IPV6="yes"; AC_DEFINE(HAVE_IPV6, 1)],
 795                             [],
 796 [$ac_includes_default
 797 #include <netinet/in.h>])])
 798 AC_SUBST(HAVE_IPV6)
 799
 800 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 801 [AC_TRY_LINK(
 802 [#include <machine/vmparam.h>
 803 #include <sys/exec.h>
 804 ],
 805 [PS_STRINGS->ps_nargvstr = 1;
 806 PS_STRINGS->ps_argvstr = "foo";],
 807 [pgac_cv_var_PS_STRINGS=yes],
 808 [pgac_cv_var_PS_STRINGS=no])])
 809 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 810   AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
 811 fi
 812
 813
 814 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 815 # is missing.  Yes, there are machines that have only one.  We may
 816 # also decide to use snprintf.c if snprintf() is present but does not
 817 # have working "long long int" support -- see below.
 818
 819 pgac_need_repl_snprintf=no
 820 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 821 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 822
 823
 824 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 825 # include/c.h will provide declarations.  Note this is a separate test
 826 # from whether the functions exist in the C library --- there are
 827 # systems that have the functions but don't bother to declare them :-(
 828
 829 AC_CHECK_DECLS([snprintf, vsnprintf])
 830
 831
 832 # do this one the hard way in case isinf() is a macro
 833 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 834 [AC_TRY_LINK(
 835 [#include <math.h>
 836 ],
 837 [double x = 0.0; int res = isinf(x);],
 838 [ac_cv_func_isinf=yes],
 839 [ac_cv_func_isinf=no])])
 840
 841 if test $ac_cv_func_isinf = yes ; then
 842   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
 843 else
 844   AC_LIBOBJ(isinf)
 845   # Look for a way to implement a substitute for isinf()
 846   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 847 fi
 848
 849 AC_REPLACE_FUNCS([fseeko gethostname getopt_long getrusage inet_aton random srandom strcasecmp strdup strerror strtol strtoul])
 850
 851 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 852 # We override the previous test that said fseeko/ftello didn't exist
 853 # OS tests are also done in include/c.h and port/fseeko.c
 854 case $host_os in bsdi*|netbsd*)
 855 ac_cv_func_fseeko=yes
 856 esac
 857
 858 # Solaris has a very slow qsort in certain cases, so we replace it.
 859 case $host_os in
 860   solaris*) AC_LIBOBJ(qsort) ;;
 861 esac
 862
 863 # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
 864 # this hackery with HPUXMATHLIB allows us to cope.
 865 HPUXMATHLIB=""
 866 case $host_cpu in
 867   hppa1.1)
 868         if test -r /lib/pa1.1/libm.a ; then
 869             HPUXMATHLIB="-L /lib/pa1.1 -lm"
 870         fi ;;
 871 esac
 872 AC_SUBST(HPUXMATHLIB)
 873
 874 AC_CHECK_FUNCS(rint, [],
 875                [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
 876
 877
 878 if test "$with_readline" = yes; then
 879   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 880   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 881 fi
 882
 883
 884 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 885 AC_MSG_CHECKING(for finite)
 886 AC_TRY_LINK([#include <math.h>],
 887             [int dummy=finite(1.0);],
 888             [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
 889 AC_MSG_RESULT(yes)],
 890             [AC_MSG_RESULT(no)])
 891
 892 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 893 dnl (especially on GNU libc)
 894 dnl See also comments in pg_config.h.
 895 AC_MSG_CHECKING(for sigsetjmp)
 896 AC_TRY_LINK([#include <setjmp.h>],
 897             [sigjmp_buf x; sigsetjmp(x, 1);],
 898             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
 899 AC_MSG_RESULT(yes)],
 900             [AC_MSG_RESULT(no)])
 901
 902 AC_CHECK_FUNC(syslog,
 903              [AC_CHECK_HEADER(syslog.h,
 904              [AC_DEFINE(HAVE_SYSLOG, 1, [])],
 905              [])])
 906
 907 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 908 [AC_TRY_LINK([#include <unistd.h>],
 909   [extern int optreset; optreset = 1;],
 910   [pgac_cv_var_int_optreset=yes],
 911   [pgac_cv_var_int_optreset=no])])
 912 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 913   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
 914 fi
 915
 916 AC_CHECK_FUNCS([strtoll strtoq], [break])
 917 AC_CHECK_FUNCS([strtoull strtouq], [break])
 918
 919 # Check for one of atexit() or on_exit()
 920 AC_CHECK_FUNCS(atexit, [],
 921                [AC_CHECK_FUNCS(on_exit, [],
 922                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 923
 924 AC_FUNC_FSEEKO
 925
 926
 927 # This test makes sure that run tests work at all.  Sometimes a shared
 928 # library is found by the linker, but the runtime linker can't find it.
 929 # This check should come after all modifications of compiler or linker
 930 # variables, and before any other run tests.
 931 AC_MSG_CHECKING([test program])
 932 AC_TRY_RUN([int main() { return 0; }],
 933 [AC_MSG_RESULT(ok)],
 934 [AC_MSG_RESULT(failed)
 935 AC_MSG_ERROR([[
 936 *** Could not execute a simple test program.  This may be a problem
 937 *** related to locating shared libraries.  Check the file 'config.log'
 938 *** for the exact reason.]])],
 939 [AC_MSG_RESULT([cross-compiling])])
 940
 941
 942 dnl Check to see if we have a working 64-bit integer type.
 943 dnl This breaks down into two steps:
 944 dnl (1) figure out if the compiler has a 64-bit int type with working
 945 dnl arithmetic, and if so
 946 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
 947 dnl snprintf is the only library routine we really need for int8 support.)
 948 dnl It's entirely possible to have a compiler that handles a 64-bit type
 949 dnl when the C library doesn't; this is fairly likely when using gcc on
 950 dnl an older platform, for example.
 951 dnl If there is no native snprintf() or it does not handle the 64-bit type,
 952 dnl we force our own version of snprintf() to be used instead.
 953 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
 954
 955 PGAC_TYPE_64BIT_INT([long int])
 956
 957 if test x"$HAVE_LONG_INT_64" = x"no" ; then
 958   PGAC_TYPE_64BIT_INT([long long int])
 959 fi
 960
 961
 962 dnl If we need to use "long long int", figure out whether nnnLL notation works.
 963
 964 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
 965   AC_TRY_COMPILE([
 966 #define INT64CONST(x)  x##LL
 967 long long int foo = INT64CONST(0x1234567890123456);
 968 ],
 969         [],
 970         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
 971         [])
 972 fi
 973
 974
 975 # If we found "long int" is 64 bits, assume snprintf handles it.  If
 976 # we found we need to use "long long int", better check.  We cope with
 977 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
 978 # neither works, fall back to our own snprintf emulation (which we
 979 # know uses %lld).
 980
 981 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
 982   if test $pgac_need_repl_snprintf = no; then
 983     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
 984     if test "$LONG_LONG_INT_FORMAT" = ""; then
 985       # Force usage of our own snprintf, since system snprintf is broken
 986       pgac_need_repl_snprintf=yes
 987       LONG_LONG_INT_FORMAT='%lld'
 988     fi
 989   else
 990     # Here if we previously decided we needed to use our own snprintf
 991     LONG_LONG_INT_FORMAT='%lld'
 992   fi
 993   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
 994 else
 995   # Here if we are not using 'long long int' at all
 996   INT64_FORMAT='"%ld"'
 997 fi
 998
 999 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1000                    [Define this as the appropriate snprintf format for 64-bit ints, if any])
1001
1002 if test $pgac_need_repl_snprintf = yes; then
1003   AC_LIBOBJ(snprintf)
1004 fi
1005
1006 dnl Need a #define for the size of Datum (unsigned long)
1007
1008 AC_CHECK_SIZEOF([unsigned long])
1009 AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1010
1011 # Determine memory alignment requirements for the basic C data types.
1012
1013 PGAC_CHECK_ALIGNOF(short)
1014 PGAC_CHECK_ALIGNOF(int)
1015 PGAC_CHECK_ALIGNOF(long)
1016 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1017   PGAC_CHECK_ALIGNOF(long long int)
1018 fi
1019 PGAC_CHECK_ALIGNOF(double)
1020
1021 # Compute maximum alignment of any basic type.
1022 # We assume long's alignment is at least as strong as char, short, or int;
1023 # but we must check long long (if it exists) and double.
1024
1025 MAX_ALIGNOF=$pgac_cv_alignof_long
1026 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1027   MAX_ALIGNOF=$pgac_cv_alignof_double
1028 fi
1029 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1030   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1031 fi
1032 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1033
1034
1035 # Some platforms predefine the types int8, int16, etc.  Only check
1036 # a (hopefully) representative subset.
1037 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1038 [#include <stdio.h>
1039 #ifdef HAVE_SUPPORTDEFS_H
1040 #include <SupportDefs.h>
1041 #endif])
1042
1043 # We also check for sig_atomic_t, which *should* be defined per ANSI
1044 # C, but is missing on some old platforms.
1045 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1046
1047
1048 PGAC_FUNC_POSIX_SIGNALS
1049 if test $ac_cv_func_fseeko = yes; then
1050 AC_SYS_LARGEFILE
1051 fi
1052
1053
1054 # Select semaphore implementation type.
1055 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1056   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores])
1057   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1058 else
1059   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1060     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores])
1061     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1062   else
1063     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores])
1064     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1065   fi
1066 fi
1067
1068
1069 # Select shared-memory implementation type.
1070 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory])
1071 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1072
1073
1074 if test "$enable_nls" = yes ; then
1075   PGAC_CHECK_GETTEXT
1076 fi
1077
1078 # Check for Tcl configuration script tclConfig.sh
1079 if test "$with_tcl" = yes; then
1080     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1081     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1082                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1083     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1084 fi
1085
1086 # Check for Tk configuration script tkConfig.sh
1087 if test "$with_tk" = yes; then
1088     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1089     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1090 fi
1091
1092
1093 #
1094 # Check for DocBook and tools
1095 #
1096 PGAC_PROG_NSGMLS
1097 PGAC_PROG_JADE
1098 PGAC_CHECK_DOCBOOK(3.1)
1099 PGAC_PATH_DOCBOOK_STYLESHEETS
1100 PGAC_PATH_COLLATEINDEX
1101 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1102
1103
1104 # prepare build tree if outside source tree
1105 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1106 # Note 2: /bin/pwd might be better than shell's built-in at getting
1107 #         a symlink-free name.
1108 if test "$no_create" != yes; then
1109   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1110     :
1111   else
1112     AC_SUBST(vpath_build, yes)
1113     _AS_ECHO_N([preparing build tree... ])
1114     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1115     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1116       || AC_MSG_ERROR(failed)
1117     AC_MSG_RESULT(done)
1118   fi
1119 fi
1120
1121
1122 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1123
1124 AC_CONFIG_LINKS([
1125   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1126   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1127   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1128   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1129   src/include/pg_config_os.h:src/include/port/${template}.h
1130   src/Makefile.port:src/makefiles/Makefile.${template}
1131 ])
1132
1133 AC_CONFIG_HEADERS([src/include/pg_config.h],
1134 [
1135 # Update timestamp for pg_config.h (see Makefile.global)
1136 echo >src/include/stamp-h
1137 ])
1138
1139 AC_OUTPUT