granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.5devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2014, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif], [ICC=[yes]], [ICC=[no]])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # set CFLAGS_VECTOR from the environment, if available
 418 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 419   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 425 # but has its own.  Also check other compiler-specific flags here.
 426
 427 if test "$GCC" = yes -a "$ICC" = no; then
 428   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 429   # These work in some but not all gcc versions
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 432   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 433   # This was included in -Wall/-Wformat in older GCC versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 435   # Disable strict-aliasing rules; needed for gcc 3.3+
 436   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 437   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 438   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 439   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 441   # Optimization flags for specific files that benefit from vectorization
 442   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 443   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 444 elif test "$ICC" = yes; then
 445   # Intel's compiler has a bug/misoptimization in checking for
 446   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 447   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 448   # Make sure strict aliasing is off (though this is said to be the default)
 449   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 450 elif test "$PORTNAME" = "aix"; then
 451   # AIX's xlc has to have strict aliasing turned off too
 452   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 453 elif test "$PORTNAME" = "hpux"; then
 454   # On some versions of HP-UX, libm functions do not set errno by default.
 455   # Fix that by using +Olibmerrno if the compiler recognizes it.
 456   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 457 fi
 458
 459 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 460
 461 # supply -g if --enable-debug
 462 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   CFLAGS="$CFLAGS -g"
 464 fi
 465
 466 # enable code coverage if --enable-coverage
 467 if test "$enable_coverage" = yes; then
 468   if test "$GCC" = yes; then
 469     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 470   else
 471     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 472   fi
 473 fi
 474
 475 # enable profiling if --enable-profiling
 476 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 477   if test "$GCC" = yes; then
 478     AC_DEFINE([PROFILE_PID_DIR], 1,
 479            [Define to 1 to allow profiling output to be saved separately for each process.])
 480     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 481   else
 482     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 483   fi
 484 fi
 485
 486 # We already have this in Makefile.win32, but configure needs it too
 487 if test "$PORTNAME" = "win32"; then
 488   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 489 fi
 490
 491 # Check if the compiler still works with the template settings
 492 AC_MSG_CHECKING([whether the C compiler still works])
 493 AC_TRY_LINK([], [return 0;],
 494   [AC_MSG_RESULT(yes)],
 495   [AC_MSG_RESULT(no)
 496    AC_MSG_ERROR([cannot proceed])])
 497
 498 # Defend against gcc -ffast-math
 499 if test "$GCC" = yes; then
 500 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 501 choke me
 502 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 503 fi
 504
 505 AC_PROG_CPP
 506 AC_SUBST(GCC)
 507
 508
 509 #
 510 # Set up TAS assembly code if needed; the template file has now had its
 511 # chance to request this.
 512 #
 513 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 514
 515 if test "$need_tas" = yes ; then
 516   TAS=tas.o
 517 else
 518   TAS=""
 519 fi
 520 AC_SUBST(TAS)
 521
 522
 523 #
 524 # Automatic dependency tracking
 525 #
 526 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 527               [autodepend=yes])
 528 AC_SUBST(autodepend)
 529
 530
 531 #
 532 # Enable assert checks
 533 #
 534 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 535               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 536                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 537
 538
 539 #
 540 # Include directories
 541 #
 542 ac_save_IFS=$IFS
 543 IFS="${IFS}${PATH_SEPARATOR}"
 544 # SRCH_INC comes from the template file
 545 for dir in $with_includes $SRCH_INC; do
 546   if test -d "$dir"; then
 547     INCLUDES="$INCLUDES -I$dir"
 548   else
 549     AC_MSG_WARN([*** Include directory $dir does not exist.])
 550   fi
 551 done
 552 IFS=$ac_save_IFS
 553 AC_SUBST(INCLUDES)
 554
 555
 556 #
 557 # Library directories
 558 #
 559 ac_save_IFS=$IFS
 560 IFS="${IFS}${PATH_SEPARATOR}"
 561 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 562 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 563   if test -d "$dir"; then
 564     LIBDIRS="$LIBDIRS -L$dir"
 565   else
 566     AC_MSG_WARN([*** Library directory $dir does not exist.])
 567   fi
 568 done
 569 IFS=$ac_save_IFS
 570
 571 #
 572 # Enable thread-safe client libraries
 573 #
 574 AC_MSG_CHECKING([allow thread-safe client libraries])
 575 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 576 if test "$enable_thread_safety" = yes; then
 577   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 578           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 579 fi
 580 AC_MSG_RESULT([$enable_thread_safety])
 581 AC_SUBST(enable_thread_safety)
 582
 583 #
 584 # Optionally build Tcl modules (PL/Tcl)
 585 #
 586 AC_MSG_CHECKING([whether to build with Tcl])
 587 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 588 AC_MSG_RESULT([$with_tcl])
 589 AC_SUBST([with_tcl])
 590
 591 # We see if the path to the Tcl/Tk configuration scripts is specified.
 592 # This will override the use of tclsh to find the paths to search.
 593
 594 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 595
 596 #
 597 # Optionally build Perl modules (PL/Perl)
 598 #
 599 AC_MSG_CHECKING([whether to build Perl modules])
 600 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 601 AC_MSG_RESULT([$with_perl])
 602 AC_SUBST(with_perl)
 603
 604 #
 605 # Optionally build Python modules (PL/Python)
 606 #
 607 AC_MSG_CHECKING([whether to build Python modules])
 608 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 609 AC_MSG_RESULT([$with_python])
 610 AC_SUBST(with_python)
 611
 612 #
 613 # GSSAPI
 614 #
 615 AC_MSG_CHECKING([whether to build with GSSAPI support])
 616 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 617 [
 618   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 619   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 620 ])
 621 AC_MSG_RESULT([$with_gssapi])
 622
 623
 624 AC_SUBST(krb_srvtab)
 625
 626
 627 #
 628 # Kerberos configuration parameters
 629 #
 630 PGAC_ARG_REQ(with, krb-srvnam,
 631              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 632              [],
 633              [with_krb_srvnam="postgres"])
 634 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 635                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 636
 637
 638 #
 639 # PAM
 640 #
 641 AC_MSG_CHECKING([whether to build with PAM support])
 642 PGAC_ARG_BOOL(with, pam, no,
 643               [build with PAM support],
 644               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 645 AC_MSG_RESULT([$with_pam])
 646
 647
 648 #
 649 # LDAP
 650 #
 651 AC_MSG_CHECKING([whether to build with LDAP support])
 652 PGAC_ARG_BOOL(with, ldap, no,
 653               [build with LDAP support],
 654               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 655 AC_MSG_RESULT([$with_ldap])
 656
 657
 658 #
 659 # Bonjour
 660 #
 661 AC_MSG_CHECKING([whether to build with Bonjour support])
 662 PGAC_ARG_BOOL(with, bonjour, no,
 663               [build with Bonjour support],
 664               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 665 AC_MSG_RESULT([$with_bonjour])
 666
 667
 668 #
 669 # OpenSSL
 670 #
 671 AC_MSG_CHECKING([whether to build with OpenSSL support])
 672 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 673               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 674 AC_MSG_RESULT([$with_openssl])
 675 AC_SUBST(with_openssl)
 676
 677 #
 678 # SELinux
 679 #
 680 AC_MSG_CHECKING([whether to build with SELinux support])
 681 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 682 AC_SUBST(with_selinux)
 683 AC_MSG_RESULT([$with_selinux])
 684
 685 #
 686 # Readline
 687 #
 688 PGAC_ARG_BOOL(with, readline, yes,
 689               [do not use GNU Readline nor BSD Libedit for editing])
 690 # readline on MinGW has problems with backslashes in psql and other bugs.
 691 # This is particularly a problem with non-US code pages.
 692 # Therefore disable its use until we understand the cause. 2004-07-20
 693 if test "$PORTNAME" = "win32"; then
 694   if test "$with_readline" = yes; then
 695     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 696     with_readline=no
 697   fi
 698 fi
 699
 700
 701 #
 702 # Prefer libedit
 703 #
 704 PGAC_ARG_BOOL(with, libedit-preferred, no,
 705               [prefer BSD Libedit over GNU Readline])
 706
 707
 708 #
 709 # UUID library
 710 #
 711 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 712 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 713 # UUID library.  More than one of these might be present on a given platform,
 714 # so we make the user say which one she wants.
 715 #
 716 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 717 if test x"$with_uuid" = x"" ; then
 718   with_uuid=no
 719 fi
 720 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 721 if test "$with_ossp_uuid" = yes ; then
 722   with_uuid=ossp
 723 fi
 724
 725 if test "$with_uuid" = bsd ; then
 726   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 727   UUID_EXTRA_OBJS="md5.o sha1.o"
 728 elif test "$with_uuid" = e2fs ; then
 729   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 730   UUID_EXTRA_OBJS="md5.o sha1.o"
 731 elif test "$with_uuid" = ossp ; then
 732   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 733   UUID_EXTRA_OBJS=""
 734 elif test "$with_uuid" = no ; then
 735   UUID_EXTRA_OBJS=""
 736 else
 737   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 738 fi
 739 AC_SUBST(with_uuid)
 740 AC_SUBST(UUID_EXTRA_OBJS)
 741
 742
 743 #
 744 # XML
 745 #
 746 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 747               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 748
 749 if test "$with_libxml" = yes ; then
 750   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 751   if test -n "$XML2_CONFIG"; then
 752     for pgac_option in `$XML2_CONFIG --cflags`; do
 753       case $pgac_option in
 754         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 755       esac
 756     done
 757     for pgac_option in `$XML2_CONFIG --libs`; do
 758       case $pgac_option in
 759         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 760       esac
 761     done
 762   fi
 763 fi
 764
 765 AC_SUBST(with_libxml)
 766
 767 #
 768 # XSLT
 769 #
 770 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 771               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 772
 773
 774 AC_SUBST(with_libxslt)
 775
 776 #
 777 # tzdata
 778 #
 779 PGAC_ARG_REQ(with, system-tzdata,
 780              [DIR], [use system time zone data in DIR])
 781 AC_SUBST(with_system_tzdata)
 782
 783 #
 784 # Zlib
 785 #
 786 PGAC_ARG_BOOL(with, zlib, yes,
 787               [do not use Zlib])
 788 AC_SUBST(with_zlib)
 789
 790 #
 791 # Elf
 792 #
 793
 794 # Assume system is ELF if it predefines __ELF__ as 1,
 795 # otherwise believe host_os based default.
 796 case $host_os in
 797     freebsd1*|freebsd2*) elf=no;;
 798     freebsd3*|freebsd4*) elf=yes;;
 799 esac
 800
 801 AC_EGREP_CPP(yes,
 802 [#if __ELF__
 803   yes
 804 #endif
 805 ],
 806 [ELF_SYS=true],
 807 [if test "X$elf" = "Xyes" ; then
 808   ELF_SYS=true
 809 else
 810   ELF_SYS=
 811 fi])
 812 AC_SUBST(ELF_SYS)
 813
 814 #
 815 # Assignments
 816 #
 817
 818 CPPFLAGS="$CPPFLAGS $INCLUDES"
 819 LDFLAGS="$LDFLAGS $LIBDIRS"
 820
 821 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 822 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 823
 824 PGAC_PROG_LD
 825 AC_SUBST(LD)
 826 AC_SUBST(with_gnu_ld)
 827 case $host_os in sysv5*)
 828   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 829   [
 830     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 831     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 832     LDFLAGS=$pgac_save_LDFLAGS
 833   ])
 834   ld_R_works=$pgac_cv_prog_ld_R
 835   AC_SUBST(ld_R_works)
 836 esac
 837 AC_PROG_RANLIB
 838 PGAC_CHECK_STRIP
 839 AC_CHECK_TOOL(AR, ar, ar)
 840 if test "$PORTNAME" = "win32"; then
 841   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 842   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 843   AC_CHECK_TOOL(WINDRES, windres, windres)
 844 fi
 845
 846 AC_PROG_INSTALL
 847 # When Autoconf chooses install-sh as install program it tries to generate
 848 # a relative path to it in each makefile where it subsitutes it. This clashes
 849 # with our Makefile.global concept. This workaround helps.
 850 case $INSTALL in
 851   *install-sh*) install_bin='';;
 852   *) install_bin=$INSTALL;;
 853 esac
 854 AC_SUBST(install_bin)
 855
 856 AC_PATH_PROG(TAR, tar)
 857 AC_PROG_LN_S
 858 AC_PROG_AWK
 859 AC_PROG_MKDIR_P
 860 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 861 # a relative path to it in each makefile where it subsitutes it. This clashes
 862 # with our Makefile.global concept. This workaround helps.
 863 case $MKDIR_P in
 864   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 865 esac
 866
 867 PGAC_PATH_BISON
 868 PGAC_PATH_FLEX
 869
 870 PGAC_PATH_PERL
 871 if test "$with_perl" = yes; then
 872   if test -z "$PERL"; then
 873     AC_MSG_ERROR([Perl not found])
 874   fi
 875   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 876   PGAC_CHECK_PERL_EMBED_LDFLAGS
 877 fi
 878
 879 if test "$with_python" = yes; then
 880   PGAC_PATH_PYTHON
 881   PGAC_CHECK_PYTHON_EMBED_SETUP
 882 fi
 883
 884 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 885   AC_PATH_PROG(ZIC, zic)
 886   if test -z "$ZIC"; then
 887     AC_MSG_ERROR([
 888 When cross-compiling, either use the option --with-system-tzdata to use
 889 existing time-zone data, or set the environment variable ZIC to a zic
 890 program to use during the build.])
 891   fi
 892 fi
 893
 894
 895 ##
 896 ## Libraries
 897 ##
 898 ## Most libraries are included only if they demonstrably provide a function
 899 ## we need, but libm is an exception: always include it, because there are
 900 ## too many compilers that play cute optimization games that will break
 901 ## probes for standard functions such as pow().
 902 ##
 903
 904 AC_CHECK_LIB(m, main)
 905 AC_SEARCH_LIBS(setproctitle, util)
 906 AC_SEARCH_LIBS(dlopen, dl)
 907 AC_SEARCH_LIBS(socket, [socket ws2_32])
 908 AC_SEARCH_LIBS(shl_load, dld)
 909 # We only use libld in port/dynloader/aix.c
 910 case $host_os in
 911      aix*)
 912         AC_SEARCH_LIBS(ldopen, ld)
 913         ;;
 914 esac
 915 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 916 AC_SEARCH_LIBS(crypt, crypt)
 917 AC_SEARCH_LIBS(shm_open, rt)
 918 AC_SEARCH_LIBS(shm_unlink, rt)
 919 # Solaris:
 920 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 921 # Required for thread_test.c on Solaris 2.5:
 922 # Other ports use it too (HP-UX) so test unconditionally
 923 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 924 # Cygwin:
 925 AC_SEARCH_LIBS(shmget, cygipc)
 926
 927 if test "$with_readline" = yes; then
 928   PGAC_CHECK_READLINE
 929   if test x"$pgac_cv_check_readline" = x"no"; then
 930     AC_MSG_ERROR([readline library not found
 931 If you have readline already installed, see config.log for details on the
 932 failure.  It is possible the compiler isn't looking in the proper directory.
 933 Use --without-readline to disable readline support.])
 934   fi
 935 fi
 936
 937 if test "$with_zlib" = yes; then
 938   AC_CHECK_LIB(z, inflate, [],
 939                [AC_MSG_ERROR([zlib library not found
 940 If you have zlib already installed, see config.log for details on the
 941 failure.  It is possible the compiler isn't looking in the proper directory.
 942 Use --without-zlib to disable zlib support.])])
 943 fi
 944
 945 if test "$enable_spinlocks" = yes; then
 946   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 947 else
 948   AC_MSG_WARN([
 949 *** Not using spinlocks will cause poor performance.])
 950 fi
 951
 952 if test "$enable_atomics" = yes; then
 953   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
 954 else
 955   AC_MSG_WARN([
 956 *** Not using atomic operations will cause poor performance.])
 957 fi
 958
 959 if test "$with_gssapi" = yes ; then
 960   if test "$PORTNAME" != "win32"; then
 961     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 962                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 963   else
 964     LIBS="$LIBS -lgssapi32"
 965   fi
 966 fi
 967
 968 if test "$with_openssl" = yes ; then
 969   dnl Order matters!
 970   if test "$PORTNAME" != "win32"; then
 971      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 972      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 973   else
 974      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 975      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 976   fi
 977   AC_CHECK_FUNCS([SSL_get_current_compression])
 978 fi
 979
 980 if test "$with_pam" = yes ; then
 981   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 982 fi
 983
 984 if test "$with_libxml" = yes ; then
 985   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 986 fi
 987
 988 if test "$with_libxslt" = yes ; then
 989   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 990 fi
 991
 992 # for contrib/sepgsql
 993 if test "$with_selinux" = yes; then
 994   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 995                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 996 fi
 997
 998 # for contrib/uuid-ossp
 999 if test "$with_uuid" = bsd ; then
