granicus.if.org Git - sysstat/blob - configure.in

   1 # configure.in
   2 #
   3 # (C) 2007 - Ivana Varekova <varekova@redhat.com>
   4 # Modified by Sebastien Godard (sysstat <at> orange.fr)
   5
   6 # Initialization of $PACKAGE_VERSION and $PACKAGE_NAME variables
   7 AC_INIT(sysstat, 11.2.0)
   8
   9 # Ensure that a recent enough version of Autoconf is being used
  10 AC_PREREQ(2.53)
  11
  12 # Check whether the configure script is in the right dir
  13 AC_CONFIG_SRCDIR(ioconf.h)
  14
  15 # Check programs
  16 echo .
  17 echo Check programs:
  18 echo .
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_PROG_LN_S
  23
  24 DFLAGS=""
  25
  26 AC_CHECK_PROG(CHMOD, chmod, chmod)
  27 AC_CHECK_PROG(CHOWN, chown, chown)
  28 AC_CHECK_PROG(AR, ar, ar)
  29 AC_CHECK_PROG(INSTALL, install, install)
  30 AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
  31 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
  32 AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
  33 AC_CHECK_PROGS(ZIP, xz bzip2 gzip, gzip)
  34 INSTALL_DATA="\${INSTALL} -m 644"
  35 AC_SUBST(INSTALL_DATA)
  36 INSTALL_BIN="\${INSTALL} -m 755"
  37 AC_SUBST(INSTALL_BIN)
  38
  39 AC_PATH_PROG(PATH_CP, cp)
  40 AC_PATH_PROG(PATH_CHKCONFIG, chkconfig)
  41
  42 # Check for systemd
  43 AC_CHECK_PROG(PKG_CONFIG, pkg-config, pkg-config)
  44 AC_PATH_PROG(SYSTEMCTL, systemctl)
  45 AC_ARG_WITH([systemdsystemunitdir],
  46     AS_HELP_STRING([--with-systemdsystemunitdir=DIR],[Directory for systemd service files]),
  47     [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  48 if test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ; then
  49     AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
  50 fi
  51
  52 # Check libraries
  53
  54 # Check header files
  55 echo .
  56 echo Check header files:
  57 echo .
  58 HAVE_LIBINTL_H=
  59 HAVE_LOCALE_H=
  60 HAVE_SYS_SYSMACROS_H=
  61 AC_HEADER_STDC
  62 AC_HEADER_DIRENT
  63 AC_CHECK_HEADERS(ctype.h)
  64 AC_CHECK_HEADERS(errno.h)
  65 AC_CHECK_HEADERS(libintl.h, HAVE_LIBINTL_H=1)
  66 AC_CHECK_HEADERS(locale.h, HAVE_LOCALE_H=1)
  67 AC_CHECK_HEADERS(net/if.h)
  68 AC_CHECK_HEADERS(regex.h)
  69 AC_CHECK_HEADERS(signal.h)
  70 AC_CHECK_HEADERS(stdio.h)
  71 AC_CHECK_HEADERS(sys/file.h)
  72 AC_CHECK_HEADERS(sys/ioctl.h)
  73 AC_CHECK_HEADERS(sys/stat.h)
  74 AC_CHECK_HEADERS(sys/sysmacros.h, HAVE_SYS_SYSMACROS_H=1)
  75
  76 echo .
  77 echo Check typedefs, structures and compiler characteristics:
  78 echo .
  79 AC_TYPE_SIGNAL
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_OFF_T
  82
  83 echo .
  84 echo Check library functions:
  85 echo .
  86 AC_CHECK_FUNCS(strchr)
  87 AC_CHECK_FUNCS(strcspn)
  88 AC_CHECK_FUNCS(strspn)
  89 AC_CHECK_FUNCS(strstr)
  90
  91 # Should we check for lm_sensors?
  92 AC_MSG_CHECKING(for sensors support)
  93 AC_ARG_ENABLE(sensors,
  94               AC_HELP_STRING([--disable-sensors],
  95                              [disable sensors support]),
  96                              SENSORS=$enableval,SENSORS=yes)
  97 if test $SENSORS != "yes"; then
  98    HAVE_SENSORS="n"
  99 else
 100    HAVE_SENSORS="y"
 101 fi
 102 AC_MSG_RESULT($SENSORS)
 103
 104 # Check for lm_sensors
 105 SENSORS=no
 106 LFSENSORS=""
 107 DFSENSORS=""
 108 AC_CHECK_LIB(sensors, sensors_get_detected_chips, LFSENSORS="-lsensors", HAVE_SENSORS="n")
 109 AC_MSG_CHECKING(for sensors lib)
 110 AC_TRY_COMPILE(#include <sensors/sensors.h>
 111 #include <sensors/error.h>
 112                 , sensors_cleanup();,SENSORS=yes; DFSENSORS="-DHAVE_SENSORS", HAVE_SENSORS="n"; SENSORS=no)
 113 AC_MSG_RESULT($SENSORS)
 114 AC_SUBST(HAVE_SENSORS)
 115 AC_SUBST(LFSENSORS)
 116 AC_SUBST(DFSENSORS)
 117
 118 echo .
 119 echo Check system services:
 120 echo .
 121 AC_SYS_LARGEFILE
 122
 123 echo .
 124 echo Check configuration:
 125 echo .
 126 # Check arguments used
 127 #
 128 # Optional Features:
 129 #  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
 130 #  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
 131 #  --disable-largefile     omit support for large files
 132 #  --disable-nls           disable National Language Support
 133 #  --disable-file-attr     don't set attributes on files being installed
 134 #  --enable-install-cron   tell sysstat to install cron scripts
 135 #  --collect-all           tell sadc to collect all possible data
 136 #  --enable-clean-sa-dir   clean system activity directory
 137 #  --enable-compress-manpg compress manual pages
 138 #  --enable-install-isag   install isag script
 139 #  --enable-debuginfo      enable debug output (--debuginfo option)
 140 #  --disable-documentation do not install documentation (man pages...)
 141 #  --disable-sensors       do not link against libsensors even if available
 142 #  --disable-stripping     do not strip object files
 143 #  --enablle-copy-only     only copy files when installing sysstat
 144 #
 145 # Some influential environment variables:
 146 #  rcdir         directory where startup scripts are installed
 147 #  sa_lib_dir    sadc, sa1 and sa2 directory
 148 #  sa_dir        system activity daily datafiles directory
 149 #  conf_dir      sysstat configuration directory (default is /etc/sysconfig)
 150 #  history       number of daily datafiles to keep (default value is 7)
 151 #  compressafter number of days after which datafiles are compressed
 152 #  man_group     group for man pages
 153 #  cron_owner    crontab owner
 154 #  cron_interval crontab sampling interval
 155 #  sadc_options  options to be passed to sadc
 156 #
 157 # Fine tuning the installation directories:
 158 #  --mandir=DIR           man documentation directory [PREFIX/man]
 159 #  --docdir=DIR           other documentation directory [PREFIX/share/doc]
 160 #
 161 # Installation directories:
 162 #  --prefix=PREFIX         install architecture-independent files in PREFIX
 163 #                            [/usr/local]
 164 #  --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX
 165 #                            [PREFIX]
 166
 167 # Set directories
 168 if test -d /etc/init.d && test ! -L /etc/init.d; then
 169    if test -d /etc/init.d/rc2.d; then
 170       RC_DIR=/etc/init.d
 171       INITD_DIR=.
 172    else
 173       RC_DIR=/etc
 174       INITD_DIR=init.d
 175    fi
 176    INIT_DIR=/etc/init.d
 177 elif test -d /sbin/init.d; then
 178    RC_DIR=/sbin/init.d
 179    INIT_DIR=/sbin/init.d
 180    INITD_DIR=.
 181 else
 182    RC_DIR=/etc/rc.d
 183    INIT_DIR=/etc/rc.d/init.d
 184    INITD_DIR=init.d
 185 fi
 186
 187 AC_MSG_CHECKING(run-commands directory)
 188 AC_ARG_VAR([rcdir],[run-commands directory])
 189 if test x$rcdir != x""; then
 190         # Override previous rc directories values
 191         RC_DIR=$rcdir
 192         INIT_DIR=$rcdir/init.d
 193         INITD_DIR=init.d
 194 fi
 195 AC_MSG_RESULT($RC_DIR)
 196 if test ! -d $RC_DIR; then
 197         echo "INFO: Directory ${RC_DIR} doesn't exist."
 198         echo "INFO: Startup scripts won't be installed."
 199 fi
 200
 201 AC_SUBST(RC_DIR)
 202 AC_SUBST(INIT_DIR)
 203 AC_SUBST(INITD_DIR)
 204
 205 if test $HAVE_SYS_SYSMACROS_H; then
 206    SYSMACROS="y"
 207 else
 208    SYSMACROS="n"
 209 fi
 210 AC_SUBST(SYSMACROS)
 211
 212 # Set sadc directory
 213 if test $prefix != "NONE"; then
 214    AuxPrefix=$prefix
 215 else
 216    AuxPrefix=/usr/local
 217 fi
 218
 219 SADC_DIR=$AuxPrefix/lib
 220 if test -d $AuxPrefix/lib64; then
 221     # Verify that this OS is really 64 bit
 222     BITS=$(getconf LONG_BIT 2>/dev/null)
 223     if test $? = 0; then
 224         if test $BITS = 64; then
 225             SADC_DIR=$AuxPrefix/lib64
 226         fi
 227     else
 228         # Fallback: look for lm (long mode) flag to know if CPU is 64 bit
 229         grep " lm " /proc/cpuinfo >/dev/null 2>&1
 230         if test $? = 0; then
 231             SADC_DIR=$AuxPrefix/lib64
 232         fi
 233     fi
 234 fi
 235
 236 AC_MSG_CHECKING(sadc directory)
 237 AC_ARG_VAR([sa_lib_dir],[sadc directory])
 238 if test x$sa_lib_dir != x""; then
 239    SA_LIB_DIR=$sa_lib_dir
 240 else
 241    SA_LIB_DIR=$SADC_DIR/sa
 242 fi
 243 AC_MSG_RESULT($SA_LIB_DIR)
 244 if test ! -d $SA_LIB_DIR; then
 245    echo "INFO: Directory ${SA_LIB_DIR} will be created during installation stage."
 246 fi
 247 AC_SUBST(SA_LIB_DIR)
 248
 249 # Set system activity directory
 250 AC_MSG_CHECKING(system activity directory)
 251 AC_ARG_VAR([sa_dir],[system activity directory])
 252 if test x$sa_dir != x""; then
 253    SA_DIR=$sa_dir
 254 else
 255    SA_DIR=/var/log/sa
 256 fi
 257 AC_MSG_RESULT($SA_DIR)
 258 if test ! -d $SA_DIR; then
 259    echo "INFO: Directory ${SA_DIR} will be created during installation stage."
 260 fi
 261 AC_SUBST(SA_DIR)
 262
 263 # Set configuration directory
 264 AC_MSG_CHECKING(sysstat configuration directory)
 265 AC_ARG_VAR([conf_dir],[sysstat configuration directory])
 266 if test x$conf_dir != x""; then
 267    SYSCONFIG_DIR=$conf_dir
 268 else
 269    SYSCONFIG_DIR=/etc/sysconfig
 270 fi
 271 AC_MSG_RESULT($SYSCONFIG_DIR)
 272 if test ! -d $SYSCONFIG_DIR; then
 273    echo "INFO: Directory ${SYSCONFIG_DIR} will be created during installation stage."
 274 fi
 275 AC_SUBST(SYSCONFIG_DIR)
 276
 277 # National Language Support
 278 AC_MSG_CHECKING(National Language Support)
 279 AC_ARG_ENABLE(nls,
 280               AC_HELP_STRING([--disable-nls],
 281                              [disable National Language Support]),
 282                              AUX_NLS=$enableval,AUX_NLS=yes)
 283 if test $AUX_NLS != "no" && test $HAVE_LIBINTL_H && test $HAVE_LOCALE_H; then
 284    AUX_NLS="yes"
 285    NLS="y"
 286 else
 287    AUX_NLS="no"
 288    NLS="n"
 289 fi
 290 AC_MSG_RESULT($AUX_NLS)
 291 AC_SUBST(NLS)
 292 if test $AUX_NLS = "yes" &&  test x$MSGFMT != x"msgfmt"; then
 293    echo "WARNING: msgfmt command not found!"
 294 fi
 295 if test $AUX_NLS = "yes" &&  test x$XGETTEXT != x"xgettext"; then
 296    echo "WARNING: xgettext command not found!"
 297 fi
 298 if test $AUX_NLS = "yes" &&  test x$MSGMERGE != x"msgmerge"; then
 299    echo "WARNING: msgmerge command not found!"
 300 fi
 301
 302 # Data history to keep by sa2
 303 AC_MSG_CHECKING(number of daily data files to keep)
 304 AC_ARG_VAR([history],[number of daily data files to keep (default value is 7)])
 305 if test x$history = x""; then
 306    HISTORY=7
 307 else
 308    HISTORY=$history
 309 fi
 310 AC_MSG_RESULT($HISTORY)
 311 AC_SUBST(HISTORY)
 312
 313 # Number of days after which datafiles are compressed
 314 AC_MSG_CHECKING(number of days after which data files are compressed)
 315 AC_ARG_VAR([compressafter],[number of days after which data files are compressed (default value is 10)])
 316 if test x$compressafter = x""; then
 317    COMPRESSAFTER=10
 318 else
 319    COMPRESSAFTER=$compressafter
 320 fi
 321 AC_MSG_RESULT($COMPRESSAFTER)
 322 AC_SUBST(COMPRESSAFTER)
 323
 324 # Preallocation factor
 325 AC_MSG_CHECKING(preallocation factor value)
 326 AC_ARG_VAR([prealloc],[preallocation factor that will determine data files size (default value is 1)])
 327 if test x$prealloc = x""; then
 328    PREALLOC_FACTOR=1
 329 else
 330    PREALLOC_FACTOR=$prealloc
 331 fi
 332 AC_MSG_RESULT($PREALLOC_FACTOR)
 333 AC_SUBST(PREALLOC_FACTOR)
 334
 335 # Manual page group
 336 grep ^man: /etc/group >/dev/null 2>&1
 337 if test $? = 0; then
 338    GRP=man
 339 else
 340    GRP=root
 341 fi
 342
 343 AC_MSG_CHECKING(group for manual pages)
 344 AC_ARG_VAR([man_group],[group for manual pages])
 345 if test x$man_group = x""; then
 346    MAN_GROUP=$GRP
 347    AC_MSG_RESULT($MAN_GROUP)
 348 else
 349    grep ^$man_group: /etc/group >/dev/null 2>&1
 350    if test $? = 1; then
 351       MAN_GROUP=$GRP
 352       AC_MSG_RESULT($MAN_GROUP)
 353       echo "WARNING: Group ${man_group} not found: Using ${GRP} instead"
 354    else
 355       MAN_GROUP=$man_group
 356       AC_MSG_RESULT($MAN_GROUP)
 357    fi
 358 fi
 359 AC_SUBST(MAN_GROUP)
 360
 361 # Don't set attributes on files being installed?
 362 AC_MSG_CHECKING(whether attributes should not be set on files being installed)
 363 AC_ARG_ENABLE(file-attr,
 364               AC_HELP_STRING([--disable-file-attr],
 365                              [do not set attributes on files being installed]),
 366                              AUX_IMG=$enableval,AUX_IMG=yes)
 367 if test $AUX_IMG != "no"; then
 368    IGNORE_FILE_ATTRIBUTES=n
 369    AUX_IMG=no
 370 else
 371    IGNORE_FILE_ATTRIBUTES=y
 372    AUX_IMG=yes
 373 fi
 374 AC_MSG_RESULT($AUX_IMG)
 375 AC_SUBST(IGNORE_FILE_ATTRIBUTES)
 376
 377 # Compress manual pages?
 378 AC_MSG_CHECKING(whether manual pages should be compressed)
 379 AC_ARG_ENABLE(compress-manpg,
 380               AC_HELP_STRING([--enable-compress-manpg],
 381                              [compress sysstat manual pages]),
 382                              AUX_MPG=$enableval,AUX_MPG=no)
 383 if test $AUX_MPG != "yes"; then
 384    COMPRESS_MANPG=n
 385    AUX_MPG=no
 386 else
 387    COMPRESS_MANPG=y
 388 fi
 389 AC_MSG_RESULT($AUX_MPG)
 390 AC_SUBST(COMPRESS_MANPG)
 391
 392 # Check whether isag should be installed
 393 AC_MSG_CHECKING(whether isag script should be installed)
 394 AC_ARG_ENABLE(install-isag,
 395               AC_HELP_STRING([--enable-install-isag],
 396                              [install isag script]),
 397                              AUX_IIS=$enableval,AUX_IIS=no)
 398 if test $AUX_IIS != "yes"; then
 399    INSTALL_ISAG=n
 400    AUX_IIS=no
 401 else
 402    INSTALL_ISAG=y
 403 fi
 404 AC_MSG_RESULT($AUX_IIS)
 405 AC_SUBST(INSTALL_ISAG)
 406
 407 # Check whether sa directory should be cleaned
 408 AC_MSG_CHECKING(whether system activity directory should be cleaned)
 409 AC_ARG_ENABLE(clean-sa-dir,
 410               AC_HELP_STRING([--enable-clean-sa-dir],
 411                              [clean system activity directory]),
 412                             AUX_CSD=$enableval,AUX_CSD=no)
 413 if test $AUX_CSD != "yes"; then
 414    CLEAN_SA_DIR=n
 415    AUX_CSD=no
 416 else
 417    CLEAN_SA_DIR=y
 418 fi
 419 AC_MSG_RESULT($AUX_CSD)
 420 AC_SUBST(CLEAN_SA_DIR)
 421
 422 # Start crontab
 423 AC_MSG_CHECKING(whether cron should start sar automatically)
 424 AC_ARG_ENABLE(install-cron,
 425               AC_HELP_STRING([--enable-install-cron],
 426                              [install a crontab to start sar]),
 427                              INSTALL_CRON=$enableval,INSTALL_CRON=n)
 428 if test $INSTALL_CRON != "yes"; then
 429    INSTALL_CRON=n
 430    AUX_CRON=no
 431 else
 432    INSTALL_CRON=y
 433    AUX_CRON=yes
 434 fi
 435 AC_MSG_RESULT($AUX_CRON)
 436 AC_SUBST(INSTALL_CRON)
 437
 438 # Crontab owner
 439 CUSR="root"
 440 if test $INSTALL_CRON = "y"; then
 441    AC_MSG_CHECKING(crontab owner)
 442    AC_ARG_VAR([cron_owner],[crontab owner])
 443    if test x$cron_owner = x""; then
 444       CRON_OWNER=$CUSR
 445       AC_MSG_RESULT($CRON_OWNER)
 446    else
 447       grep ^$cron_owner: /etc/passwd >/dev/null 2>&1
 448       if test $? = 1; then
 449          CRON_OWNER=$CUSR;
 450          AC_MSG_RESULT($CRON_OWNER)
 451          echo "WARNING: User ${cron_owner} not found: Using ${CUSR} instead."
 452       else
 453          CRON_OWNER=$cron_owner
 454          AC_MSG_RESULT($CRON_OWNER)
 455       fi
 456    fi
 457    echo "INFO: Crontab for ${CRON_OWNER} will be saved in current directory if necessary"
 458    if test $CRON_OWNER = "root"; then
 459       SU_C_OWNER=""
 460       QUOTE=""
 461       REM_CHOWN="# REM_CHOWN"
 462    else
 463       SU_C_OWNER="su $CRON_OWNER -c "
 464       QUOTE=\"
 465       # " (ignore this line)
 466       REM_CHOWN=$CHOWN
 467    fi
 468
 469 #  Crontab interval
 470    AC_MSG_CHECKING(crontab interval)
 471    AC_ARG_VAR([cron_interval],[crontab interval])
 472    if test x$cron_interval = x""; then
 473       CRON_INTERVAL=10
 474    else
 475       CRON_INTERVAL=$cron_interval
 476    fi
 477    AC_MSG_RESULT($CRON_INTERVAL)
 478    CRON_INTERVAL_SEC=`expr ${CRON_INTERVAL} \* 60`
 479    CRON_COUNT=`expr 60 / ${CRON_INTERVAL}`
 480
 481 #  Check whether sadc should collect all possible activities
 482    AC_MSG_CHECKING(whether sadc should collect all possible activities)
 483    AC_ARG_ENABLE(collect-all,
 484                  AC_HELP_STRING([--enable-collect-all],
 485                                 [collect all possible activities]),
 486                                 COLLECT_ALL=$enableval,COLLECT_ALL=n)
 487    if test $COLLECT_ALL != "yes"; then
 488       COLLECT_ALL=""
 489       AUX_COLL=no
 490    else
 491       COLLECT_ALL="-S XALL"
 492       AUX_COLL=yes
 493    fi
 494    AC_MSG_RESULT($AUX_COLL)
 495
 496    AC_MSG_CHECKING(options to be passed to sadc)
 497    AC_ARG_VAR([sadc_options],[options to be passed to sadc])
 498    if test x"$sadc_options" != x""; then
 499         SADC_OPT="$sadc_options"
 500    else
 501         SADC_OPT=
 502    fi
 503    AC_MSG_RESULT($SADC_OPT)
 504    AC_SUBST(SADC_OPT)
 505
 506 #  Check whether files should only be copied
 507    AC_MSG_CHECKING(whether files should only be copied)
 508    AC_ARG_ENABLE(copy-only,
 509                  AC_HELP_STRING([--enable-copy-only],
 510                                 [only copy files when installing]),
 511                                 OCOPY=$enableval,OCOPY=no)
 512    if test $OCOPY != "yes"; then
 513       COPY_ONLY=n
 514       OCOPY=no
 515    else
 516       COPY_ONLY=y
 517    fi
 518    AC_MSG_RESULT($OCOPY)
 519    AC_SUBST(COPY_ONLY)
 520
 521 else
 522    CRON_OWNER="root"
 523    SU_C_OWNER=""
 524    QUOTE=""
 525    REM_CHOWN="# REM_CHOWN"
 526    CRON_INTERVAL=10
 527    CRON_INTERVAL_SEC=600
 528    CRON_COUNT=6
 529    COLLECT_ALL=""
 530 fi
 531 AC_SUBST(CRON_OWNER)
 532 AC_SUBST(SU_C_OWNER)
 533 AC_SUBST(CRON_INTERVAL)
 534 AC_SUBST(CRON_INTERVAL_SEC)
 535 AC_SUBST(CRON_COUNT)
 536 AC_SUBST(QUOTE)
 537 AC_SUBST(REM_CHOWN)
 538 AC_SUBST(COLLECT_ALL)
 539
 540 # Check whether documentation should be installed
 541 AC_MSG_CHECKING(whether documentation should be installed)
 542 AC_ARG_ENABLE(documentation,
 543               AC_HELP_STRING([--disable-documentation],
 544                              [do not install documentation]),
 545                              AUX_DOC=$enableval,AUX_DOC=yes)
 546 if  test  $AUX_DOC !=  "no"; then
 547    AUX_DOC="yes"
 548    INSTALL_DOC="y"
 549 else
 550    AUX_DOC="no"
 551    INSTALL_DOC="n"
 552 fi
 553 AC_MSG_RESULT($AUX_DOC)
 554 AC_SUBST(INSTALL_DOC)
 555
 556 # Set directory for installing manual pages (see comment in Makefile)
 557 AC_SUBST(mandir)
 558
 559 # Check whether --debuginfo options should be allowed
 560 AC_ARG_ENABLE(debuginfo,
 561               AC_HELP_STRING([--enable-debuginfo],
 562                              [enable debug output (--debuginfo option)]),
 563                              WITH_DEBUG=yes ; DFLAGS="$DFLAGS -DDEBUG" , WITH_DEBUG=no)
 564 AC_SUBST(WITH_DEBUG)
 565 AC_SUBST(DFLAGS)
 566
 567 # Check whether object files should be stripped
 568 AC_MSG_CHECKING(whether object files should be stripped)
 569 AC_ARG_ENABLE(stripping,
 570               AC_HELP_STRING([--disable-stripping],
 571                              [do not strip object files]),
 572                              AUX_STRIP=$enableval,AUX_STRIP=yes)
 573 if test $AUX_STRIP != "no"; then
 574    AUX_STRIP="yes"
 575    STRIP="-s"
 576 else
 577    AUX_STRIP="no"
 578    STRIP=
 579 fi
 580 AC_MSG_RESULT($AUX_STRIP)
 581 AC_SUBST(STRIP)
 582
 583 # Create files
 584 echo .
 585 echo Now create files:
 586 echo .
 587 AC_CONFIG_FILES([sa1], [chmod +x sa1])          # Permissions must be changed
 588 AC_CONFIG_FILES([sa2], [chmod +x sa2])          # Permissions must be changed
 589 AC_CONFIG_FILES([cron/crontab:cron/crontab.sample])     # File must be renamed
 590 AC_CONFIG_FILES([sysstat.sysconfig])
 591 AC_CONFIG_FILES([version.h:version.in])         # File must be renamed
 592 AC_CONFIG_FILES([sysconfig.h:sysconfig.in])     # File must be renamed
 593 AC_CONFIG_FILES([prealloc.h:prealloc.in])       # File must be renamed
 594 AC_CONFIG_FILES([cron/sysstat.cron.daily])
 595 AC_CONFIG_FILES([cron/sysstat.cron.hourly])
 596 AC_CONFIG_FILES([cron/sysstat.crond])
 597 AC_CONFIG_FILES([cron/sysstat.crond.sample.in:cron/sysstat.crond.in], [sed s/^/#/ cron/sysstat.crond.sample.in > cron/sysstat.crond.sample])
 598 AC_CONFIG_FILES([sysstat], [chmod +x sysstat])  # Permissions must be changed
 599 AC_CONFIG_FILES([sysstat.service])
 600 AC_CONFIG_FILES([cron/sysstat-collect.service])
 601 AC_CONFIG_FILES([cron/sysstat-collect.timer])
 602 AC_CONFIG_FILES([cron/sysstat-summary.service])
 603 AC_CONFIG_FILES([cron/sysstat-summary.timer])
 604 AC_CONFIG_FILES([man/sa1.8:man/sa1.in])         # File must be renamed
 605 AC_CONFIG_FILES([man/sa2.8:man/sa2.in])         # File must be renamed
 606 AC_CONFIG_FILES([man/sadc.8:man/sadc.in])       # File must be renamed
 607 AC_CONFIG_FILES([man/sadf.1:man/sadf.in])       # File must be renamed
 608 AC_CONFIG_FILES([man/sar.1:man/sar.in])         # File must be renamed
 609 AC_CONFIG_FILES([man/sysstat.5:man/sysstat.in]) # File must be renamed
 610 AC_CONFIG_FILES([man/iostat.1:man/iostat.in])   # File must be renamed
 611 AC_CONFIG_FILES([man/cifsiostat.1:man/cifsiostat.in])   # File must be renamed
 612 AC_CONFIG_FILES([contrib/isag/isag], [chmod +x contrib/isag/isag]) # Permissions must be changed
 613
 614 AC_OUTPUT(Makefile)
 615
 616 echo "
 617    Sysstat version:             $PACKAGE_VERSION
 618    Installation prefix:         $prefix
 619    rc directory:                ${RC_DIR}
 620    Init directory:              ${INIT_DIR}
 621    Systemd unit dir:            ${with_systemdsystemunitdir}
 622    Configuration directory:     ${SYSCONFIG_DIR}
 623    Man pages directory:         $mandir
 624    Compiler:                    $CC
 625    Compiler flags:              $CFLAGS
 626 "
 627