granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(srclib/apr/build/find_apr.m4)
  20 sinclude(srclib/apr-util/build/find_apu.m4)
  21 sinclude(acinclude.m4)
  22
  23 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  24 dnl by configure until it is too late.  Is that how it should be or not?
  25 dnl Something seems broken here.
  26 AC_PREFIX_DEFAULT(/usr/local/apache2)
  27
  28 dnl Get the layout here, so we can pass the required variables to apr
  29 APACHE_ENABLE_LAYOUT
  30
  31 dnl reparse the configure arguments.
  32 APR_PARSE_ARGUMENTS
  33
  34 dnl export expanded and relative configure argument variables
  35 APACHE_EXPORT_ARGUMENTS
  36
  37 dnl Save user-defined environment settings for later restoration
  38 dnl
  39 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  42 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  43 APR_SAVE_THE_ENVIRONMENT(LIBS)
  44 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  45
  46 dnl Generate ./config.nice for reproducing runs of configure
  47 dnl
  48 APR_CONFIG_NICE(config.nice)
  49
  50 nl='
  51 '
  52 dnl Check that mkdir -p works
  53 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  54
  55 dnl ## Run configure for packages Apache uses
  56
  57 dnl shared library support for these packages doesn't currently
  58 dnl work on some platforms
  59
  60 AC_CANONICAL_SYSTEM
  61
  62 orig_prefix="$prefix"
  63
  64 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  65
  66 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr")
  67
  68 if test "$apr_found" = "no"; then
  69   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  70 fi
  71
  72 if test "$apr_found" = "reconfig"; then
  73   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  80 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  81 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  82 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  83 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  84
  85 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  86
  87 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util")
  88
  89 if test "$apu_found" = "no"; then
  90   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  91 fi
  92
  93 if test "$apu_found" = "reconfig"; then
  94   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  95   dnl We must be the last to build and the first to be cleaned
  96   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  97   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  98 fi
  99
 100 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 101 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 102
 103 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 104
 105 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 106
 107 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 108
 109 dnl Absolute source/build directory
 110 abs_srcdir=`(cd $srcdir && pwd)`
 111 abs_builddir=`pwd`
 112
 113 dnl If the source dir is not equal to the build dir,
 114 dnl then we are running in VPATH mode.
 115
 116 if test "$abs_builddir" != "$abs_srcdir"; then
 117   USE_VPATH=1
 118   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/modules/proxy -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/modules/filters -I\$(top_srcdir)/modules/filters -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 119 else
 120   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 121 fi
 122
 123 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 124
 125 case $host in
 126   *os2*)
 127       # Use a custom made libtool replacement
 128       echo "using aplibtool"
 129       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 130       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 131       SH_LIBS="\$(ALL_LIBS)"
 132       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 133       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 134       MK_IMPLIB="emximp"
 135       other_targets="$other_targets os2core"
 136       INSTALL_PROG_FLAGS="-e .exe"
 137       SHLTCFLAGS=""
 138       LTCFLAGS=""
 139       ;;
 140   *)
 141       if test "x$LTFLAGS" = "x"; then
 142           LTFLAGS='--silent'
 143       fi
 144       my_libtool=`$apr_config --apr-libtool`
 145       LIBTOOL="$my_libtool \$(LTFLAGS)"
 146       libtoolversion=`$my_libtool --version`
 147       case $libtoolversion in
 148           *1.4*)
 149               SH_LIBTOOL='$(LIBTOOL)'
 150               SHLTCFLAGS="-prefer-pic"
 151               LTCFLAGS="-prefer-non-pic -static"
 152               ;;
 153           *)
 154               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 155               SHLTCFLAGS=""
 156               LTCFLAGS=""
 157               ;;
 158       esac
 159       ;;
 160 esac
 161 APACHE_SUBST(SHLTCFLAGS)
 162 APACHE_SUBST(LTCFLAGS)
 163
 164 AP_SIG_GRACEFUL=USR1
 165
 166 case $host in
 167   *-apple-aux3*)
 168       APR_SETVAR(APACHE_MPM, [prefork])
 169       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 170       ;;
 171   *-beos*)
 172       APR_SETVAR(APACHE_MPM, [beos])
 173       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 174       ;;
 175   *os2_emx*)
 176       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 177       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 178       ;;
 179   *-linux-*)
 180       case `uname -r` in
 181         2.0* )
 182             AP_SIG_GRACEFUL=WINCH
 183             ;;
 184         2.[[2-9]]* )
 185             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 186             ;;
 187         * )
 188             ;;
 189       esac
 190       ;;
 191   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 192       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 193       ;;
 194   *-solaris2*)
 195       dnl This is a hack -- we should be using AC_TRY_RUN instead
 196       ap_platform_runtime_link_flag="-R"
 197       dnl solaris 8 and above don't have a thundering herd
 198       dnl not sure about rev's before this one.
 199       case `uname -r` in
 200         5.[567]*)
 201             ;;
 202         * )
 203             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 204             ;;
 205       esac
 206       ;;
 207   *cygwin*)
 208       APR_SETVAR(APACHE_MPM, [prefork])
 209       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 210       ;;
 211   *aix*)
 212       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 213       if test $aixver -ge 4320; then
 214         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 215       fi
 216       ;;
 217 esac
 218
 219 dnl
 220 dnl Process command line arguments. This is done early in the process so the
 221 dnl user can get feedback quickly in case of an error.
 222 dnl
 223 dnl ### need to move some of the arguments "up here"
 224
 225 dnl ## Check for programs
 226
 227 AC_PATH_PROG(RM, rm)
 228 AC_PROG_AWK
 229 AC_PROG_CC
 230 AC_PROG_CPP
 231 AC_PROG_INSTALL
 232 AC_PROG_LN_S
 233 AC_CHECK_TOOL(RANLIB, ranlib, true)
 234 dnl AC_PATH_PROG(PERL_PATH, perl)
 235
 236 dnl various OS checks that apparently set required flags
 237 AC_AIX
 238 AC_ISC_POSIX
 239 AC_MINIX
 240
 241 dnl ## Check for libraries
 242
 243 dnl ## Check for header files
 244
 245 dnl I think these are just used all over the place, so just check for
 246 dnl them at the base of the tree. If some are specific to a single
 247 dnl directory, they should be moved (Comment #Spoon)
 248
 249 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 250 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 251 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 252
 253 AC_HEADER_STDC
 254 AC_CHECK_HEADERS( \
 255 string.h \
 256 limits.h \
 257 unistd.h \
 258 sys/socket.h \
 259 pwd.h \
 260 grp.h \
 261 strings.h \
 262 sys/processor.h \
 263 sys/sem.h
 264 )
 265 AC_HEADER_SYS_WAIT
 266
 267 dnl ## Check for typedefs, structures, and compiler characteristics.
 268
 269 AC_C_CONST
 270 if test "$ac_cv_prog_gcc" = "yes"; then
 271   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 272 fi
 273
 274 dnl ## Check for library functions
 275
 276 dnl See Comment #Spoon
 277
 278 AC_CHECK_FUNCS( \
 279 getpwnam \
 280 getgrnam \
 281 initgroups \
 282 bindprocessor \
 283 timegm \
 284 )
 285
 286 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 287 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 288 [AC_TRY_COMPILE([#include <sys/types.h>
 289 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 290   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 291 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 292     AC_DEFINE(HAVE_GMTOFF)
 293 fi
 294
 295 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 296
 297 case $host in
 298     *aix*)
 299         # for 32-bit builds, increase MAXDATA to allow lots of threads
 300         if test x$OBJECT_MODE != x64; then
 301             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 302         fi
 303         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 304         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 305         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 306         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 307         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 308         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 309         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 310         ;;
 311     *os390*)
 312         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 313         ;;
 314     *)
 315         OS_SPECIFIC_VARS=""
 316 esac
 317
 318 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 319         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 320         [PORT=80])
 321
 322 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 323 [
 324   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 325 ])dnl
 326
 327 prefix="$orig_prefix"
 328 APACHE_ENABLE_MODULES
 329
 330 dnl reading config stubs
 331 esyscmd(./build/config-stubs .)
 332
 333 APACHE_SUBST(progname)
 334 APACHE_SUBST(MPM_LIB)
 335 APACHE_SUBST(OS)
 336 APACHE_SUBST(OS_DIR)
 337 APACHE_SUBST(BUILTIN_LIBS)
 338 APACHE_SUBST(SHLIBPATH_VAR)
 339 APACHE_SUBST(OS_SPECIFIC_VARS)
 340
 341 PRE_SHARED_CMDS='echo ""'
 342 POST_SHARED_CMDS='echo ""'
 343
 344 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 345
 346 if test "$apache_need_shared" = "yes"; then
 347   if test -f $ac_aux_dir/ltconfig; then
 348     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 349   fi
 350   shared_build="shared-build"
 351 fi
 352
 353 dnl enable_so tells us if *any* modules can be built as DSOs
 354
 355 if test "$enable_so" = "yes"; then
 356   case $host in
 357     *-ibm-aix*)
 358       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 359       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 360       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 361       ;;
 362     *beos)
 363       SH_LDFLAGS='$(top_builddir)/_APP_'
 364       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 365       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 366       ;;
 367     *os390)
 368       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 369       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 370   esac
 371 fi
 372
 373 APACHE_SUBST(PRE_SHARED_CMDS)
 374 APACHE_SUBST(POST_SHARED_CMDS)
 375 APACHE_SUBST(shared_build)
 376
 377 AC_ARG_WITH(program-name,
 378 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 379   progname="$withval" ], [
 380   progname="httpd"] )
 381
 382 # SuExec parameters
 383 AC_ARG_WITH(suexec-bin,
 384 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 385   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 386 ] )
 387
 388 AC_ARG_WITH(suexec-caller,
 389 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 390   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 391
 392 AC_ARG_WITH(suexec-userdir,
 393 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 394   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 395
 396 AC_ARG_WITH(suexec-docroot,
 397 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 398   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 399
 400 AC_ARG_WITH(suexec-uidmin,
 401 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 402   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 403
 404 AC_ARG_WITH(suexec-gidmin,
 405 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 406   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 407
 408 AC_ARG_WITH(suexec-logfile,
 409 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 410   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 411
 412 AC_ARG_WITH(suexec-safepath,
 413 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 414   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 415
 416 AC_ARG_WITH(suexec-umask,
 417 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 418   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 419
 420 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 421 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 422
 423 dnl APR should go after the other libs, so the right symbols can be picked up
 424 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 425 APACHE_SUBST(AP_LIBS)
 426 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 427 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 428
 429 AC_DEFINE(AP_USING_AUTOCONF, 1,
 430                 [Using autoconf to configure Apache])
 431
 432 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 433     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 434               [This platform doesn't suffer from the thundering herd problem])
 435 fi
 436
 437 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 438 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 439 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 440 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 441 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 442 AC_SUBST(AP_SIG_GRACEFUL)
 443 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 444 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 445
 446 dnl check for endianness
 447 if test "$cross_compiling" = "no"; then
 448   AC_C_BIGENDIAN
 449 else
 450   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 451                 [byte order is unknown due to cross-compilation])
 452 fi
 453
 454 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 455 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 456 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 457 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 458
 459 if test -d ./test; then
 460     APACHE_FAST_OUTPUT(test/Makefile)
 461 fi
 462
 463 dnl ## Finalize the variables
 464 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 465
 466 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 467 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 468 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 469 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 470 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 471 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 472
 473 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 474
 475 APACHE_GEN_CONFIG_VARS
 476
 477 dnl ## Build modules.c
 478 rm -f modules.c
 479 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 480
 481 APR_EXPAND_VAR(ap_prefix, $prefix)
 482 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 483         [Root directory of the Apache install area])
 484 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 485         [Location of the config file, relative to the Apache root directory])
 486 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 487         [Location of the MIME types config file, relative to the Apache root directory])
 488 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 489         [Location of the source for the current MPM])
 490
 491 perlbin=`$ac_aux_dir/PrintPath perl`
 492 if test "x$perlbin" = "x"; then
 493     perlbin="/replace/with/path/to/perl/interpreter"
 494 fi
 495 AC_SUBST(perlbin)
 496
 497 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 498
 499 BSD_MAKEFILE=no
 500 ap_make_include=include
 501 ap_make_delimiter=' '
 502 case $host in
 503 *bsdi*)
 504     # Check whether they've installed GNU make
 505     if make --version > /dev/null 2>&1; then
 506         true
 507     else
 508         BSD_MAKEFILE=yes
 509         ap_make_include=.include
 510         ap_make_delimiter='"'
 511     fi
 512     ;;
 513 esac
 514 AC_SUBST(ap_make_include)
 515 AC_SUBST(ap_make_delimiter)
 516
 517 dnl Ensure that docs/conf is created.
 518 test -d docs/conf||$mkdir_p docs/conf
 519
 520 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 521   APACHE_GEN_MAKEFILES
 522 ])
 523