1000   # On BSD, the UUID functions are in libc
1001   AC_CHECK_FUNC(uuid_to_string,
1002     [UUID_LIBS=""],
1003     [AC_MSG_ERROR([BSD UUID functions are not present])])
1004 elif test "$with_uuid" = e2fs ; then
1005   # On OS X, the UUID functions are in libc
1006   AC_CHECK_FUNC(uuid_generate,
1007     [UUID_LIBS=""],
1008     [AC_CHECK_LIB(uuid, uuid_generate,
1009       [UUID_LIBS="-luuid"],
1010       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1011 elif test "$with_uuid" = ossp ; then
1012   AC_CHECK_LIB(ossp-uuid, uuid_export,
1013     [UUID_LIBS="-lossp-uuid"],
1014     [AC_CHECK_LIB(uuid, uuid_export,
1015       [UUID_LIBS="-luuid"],
1016       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1017 fi
1018 AC_SUBST(UUID_LIBS)
1019
1020
1021 ##
1022 ## Header files
1023 ##
1024
1025 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1026 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1027
1028 # On BSD, test for net/if.h will fail unless sys/socket.h
1029 # is included first.
1030 AC_CHECK_HEADERS(net/if.h, [], [],
1031 [AC_INCLUDES_DEFAULT
1032 #ifdef HAVE_SYS_SOCKET_H
1033 #include <sys/socket.h>
1034 #endif
1035 ])
1036
1037 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1038 # is included first.
1039 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1040 [AC_INCLUDES_DEFAULT
1041 #include <sys/param.h>
1042 ])
1043
1044 # At least on IRIX, test for netinet/tcp.h will fail unless
1045 # netinet/in.h is included first.
1046 AC_CHECK_HEADERS(netinet/in.h)
1047 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1048 [AC_INCLUDES_DEFAULT
1049 #ifdef HAVE_NETINET_IN_H
1050 #include <netinet/in.h>
1051 #endif
1052 ])
1053
1054 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1055   AC_CHECK_HEADERS(readline/readline.h, [],
1056         [AC_CHECK_HEADERS(readline.h, [],
1057                 [AC_MSG_ERROR([readline header not found
1058 If you have readline already installed, see config.log for details on the
1059 failure.  It is possible the compiler isn't looking in the proper directory.
1060 Use --without-readline to disable readline support.])])])
1061   AC_CHECK_HEADERS(readline/history.h, [],
1062         [AC_CHECK_HEADERS(history.h, [],
1063                 [AC_MSG_ERROR([history header not found
1064 If you have readline already installed, see config.log for details on the
1065 failure.  It is possible the compiler isn't looking in the proper directory.
1066 Use --without-readline to disable readline support.])])])
1067 fi
1068
1069 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1070 # Some installations of libedit usurp /usr/include/readline/, which seems
1071 # bad practice, since in combined installations readline will have its headers
1072 # there.  We might have to resort to AC_EGREP checks to make sure we found
1073 # the proper header...
1074   AC_CHECK_HEADERS(editline/readline.h, [],
1075         [AC_CHECK_HEADERS(readline.h, [],
1076                 [AC_CHECK_HEADERS(readline/readline.h, [],
1077                         [AC_MSG_ERROR([readline header not found
1078 If you have libedit already installed, see config.log for details on the
1079 failure.  It is possible the compiler isn't looking in the proper directory.
1080 Use --without-readline to disable libedit support.])])])])
1081 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1082 # not be there at all.  Hence, don't complain if not found.  We must check
1083 # though, since in yet other versions it is an independent header.
1084   AC_CHECK_HEADERS(editline/history.h, [],
1085         [AC_CHECK_HEADERS(history.h, [],
1086                 [AC_CHECK_HEADERS(readline/history.h)])])
1087 fi
1088
1089 if test "$with_zlib" = yes; then
1090   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1091 If you have zlib already installed, see config.log for details on the
1092 failure.  It is possible the compiler isn't looking in the proper directory.
1093 Use --without-zlib to disable zlib support.])])
1094 fi
1095
1096 if test "$with_gssapi" = yes ; then
1097   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1098         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1099 fi
1100
1101 if test "$with_openssl" = yes ; then
1102   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1103   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1104 fi
1105
1106 if test "$with_pam" = yes ; then
1107   AC_CHECK_HEADERS(security/pam_appl.h, [],
1108                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1109                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1110 fi
1111
1112 if test "$with_libxml" = yes ; then
1113   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1114 fi
1115
1116 if test "$with_libxslt" = yes ; then
1117   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1118 fi
1119
1120 if test "$with_ldap" = yes ; then
1121   if test "$PORTNAME" != "win32"; then
1122      AC_CHECK_HEADERS(ldap.h, [],
1123                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1124      PGAC_LDAP_SAFE
1125   else
1126      AC_CHECK_HEADERS(winldap.h, [],
1127                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1128                       [AC_INCLUDES_DEFAULT
1129 #include <windows.h>
1130                       ])
1131   fi
1132 fi
1133
1134 if test "$with_bonjour" = yes ; then
1135   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1136 fi
1137
1138 # for contrib/uuid-ossp
1139 if test "$with_uuid" = bsd ; then
1140   AC_CHECK_HEADERS(uuid.h,
1141     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1142       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1143     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1144 elif test "$with_uuid" = e2fs ; then
1145   AC_CHECK_HEADERS(uuid/uuid.h,
1146     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1147       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1148     [AC_CHECK_HEADERS(uuid.h,
1149       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1150         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1151       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1152 elif test "$with_uuid" = ossp ; then
1153   AC_CHECK_HEADERS(ossp/uuid.h,
1154     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1155       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1156     [AC_CHECK_HEADERS(uuid.h,
1157       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1158         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1159       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1160 fi
1161
1162 if test "$PORTNAME" = "win32" ; then
1163    AC_CHECK_HEADERS(crtdefs.h)
1164 fi
1165
1166 ##
1167 ## Types, structures, compiler characteristics
1168 ##
1169
1170 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1171 AC_C_BIGENDIAN
1172 PGAC_C_INLINE
1173 PGAC_PRINTF_ARCHETYPE
1174 AC_C_FLEXIBLE_ARRAY_MEMBER
1175 PGAC_C_SIGNED
1176 PGAC_C_FUNCNAME_SUPPORT
1177 PGAC_C_STATIC_ASSERT
1178 PGAC_C_TYPES_COMPATIBLE
1179 PGAC_C_BUILTIN_CONSTANT_P
1180 PGAC_C_BUILTIN_UNREACHABLE
1181 PGAC_C_VA_ARGS
1182 PGAC_STRUCT_TIMEZONE
1183 PGAC_UNION_SEMUN
1184 PGAC_STRUCT_SOCKADDR_UN
1185 PGAC_STRUCT_SOCKADDR_STORAGE
1186 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1187 PGAC_STRUCT_ADDRINFO
1188 AC_TYPE_INTPTR_T
1189 AC_TYPE_UINTPTR_T
1190 AC_TYPE_LONG_LONG_INT
1191
1192 PGAC_TYPE_LOCALE_T
1193
1194 AC_CHECK_TYPES([struct cmsgcred], [], [],
1195 [#include <sys/socket.h>
1196 #include <sys/param.h>
1197 #ifdef HAVE_SYS_UCRED_H
1198 #include <sys/ucred.h>
1199 #endif])
1200
1201 AC_CHECK_TYPES([struct option], [], [],
1202 [#ifdef HAVE_GETOPT_H
1203 #include <getopt.h>
1204 #endif])
1205
1206 if test "$with_zlib" = yes; then
1207   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1208   # did not).  While we could work around the lack of z_streamp, it
1209   # seems unwise to encourage people to use such old zlib versions...
1210   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1211 Use --without-zlib to disable zlib support.])],
1212                 [#include <zlib.h>])
1213 fi
1214
1215 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1216 case $host_cpu in
1217   ppc*|powerpc*)
1218     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1219     AC_TRY_COMPILE([],
1220         [int a = 0; int *p = &a; int r;
1221          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1222         [pgac_cv_have_ppc_mutex_hint=yes],
1223         [pgac_cv_have_ppc_mutex_hint=no])
1224     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1225     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1226         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1227     fi
1228   ;;
1229 esac
1230
1231 # Check largefile support.  You might think this is a system service not a
1232 # compiler characteristic, but you'd be wrong.  We must check this before
1233 # probing existence of related functions such as fseeko, since the largefile
1234 # defines can affect what is generated for that.
1235 if test "$PORTNAME" != "win32"; then
1236    AC_SYS_LARGEFILE
1237    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1238    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1239    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1240    dnl versions where the feature actually works, it's on by default anyway.
1241    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1242 fi
1243
1244 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1245 AC_CHECK_SIZEOF([off_t])
1246
1247 # If we don't have largefile support, can't handle segsize >= 2GB.
1248 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1249    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1250 fi
1251
1252
1253 ##
1254 ## Functions, global variables
1255 ##
1256
1257 PGAC_VAR_INT_TIMEZONE
1258 AC_FUNC_ACCEPT_ARGTYPES
1259 PGAC_FUNC_GETTIMEOFDAY_1ARG
1260
1261 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1262 # symbols that that library has no business exposing to the world.  Pending
1263 # acquisition of a clue by those developers, ignore libedit (including its
1264 # possible alias of libreadline) while checking for everything else.
1265 LIBS_including_readline="$LIBS"
1266 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1267
1268 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1269
1270 AC_REPLACE_FUNCS(fseeko)
1271 case $host_os in
1272         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1273         # Mingw uses macros to access Win32 API calls
1274         netbsd*|mingw*)
1275                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1276                 ac_cv_func_fseeko=yes;;
1277         *)
1278                 AC_FUNC_FSEEKO;;
1279 esac
1280
1281 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1282 # by calling it, 2009-04-02
1283 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1284 if test "$PORTNAME" != "solaris"; then
1285 AC_CHECK_FUNCS(posix_fadvise)
1286 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1287 fi
1288
1289 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1290 AC_CHECK_DECLS([strlcat, strlcpy])
1291 # This is probably only present on Darwin, but may as well check always
1292 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1293
1294 HAVE_IPV6=no
1295 AC_CHECK_TYPE([struct sockaddr_in6],
1296         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1297          HAVE_IPV6=yes],
1298         [],
1299 [$ac_includes_default
1300 #include <netinet/in.h>])
1301 AC_SUBST(HAVE_IPV6)
1302
1303 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1304 [AC_TRY_LINK(
1305 [#include <machine/vmparam.h>
1306 #include <sys/exec.h>
1307 ],
1308 [PS_STRINGS->ps_nargvstr = 1;
1309 PS_STRINGS->ps_argvstr = "foo";],
1310 [pgac_cv_var_PS_STRINGS=yes],
1311 [pgac_cv_var_PS_STRINGS=no])])
1312 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1313   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1314 fi
1315
1316
1317 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1318 # is missing.  Yes, there are machines that have only one.  We may
1319 # also decide to use snprintf.c if snprintf() is present but does not
1320 # have all the features we need --- see below.
1321
1322 if test "$PORTNAME" = "win32"; then
1323   # Win32 gets snprintf.c built unconditionally.
1324   #
1325   # To properly translate all NLS languages strings, we must support the
1326   # *printf() %$ format, which allows *printf() arguments to be selected
1327   # by position in the translated string.
1328   #
1329   # libintl versions < 0.13 use the native *printf() functions, and Win32
1330   # *printf() doesn't understand %$, so we must use our /port versions,
1331   # which do understand %$. libintl versions >= 0.13 include their own
1332   # *printf versions on Win32.  The libintl 0.13 release note text is:
1333   #
1334   #   C format strings with positions, as they arise when a translator
1335   #   needs to reorder a sentence, are now supported on all platforms.
1336   #   On those few platforms (NetBSD and Woe32) for which the native
1337   #   printf()/fprintf()/... functions don't support such format
1338   #   strings, replacements are provided through <libintl.h>.
1339   #
1340   # We could use libintl >= 0.13's *printf() if we were sure that we had
1341   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1342   # to guarantee that, it is best to just use our own, so we are sure to
1343   # get %$ support. In include/port.h we disable the *printf() macros
1344   # that might have been defined by libintl.
1345   #
1346   # We do this unconditionally whether NLS is used or not so we are sure
1347   # that all Win32 libraries and binaries behave the same.
1348   pgac_need_repl_snprintf=yes
1349 else
1350   pgac_need_repl_snprintf=no
1351   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1352   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1353 fi
1354
1355
1356 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1357 # include/c.h will provide declarations.  Note this is a separate test
1358 # from whether the functions exist in the C library --- there are
1359 # systems that have the functions but don't bother to declare them :-(
1360
1361 AC_CHECK_DECLS([snprintf, vsnprintf])
1362
1363
1364 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1365 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1366 [AC_TRY_LINK([
1367 #include <math.h>
1368 double glob_double;
1369 ],
1370 [return isinf(glob_double) ? 0 : 1;],
1371 [ac_cv_func_isinf=yes],
1372 [ac_cv_func_isinf=no])])
1373
1374 if test $ac_cv_func_isinf = yes ; then
1375   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1376 else
1377   AC_LIBOBJ(isinf)
1378   # Look for a way to implement a substitute for isinf()
1379   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1380 fi
1381
1382 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1383
1384 case $host_os in
1385
1386         # Windows uses a specialised env handler
1387         # and doesn't need a replacement getpeereid because it doesn't use
1388         # Unix sockets.
1389         mingw*)
1390                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1391                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1392                 ac_cv_func_unsetenv=yes
1393                 ac_cv_func_getpeereid=yes;;
1394         *)
1395                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1396                 ;;
1397 esac
1398
1399 # System's version of getaddrinfo(), if any, may be used only if we found
1400 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1401 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1402 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1403    test "$PORTNAME" != "win32"; then
1404   AC_REPLACE_FUNCS([getaddrinfo])
1405 else
1406   AC_LIBOBJ(getaddrinfo)
1407 fi
1408
1409 # Similarly, use system's getopt_long() only if system provides struct option.
1410 if test x"$ac_cv_type_struct_option" = xyes ; then
1411   AC_REPLACE_FUNCS([getopt_long])
1412 else
1413   AC_LIBOBJ(getopt_long)
1414 fi
1415
1416 # Solaris' getopt() doesn't do what we want for long options, so always use
1417 # our version on that platform.
1418 if test "$PORTNAME" = "solaris"; then
1419   AC_LIBOBJ(getopt)
1420 fi
1421
1422 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1423 # so always use our version on Windows.
1424 if test "$PORTNAME" = "win32"; then
1425   AC_LIBOBJ(getopt)
1426   AC_LIBOBJ(getopt_long)
1427 fi
1428
1429 # Win32 support
1430 if test "$PORTNAME" = "win32"; then
1431   AC_REPLACE_FUNCS(gettimeofday)
1432   AC_LIBOBJ(kill)
1433   AC_LIBOBJ(open)
1434   AC_LIBOBJ(system)
1435   AC_LIBOBJ(win32env)
1436   AC_LIBOBJ(win32error)
1437   AC_LIBOBJ(win32setlocale)
1438   AC_DEFINE([HAVE_SYMLINK], 1,
1439             [Define to 1 if you have the `symlink' function.])
1440   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1441 #define WIN32_LEAN_AND_MEAN
1442 #include <windows.h>
1443 #include <string.h>
1444 #include <dbghelp.h>])
1445 fi
1446 if test x"$pgac_minidump_type" = x"yes" ; then
1447   AC_SUBST(have_win32_dbghelp,yes)
1448 else
1449   AC_SUBST(have_win32_dbghelp,no)
1450 fi
1451
1452 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1453 dnl (especially on GNU libc)
1454 dnl See also comments in c.h.
1455 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1456 [AC_TRY_LINK([#include <setjmp.h>],
1457             [sigjmp_buf x; sigsetjmp(x, 1);],
1458             [pgac_cv_func_sigsetjmp=yes],
1459             [pgac_cv_func_sigsetjmp=no])])
1460 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1461   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1462 fi
1463
1464 AC_DECL_SYS_SIGLIST
1465
1466 AC_CHECK_FUNC(syslog,
1467               [AC_CHECK_HEADER(syslog.h,
1468                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1469
1470 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1471 [AC_TRY_LINK([#include <unistd.h>],
1472   [extern int opterr; opterr = 1;],
1473   [pgac_cv_var_int_opterr=yes],
1474   [pgac_cv_var_int_opterr=no])])
1475 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1476   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1477 fi
1478
1479 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1480 [AC_TRY_LINK([#include <unistd.h>],
1481   [extern int optreset; optreset = 1;],
1482   [pgac_cv_var_int_optreset=yes],
1483   [pgac_cv_var_int_optreset=no])])
1484 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1485   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1486 fi
1487
1488 AC_CHECK_FUNCS([strtoll strtoq], [break])
1489 AC_CHECK_FUNCS([strtoull strtouq], [break])
1490
1491 # Lastly, restore full LIBS list and check for readline/libedit symbols
1492 LIBS="$LIBS_including_readline"
1493
1494 if test "$with_readline" = yes; then
1495   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1496   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1497   AC_CHECK_FUNCS([append_history history_truncate_file])
1498 fi
1499
1500
1501 #
1502 # Pthreads
1503 #
1504 # For each platform, we need to know about any special compile and link
1505 # libraries, and whether the normal C function names are thread-safe.
1506 # See the comment at the top of src/port/thread.c for more information.
1507 # WIN32 doesn't need the pthread tests;  it always uses threads
1508 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1509 ACX_PTHREAD     # set thread flags
1510
1511 # Some platforms use these, so just define them.  They can't hurt if they
1512 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1513 # enables 5-arg getpwuid_r, among other things.
1514 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1515
1516 # Check for *_r functions
1517 _CFLAGS="$CFLAGS"
1518 _LIBS="$LIBS"
1519 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1520 LIBS="$LIBS $PTHREAD_LIBS"
1521
1522 if test "$PORTNAME" != "win32"; then
1523 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1524 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1525 fi
1526
1527 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1528
1529 # Do test here with the proper thread flags
1530 PGAC_FUNC_GETPWUID_R_5ARG
1531 PGAC_FUNC_STRERROR_R_INT
1532
1533 CFLAGS="$_CFLAGS"
1534 LIBS="$_LIBS"
1535
1536 else
1537 # do not use values from template file
1538 PTHREAD_CFLAGS=
1539 PTHREAD_LIBS=
1540 fi
1541
1542 AC_SUBST(PTHREAD_CFLAGS)
1543 AC_SUBST(PTHREAD_LIBS)
1544
1545
1546 # We can test for libldap_r only after we know PTHREAD_LIBS
1547 if test "$with_ldap" = yes ; then
1548   _LIBS="$LIBS"
1549   if test "$PORTNAME" != "win32"; then
1550     AC_CHECK_LIB(ldap, ldap_bind, [],
1551                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1552                  [$EXTRA_LDAP_LIBS])
1553     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1554     if test "$enable_thread_safety" = yes; then
1555       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1556       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1557                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1558                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1559       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1560     else
1561       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1562     fi
1563   else
1564     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1565     LDAP_LIBS_FE="-lwldap32"
1566     LDAP_LIBS_BE="-lwldap32"
1567   fi
1568   LIBS="$_LIBS"
1569 fi
1570 AC_SUBST(LDAP_LIBS_FE)
1571 AC_SUBST(LDAP_LIBS_BE)
1572
1573
1574 # This test makes sure that run tests work at all.  Sometimes a shared
1575 # library is found by the linker, but the runtime linker can't find it.
1576 # This check should come after all modifications of compiler or linker
1577 # variables, and before any other run tests.
1578 AC_MSG_CHECKING([test program])
1579 AC_TRY_RUN([int main() { return 0; }],
1580 [AC_MSG_RESULT(ok)],
1581 [AC_MSG_RESULT(failed)
1582 AC_MSG_ERROR([[
1583 Could not execute a simple test program.  This may be a problem
1584 related to locating shared libraries.  Check the file 'config.log'
1585 for the exact reason.]])],
1586 [AC_MSG_RESULT([cross-compiling])])
1587
1588 # --------------------
1589 # Run tests below here
1590 # --------------------
1591
1592 # Force use of our snprintf if system's doesn't do arg control
1593 # See comment above at snprintf test for details.
1594 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1595   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1596   if test $pgac_cv_snprintf_arg_control != yes ; then
1597     pgac_need_repl_snprintf=yes
1598   fi
1599 fi
1600
1601
1602 dnl Check to see if we have a working 64-bit integer type.
1603 dnl This breaks down into two steps:
1604 dnl (1) figure out if the compiler has a 64-bit int type with working
1605 dnl arithmetic, and if so
1606 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1607 dnl snprintf is the only library routine we really need for int8 support.)
1608 dnl It's entirely possible to have a compiler that handles a 64-bit type
1609 dnl when the C library doesn't; this is fairly likely when using gcc on
1610 dnl an older platform, for example.
1611 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1612 dnl we force our own version of snprintf() to be used instead.
1613 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1614
1615 dnl As of Postgres 8.4, we no longer support compilers without a working
1616 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1617
1618 PGAC_TYPE_64BIT_INT([long int])
1619
1620 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1621   pg_int64_type="long int"
1622 else
1623   PGAC_TYPE_64BIT_INT([long long int])
1624   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1625     pg_int64_type="long long int"
1626   else
1627     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1628   fi
1629 fi
1630
1631 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1632   [Define to the name of a signed 64-bit integer type.])
1633
1634 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1635
1636 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1637   AC_TRY_COMPILE([
1638 #define INT64CONST(x)  x##LL
1639 long long int foo = INT64CONST(0x1234567890123456);
1640 ],
1641         [],
1642         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1643         [])
1644 fi
1645
1646
1647 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1648 # we found we need to use "long long int", better check.  We cope with
1649 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1650 # work, fall back to our own snprintf emulation (which we know uses %lld).
1651
1652 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1653   if test $pgac_need_repl_snprintf = no; then
1654     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1655     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1656       # Force usage of our own snprintf, since system snprintf is broken
1657       pgac_need_repl_snprintf=yes
1658       LONG_LONG_INT_MODIFIER='ll'
1659     fi
1660   else
1661     # Here if we previously decided we needed to use our own snprintf
1662     LONG_LONG_INT_MODIFIER='ll'
1663   fi
1664 else
1665   # Here if we are not using 'long long int' at all
1666   LONG_LONG_INT_MODIFIER='l'
1667 fi
1668
1669 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1670
1671 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1672                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1673
1674 # Also force use of our snprintf if the system's doesn't support the %z flag.
1675 if test "$pgac_need_repl_snprintf" = no; then
1676   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1677   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1678     pgac_need_repl_snprintf=yes
1679   fi
1680 fi
1681
1682 # Now we have checked all the reasons to replace snprintf
1683 if test $pgac_need_repl_snprintf = yes; then
1684   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1685   AC_LIBOBJ(snprintf)
1686 fi
1687
1688 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1689 AC_CHECK_SIZEOF([void *])
1690 AC_CHECK_SIZEOF([size_t])
1691 AC_CHECK_SIZEOF([long])
1692
1693 # Decide whether float4 is passed by value: user-selectable, enabled by default
1694 AC_MSG_CHECKING([whether to build with float4 passed by value])
1695 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1696               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1697                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1698                float4passbyval=true],
1699               [float4passbyval=false])
1700 AC_MSG_RESULT([$enable_float4_byval])
1701 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1702
1703 # Decide whether float8 is passed by value.
1704 # Note: this setting also controls int8 and related types such as timestamp.
1705 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1706 # If not, trying to select it is an error.
1707 AC_MSG_CHECKING([whether to build with float8 passed by value])
1708 if test $ac_cv_sizeof_void_p -ge 8 ; then
1709   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1710 else
1711   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1712   if test "$enable_float8_byval" = yes ; then
1713     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1714   fi
1715 fi
1716 if test "$enable_float8_byval" = yes ; then
1717   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1718             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1719   float8passbyval=true
1720 else
1721   float8passbyval=false
1722 fi
1723 AC_MSG_RESULT([$enable_float8_byval])
1724 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1725
1726 # Determine memory alignment requirements for the basic C data types.
1727
1728 AC_CHECK_ALIGNOF(short)
1729 AC_CHECK_ALIGNOF(int)
1730 AC_CHECK_ALIGNOF(long)
1731 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1732   AC_CHECK_ALIGNOF(long long int)
1733 fi
1734 AC_CHECK_ALIGNOF(double)
1735
1736 # Compute maximum alignment of any basic type.
1737 # We assume long's alignment is at least as strong as char, short, or int;
1738 # but we must check long long (if it exists) and double.
1739
1740 MAX_ALIGNOF=$ac_cv_alignof_long
1741 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1742   MAX_ALIGNOF=$ac_cv_alignof_double
1743 fi
1744 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1745   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1746 fi
1747 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1748
1749
1750 # Some platforms predefine the types int8, int16, etc.  Only check
1751 # a (hopefully) representative subset.
1752 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1753 [#include <stdio.h>])
1754
1755 # We also check for sig_atomic_t, which *should* be defined per ANSI
1756 # C, but is missing on some old platforms.
1757 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1758
1759 # Check for various atomic operations now that we have checked how to declare
1760 # 64bit integers.
1761 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1762 PGAC_HAVE_GCC__SYNC_INT32_TAS
1763 PGAC_HAVE_GCC__SYNC_INT32_CAS
1764 PGAC_HAVE_GCC__SYNC_INT64_CAS
1765 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1766 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1767
1768 if test "$PORTNAME" != "win32"
1769 then
1770 PGAC_FUNC_POSIX_SIGNALS
1771 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1772   AC_MSG_ERROR([
1773 Thread-safety requires POSIX signals, which are not supported by this
1774 operating system;  use --disable-thread-safety to disable thread safety.])
1775 fi
1776 fi
1777
1778
1779 # Select semaphore implementation type.
1780 if test "$PORTNAME" != "win32"; then
1781   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1782     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1783     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1784   else
1785     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1786       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1787       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1788     else
1789       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1790       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1791     fi
1792   fi
1793 else
1794   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1795   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1796 fi
1797
1798
1799 # Select shared-memory implementation type.
1800 if test "$PORTNAME" != "win32"; then
1801   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1802   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1803 else
1804   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1805   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1806 fi
1807
1808 # Select latch implementation type.
1809 if test "$PORTNAME" != "win32"; then
1810   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1811 else
1812   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1813 fi
1814
1815 # If not set in template file, set bytes to use libc memset()
1816 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1817   MEMSET_LOOP_LIMIT=1024
1818 fi
1819 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1820
1821
1822 if test "$enable_nls" = yes ; then
1823   PGAC_CHECK_GETTEXT
1824 fi
1825
1826 # Check for Tcl configuration script tclConfig.sh
1827 if test "$with_tcl" = yes; then
1828     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1829     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1830                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1831     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1832     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1833     ac_save_CPPFLAGS=$CPPFLAGS
1834     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1835     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1836     CPPFLAGS=$ac_save_CPPFLAGS
1837 fi
1838
1839 # check for <perl.h>
1840 if test "$with_perl" = yes; then
1841   ac_save_CPPFLAGS=$CPPFLAGS
1842   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1843   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1844                   [#include <EXTERN.h>])
1845   # While we're at it, check that we can link to libperl.
1846   # On most platforms, if perl.h is there then libperl.so will be too, but at
1847   # this writing Debian packages them separately.  There is no known reason to
1848   # waste cycles on separate probes for the Tcl or Python libraries, though.
1849   pgac_save_LIBS=$LIBS
1850   LIBS="$perl_embed_ldflags"
1851   AC_MSG_CHECKING([for libperl])
1852   AC_TRY_LINK([
1853 #include <EXTERN.h>
1854 #include <perl.h>
1855 ],  [perl_alloc();],
1856     [AC_MSG_RESULT(yes)],
1857     [AC_MSG_RESULT(no)
1858      AC_MSG_ERROR([libperl library is required for Perl])])
1859   LIBS=$pgac_save_LIBS
1860   CPPFLAGS=$ac_save_CPPFLAGS
1861 fi
1862
1863 # check for <Python.h>
1864 if test "$with_python" = yes; then
1865   ac_save_CPPFLAGS=$CPPFLAGS
1866   CPPFLAGS="$python_includespec $CPPFLAGS"
1867   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1868   CPPFLAGS=$ac_save_CPPFLAGS
1869 fi
1870
1871 #
1872 # Check for DocBook and tools
1873 #
1874 PGAC_PROG_NSGMLS
1875 PGAC_PROG_JADE
1876 PGAC_CHECK_DOCBOOK(4.2)
1877 PGAC_PATH_DOCBOOK_STYLESHEETS
1878 PGAC_PATH_COLLATEINDEX
1879 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
1880 AC_CHECK_PROGS(XMLLINT, xmllint)
1881 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1882 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1883
1884 #
1885 # Check for test tools
1886 #
1887 if test "$enable_tap_tests" = yes; then
1888   AC_CHECK_PROGS(PROVE, prove)
1889   if test -z "$PROVE"; then
1890     AC_MSG_ERROR([prove not found])
1891   fi
1892   if test -z "$PERL"; then
1893     AC_MSG_ERROR([Perl not found])
1894   fi
1895 fi
1896
1897 # Thread testing
1898
1899 # We have to run the thread test near the end so we have all our symbols
1900 # defined.  Cross compiling throws a warning.
1901 #
1902 if test "$enable_thread_safety" = yes; then
1903 if test "$PORTNAME" != "win32"
1904 then
1905 AC_MSG_CHECKING([thread safety of required library functions])
1906
1907 _CFLAGS="$CFLAGS"
1908 _LIBS="$LIBS"
1909 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1910 LIBS="$LIBS $PTHREAD_LIBS"
1911 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1912   [AC_MSG_RESULT(yes)],
1913   [AC_MSG_RESULT(no)
1914   AC_MSG_ERROR([thread test program failed
1915 This platform is not thread-safe.  Check the file 'config.log' or compile
1916 and run src/test/thread/thread_test for the exact reason.
1917 Use --disable-thread-safety to disable thread safety.])],
1918   [AC_MSG_RESULT(maybe)
1919   AC_MSG_WARN([
1920 *** Skipping thread test program because of cross-compile build.
1921 *** Run the program in src/test/thread on the target machine.
1922 ])])
1923 CFLAGS="$_CFLAGS"
1924 LIBS="$_LIBS"
1925 else
1926 AC_MSG_WARN([*** skipping thread test on Win32])
1927 fi
1928 fi
1929
1930 # If compiler will take -Wl,--as-needed (or various platform-specific
1931 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1932 # trying to filter LIBS to the minimum for each executable.
1933 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1934 # libreadline; therefore we postpone testing it until we know what library
1935 # dependencies readline has.  The test code will try to link with $LIBS.
1936 if test "$with_readline" = yes; then
1937   link_test_func=readline
1938 else
1939   link_test_func=exit
1940 fi
1941
1942 if test "$PORTNAME" = "darwin"; then
1943   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1944 elif test "$PORTNAME" = "openbsd"; then
1945   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1946 else
1947   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1948 fi
1949
1950 # Create compiler version string
1951 if test x"$GCC" = x"yes" ; then
1952   cc_string=`${CC} --version | sed q`
1953   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1954 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1955   cc_string=`${CC} -V 2>&1 | sed q`
1956 else
1957   cc_string=$CC
1958 fi
1959
1960 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1961                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1962                    [A string containing the version number, platform, and C compiler])
1963
1964 # Supply a numeric version string for use by 3rd party add-ons
1965 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1966 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1967 tr '.' '        ' |
1968 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1969 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1970
1971
1972 # Begin output steps
1973
1974 AC_MSG_NOTICE([using compiler=$cc_string])
1975 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1976 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1977 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1978
1979 # prepare build tree if outside source tree
1980 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1981 # Note 2: /bin/pwd might be better than shell's built-in at getting
1982 #         a symlink-free name.
1983 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1984   vpath_build=no
1985 else
1986   vpath_build=yes
1987   if test "$no_create" != yes; then
1988     _AS_ECHO_N([preparing build tree... ])
1989     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1990     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1991       || AC_MSG_ERROR(failed)
1992     AC_MSG_RESULT(done)
1993   fi
1994 fi
1995 AC_SUBST(vpath_build)
1996
1997
1998 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1999
2000 AC_CONFIG_LINKS([
2001   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2002   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2003   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2004   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2005   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2006   src/include/pg_config_os.h:src/include/port/${template}.h
2007   src/Makefile.port:src/makefiles/Makefile.${template}
2008 ])
2009
2010 if test "$PORTNAME" = "win32"; then
2011 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2012 # Links sometimes fail undetected on Mingw -
2013 # so here we detect it and warn the user
2014 for FILE in $CONFIG_LINKS
2015  do
2016         # test -e works for symlinks in the MinGW console
2017         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2018  done
2019 ])
2020 fi
2021
2022 AC_CONFIG_HEADERS([src/include/pg_config.h],
2023 [
2024 # Update timestamp for pg_config.h (see Makefile.global)
2025 echo >src/include/stamp-h
2026 ])
2027
2028 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2029 [
2030 # Update timestamp for pg_config_ext.h (see Makefile.global)
2031 echo >src/include/stamp-ext-h
2032 ])
2033
2034 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2035                   [echo >src/interfaces/ecpg/include/stamp-h])
2036
2037 AC_OUTPUT