granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 HTTPD_MMN=`$abs_srcdir/build/get-version.sh mmn $abs_srcdir/include/ap_mmn.h MODULE_MAGIC_NUMBER`
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225 if test "x$with_pcre" = "x" || test "$with_pcre" = "yes"; then
 226   with_pcre="$PATH"
 227 else if which $with_pcre 2>/dev/null; then :; else
 228   with_pcre="$with_pcre/bin:$with_pcre"
 229 fi
 230 fi
 231
 232 AC_CHECK_TARGET_TOOLS(PCRE_CONFIG, [pcre2-config pcre-config],
 233                       [`which $with_pcre 2>/dev/null`], $with_pcre)
 234
 235 if test "x$PCRE_CONFIG" != "x"; then
 236   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 237     AC_MSG_ERROR([Did not find working script at $PCRE_CONFIG])
 238   fi
 239   case `$PCRE_CONFIG --version` in
 240   [1[0-9].*])
 241     AC_DEFINE(HAVE_PCRE2, 1, [Detected PCRE2])
 242     ;;
 243   [[1-5].*])
 244     AC_MSG_ERROR([Need at least pcre version 6.7])
 245     ;;
 246   [6.[0-6]*])
 247     AC_MSG_ERROR([Need at least pcre version 6.7])
 248     ;;
 249   esac
 250   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 251   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 252   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs8 2>/dev/null || $PCRE_CONFIG --libs`])
 253   APR_ADDTO(HTTPD_LIBS, [\$(PCRE_LIBS)])
 254 else
 255   AC_MSG_ERROR([pcre(2)-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 256 fi
 257 APACHE_SUBST(PCRE_LIBS)
 258
 259 AC_MSG_NOTICE([])
 260 AC_MSG_NOTICE([Configuring Apache httpd...])
 261 AC_MSG_NOTICE([])
 262
 263 dnl If the source dir is not equal to the build dir,
 264 dnl then we are running in VPATH mode.
 265
 266 APR_ADDTO(INCLUDES, [-I.])
 267
 268 if test "$abs_builddir" != "$abs_srcdir"; then
 269   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 270 fi
 271
 272 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 273
 274 # apr/apr-util --includes may pick up system paths for dependent
 275 # libraries, so ensure these are later in INCLUDES than local source
 276 # directories.
 277 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 278 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 279
 280 dnl Add in path to PCRE includes
 281 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 282
 283 save_CPPFLAGS="$CPPFLAGS"
 284 CPPFLAGS="$CPPFLAGS $PCRE_INCLUDES"
 285 AC_EGREP_CPP(yes,
 286 [
 287 #include <pcre.h>
 288 #ifdef PCRE_DUPNAMES
 289 yes
 290 #endif
 291 ],pcre_have_dupnames=yes,pcre_have_dupnames=no)
 292 if test "$pcre_have_dupnames" != "yes"; then
 293     AC_MSG_ERROR([pcre version does not support PCRE_DUPNAMES])
 294 fi
 295 CPPFLAGS="$save_CPPFLAGS"
 296
 297 AC_MSG_NOTICE([])
 298 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 299 AC_MSG_NOTICE([])
 300
 301 case $host in
 302   *os2*)
 303       # Use a custom made libtool replacement
 304       echo "using aplibtool"
 305       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 306       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 307       SH_LIBS="\$(ALL_LIBS)"
 308       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 309       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 310       MK_IMPLIB="emximp"
 311       other_targets="$other_targets os2core"
 312       INSTALL_PROG_FLAGS="-e .exe"
 313       SHLTCFLAGS=""
 314       LTCFLAGS=""
 315       ;;
 316   *)
 317       if test "x$LTFLAGS" = "x"; then
 318           LTFLAGS='--silent'
 319       fi
 320       my_libtool=`$apr_config --apr-libtool`
 321       LIBTOOL="$my_libtool \$(LTFLAGS)"
 322       libtoolversion=`$my_libtool --version`
 323       case $libtoolversion in
 324           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 325               SH_LIBTOOL='$(LIBTOOL)'
 326               SHLTCFLAGS="-prefer-pic"
 327               LTCFLAGS="-prefer-non-pic -static"
 328               ;;
 329           *)
 330               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 331               SHLTCFLAGS=""
 332               LTCFLAGS=""
 333               ;;
 334       esac
 335       ;;
 336 esac
 337 APACHE_SUBST(SHLTCFLAGS)
 338 APACHE_SUBST(LTCFLAGS)
 339
 340 case $host in
 341   *-apple-aux3*)
 342       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 343       ;;
 344   *os2-emx*)
 345       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 346       ;;
 347   *-linux-*)
 348       case `uname -r` in
 349         # Unserialized accept() was not recommended until Linux 2.2.
 350         [[01]].* | 2.[[01]]* )
 351             ;;
 352         * )
 353             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 354             ;;
 355       esac
 356       ;;
 357   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 358       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 359       ;;
 360   *-solaris2*)
 361       dnl This is a hack -- we should be using AC_TRY_RUN instead
 362       ap_platform_runtime_link_flag="-R"
 363       dnl solaris 8 and above don't have a thundering herd
 364       dnl not sure about rev's before this one.
 365       case `uname -r` in
 366         5.[[567]]*)
 367             ;;
 368         * )
 369             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 370             ;;
 371       esac
 372       ;;
 373   *cygwin*)
 374       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 375       ;;
 376   *mingw32*)
 377       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 378       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 379       APR_SETIFNULL(ac_cv_func_times, [no])
 380       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 381       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 382       ;;
 383   *aix*)
 384       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 385       if test $aixver -ge 4320; then
 386         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 387       fi
 388       ;;
 389   *os390*)
 390       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 391       ;;
 392 esac
 393
 394 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 395
 396 dnl
 397 dnl Process command line arguments. This is done early in the process so the
 398 dnl user can get feedback quickly in case of an error.
 399 dnl
 400 dnl ### need to move some of the arguments "up here"
 401
 402 dnl ## Check for programs
 403
 404 AC_PATH_PROG(RM, rm)
 405 AC_PATH_PROG(PKGCONFIG, pkg-config)
 406 AC_PATH_PROG(RSYNC, rsync)
 407 AC_PROG_AWK
 408 AC_PROG_LN_S
 409 AC_CHECK_TOOL(RANLIB, ranlib, true)
 410 dnl AC_PATH_PROG(PERL_PATH, perl)
 411 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 412
 413 # Hard-coded install programs
 414 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 415 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 416 APACHE_SUBST(MKINSTALLDIRS)
 417 APACHE_SUBST(INSTALL)
 418
 419 dnl Various OS checks that apparently set required flags
 420 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 421 AC_USE_SYSTEM_EXTENSIONS
 422 ], [
 423 AC_AIX
 424 AC_MINIX
 425 ])
 426
 427 AC_ISC_POSIX
 428
 429 # Ensure that satisfactory versions of apr and apr-util are
 430 # found if external copies are configured.
 431 if test "${apr_found}" = "yes"; then
 432   # Require at least APR 1.3.x otherwise fail
 433   APACHE_CHECK_APxVER([apr], 1, 3)
 434 fi
 435
 436 if test "${apu_found}" = "yes"; then
 437   # Require at least APR-util 1.3.x otherwise fail
 438   if test "${apr_found}" = "yes"; then
 439     # we need to add the APR includes to CPPFLAGS
 440     apu_ckver_CPPFLAGS="$CPPFLAGS"
 441     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 442     APACHE_CHECK_APxVER([apu], 1, 3)
 443     CPPFLAGS="$apu_ckver_CPPFLAGS"
 444   else
 445     APACHE_CHECK_APxVER([apu], 1, 3)
 446   fi
 447 fi
 448
 449 dnl Check for what we can generate dependency files with
 450 APR_CHECK_DEPEND
 451
 452 dnl ## Check for libraries
 453
 454 dnl ## Check for header files
 455
 456 dnl I think these are just used all over the place, so just check for
 457 dnl them at the base of the tree. If some are specific to a single
 458 dnl directory, they should be moved (Comment #Spoon)
 459
 460 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 461 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 462 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 463
 464 AC_HEADER_STDC
 465 AC_CHECK_HEADERS( \
 466 string.h \
 467 limits.h \
 468 unistd.h \
 469 sys/socket.h \
 470 pwd.h \
 471 grp.h \
 472 strings.h \
 473 sys/prctl.h \
 474 sys/processor.h \
 475 sys/sem.h \
 476 sys/sdt.h \
 477 sys/loadavg.h
 478 )
 479 AC_HEADER_SYS_WAIT
 480
 481 dnl ## Check for typedefs, structures, and compiler characteristics.
 482
 483 AC_C_CONST
 484
 485 dnl ## Check for library functions
 486 dnl ## sqrt() only needed in support/ab.c
 487 saved_LIBS="$LIBS"
 488 LIBS=""
 489 AC_SEARCH_LIBS(sqrt, m)
 490 MATH_LIBS="$LIBS"
 491 APACHE_SUBST(MATH_LIBS)
 492 LIBS="$saved_LIBS"
 493
 494 saved_LIBS="$LIBS"
 495 LIBS=""
 496 AC_SEARCH_LIBS(crypt, crypt)
 497 CRYPT_LIBS="$LIBS"
 498 APACHE_SUBST(CRYPT_LIBS)
 499 LIBS="$saved_LIBS"
 500
 501 dnl See Comment #Spoon
 502
 503 AC_CHECK_FUNCS( \
 504 getpwnam \
 505 getgrnam \
 506 initgroups \
 507 bindprocessor \
 508 prctl \
 509 timegm \
 510 getpgid \
 511 fopen64 \
 512 getloadavg
 513 )
 514
 515 dnl confirm that a void pointer is large enough to store a long integer
 516 APACHE_CHECK_VOID_PTR_LEN
 517
 518 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 519 [AC_TRY_RUN(#define _GNU_SOURCE
 520 #include <unistd.h>
 521 #include <sys/syscall.h>
 522 #include <sys/types.h>
 523 int main(int argc, char **argv) {
 524 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 525 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 526 if test "$ac_cv_gettid" = "yes"; then
 527     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 528 fi
 529
 530 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 531 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 532 [AC_TRY_COMPILE([#include <sys/types.h>
 533 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 534   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 535 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 536     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 537 fi
 538
 539 APACHE_CHECK_SYSTEMD
 540
 541 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 542
 543 case $host in
 544     *aix*)
 545         # for 32-bit builds, increase MAXDATA to allow lots of threads
 546         if test x$OBJECT_MODE != x64; then
 547             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 548         fi
 549         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 550         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 551         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 552         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 553         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 554         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 555         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 556         ;;
 557     *os390*)
 558         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 559         ;;
 560     *)
 561         OS_SPECIFIC_VARS=""
 562 esac
 563
 564 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 565         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 566         [PORT=80])
 567
 568 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 569         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 570         [SSLPORT=443])
 571
 572 DTRACE=true
 573 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 574 [
 575   enable_dtrace=$enableval
 576   if test "$enableval" = "yes"; then
 577     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 578     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 579   fi
 580 ],
 581 [
 582   enable_dtrace=no
 583 ])
 584
 585 dnl Disabled dtrace build for now.
 586 enable_dtrace=no
 587
 588 case $host in
 589   *-solaris2*)
 590     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 591         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 592                   [Enable DTrace probes])
 593         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 594         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 595     fi
 596     ;;
 597 esac
 598
 599 APACHE_SUBST(DTRACE)
 600
 601 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 602 [
 603     if test "$enableval" = "yes"; then
 604         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 605                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 606         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 607     fi
 608 ])dnl
 609
 610 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 611 [
 612     if test "$enableval" = "yes"; then
 613         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 614                   [Allow modules to run hook after a fatal exception])
 615     fi
 616 ])dnl
 617
 618 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 619 [
 620   LOAD_ALL_MODULES=$enableval
 621   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 622 ],
 623 [
 624   LOAD_ALL_MODULES="no"
 625 ])
 626
 627 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 628 [
 629   if test "$enableval" = "yes"; then
 630     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 631     if test "$GCC" = "yes"; then
 632       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 633       APACHE_ADD_GCC_CFLAG([-std=c89])
 634       APACHE_ADD_GCC_CFLAG([-Werror])
 635       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 636       APACHE_ADD_GCC_CFLAG([-Wformat])
 637       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 638       APACHE_ADD_GCC_CFLAG([-Wunused])
 639     elif test "$AIX_XLC" = "yes"; then
 640       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 641     fi
 642     if test "x$enable_load_all_modules" = "x"; then
 643       LOAD_ALL_MODULES=yes
 644       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 645     fi
 646     if test "x$enable_bucketeer" = "x"; then
 647       enable_bucketeer=yes
 648       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 649     fi
 650   fi
 651 ])dnl
 652
 653 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 654 [
 655   if test "$enableval" = "yes"; then
 656     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 657     if test "$GCC" = "yes"; then
 658       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 659       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 660       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 661       APACHE_ADD_GCC_CFLAG([-Wformat])
 662       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 663       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 664     elif test "$AIX_XLC" = "yes"; then
 665       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 666     fi
 667   fi
 668 ])dnl
 669
 670 dnl Conditionally enable PIE support for GNU toolchains.
 671 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 672 if test "$enable_pie" = "yes"; then
 673    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 674      save_CFLAGS=$CFLAGS
 675      save_LDFLAGS=$LDFLAGS
 676      CFLAGS="$CFLAGS -fPIE"
 677      LDFLAGS="$LDFLAGS -pie"
 678      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 679       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 680      CFLAGS=$save_CFLAGS
 681      LDFLAGS=$save_LDFLAGS
 682    ])
 683    if test "$ap_cv_cc_pie" = "yes"; then
 684      PICFLAGS="-fPIE"
 685      PILDFLAGS="-pie"
 686    else
 687      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 688    fi
 689 fi
 690 APACHE_SUBST(PICFLAGS)
 691 APACHE_SUBST(PILDFLAGS)
 692
 693 AC_ARG_WITH(valgrind,
 694   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 695                           (optionally: set path to valgrind headers) ],
 696   [ if test "$withval" != no; then
 697       if test "$withval" = yes; then
 698         withval=/usr/include/valgrind
 699       fi
 700       APR_ADDTO(CPPFLAGS, -I$withval)
 701       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 702       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 703         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 704         [AC_MSG_ERROR(valgrind headers not found) ]
 705       )
 706     fi ]
 707 )
 708
 709 prefix="$orig_prefix"
 710 APACHE_ENABLE_MODULES
 711
 712 dnl reading config stubs
 713 esyscmd(./build/config-stubs .)
 714
 715 APACHE_SUBST(progname)
 716 APACHE_SUBST(OS)
 717 APACHE_SUBST(OS_DIR)
 718 APACHE_SUBST(BUILTIN_LIBS)
 719 APACHE_SUBST(SHLIBPATH_VAR)
 720 APACHE_SUBST(OS_SPECIFIC_VARS)
 721 APACHE_SUBST(HTTPD_LIBS)
 722
 723 PRE_SHARED_CMDS='echo ""'
 724 POST_SHARED_CMDS='echo ""'
 725
 726 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 727
 728 if test "$apache_need_shared" = "yes"; then
 729   if test -f $ac_aux_dir/ltconfig; then
 730     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 731   fi
 732   shared_build="shared-build"
 733 fi
 734
 735 dnl enable_so tells us if *any* modules can be built as DSOs
 736
 737 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 738   case $host in
 739     *-ibm-aix*)
 740       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 741       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 742       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 743       ;;
 744     *os390)
 745       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 746       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 747   esac
 748   MOD_SO_ENABLED=yes
 749 fi
 750 AC_SUBST(MOD_SO_ENABLED)
 751
 752 APACHE_SUBST(PRE_SHARED_CMDS)
 753 APACHE_SUBST(POST_SHARED_CMDS)
 754 APACHE_SUBST(shared_build)
 755
 756 AC_ARG_WITH(program-name,
 757 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 758   progname="$withval" ], [
 759   progname="httpd"] )
 760
 761 # SuExec parameters
 762 AC_ARG_WITH(suexec-bin,
 763 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 764   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 765 ] )
 766
 767 AC_ARG_WITH(suexec-caller,
 768 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 769   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 770
 771 AC_ARG_WITH(suexec-userdir,
 772 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 773   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 774
 775 AC_ARG_WITH(suexec-docroot,
 776 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 777   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 778
 779 AC_ARG_WITH(suexec-uidmin,
 780 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 781   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 782
 783 AC_ARG_WITH(suexec-gidmin,
 784 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 785   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 786
 787 AC_ARG_WITH(suexec-logfile,
 788 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 789   if test "x$withval" = "xyes"; then
 790     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 791   elif test "x$withval" != "xno"; then
 792     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 793   fi
 794 ])
 795
 796 AC_ARG_WITH(suexec-syslog,
 797 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 798   if test $withval = "yes"; then
 799     if test "x${with_suexec_logfile}" != "xno"; then
 800       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 801       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 802     fi
 803     AC_CHECK_FUNCS([vsyslog], [], [
 804        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 805     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 806   fi
 807 ])
 808
 809
 810 AC_ARG_WITH(suexec-safepath,
 811 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 812   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 813
 814 AC_ARG_WITH(suexec-umask,
 815 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 816   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 817
 818 INSTALL_SUEXEC=setuid
 819 AC_ARG_ENABLE([suexec-capabilities],
 820 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 821   if test "$enableval" = "yes"; then
 822     INSTALL_SUEXEC=caps
 823     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 824               [Enable if suexec is installed with Linux capabilities, not setuid])
 825   fi
 826 ])
 827 APACHE_SUBST(INSTALL_SUEXEC)
 828
 829 dnl APR should go after the other libs, so the right symbols can be picked up
 830 if test x${apu_found} != xobsolete; then
 831   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 832 fi
 833 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 834 APACHE_SUBST(AP_LIBS)
 835 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 836 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 837
 838 AC_DEFINE(AP_USING_AUTOCONF, 1,
 839                 [Using autoconf to configure Apache])
 840
 841 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 842     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 843               [This platform doesn't suffer from the thundering herd problem])
 844 fi
 845
 846 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 847     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 848               [Listening sockets are non-blocking when there are more than 1])
 849 fi
 850
 851 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 852
 853 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 854 [
 855   v4mapped=$enableval
 856 ],
 857 [
 858     case $host in
 859     *freebsd[[1234]].*)
 860         v4mapped=yes
 861         ;;
 862     *freebsd*|*netbsd*|*openbsd*)
 863         v4mapped=no
 864         ;;
 865     *)
 866         v4mapped=yes
 867         ;;
 868     esac
 869     if ap_mpm_is_enabled winnt; then
 870         dnl WinNT MPM doesn't support this.
 871         v4mapped=no
 872     fi
 873 ])
 874
 875 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 876     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 877               [Allow IPv4 connections on IPv6 listening sockets])
 878 fi
 879
 880 AC_ARG_ENABLE(bsd-makefiles,APACHE_HELP_STRING(--enable-bsd-makefiles,use BSD Makefile syntax),
 881 [
 882   FORCE_BSD_MAKEFILE=$enableval
 883   AC_MSG_NOTICE([Setting "FORCE_BSD_MAKEFILE" to $FORCE_BSD_MAKEFILE])
 884 ],
 885 [
 886   FORCE_BSD_MAKEFILE="auto"
 887 ])
 888
 889 AC_ARG_WITH([test-suite],
 890     APACHE_HELP_STRING([--with-test-suite=PATH], [enable in-tree 'make check' with the given Apache::Test suite location]),
 891     [
 892         if test "x$withval" = "xyes"; then
 893             AC_MSG_ERROR([option --with-test-suite requires a directory]);
 894         else
 895             test -f "$withval/Makefile.PL" || AC_MSG_ERROR([--with-test-suite directory $withval does not contain the expected Makefile.PL])
 896             TEST_SUITE_LOCATION="$withval"
 897         fi
 898     ],
 899     [ TEST_SUITE_LOCATION="no" ]
 900 )
 901
 902 APACHE_SUBST(TEST_SUITE_LOCATION)
 903
 904 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 905 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 906 APACHE_FAST_OUTPUT(support/Makefile)
 907
 908 if test -d ./test; then
 909     APACHE_FAST_OUTPUT(test/Makefile)
 910 fi
 911
 912 dnl ## Finalize the variables
 913 AC_MSG_NOTICE([])
 914 AC_MSG_NOTICE([Restore user-defined environment settings...])
 915 AC_MSG_NOTICE([])
 916
 917 APACHE_CONF_SEL_CC=${CC}
 918 APACHE_CONF_SEL_CFLAGS=${CFLAGS}
 919 APACHE_CONF_SEL_LDFLAGS=${LDFLAGS}
 920 APACHE_CONF_SEL_LIBS=${LIBS}
 921 APACHE_CONF_SEL_CPPFLAGS=${CPPFLAGS}
 922 APACHE_CONF_SEL_CPP=${CPP}
 923
 924 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 925 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 926 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 927 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 928 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 929 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 930
 931 AC_MSG_NOTICE([])
 932 AC_MSG_NOTICE([Construct makefiles and header files...])
 933 AC_MSG_NOTICE([])
 934
 935 APACHE_GEN_CONFIG_VARS
 936
 937 dnl ## Build modules.c
 938 rm -f modules.c
 939 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 940
 941 APR_EXPAND_VAR(ap_prefix, $prefix)
 942 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 943         [Root directory of the Apache install area])
 944 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 945         [Location of the config file, relative to the Apache root directory])
 946 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 947         [Location of the MIME types config file, relative to the Apache root directory])
 948
 949 perlbin=`$ac_aux_dir/PrintPath perl`
 950 if test "x$perlbin" = "x"; then
 951     perlbin="/replace/with/path/to/perl/interpreter"
 952 fi
 953 AC_SUBST(perlbin)
 954
 955 dnl If we are running on a BSD variant, see if we need to use the BSD .include syntax.
 956
 957 ap_make_include=include
 958 ap_make_ifdef=ifdef
 959 ap_make_else=else
 960 ap_make_endif=endif
 961 ap_make_delimiter=' '
 962 if test "x$FORCE_BSD_MAKEFILE" = "xno"; then
 963   BSD_MAKEFILE=no
 964 elif test "x$FORCE_BSD_MAKEFILE" = "xyes"; then
 965   BSD_MAKEFILE=yes
 966 else
 967   case $host in
 968   *bsd*)
 969       # Check whether they've installed GNU make
 970       if make --version > /dev/null 2>&1; then
 971           BSD_MAKEFILE=no
 972       elif gmake --version > /dev/null 2>&1; then
 973           BSD_MAKEFILE=no
 974       else
 975           BSD_MAKEFILE=yes
 976       fi
 977       ;;
 978   *)
 979       BSD_MAKEFILE=no
 980       ;;
 981   esac
 982 fi
 983 if test "x$BSD_MAKEFILE" = "xyes"; then
 984   ap_make_include=.include
 985   ap_make_ifdef=.ifdef
 986   ap_make_else=.else
 987   ap_make_endif=.endif
 988   ap_make_delimiter='"'
 989 fi
 990 AC_MSG_NOTICE([using BSD Makefile syntax... $BSD_MAKEFILE])
 991
 992 AC_SUBST(ap_make_include)
 993 AC_SUBST(ap_make_ifdef)
 994 AC_SUBST(ap_make_else)
 995 AC_SUBST(ap_make_endif)
 996 AC_SUBST(ap_make_delimiter)
 997
 998 dnl Ensure that docs/conf is created.
 999 test -d docs/conf||$mkdir_p docs/conf
1000
1001 AC_CONFIG_FILES(docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh)
1002 AC_CONFIG_COMMANDS([default], [true], [APACHE_GEN_MAKEFILES])
1003 AC_OUTPUT
1004
1005 AC_MSG_NOTICE([summary of build options:
1006
1007     Server Version: ${HTTPD_VERSION}
1008     Install prefix: ${prefix}
1009     C compiler:     ${APACHE_CONF_SEL_CC}
1010     CFLAGS:         ${APACHE_CONF_SEL_CFLAGS}
1011     LDFLAGS:        ${APACHE_CONF_SEL_LDFLAGS}
1012     LIBS:           ${APACHE_CONF_SEL_LIBS}
1013     CPPFLAGS:       ${APACHE_CONF_SEL_CPPFLAGS}
1014     C preprocessor: ${APACHE_CONF_SEL_CPP}
1015 ])