granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APACHE_ENABLE_LAYOUT
  28
  29 dnl reparse the configure arguments.
  30 APACHE_PARSE_ARGUMENTS
  31
  32 dnl Save user-defined environment settings for later restoration
  33 dnl
  34 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  35 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  36 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  37 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(LIBS)
  39 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  40
  41 dnl Generate ./config.nice for reproducing runs of configure
  42 dnl
  43 APR_CONFIG_NICE(config.nice)
  44
  45 nl='
  46 '
  47
  48 dnl ## Run configure for packages Apache uses
  49
  50 dnl shared library support for these packages doesn't currently
  51 dnl work on some platforms
  52
  53 AC_CANONICAL_SYSTEM
  54
  55 orig_prefix="$prefix"
  56
  57 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  58
  59 APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  60
  61 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  62
  63 APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --bindir=$bindir")
  64
  65 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
  66
  67 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --bindir=$bindir")
  68
  69 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
  70
  71 echo $ac_n "obtaining flag settings from the sub-configures...${nl}"
  72 . ./srclib/apr/APRVARS
  73
  74 dnl Now that we have APR's EXTRA_flags in our environment, move them over
  75 dnl to the normal variables to avoid duplications and use them for testing.
  76 dnl We ignore EXTRA_INCLUDES because our own includes will encompass them.
  77 dnl
  78 APR_ADDTO(CFLAGS, $EXTRA_CFLAGS)
  79 APR_ADDTO(CPPFLAGS, $EXTRA_CPPFLAGS)
  80 APR_ADDTO(LDFLAGS, $EXTRA_LDFLAGS)
  81 APR_ADDTO(LIBS, $EXTRA_LIBS)
  82 EXTRA_CFLAGS=
  83 EXTRA_CPPFLAGS=
  84 EXTRA_LDFLAGS=
  85 EXTRA_LIBS=
  86 EXTRA_INCLUDES=
  87
  88 dnl Absolute source/build directory
  89 abs_srcdir=`(cd $srcdir && pwd)`
  90 abs_builddir=`pwd`
  91
  92 dnl If the source dir is not equal to the build dir,
  93 dnl then we are running in VPATH mode.
  94
  95 if test "$abs_builddir" != "$abs_srcdir"; then
  96   USE_VPATH=1
  97   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_builddir)/srclib/apr-util/include -I\$(top_srcdir)/srclib/apr-util/include])
  98 else
  99   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr-util/include])
 100 fi
 101
 102 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 103
 104 case $host in
 105   *os2*)
 106       # Use a custom made libtool replacement
 107       echo "using aplibtool"
 108       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 109       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 110       SH_LIBS="\$(ALL_LIBS)"
 111       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 112       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 113       MK_IMPLIB="emximp"
 114       other_targets="$other_targets os2core"
 115       INSTALL_PROG_FLAGS="-e .exe"
 116       SHLTCFLAGS=""
 117       LTCFLAGS=""
 118       ;;
 119   *)
 120       if test "x$LTFLAGS" = "x"; then
 121           LTFLAGS='--silent'
 122       fi
 123       LIBTOOL='$(SHELL) $(top_builddir)/srclib/apr/libtool $(LTFLAGS)'
 124       libtoolversion=`$abs_builddir/srclib/apr/libtool --version`
 125       case $libtoolversion in
 126           *1.4*)
 127               SH_LIBTOOL='$(LIBTOOL)'
 128               SHLTCFLAGS="-prefer-pic"
 129               LTCFLAGS="-prefer-non-pic -static"
 130               ;;
 131           *)
 132               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 133               SHLTCFLAGS=""
 134               LTCFLAGS=""
 135               ;;
 136       esac
 137       ;;
 138 esac
 139 APACHE_SUBST(SHLTCFLAGS)
 140 APACHE_SUBST(LTCFLAGS)
 141
 142 AP_SIG_GRACEFUL=USR1
 143
 144 case $host in
 145   *-apple-aux3*)
 146       APR_SETVAR(APACHE_MPM, [prefork])
 147       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 148       ;;
 149   *-beos*)
 150       APR_SETVAR(APACHE_MPM, [beos])
 151       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 152       ;;
 153   *os2_emx*)
 154       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 155       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 156       ;;
 157   *-linux-*)
 158       case `uname -r` in
 159         2.0* )
 160             AP_SIG_GRACEFUL=WINCH
 161             ;;
 162         2.[[2-9]]* )
 163             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 164             ;;
 165         * )
 166             ;;
 167       esac
 168       ;;
 169   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 170       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 171       ;;
 172   *-solaris2*)
 173       dnl  This is a hack -- we should be using AC_TRY_RUN instead
 174       ap_platform_runtime_link_flag="-R"
 175       ;;
 176   *cygwin*)
 177       APR_SETVAR(APACHE_MPM, [prefork])
 178       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 179       ;;
 180 esac
 181
 182 dnl
 183 dnl Process command line arguments. This is done early in the process so the
 184 dnl user can get feedback quickly in case of an error.
 185 dnl
 186 dnl ### need to move some of the arguments "up here"
 187
 188 dnl ## Check for programs
 189
 190 AC_PATH_PROG(RM, rm)
 191 AC_PROG_AWK
 192 AC_PROG_CC
 193 AC_PROG_CPP
 194 AC_PROG_INSTALL
 195 AC_PROG_LN_S
 196 AC_CHECK_TOOL(RANLIB, ranlib, true)
 197 dnl AC_PATH_PROG(PERL_PATH, perl)
 198
 199 dnl various OS checks that apparently set required flags
 200 AC_AIX
 201 AC_ISC_POSIX
 202 AC_MINIX
 203
 204 dnl ## Check for libraries
 205
 206 dnl ## Check for header files
 207
 208 dnl I think these are just used all over the place, so just check for
 209 dnl them at the base of the tree. If some are specific to a single
 210 dnl directory, they should be moved (Comment #Spoon)
 211
 212 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 213 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 214 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 215
 216 AC_HEADER_STDC
 217 AC_CHECK_HEADERS( \
 218 string.h \
 219 limits.h \
 220 unistd.h \
 221 sys/socket.h \
 222 pwd.h \
 223 grp.h \
 224 strings.h \
 225 sys/processor.h \
 226 sys/sem.h
 227 )
 228 AC_HEADER_SYS_WAIT
 229
 230 dnl ## Check for typedefs, structures, and compiler characteristics.
 231
 232 AC_C_CONST
 233 if test "$ac_cv_prog_gcc" = "yes"; then
 234   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 235 fi
 236
 237 dnl ## Check for library functions
 238
 239 dnl See Comment #Spoon
 240
 241 AC_CHECK_FUNCS( \
 242 getpwnam \
 243 getgrnam \
 244 initgroups \
 245 bindprocessor \
 246 timegm \
 247 )
 248
 249 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 250 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 251 [AC_TRY_COMPILE([#include <sys/types.h>
 252 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 253   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 254 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 255     AC_DEFINE(HAVE_GMTOFF)
 256 fi
 257
 258 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 259
 260 case $host in
 261     *aix*)
 262         # for 32-bit builds, increase MAXDATA to allow lots of threads
 263         if test x$OBJECT_MODE != x64; then
 264             OS_SPECIFIC_VARS="set LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 265         fi
 266         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS set AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 267         ;;
 268     *os390*)
 269         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 270         ;;
 271     *)
 272         OS_SPECIFIC_VARS=""
 273 esac
 274
 275 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 276         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 277         [PORT=80])
 278
 279 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 280 [
 281   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 282 ])dnl
 283
 284 prefix="$orig_prefix"
 285 APACHE_ENABLE_MODULES
 286
 287 dnl reading config stubs
 288 esyscmd(./build/config-stubs .)
 289
 290 APACHE_SUBST(progname)
 291 APACHE_SUBST(MPM_LIB)
 292 APACHE_SUBST(OS)
 293 APACHE_SUBST(OS_DIR)
 294 APACHE_SUBST(BUILTIN_LIBS)
 295 APACHE_SUBST(SHLIBPATH_VAR)
 296 APACHE_SUBST(OS_SPECIFIC_VARS)
 297
 298 PRE_SHARED_CMDS='echo ""'
 299 POST_SHARED_CMDS='echo ""'
 300
 301 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 302
 303 if test "$apache_need_shared" = "yes"; then
 304   if test -f $ac_aux_dir/ltconfig; then
 305     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 306   fi
 307   shared_build="shared-build"
 308 fi
 309
 310 dnl enable_so tells us if *any* modules can be built as DSOs
 311
 312 if test "$enable_so" = "yes"; then
 313   case $host in
 314     *-ibm-aix*)
 315       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 316       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 317       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 318       ;;
 319     *beos)
 320       SH_LDFLAGS='$(top_builddir)/_APP_'
 321       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 322       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 323       ;;
 324     *os390)
 325       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 326       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 327   esac
 328 fi
 329
 330 APACHE_SUBST(PRE_SHARED_CMDS)
 331 APACHE_SUBST(POST_SHARED_CMDS)
 332 APACHE_SUBST(shared_build)
 333
 334 AC_ARG_WITH(program-name,
 335 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 336   progname="$withval" ], [
 337   progname="httpd"] )
 338
 339 # SuExec parameters
 340 AC_ARG_WITH(suexec-bin,
 341 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 342   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 343 ] )
 344
 345 AC_ARG_WITH(suexec-caller,
 346 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 347   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 348
 349 AC_ARG_WITH(suexec-userdir,
 350 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 351   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 352
 353 AC_ARG_WITH(suexec-docroot,
 354 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 355   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 356
 357 AC_ARG_WITH(suexec-uidmin,
 358 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 359   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 360
 361 AC_ARG_WITH(suexec-gidmin,
 362 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 363   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 364
 365 AC_ARG_WITH(suexec-logfile,
 366 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 367   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 368
 369 AC_ARG_WITH(suexec-safepath,
 370 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 371   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 372
 373 AC_ARG_WITH(suexec-umask,
 374 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 375   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 376
 377 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 378 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $abs_builddir/srclib/apr-util/libaprutil.la $AP_LIBS"
 379
 380 dnl APR should go after the other libs, so the right symbols can be picked up
 381 AP_LIBS="$AP_LIBS $abs_builddir/srclib/apr/libapr.la"
 382 APACHE_SUBST(AP_LIBS)
 383
 384 AC_DEFINE(AP_USING_AUTOCONF, 1,
 385                 [Using autoconf to configure Apache])
 386
 387 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 388     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 389               [This platform doesn't suffer from the thundering herd problem])
 390 fi
 391
 392 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 393 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 394 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 395 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 396 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 397 AC_SUBST(AP_SIG_GRACEFUL)
 398 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 399 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 400
 401 dnl check for endianness
 402 if test "$cross_compiling" = "no"; then
 403   AC_C_BIGENDIAN
 404 else
 405   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 406                 [byte order is unknown due to cross-compilation])
 407 fi
 408
 409 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 410 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 411 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 412 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 413
 414 if test -d ./test; then
 415     APACHE_FAST_OUTPUT(test/Makefile)
 416 fi
 417
 418 dnl get the exported vars from APRUTIL
 419 . ./srclib/apr-util/export_vars.sh
 420 APR_ADDTO(LIBS, $APRUTIL_EXPORT_LIBS)
 421 APR_ADDTO(INCLUDES, $APRUTIL_EXPORT_INCLUDES)
 422 APR_ADDTO(LDFLAGS, $APRUTIL_LDFLAGS)
 423 AP_LIBS="$AP_LIBS $LIBTOOL_LIBS"
 424
 425 dnl ## Finalize the variables
 426 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 427
 428 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 429 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 430 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 431 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 432 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 433 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 434
 435 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 436
 437 APACHE_GEN_CONFIG_VARS
 438
 439 dnl ## Build modules.c
 440 rm -f modules.c
 441 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 442
 443 APR_EXPAND_VAR(ap_prefix, $prefix)
 444 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 445         [Root directory of the Apache install area])
 446 APR_EXPAND_VAR(ap_sysconfdir, $sysconfdir)
 447 APR_PATH_RELATIVE(rel_sysconfdir, $ap_sysconfdir, $prefix)
 448 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 449         [Location of the config file, relative to the Apache root directory])
 450 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 451         [Location of the source for the current MPM])
 452
 453 perlbin=`$ac_aux_dir/PrintPath perl`
 454 if test "x$perlbin" = "x"; then
 455     perlbin="/replace/with/path/to/perl/interpreter"
 456 fi
 457 AC_SUBST(perlbin)
 458
 459 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 460
 461 BSD_MAKEFILE=no
 462 case $host in
 463 *bsdi*)
 464     # Check whether they've installed GNU make
 465     if make --version > /dev/null 2>&1; then
 466         true
 467     else
 468         BSD_MAKEFILE=yes
 469     fi
 470     ;;
 471 esac
 472
 473 AC_OUTPUT($APACHE_OUTPUT_FILES support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 474   APACHE_GEN_MAKEFILES
 475 ])
 476