granicus.if.org Git - strace/blob - configure.in

   1 AC_INIT(strace.c)
   2 AC_CANONICAL_HOST()
   3 AC_MSG_CHECKING(for supported operating system)
   4 changequote(,)dnl
   5
   6 case "$host_os" in
   7 linux*)
   8         opsys=linux
   9         ;;
  10 sunos4*)
  11         opsys=sunos4
  12         ;;
  13 solaris2*)
  14         opsys=svr4
  15         ;;
  16 sysv4*)
  17         opsys=svr4
  18         ;;
  19 sysv5*)
  20         opsys=svr4
  21         ;;
  22 irix[56]*)
  23         opsys=svr4
  24         ;;
  25 *)
  26         AC_MSG_ERROR(this operating system is not yet supported by strace)
  27         ;;
  28 esac
  29 AC_MSG_RESULT($opsys)
  30
  31 # Autoheader trick.  Heh, heh.
  32 opsys_list='
  33 @@@syms="$syms LINUX SUNOS4 SVR4"@@@
  34 '
  35
  36 AC_MSG_CHECKING(for supported architecture)
  37 case "$host_cpu" in
  38 i[3456]86|pentium)
  39         arch=i386
  40         ;;
  41 ia64)
  42         arch=ia64
  43         ;;
  44 m68k)
  45         arch=m68k
  46         ;;
  47 sparc)
  48         arch=sparc
  49         ;;
  50 mips*)
  51         arch=mips
  52         ;;
  53 alpha*)
  54         arch=alpha
  55         ;;
  56 ppc|powerpc)
  57         arch=powerpc
  58         ;;
  59 arm)
  60         arch=arm
  61         ;;
  62 s390)
  63         arch=s390
  64         ;;
  65 *)
  66         AC_MSG_ERROR(this architecture is not yet supported by strace)
  67         ;;
  68 esac
  69 AC_MSG_RESULT($arch)
  70
  71 # Autoheader trick.  Heh, heh.
  72 arch_list='
  73 @@@syms="$syms I386 IA64 M68K SPARC MIPS ALPHA ARM POWERPC"@@@
  74 '
  75
  76 osarch="$opsys"
  77 if [ -d "$srcdir/$opsys/$arch" ]; then
  78         osarch="$opsys/$arch"
  79 fi
  80
  81 OPSYS=`echo $opsys | tr '[a-z]' '[A-Z]'`
  82 ARCH=`echo $arch | tr '[a-z]' '[A-Z]'`
  83
  84 changequote([,])dnl
  85 CFLAGS="-D_GNU_SOURCE $CFLAGS"
  86 AC_CONFIG_HEADER(config.h)
  87 AC_SUBST(opsys)
  88 AC_DEFINE_UNQUOTED($OPSYS)
  89 case "$host_os" in
  90 sysv4.2uw*)
  91         AC_DEFINE(UNIXWARE, 2)
  92         ;;
  93 sysv5*)
  94         AC_DEFINE(UNIXWARE, 7)
  95         ;;
  96 esac
  97 AC_SUBST(arch)
  98 AC_DEFINE_UNQUOTED($ARCH)
  99 AC_SUBST(osarch)
 100 AC_PROG_CC
 101 AC_PROG_HOSTCC($host_alias $host)
 102 AC_MP_PROCFS
 103 AC_POLLABLE_PROCFS
 104 AC_STRUCT_PR_SYSCALL
 105 AC_STRUCT_MSG_CONTROL
 106 AC_INCLUDEDIR
 107 if test "x$OPSYS" = "xSUNOS4" && test "x$ARCH" = "xSPARC"
 108 then
 109         AC_MSG_CHECKING(for valid machine include directory)
 110         if test -d "$includedir/sun4"
 111         then
 112                 rm -f machine
 113                 ln -s $includedir/sun4 machine
 114                 AC_MSG_RESULT(yes)
 115                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE)
 116         else
 117                 AC_MSG_RESULT(no)
 118         fi
 119 fi
 120 AC_WARNFLAGS
 121 if test "x$OPSYS" = "xSUNOS4"
 122 then
 123         if test -n "$GCC"
 124         then
 125                 # SunOS 4.x header files don't declare int functions.
 126                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 127         fi
 128 fi
 129 AC_PROG_CPP
 130 AC_PROG_GCC_TRADITIONAL
 131 AC_PROG_INSTALL
 132 AC_C_CONST
 133 AC_HEADER_STDC
 134 AC_HEADER_DIRENT
 135 AC_TYPE_SIGNAL
 136 AC_STRUCT_ST_BLKSIZE
 137 AC_STRUCT_ST_BLOCKS
 138 AC_STRUCT_ST_RDEV
 139 AC_HEADER_STAT
 140 AC_TYPE_UID_T
 141 AC_TYPE_MODE_T
 142 AC_TYPE_GETGROUPS
 143 AC_HEADER_MAJOR
 144 AC_SIG_ATOMIC_T
 145 AC_STAT64
 146 AC_CHECK_LIB(nsl, main)
 147 AC_CHECK_FUNCS(sigaction strerror strsignal pread sys_siglist _sys_siglist getdents mctl putpmsg prctl sendmsg inet_ntop)
 148 AC_CHECK_HEADERS(sys/reg.h sys/filio.h sys/acl.h sys/asynch.h sys/door.h sys/stream.h sys/tiuser.h sys/sysconfig.h asm/sigcontext.h ioctls.h sys/ioctl.h sys/ptrace.h termio.h linux/ptrace.h asm/reg.h linux/in6.h sys/uio.h linux/netlink.h linux/if_packet.h sys/poll.h)
 149 AC_DECL_SYS_ERRLIST
 150 AC_DECL_SYS_SIGLIST
 151 AC_DECL__SYS_SIGLIST
 152 if test ! -d $osarch; then
 153         mkdir -p $osarch
 154 fi
 155 AC_OUTPUT(Makefile $osarch/Makefile)