granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.6devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2016, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif])], [ICC=yes], [ICC=no])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # CFLAGS we determined above will be added back at the end
 418 user_CFLAGS=$CFLAGS
 419 CFLAGS=""
 420
 421 # set CFLAGS_VECTOR from the environment, if available
 422 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 423   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 424 fi
 425
 426 # Some versions of GCC support some additional useful warning flags.
 427 # Check whether they are supported, and add them to CFLAGS if so.
 428 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 429 # but has its own.  Also check other compiler-specific flags here.
 430
 431 if test "$GCC" = yes -a "$ICC" = no; then
 432   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 433   # These work in some but not all gcc versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 436   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 437   # This was included in -Wall/-Wformat in older GCC versions
 438   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 439   # Disable strict-aliasing rules; needed for gcc 3.3+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 442   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 443   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 444   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 445   # Optimization flags for specific files that benefit from vectorization
 446   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 447   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 448   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 449   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 450   # test for the positive form and if that works, add the negative form
 451   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 452   if test -n "$NOT_THE_CFLAGS"; then
 453     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 454   fi
 455 elif test "$ICC" = yes; then
 456   # Intel's compiler has a bug/misoptimization in checking for
 457   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 458   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 459   # Make sure strict aliasing is off (though this is said to be the default)
 460   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 461 elif test "$PORTNAME" = "aix"; then
 462   # AIX's xlc has to have strict aliasing turned off too
 463   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 464   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 465 elif test "$PORTNAME" = "hpux"; then
 466   # On some versions of HP-UX, libm functions do not set errno by default.
 467   # Fix that by using +Olibmerrno if the compiler recognizes it.
 468   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 469 fi
 470
 471 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 472
 473 # supply -g if --enable-debug
 474 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 475   CFLAGS="$CFLAGS -g"
 476 fi
 477
 478 # enable code coverage if --enable-coverage
 479 if test "$enable_coverage" = yes; then
 480   if test "$GCC" = yes; then
 481     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 482   else
 483     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # enable profiling if --enable-profiling
 488 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 489   if test "$GCC" = yes; then
 490     AC_DEFINE([PROFILE_PID_DIR], 1,
 491            [Define to 1 to allow profiling output to be saved separately for each process.])
 492     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 493   else
 494     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 495   fi
 496 fi
 497
 498 # We already have this in Makefile.win32, but configure needs it too
 499 if test "$PORTNAME" = "win32"; then
 500   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 501 fi
 502
 503 # Now that we're done automatically adding stuff to CFLAGS, put back the
 504 # user-specified flags (if any) at the end.  This lets users override
 505 # the automatic additions.
 506 CFLAGS="$CFLAGS $user_CFLAGS"
 507
 508 # Check if the compiler still works with the final flag settings
 509 AC_MSG_CHECKING([whether the C compiler still works])
 510 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 511   [AC_MSG_RESULT(yes)],
 512   [AC_MSG_RESULT(no)
 513    AC_MSG_ERROR([cannot proceed])])
 514
 515 # Defend against gcc -ffast-math
 516 if test "$GCC" = yes; then
 517 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 518 choke me
 519 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 520 fi
 521
 522 AC_PROG_CPP
 523 AC_SUBST(GCC)
 524
 525
 526 #
 527 # Set up TAS assembly code if needed; the template file has now had its
 528 # chance to request this.
 529 #
 530 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 531
 532 if test "$need_tas" = yes ; then
 533   TAS=tas.o
 534 else
 535   TAS=""
 536 fi
 537 AC_SUBST(TAS)
 538
 539
 540 #
 541 # Automatic dependency tracking
 542 #
 543 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 544               [autodepend=yes])
 545 AC_SUBST(autodepend)
 546
 547
 548 #
 549 # Enable assert checks
 550 #
 551 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 552               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 553                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 554
 555
 556 #
 557 # Include directories
 558 #
 559 ac_save_IFS=$IFS
 560 IFS="${IFS}${PATH_SEPARATOR}"
 561 # SRCH_INC comes from the template file
 562 for dir in $with_includes $SRCH_INC; do
 563   if test -d "$dir"; then
 564     INCLUDES="$INCLUDES -I$dir"
 565   else
 566     AC_MSG_WARN([*** Include directory $dir does not exist.])
 567   fi
 568 done
 569 IFS=$ac_save_IFS
 570 AC_SUBST(INCLUDES)
 571
 572
 573 #
 574 # Library directories
 575 #
 576 ac_save_IFS=$IFS
 577 IFS="${IFS}${PATH_SEPARATOR}"
 578 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 579 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 580   if test -d "$dir"; then
 581     LIBDIRS="$LIBDIRS -L$dir"
 582   else
 583     AC_MSG_WARN([*** Library directory $dir does not exist.])
 584   fi
 585 done
 586 IFS=$ac_save_IFS
 587
 588 #
 589 # Enable thread-safe client libraries
 590 #
 591 AC_MSG_CHECKING([allow thread-safe client libraries])
 592 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 593 if test "$enable_thread_safety" = yes; then
 594   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 595           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 596 fi
 597 AC_MSG_RESULT([$enable_thread_safety])
 598 AC_SUBST(enable_thread_safety)
 599
 600 #
 601 # Optionally build Tcl modules (PL/Tcl)
 602 #
 603 AC_MSG_CHECKING([whether to build with Tcl])
 604 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 605 AC_MSG_RESULT([$with_tcl])
 606 AC_SUBST([with_tcl])
 607
 608 # We see if the path to the Tcl/Tk configuration scripts is specified.
 609 # This will override the use of tclsh to find the paths to search.
 610
 611 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 612
 613 #
 614 # Optionally build Perl modules (PL/Perl)
 615 #
 616 AC_MSG_CHECKING([whether to build Perl modules])
 617 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 618 AC_MSG_RESULT([$with_perl])
 619 AC_SUBST(with_perl)
 620
 621 #
 622 # Optionally build Python modules (PL/Python)
 623 #
 624 AC_MSG_CHECKING([whether to build Python modules])
 625 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 626 AC_MSG_RESULT([$with_python])
 627 AC_SUBST(with_python)
 628
 629 #
 630 # GSSAPI
 631 #
 632 AC_MSG_CHECKING([whether to build with GSSAPI support])
 633 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 634 [
 635   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 636   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 637 ])
 638 AC_MSG_RESULT([$with_gssapi])
 639
 640
 641 AC_SUBST(krb_srvtab)
 642
 643
 644 #
 645 # Kerberos configuration parameters
 646 #
 647 PGAC_ARG_REQ(with, krb-srvnam,
 648              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 649              [],
 650              [with_krb_srvnam="postgres"])
 651 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 652                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 653
 654
 655 #
 656 # PAM
 657 #
 658 AC_MSG_CHECKING([whether to build with PAM support])
 659 PGAC_ARG_BOOL(with, pam, no,
 660               [build with PAM support],
 661               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 662 AC_MSG_RESULT([$with_pam])
 663
 664
 665 #
 666 # LDAP
 667 #
 668 AC_MSG_CHECKING([whether to build with LDAP support])
 669 PGAC_ARG_BOOL(with, ldap, no,
 670               [build with LDAP support],
 671               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 672 AC_MSG_RESULT([$with_ldap])
 673
 674
 675 #
 676 # Bonjour
 677 #
 678 AC_MSG_CHECKING([whether to build with Bonjour support])
 679 PGAC_ARG_BOOL(with, bonjour, no,
 680               [build with Bonjour support],
 681               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 682 AC_MSG_RESULT([$with_bonjour])
 683
 684
 685 #
 686 # OpenSSL
 687 #
 688 AC_MSG_CHECKING([whether to build with OpenSSL support])
 689 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 690               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 691 AC_MSG_RESULT([$with_openssl])
 692 AC_SUBST(with_openssl)
 693
 694 #
 695 # SELinux
 696 #
 697 AC_MSG_CHECKING([whether to build with SELinux support])
 698 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 699 AC_SUBST(with_selinux)
 700 AC_MSG_RESULT([$with_selinux])
 701
 702 #
 703 # Systemd
 704 #
 705 AC_MSG_CHECKING([whether to build with systemd support])
 706 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 707               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 708 AC_SUBST(with_systemd)
 709 AC_MSG_RESULT([$with_systemd])
 710
 711 #
 712 # Readline
 713 #
 714 PGAC_ARG_BOOL(with, readline, yes,
 715               [do not use GNU Readline nor BSD Libedit for editing])
 716 # readline on MinGW has problems with backslashes in psql and other bugs.
 717 # This is particularly a problem with non-US code pages.
 718 # Therefore disable its use until we understand the cause. 2004-07-20
 719 if test "$PORTNAME" = "win32"; then
 720   if test "$with_readline" = yes; then
 721     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 722     with_readline=no
 723   fi
 724 fi
 725
 726
 727 #
 728 # Prefer libedit
 729 #
 730 PGAC_ARG_BOOL(with, libedit-preferred, no,
 731               [prefer BSD Libedit over GNU Readline])
 732
 733
 734 #
 735 # UUID library
 736 #
 737 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 738 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 739 # UUID library.  More than one of these might be present on a given platform,
 740 # so we make the user say which one she wants.
 741 #
 742 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 743 if test x"$with_uuid" = x"" ; then
 744   with_uuid=no
 745 fi
 746 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 747 if test "$with_ossp_uuid" = yes ; then
 748   with_uuid=ossp
 749 fi
 750
 751 if test "$with_uuid" = bsd ; then
 752   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 753   UUID_EXTRA_OBJS="md5.o sha1.o"
 754 elif test "$with_uuid" = e2fs ; then
 755   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 756   UUID_EXTRA_OBJS="md5.o sha1.o"
 757 elif test "$with_uuid" = ossp ; then
 758   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 759   UUID_EXTRA_OBJS=""
 760 elif test "$with_uuid" = no ; then
 761   UUID_EXTRA_OBJS=""
 762 else
 763   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 764 fi
 765 AC_SUBST(with_uuid)
 766 AC_SUBST(UUID_EXTRA_OBJS)
 767
 768
 769 #
 770 # XML
 771 #
 772 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 773               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 774
 775 if test "$with_libxml" = yes ; then
 776   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 777   if test -n "$XML2_CONFIG"; then
 778     for pgac_option in `$XML2_CONFIG --cflags`; do
 779       case $pgac_option in
 780         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 781       esac
 782     done
 783     for pgac_option in `$XML2_CONFIG --libs`; do
 784       case $pgac_option in
 785         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 786       esac
 787     done
 788   fi
 789 fi
 790
 791 AC_SUBST(with_libxml)
 792
 793 #
 794 # XSLT
 795 #
 796 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 797               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 798
 799
 800 AC_SUBST(with_libxslt)
 801
 802 #
 803 # tzdata
 804 #
 805 PGAC_ARG_REQ(with, system-tzdata,
 806              [DIR], [use system time zone data in DIR])
 807 AC_SUBST(with_system_tzdata)
 808
 809 #
 810 # Zlib
 811 #
 812 PGAC_ARG_BOOL(with, zlib, yes,
 813               [do not use Zlib])
 814 AC_SUBST(with_zlib)
 815
 816 #
 817 # Elf
 818 #
 819
 820 # Assume system is ELF if it predefines __ELF__ as 1,
 821 # otherwise believe host_os based default.
 822 case $host_os in
 823     freebsd1*|freebsd2*) elf=no;;
 824     freebsd3*|freebsd4*) elf=yes;;
 825 esac
 826
 827 AC_EGREP_CPP(yes,
 828 [#if __ELF__
 829   yes
 830 #endif
 831 ],
 832 [ELF_SYS=true],
 833 [if test "X$elf" = "Xyes" ; then
 834   ELF_SYS=true
 835 else
 836   ELF_SYS=
 837 fi])
 838 AC_SUBST(ELF_SYS)
 839
 840 #
 841 # Assignments
 842 #
 843
 844 CPPFLAGS="$CPPFLAGS $INCLUDES"
 845 LDFLAGS="$LDFLAGS $LIBDIRS"
 846
 847 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 848 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 849
 850 PGAC_PROG_LD
 851 AC_SUBST(LD)
 852 AC_SUBST(with_gnu_ld)
 853 case $host_os in sysv5*)
 854   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 855   [
 856     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 857     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 858       [pgac_cv_prog_ld_R=yes],
 859       [pgac_cv_prog_ld_R=no])
 860     LDFLAGS=$pgac_save_LDFLAGS
 861   ])
 862   ld_R_works=$pgac_cv_prog_ld_R
 863   AC_SUBST(ld_R_works)
 864 esac
 865 AC_PROG_RANLIB
 866 PGAC_CHECK_STRIP
 867 AC_CHECK_TOOL(AR, ar, ar)
 868 if test "$PORTNAME" = "win32"; then
 869   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 870   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 871   AC_CHECK_TOOL(WINDRES, windres, windres)
 872 fi
 873
 874 AC_PROG_INSTALL
 875 # When Autoconf chooses install-sh as install program it tries to generate
 876 # a relative path to it in each makefile where it subsitutes it. This clashes
 877 # with our Makefile.global concept. This workaround helps.
 878 case $INSTALL in
 879   *install-sh*) install_bin='';;
 880   *) install_bin=$INSTALL;;
 881 esac
 882 AC_SUBST(install_bin)
 883
 884 AC_PATH_PROG(TAR, tar)
 885 AC_PROG_LN_S
 886 AC_PROG_AWK
 887 AC_PROG_MKDIR_P
 888 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 889 # a relative path to it in each makefile where it subsitutes it. This clashes
 890 # with our Makefile.global concept. This workaround helps.
 891 case $MKDIR_P in
 892   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 893 esac
 894
 895 PGAC_PATH_BISON
 896 PGAC_PATH_FLEX
 897
 898 PGAC_PATH_PERL
 899 if test "$with_perl" = yes; then
 900   if test -z "$PERL"; then
 901     AC_MSG_ERROR([Perl not found])
 902   fi
 903   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 904   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 905     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 906 You might have to rebuild your Perl installation.  Refer to the
 907 documentation for details.  Use --without-perl to disable building
 908 PL/Perl.])
 909   fi
 910   PGAC_CHECK_PERL_EMBED_LDFLAGS
 911 fi
 912
 913 if test "$with_python" = yes; then
 914   PGAC_PATH_PYTHON
 915   PGAC_CHECK_PYTHON_EMBED_SETUP
 916
 917   # We need libpython as a shared library.  With Python >=2.5, we
 918   # check the Py_ENABLE_SHARED setting.  On Debian, the setting is not
 919   # correct before the jessie release (http://bugs.debian.org/695979).
 920   # We also want to support older Python versions.  So as a fallback
 921   # we see if there is a file that is named like a shared library.
 922
 923   if test "$python_enable_shared" != 1; then
 924     if test "$PORTNAME" = darwin; then
 925       # OS X does supply a .dylib even though Py_ENABLE_SHARED does
 926       # not get set.  The file detection logic below doesn't succeed
 927       # on older OS X versions, so make it explicit.
 928       python_enable_shared=1
 929     elif test "$PORTNAME" = win32; then
 930       # Windows also needs an explicit override.
 931       python_enable_shared=1
 932     else
 933       # We don't know the platform shared library extension here yet,
 934       # so we try some candidates.
 935       for dlsuffix in .so .sl; do
 936         if ls "$python_libdir"/libpython*${dlsuffix}* >/dev/null 2>&1; then
 937           python_enable_shared=1
 938           break
 939         fi
 940       done
 941     fi
 942   fi
 943
 944   if test "$python_enable_shared" != 1; then
 945     AC_MSG_ERROR([cannot build PL/Python because libpython is not a shared library
 946 You might have to rebuild your Python installation.  Refer to the
 947 documentation for details.  Use --without-python to disable building
 948 PL/Python.])
 949   fi
 950 fi
 951
 952 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 953   AC_PATH_PROG(ZIC, zic)
 954   if test -z "$ZIC"; then
 955     AC_MSG_ERROR([
 956 When cross-compiling, either use the option --with-system-tzdata to use
 957 existing time-zone data, or set the environment variable ZIC to a zic
 958 program to use during the build.])
 959   fi
 960 fi
 961
 962 #
 963 # Pthreads
 964 #
 965 # For each platform, we need to know about any special compile and link
 966 # libraries, and whether the normal C function names are thread-safe.
 967 # See the comment at the top of src/port/thread.c for more information.
 968 # WIN32 doesn't need the pthread tests;  it always uses threads
 969 #
 970 # These tests are run before the library-tests, because linking with the
 971 # other libraries can pull in the pthread functions as a side-effect.  We
 972 # want to use the -pthread or similar flags directly, and not rely on
 973 # the side-effects of linking with some other library.
 974 #
 975 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 976 # invocation below is the first one in the script, and autoconf generates
 977 # additional code for that, which must not be inside the if-block. AS_IF
 978 # knows how to do that.
 979 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 980 [ # then
 981 AX_PTHREAD      # set thread flags
 982
 983 # Some platforms use these, so just define them.  They can't hurt if they
 984 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 985 # enables 5-arg getpwuid_r, among other things.
 986 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 987
 988 # Check for *_r functions
 989 _CFLAGS="$CFLAGS"
 990 _LIBS="$LIBS"
 991 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 992 LIBS="$LIBS $PTHREAD_LIBS"
 993
 994 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 995 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 996
 997 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 998
 999 # Do test here with the proper thread flags
1000 PGAC_FUNC_STRERROR_R_INT
1001
1002 CFLAGS="$_CFLAGS"
1003 LIBS="$_LIBS"
1004
1005 ], [ # else
1006 # do not use values from template file
1007 PTHREAD_CFLAGS=
1008 PTHREAD_LIBS=
1009 ]) # fi
1010
1011 AC_SUBST(PTHREAD_CFLAGS)
1012 AC_SUBST(PTHREAD_LIBS)
1013
1014
1015 ##
1016 ## Libraries
1017 ##
1018 ## Most libraries are included only if they demonstrably provide a function
1019 ## we need, but libm is an exception: always include it, because there are
1020 ## too many compilers that play cute optimization games that will break
1021 ## probes for standard functions such as pow().
1022 ##
1023
1024 AC_CHECK_LIB(m, main)
1025 AC_SEARCH_LIBS(setproctitle, util)
1026 AC_SEARCH_LIBS(dlopen, dl)
1027 AC_SEARCH_LIBS(socket, [socket ws2_32])
1028 AC_SEARCH_LIBS(shl_load, dld)
1029 # We only use libld in port/dynloader/aix.c
1030 case $host_os in
1031      aix*)
1032         AC_SEARCH_LIBS(ldopen, ld)
1033         ;;
1034 esac
1035 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1036 AC_SEARCH_LIBS(crypt, crypt)
1037 AC_SEARCH_LIBS(shm_open, rt)
1038 AC_SEARCH_LIBS(shm_unlink, rt)
1039 # Solaris:
1040 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1041 # Required for thread_test.c on Solaris
1042 AC_SEARCH_LIBS(sched_yield, rt)
1043 # Required for thread_test.c on Solaris 2.5:
1044 # Other ports use it too (HP-UX) so test unconditionally
1045 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1046 # Cygwin:
1047 AC_SEARCH_LIBS(shmget, cygipc)
1048
1049 if test "$with_readline" = yes; then
1050   PGAC_CHECK_READLINE
1051   if test x"$pgac_cv_check_readline" = x"no"; then
1052     AC_MSG_ERROR([readline library not found
1053 If you have readline already installed, see config.log for details on the
1054 failure.  It is possible the compiler isn't looking in the proper directory.
1055 Use --without-readline to disable readline support.])
1056   fi
1057 fi
1058
1059 if test "$with_zlib" = yes; then
1060   AC_CHECK_LIB(z, inflate, [],
1061                [AC_MSG_ERROR([zlib library not found
1062 If you have zlib already installed, see config.log for details on the
1063 failure.  It is possible the compiler isn't looking in the proper directory.
1064 Use --without-zlib to disable zlib support.])])
1065 fi
1066
1067 if test "$enable_spinlocks" = yes; then
1068   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1069 else
1070   AC_MSG_WARN([
1071 *** Not using spinlocks will cause poor performance.])
1072 fi
1073
1074 if test "$enable_atomics" = yes; then
1075   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1076 else
1077   AC_MSG_WARN([
1078 *** Not using atomic operations will cause poor performance.])
1079 fi
1080
1081 if test "$with_gssapi" = yes ; then
1082   if test "$PORTNAME" != "win32"; then
1083     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1084                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1085   else
1086     LIBS="$LIBS -lgssapi32"
1087   fi
1088 fi
1089
1090 if test "$with_openssl" = yes ; then
1091   dnl Order matters!
1092   if test "$PORTNAME" != "win32"; then
1093      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1094      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1095   else
1096      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1097      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1098   fi
1099   AC_CHECK_FUNCS([SSL_get_current_compression])
1100 fi
1101
1102 if test "$with_pam" = yes ; then
1103   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1104 fi
1105
1106 if test "$with_libxml" = yes ; then
1107   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1108 fi
1109
1110 if test "$with_libxslt" = yes ; then
1111   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1112 fi
1113
1114 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1115 if test "$with_ldap" = yes ; then
1116   _LIBS="$LIBS"
1117   if test "$PORTNAME" != "win32"; then
1118     AC_CHECK_LIB(ldap, ldap_bind, [],
1119                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1120                  [$EXTRA_LDAP_LIBS])
1121     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1122     if test "$enable_thread_safety" = yes; then
1123       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1124       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1125                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1126                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1127       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1128     else
1129       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1130     fi
1131   else
1132     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1133     LDAP_LIBS_FE="-lwldap32"
1134     LDAP_LIBS_BE="-lwldap32"
1135   fi
1136   LIBS="$_LIBS"
1137 fi
1138 AC_SUBST(LDAP_LIBS_FE)
1139 AC_SUBST(LDAP_LIBS_BE)
1140
1141 # for contrib/sepgsql
1142 if test "$with_selinux" = yes; then
1143   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1144                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1145 fi
1146
1147 # for contrib/uuid-ossp
1148 if test "$with_uuid" = bsd ; then
1149   # On BSD, the UUID functions are in libc
1150   AC_CHECK_FUNC(uuid_to_string,
1151     [UUID_LIBS=""],
1152     [AC_MSG_ERROR([BSD UUID functions are not present])])
1153 elif test "$with_uuid" = e2fs ; then
1154   # On OS X, the UUID functions are in libc
1155   AC_CHECK_FUNC(uuid_generate,
1156     [UUID_LIBS=""],
1157     [AC_CHECK_LIB(uuid, uuid_generate,
1158       [UUID_LIBS="-luuid"],
1159       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1160 elif test "$with_uuid" = ossp ; then
1161   AC_CHECK_LIB(ossp-uuid, uuid_export,
1162     [UUID_LIBS="-lossp-uuid"],
1163     [AC_CHECK_LIB(uuid, uuid_export,
1164       [UUID_LIBS="-luuid"],
1165       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1166 fi
1167 AC_SUBST(UUID_LIBS)
1168
1169
1170 ##
1171 ## Header files
1172 ##
1173
1174 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1175 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1176
1177 # On BSD, test for net/if.h will fail unless sys/socket.h
1178 # is included first.
1179 AC_CHECK_HEADERS(net/if.h, [], [],
1180 [AC_INCLUDES_DEFAULT
1181 #ifdef HAVE_SYS_SOCKET_H
1182 #include <sys/socket.h>
1183 #endif
1184 ])
1185
1186 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1187 # is included first.
1188 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1189 [AC_INCLUDES_DEFAULT
1190 #include <sys/param.h>
1191 ])
1192
1193 # At least on IRIX, test for netinet/tcp.h will fail unless
1194 # netinet/in.h is included first.
1195 AC_CHECK_HEADERS(netinet/in.h)
1196 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1197 [AC_INCLUDES_DEFAULT
1198 #ifdef HAVE_NETINET_IN_H
1199 #include <netinet/in.h>
1200 #endif
1201 ])
1202
1203 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1204   AC_CHECK_HEADERS(readline/readline.h, [],
1205         [AC_CHECK_HEADERS(readline.h, [],
1206                 [AC_MSG_ERROR([readline header not found
1207 If you have readline already installed, see config.log for details on the
1208 failure.  It is possible the compiler isn't looking in the proper directory.
1209 Use --without-readline to disable readline support.])])])
1210   AC_CHECK_HEADERS(readline/history.h, [],
1211         [AC_CHECK_HEADERS(history.h, [],
1212                 [AC_MSG_ERROR([history header not found
1213 If you have readline already installed, see config.log for details on the
1214 failure.  It is possible the compiler isn't looking in the proper directory.
1215 Use --without-readline to disable readline support.])])])
1216 fi
1217
1218 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1219 # Some installations of libedit usurp /usr/include/readline/, which seems
1220 # bad practice, since in combined installations readline will have its headers
1221 # there.  We might have to resort to AC_EGREP checks to make sure we found
1222 # the proper header...
1223   AC_CHECK_HEADERS(editline/readline.h, [],
1224         [AC_CHECK_HEADERS(readline.h, [],
1225                 [AC_CHECK_HEADERS(readline/readline.h, [],
1226                         [AC_MSG_ERROR([readline header not found
1227 If you have libedit already installed, see config.log for details on the
1228 failure.  It is possible the compiler isn't looking in the proper directory.
1229 Use --without-readline to disable libedit support.])])])])
1230 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1231 # not be there at all.  Hence, don't complain if not found.  We must check
1232 # though, since in yet other versions it is an independent header.
1233   AC_CHECK_HEADERS(editline/history.h, [],
1234         [AC_CHECK_HEADERS(history.h, [],
1235                 [AC_CHECK_HEADERS(readline/history.h)])])
1236 fi
1237
1238 if test "$with_zlib" = yes; then
1239   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1240 If you have zlib already installed, see config.log for details on the
1241 failure.  It is possible the compiler isn't looking in the proper directory.
1242 Use --without-zlib to disable zlib support.])])
1243 fi
1244
1245 if test "$with_gssapi" = yes ; then
1246   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1247         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1248 fi
1249
1250 if test "$with_openssl" = yes ; then
1251   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1252   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1253 fi
1254
1255 if test "$with_pam" = yes ; then
1256   AC_CHECK_HEADERS(security/pam_appl.h, [],
1257                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1258                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1259 fi
1260
1261 if test "$with_systemd" = yes ; then
1262   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1263 fi
1264
1265 if test "$with_libxml" = yes ; then
1266   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1267 fi
1268
1269 if test "$with_libxslt" = yes ; then
1270   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1271 fi
1272
1273 if test "$with_ldap" = yes ; then
1274   if test "$PORTNAME" != "win32"; then
1275      AC_CHECK_HEADERS(ldap.h, [],
1276                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1277      PGAC_LDAP_SAFE
1278   else
1279      AC_CHECK_HEADERS(winldap.h, [],
1280                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1281                       [AC_INCLUDES_DEFAULT
1282 #include <windows.h>
1283                       ])
1284   fi
1285 fi
1286
1287 if test "$with_bonjour" = yes ; then
1288   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1289 fi
1290
1291 # for contrib/uuid-ossp
1292 if test "$with_uuid" = bsd ; then
1293   AC_CHECK_HEADERS(uuid.h,
1294     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1295       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1296     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1297 elif test "$with_uuid" = e2fs ; then
1298   AC_CHECK_HEADERS(uuid/uuid.h,
1299     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1300       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1301     [AC_CHECK_HEADERS(uuid.h,
1302       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1303         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1304       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1305 elif test "$with_uuid" = ossp ; then
1306   AC_CHECK_HEADERS(ossp/uuid.h,
1307     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1308       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1309     [AC_CHECK_HEADERS(uuid.h,
1310       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1311         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1312       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1313 fi
1314
1315 if test "$PORTNAME" = "win32" ; then
1316    AC_CHECK_HEADERS(crtdefs.h)
1317 fi
1318
1319 ##
1320 ## Types, structures, compiler characteristics
1321 ##
1322
1323 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1324 AC_C_BIGENDIAN
1325 AC_C_INLINE
1326 PGAC_PRINTF_ARCHETYPE
1327 AC_C_FLEXIBLE_ARRAY_MEMBER
1328 PGAC_C_SIGNED
1329 PGAC_C_FUNCNAME_SUPPORT
1330 PGAC_C_STATIC_ASSERT
1331 PGAC_C_TYPES_COMPATIBLE
1332 PGAC_C_BUILTIN_BSWAP32
1333 PGAC_C_BUILTIN_BSWAP64
1334 PGAC_C_BUILTIN_CONSTANT_P
1335 PGAC_C_BUILTIN_UNREACHABLE
1336 PGAC_C_VA_ARGS
1337 PGAC_STRUCT_TIMEZONE
1338 PGAC_UNION_SEMUN
1339 PGAC_STRUCT_SOCKADDR_UN
1340 PGAC_STRUCT_SOCKADDR_STORAGE
1341 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1342 PGAC_STRUCT_ADDRINFO
1343 AC_TYPE_INTPTR_T
1344 AC_TYPE_UINTPTR_T
1345 AC_TYPE_LONG_LONG_INT
1346
1347 PGAC_TYPE_LOCALE_T
1348
1349 AC_CHECK_TYPES([struct cmsgcred], [], [],
1350 [#include <sys/socket.h>
1351 #include <sys/param.h>
1352 #ifdef HAVE_SYS_UCRED_H
1353 #include <sys/ucred.h>
1354 #endif])
1355
1356 AC_CHECK_TYPES([struct option], [], [],
1357 [#ifdef HAVE_GETOPT_H
1358 #include <getopt.h>
1359 #endif])
1360
1361 if test "$with_zlib" = yes; then
1362   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1363   # did not).  While we could work around the lack of z_streamp, it
1364   # seems unwise to encourage people to use such old zlib versions...
1365   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1366 Use --without-zlib to disable zlib support.])],
1367                 [#include <zlib.h>])
1368 fi
1369
1370 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1371 case $host_cpu in
1372   ppc*|powerpc*)
1373     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1374     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1375         [int a = 0; int *p = &a; int r;
1376          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1377         [pgac_cv_have_ppc_mutex_hint=yes],
1378         [pgac_cv_have_ppc_mutex_hint=no])
1379     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1380     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1381         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1382     fi
1383   ;;
1384 esac
1385
1386 # Check largefile support.  You might think this is a system service not a
1387 # compiler characteristic, but you'd be wrong.  We must check this before
1388 # probing existence of related functions such as fseeko, since the largefile
1389 # defines can affect what is generated for that.
1390 if test "$PORTNAME" != "win32"; then
1391    AC_SYS_LARGEFILE
1392    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1393    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1394    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1395    dnl versions where the feature actually works, it's on by default anyway.
1396    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1397 fi
1398
1399 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1400 AC_CHECK_SIZEOF([off_t])
1401
1402 # If we don't have largefile support, can't handle segsize >= 2GB.
1403 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1404    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1405 fi
1406
1407
1408 ##
1409 ## Functions, global variables
1410 ##
1411
1412 PGAC_VAR_INT_TIMEZONE
1413 AC_FUNC_ACCEPT_ARGTYPES
1414 PGAC_FUNC_GETTIMEOFDAY_1ARG
1415
1416 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1417 # symbols that that library has no business exposing to the world.  Pending
1418 # acquisition of a clue by those developers, ignore libedit (including its
1419 # possible alias of libreadline) while checking for everything else.
1420 LIBS_including_readline="$LIBS"
1421 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1422
1423 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1424
1425 AC_REPLACE_FUNCS(fseeko)
1426 case $host_os in
1427         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1428         # Mingw uses macros to access Win32 API calls
1429         netbsd*|mingw*)
1430                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1431                 ac_cv_func_fseeko=yes;;
1432         *)
1433                 AC_FUNC_FSEEKO;;
1434 esac
1435
1436 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1437 # by calling it, 2009-04-02
1438 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1439 if test "$PORTNAME" != "solaris"; then
1440 AC_CHECK_FUNCS(posix_fadvise)
1441 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1442 fi
1443
1444 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1445 AC_CHECK_DECLS([strlcat, strlcpy])
1446 # This is probably only present on Darwin, but may as well check always
1447 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1448
1449 HAVE_IPV6=no
1450 AC_CHECK_TYPE([struct sockaddr_in6],
1451         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1452          HAVE_IPV6=yes],
1453         [],
1454 [$ac_includes_default
1455 #include <netinet/in.h>])
1456 AC_SUBST(HAVE_IPV6)
1457
1458 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1459 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1460 [#include <machine/vmparam.h>
1461 #include <sys/exec.h>
1462 ],
1463 [PS_STRINGS->ps_nargvstr = 1;
1464 PS_STRINGS->ps_argvstr = "foo";])],
1465 [pgac_cv_var_PS_STRINGS=yes],
1466 [pgac_cv_var_PS_STRINGS=no])])
1467 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1468   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1469 fi
1470
1471
1472 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1473 # is missing.  Yes, there are machines that have only one.  We may
1474 # also decide to use snprintf.c if snprintf() is present but does not
1475 # have all the features we need --- see below.
1476
1477 if test "$PORTNAME" = "win32"; then
1478   # Win32 gets snprintf.c built unconditionally.
1479   #
1480   # To properly translate all NLS languages strings, we must support the
1481   # *printf() %$ format, which allows *printf() arguments to be selected
1482   # by position in the translated string.
1483   #
1484   # libintl versions < 0.13 use the native *printf() functions, and Win32
1485   # *printf() doesn't understand %$, so we must use our /port versions,
1486   # which do understand %$. libintl versions >= 0.13 include their own
1487   # *printf versions on Win32.  The libintl 0.13 release note text is:
1488   #
1489   #   C format strings with positions, as they arise when a translator
1490   #   needs to reorder a sentence, are now supported on all platforms.
1491   #   On those few platforms (NetBSD and Woe32) for which the native
1492   #   printf()/fprintf()/... functions don't support such format
1493   #   strings, replacements are provided through <libintl.h>.
1494   #
1495   # We could use libintl >= 0.13's *printf() if we were sure that we had
1496   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1497   # to guarantee that, it is best to just use our own, so we are sure to
1498   # get %$ support. In include/port.h we disable the *printf() macros
1499   # that might have been defined by libintl.
1500   #
1501   # We do this unconditionally whether NLS is used or not so we are sure
1502   # that all Win32 libraries and binaries behave the same.
1503   pgac_need_repl_snprintf=yes
1504 else
1505   pgac_need_repl_snprintf=no
1506   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1507   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1508 fi
1509
1510
1511 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1512 # include/c.h will provide declarations.  Note this is a separate test
1513 # from whether the functions exist in the C library --- there are
1514 # systems that have the functions but don't bother to declare them :-(
1515
1516 AC_CHECK_DECLS([snprintf, vsnprintf])
1517
1518
1519 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1520 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1521 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1522 #include <math.h>
1523 double glob_double;
1524 ],
1525 [return isinf(glob_double) ? 0 : 1;])],
1526 [ac_cv_func_isinf=yes],
1527 [ac_cv_func_isinf=no])])
1528
1529 if test $ac_cv_func_isinf = yes ; then
1530   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1531 else
1532   AC_LIBOBJ(isinf)
1533   # Look for a way to implement a substitute for isinf()
1534   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1535 fi
1536
1537 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1538
1539 case $host_os in
1540
1541         # Windows uses a specialised env handler
1542         # and doesn't need a replacement getpeereid because it doesn't use
1543         # Unix sockets.
1544         mingw*)
1545                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1546                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1547                 ac_cv_func_unsetenv=yes
1548                 ac_cv_func_getpeereid=yes;;
1549         *)
1550                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1551                 ;;
1552 esac
1553
1554 # System's version of getaddrinfo(), if any, may be used only if we found
1555 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1556 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1557 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1558    test "$PORTNAME" != "win32"; then
1559   AC_REPLACE_FUNCS([getaddrinfo])
1560 else
1561   AC_LIBOBJ(getaddrinfo)
1562 fi
1563
1564 # Similarly, use system's getopt_long() only if system provides struct option.
1565 if test x"$ac_cv_type_struct_option" = xyes ; then
1566   AC_REPLACE_FUNCS([getopt_long])
1567 else
1568   AC_LIBOBJ(getopt_long)
1569 fi
1570
1571 # Solaris' getopt() doesn't do what we want for long options, so always use
1572 # our version on that platform.
1573 if test "$PORTNAME" = "solaris"; then
1574   AC_LIBOBJ(getopt)
1575 fi
1576
1577 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1578 # so always use our version on Windows.
1579 if test "$PORTNAME" = "win32"; then
1580   AC_LIBOBJ(getopt)
1581   AC_LIBOBJ(getopt_long)
1582 fi
1583
1584 # Win32 (really MinGW) support
1585 if test "$PORTNAME" = "win32"; then
1586   AC_REPLACE_FUNCS(gettimeofday)
1587   AC_LIBOBJ(dirmod)
1588   AC_LIBOBJ(kill)
1589   AC_LIBOBJ(open)
1590   AC_LIBOBJ(system)
1591   AC_LIBOBJ(win32env)
1592   AC_LIBOBJ(win32error)
1593   AC_LIBOBJ(win32security)
1594   AC_LIBOBJ(win32setlocale)
1595   AC_DEFINE([HAVE_SYMLINK], 1,
1596             [Define to 1 if you have the `symlink' function.])
1597   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1598 #define WIN32_LEAN_AND_MEAN
1599 #include <windows.h>
1600 #include <string.h>
1601 #include <dbghelp.h>])
1602 fi
1603 if test x"$pgac_minidump_type" = x"yes" ; then
1604   AC_SUBST(have_win32_dbghelp,yes)
1605 else
1606   AC_SUBST(have_win32_dbghelp,no)
1607 fi
1608
1609 # Cygwin needs only a bit of that
1610 if test "$PORTNAME" = "cygwin"; then
1611   AC_LIBOBJ(dirmod)
1612 fi
1613
1614 AC_CHECK_DECLS([sys_siglist], [], [],
1615 [#include <signal.h>
1616 /* NetBSD declares sys_siglist in unistd.h.  */
1617 #ifdef HAVE_UNISTD_H
1618 # include <unistd.h>
1619 #endif
1620 ])
1621
1622 AC_CHECK_FUNC(syslog,
1623               [AC_CHECK_HEADER(syslog.h,
1624                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1625
1626 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1627 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1628   [extern int opterr; opterr = 1;])],
1629   [pgac_cv_var_int_opterr=yes],
1630   [pgac_cv_var_int_opterr=no])])
1631 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1632   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1633 fi
1634
1635 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1636 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1637   [extern int optreset; optreset = 1;])],
1638   [pgac_cv_var_int_optreset=yes],
1639   [pgac_cv_var_int_optreset=no])])
1640 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1641   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1642 fi
1643
1644 AC_CHECK_FUNCS([strtoll strtoq], [break])
1645 AC_CHECK_FUNCS([strtoull strtouq], [break])
1646
1647 # Lastly, restore full LIBS list and check for readline/libedit symbols
1648 LIBS="$LIBS_including_readline"
1649
1650 if test "$with_readline" = yes; then
1651   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1652   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1653   AC_CHECK_FUNCS([append_history history_truncate_file])
1654 fi
1655
1656
1657 # This test makes sure that run tests work at all.  Sometimes a shared
1658 # library is found by the linker, but the runtime linker can't find it.
1659 # This check should come after all modifications of compiler or linker
1660 # variables, and before any other run tests.
1661 AC_MSG_CHECKING([test program])
1662 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1663 [AC_MSG_RESULT(ok)],
1664 [AC_MSG_RESULT(failed)
1665 AC_MSG_ERROR([[
1666 Could not execute a simple test program.  This may be a problem
1667 related to locating shared libraries.  Check the file 'config.log'
1668 for the exact reason.]])],
1669 [AC_MSG_RESULT([cross-compiling])])
1670
1671 # --------------------
1672 # Run tests below here
1673 # --------------------
1674
1675 # Force use of our snprintf if system's doesn't do arg control
1676 # See comment above at snprintf test for details.
1677 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1678   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1679   if test $pgac_cv_snprintf_arg_control != yes ; then
1680     pgac_need_repl_snprintf=yes
1681   fi
1682 fi
1683
1684
1685 dnl Check to see if we have a working 64-bit integer type.
1686 dnl This breaks down into two steps:
1687 dnl (1) figure out if the compiler has a 64-bit int type with working
1688 dnl arithmetic, and if so
1689 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1690 dnl snprintf is the only library routine we really need for int8 support.)
1691 dnl It's entirely possible to have a compiler that handles a 64-bit type
1692 dnl when the C library doesn't; this is fairly likely when using gcc on
1693 dnl an older platform, for example.
1694 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1695 dnl we force our own version of snprintf() to be used instead.
1696 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1697
1698 dnl As of Postgres 8.4, we no longer support compilers without a working
1699 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1700
1701 PGAC_TYPE_64BIT_INT([long int])
1702
1703 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1704   pg_int64_type="long int"
1705 else
1706   PGAC_TYPE_64BIT_INT([long long int])
1707   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1708     pg_int64_type="long long int"
1709   else
1710     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1711   fi
1712 fi
1713
1714 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1715   [Define to the name of a signed 64-bit integer type.])
1716
1717 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1718
1719 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1720   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1721 #define INT64CONST(x)  x##LL
1722 long long int foo = INT64CONST(0x1234567890123456);
1723 ])],
1724         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1725         [])
1726 fi
1727
1728
1729 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1730 # we found we need to use "long long int", better check.  We cope with
1731 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1732 # work, fall back to our own snprintf emulation (which we know uses %lld).
1733
1734 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1735   if test $pgac_need_repl_snprintf = no; then
1736     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1737     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1738       # Force usage of our own snprintf, since system snprintf is broken
1739       pgac_need_repl_snprintf=yes
1740       LONG_LONG_INT_MODIFIER='ll'
1741     fi
1742   else
1743     # Here if we previously decided we needed to use our own snprintf
1744     LONG_LONG_INT_MODIFIER='ll'
1745   fi
1746 else
1747   # Here if we are not using 'long long int' at all
1748   LONG_LONG_INT_MODIFIER='l'
1749 fi
1750
1751 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1752
1753 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1754                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1755
1756 # Also force use of our snprintf if the system's doesn't support the %z flag.
1757 if test "$pgac_need_repl_snprintf" = no; then
1758   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1759   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1760     pgac_need_repl_snprintf=yes
1761   fi
1762 fi
1763
1764 # Now we have checked all the reasons to replace snprintf
1765 if test $pgac_need_repl_snprintf = yes; then
1766   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1767   AC_LIBOBJ(snprintf)
1768 fi
1769
1770 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1771 AC_CHECK_SIZEOF([void *])
1772 AC_CHECK_SIZEOF([size_t])
1773 AC_CHECK_SIZEOF([long])
1774
1775 # Decide whether float4 is passed by value: user-selectable, enabled by default
1776 AC_MSG_CHECKING([whether to build with float4 passed by value])
1777 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1778               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1779                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1780                float4passbyval=true],
1781               [float4passbyval=false])
1782 AC_MSG_RESULT([$enable_float4_byval])
1783 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1784
1785 # Decide whether float8 is passed by value.
1786 # Note: this setting also controls int8 and related types such as timestamp.
1787 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1788 # If not, trying to select it is an error.
1789 AC_MSG_CHECKING([whether to build with float8 passed by value])
1790 if test $ac_cv_sizeof_void_p -ge 8 ; then
1791   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1792 else
1793   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1794   if test "$enable_float8_byval" = yes ; then
1795     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1796   fi
1797 fi
1798 if test "$enable_float8_byval" = yes ; then
1799   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1800             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1801   float8passbyval=true
1802 else
1803   float8passbyval=false
1804 fi
1805 AC_MSG_RESULT([$enable_float8_byval])
1806 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1807
1808 # Determine memory alignment requirements for the basic C data types.
1809
1810 AC_CHECK_ALIGNOF(short)
1811 AC_CHECK_ALIGNOF(int)
1812 AC_CHECK_ALIGNOF(long)
1813 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1814   AC_CHECK_ALIGNOF(long long int)
1815 fi
1816 AC_CHECK_ALIGNOF(double)
1817
1818 # Compute maximum alignment of any basic type.
1819 # We assume long's alignment is at least as strong as char, short, or int;
1820 # but we must check long long (if it exists) and double.
1821
1822 MAX_ALIGNOF=$ac_cv_alignof_long
1823 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1824   MAX_ALIGNOF=$ac_cv_alignof_double
1825 fi
1826 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1827   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1828 fi
1829 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1830
1831
1832 # Some platforms predefine the types int8, int16, etc.  Only check
1833 # a (hopefully) representative subset.
1834 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1835 [#include <stdio.h>])
1836
1837 # Check for extensions offering the integer scalar type __int128.
1838 PGAC_TYPE_128BIT_INT
1839
1840 # Check for various atomic operations now that we have checked how to declare
1841 # 64bit integers.
1842 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1843 PGAC_HAVE_GCC__SYNC_INT32_TAS
1844 PGAC_HAVE_GCC__SYNC_INT32_CAS
1845 PGAC_HAVE_GCC__SYNC_INT64_CAS
1846 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1847 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1848
1849
1850 # Check for x86 cpuid instruction
1851 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1852 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1853   [[unsigned int exx[4] = {0, 0, 0, 0};
1854   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1855   ]])],
1856   [pgac_cv__get_cpuid="yes"],
1857   [pgac_cv__get_cpuid="no"])])
1858 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1859   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1860 fi
1861
1862 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1863 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1864   [[unsigned int exx[4] = {0, 0, 0, 0};
1865   __get_cpuid(exx[0], 1);
1866   ]])],
1867   [pgac_cv__cpuid="yes"],
1868   [pgac_cv__cpuid="no"])])
1869 if test x"$pgac_cv__cpuid" = x"yes"; then
1870   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1871 fi
1872
1873 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1874 #
1875 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1876 # with the default compiler flags. If not, check if adding the -msse4.2
1877 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1878 PGAC_SSE42_CRC32_INTRINSICS([])
1879 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1880   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1881 fi
1882 AC_SUBST(CFLAGS_SSE42)
1883
1884 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1885 # define __SSE4_2__ in that case.
1886 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1887 #ifndef __SSE4_2__
1888 #error __SSE4_2__ not defined
1889 #endif
1890 ])], [SSE4_2_TARGETED=1])
1891
1892 # Select CRC-32C implementation.
1893 #
1894 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1895 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1896 # a processor, but we can nevertheless produce code that uses the SSE
1897 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1898 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1899 # by the processor we're running on.
1900 #
1901 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1902 # in the template or configure command line.
1903 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1904   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1905     USE_SSE42_CRC32C=1
1906   else
1907     # the CPUID instruction is needed for the runtime check.
1908     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1909       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1910     else
1911       # fall back to slicing-by-8 algorithm which doesn't require any special
1912       # CPU support.
1913       USE_SLICING_BY_8_CRC32C=1
1914     fi
1915   fi
1916 fi
1917
1918 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1919 AC_MSG_CHECKING([which CRC-32C implementation to use])
1920 if test x"$USE_SSE42_CRC32C" = x"1"; then
1921   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1922   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1923   AC_MSG_RESULT(SSE 4.2)
1924 else
1925   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1926     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1927     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1928     AC_MSG_RESULT(SSE 4.2 with runtime check)
1929   else
1930     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1931     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1932     AC_MSG_RESULT(slicing-by-8)
1933   fi
1934 fi
1935 AC_SUBST(PG_CRC32C_OBJS)
1936
1937
1938 # Select semaphore implementation type.
1939 if test "$PORTNAME" != "win32"; then
1940   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1941     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1942     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1943   else
1944     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1945       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1946       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1947     else
1948       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1949       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1950     fi
1951   fi
1952 else
1953   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1954   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1955 fi
1956
1957
1958 # Select shared-memory implementation type.
1959 if test "$PORTNAME" != "win32"; then
1960   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1961   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1962 else
1963   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1964   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1965 fi
1966
1967 # Select latch implementation type.
1968 if test "$PORTNAME" != "win32"; then
1969   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1970 else
1971   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1972 fi
1973
1974 # If not set in template file, set bytes to use libc memset()
1975 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1976   MEMSET_LOOP_LIMIT=1024
1977 fi
1978 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1979
1980
1981 if test "$enable_nls" = yes ; then
1982   PGAC_CHECK_GETTEXT
1983 fi
1984
1985 # Check for Tcl configuration script tclConfig.sh
1986 if test "$with_tcl" = yes; then
1987     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1988     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1989                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1990     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1991     if test "$TCL_SHARED_BUILD" != 1; then
1992       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
1993 Use --without-tcl to disable building PL/Tcl.])
1994     fi
1995     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1996     ac_save_CPPFLAGS=$CPPFLAGS
1997     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1998     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1999     CPPFLAGS=$ac_save_CPPFLAGS
2000 fi
2001
2002 # check for <perl.h>
2003 if test "$with_perl" = yes; then
2004   ac_save_CPPFLAGS=$CPPFLAGS
2005   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2006   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2007                   [#include <EXTERN.h>])
2008   # While we're at it, check that we can link to libperl.
2009   # On most platforms, if perl.h is there then libperl.so will be too, but at
2010   # this writing Debian packages them separately.  There is no known reason to
2011   # waste cycles on separate probes for the Tcl or Python libraries, though.
2012   pgac_save_LIBS=$LIBS
2013   LIBS="$perl_embed_ldflags"
2014   AC_MSG_CHECKING([for libperl])
2015   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2016 #include <EXTERN.h>
2017 #include <perl.h>
2018 ],  [perl_alloc();])],
2019     [AC_MSG_RESULT(yes)],
2020     [AC_MSG_RESULT(no)
2021      AC_MSG_ERROR([libperl library is required for Perl])])
2022   LIBS=$pgac_save_LIBS
2023   CPPFLAGS=$ac_save_CPPFLAGS
2024 fi
2025
2026 # check for <Python.h>
2027 if test "$with_python" = yes; then
2028   ac_save_CPPFLAGS=$CPPFLAGS
2029   CPPFLAGS="$python_includespec $CPPFLAGS"
2030   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2031   CPPFLAGS=$ac_save_CPPFLAGS
2032 fi
2033
2034 #
2035 # Check for DocBook and tools
2036 #
2037 PGAC_PROG_NSGMLS
2038 PGAC_PROG_JADE
2039 PGAC_CHECK_DOCBOOK(4.2)
2040 PGAC_PATH_DOCBOOK_STYLESHEETS
2041 PGAC_PATH_COLLATEINDEX
2042 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2043 AC_CHECK_PROGS(XMLLINT, xmllint)
2044 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2045 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2046
2047 #
2048 # Check for test tools
2049 #
2050 if test "$enable_tap_tests" = yes; then
2051   AC_CHECK_PROGS(PROVE, prove)
2052   if test -z "$PROVE"; then
2053     AC_MSG_ERROR([prove not found])
2054   fi
2055   if test -z "$PERL"; then
2056     AC_MSG_ERROR([Perl not found])
2057   fi
2058 fi
2059
2060 # Thread testing
2061
2062 # We have to run the thread test near the end so we have all our symbols
2063 # defined.  Cross compiling throws a warning.
2064 #
2065 if test "$enable_thread_safety" = yes; then
2066 if test "$PORTNAME" != "win32"
2067 then
2068 AC_MSG_CHECKING([thread safety of required library functions])
2069
2070 _CFLAGS="$CFLAGS"
2071 _LIBS="$LIBS"
2072 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2073 LIBS="$LIBS $PTHREAD_LIBS"
2074 AC_RUN_IFELSE(
2075   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2076   [AC_MSG_RESULT(yes)],
2077   [AC_MSG_RESULT(no)
2078   AC_MSG_ERROR([thread test program failed
2079 This platform is not thread-safe.  Check the file 'config.log' or compile
2080 and run src/test/thread/thread_test for the exact reason.
2081 Use --disable-thread-safety to disable thread safety.])],
2082   [AC_MSG_RESULT(maybe)
2083   AC_MSG_WARN([
2084 *** Skipping thread test program because of cross-compile build.
2085 *** Run the program in src/test/thread on the target machine.
2086 ])])
2087 CFLAGS="$_CFLAGS"
2088 LIBS="$_LIBS"
2089 else
2090 AC_MSG_WARN([*** skipping thread test on Win32])
2091 fi
2092 fi
2093
2094 # If compiler will take -Wl,--as-needed (or various platform-specific
2095 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2096 # trying to filter LIBS to the minimum for each executable.
2097 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2098 # libreadline; therefore we postpone testing it until we know what library
2099 # dependencies readline has.  The test code will try to link with $LIBS.
2100 if test "$with_readline" = yes; then
2101   link_test_func=readline
2102 else
2103   link_test_func=exit
2104 fi
2105
2106 if test "$PORTNAME" = "darwin"; then
2107   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2108 elif test "$PORTNAME" = "openbsd"; then
2109   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2110 else
2111   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2112 fi
2113
2114 # Create compiler version string
2115 if test x"$GCC" = x"yes" ; then
2116   cc_string=`${CC} --version | sed q`
2117   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2118 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2119   cc_string=`${CC} -V 2>&1 | sed q`
2120 else
2121   cc_string=$CC
2122 fi
2123
2124 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2125                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2126                    [A string containing the version number, platform, and C compiler])
2127
2128 # Supply a numeric version string for use by 3rd party add-ons
2129 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2130 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2131 tr '.' '        ' |
2132 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2133 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2134 AC_SUBST(PG_VERSION_NUM)
2135
2136
2137 # Begin output steps
2138
2139 AC_MSG_NOTICE([using compiler=$cc_string])
2140 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2141 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2142 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2143
2144 # prepare build tree if outside source tree
2145 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2146 # Note 2: /bin/pwd might be better than shell's built-in at getting
2147 #         a symlink-free name.
2148 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2149   vpath_build=no
2150 else
2151   vpath_build=yes
2152   if test "$no_create" != yes; then
2153     _AS_ECHO_N([preparing build tree... ])
2154     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2155     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2156       || AC_MSG_ERROR(failed)
2157     AC_MSG_RESULT(done)
2158   fi
2159 fi
2160 AC_SUBST(vpath_build)
2161
2162
2163 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2164
2165 AC_CONFIG_LINKS([
2166   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2167   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2168   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2169   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2170   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2171   src/include/pg_config_os.h:src/include/port/${template}.h
2172   src/Makefile.port:src/makefiles/Makefile.${template}
2173 ])
2174
2175 if test "$PORTNAME" = "win32"; then
2176 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2177 # Links sometimes fail undetected on Mingw -
2178 # so here we detect it and warn the user
2179 for FILE in $CONFIG_LINKS
2180  do
2181         # test -e works for symlinks in the MinGW console
2182         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2183  done
2184 ])
2185 fi
2186
2187 AC_CONFIG_HEADERS([src/include/pg_config.h],
2188 [
2189 # Update timestamp for pg_config.h (see Makefile.global)
2190 echo >src/include/stamp-h
2191 ])
2192
2193 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2194 [
2195 # Update timestamp for pg_config_ext.h (see Makefile.global)
2196 echo >src/include/stamp-ext-h
2197 ])
2198
2199 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2200                   [echo >src/interfaces/ecpg/include/stamp-h])
2201
2202 AC_OUTPUT