granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  68 AC_SUBST([MANPAGE_DATE], [manpage_date])
  69
  70 AC_MSG_CHECKING([for supported architecture])
  71 arch_m32=
  72 arch_mx32=
  73 case "$host_cpu" in
  74 bfin)
  75         arch=bfin
  76         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  77         ;;
  78 i[[3456]]86|pentium)
  79         arch=i386
  80         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  81         ;;
  82 ia64)
  83         arch=ia64
  84         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  85         ;;
  86 m68k)
  87         arch=m68k
  88         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  89         ;;
  90 sparc64*)
  91         arch=sparc64
  92         arch_m32=sparc
  93         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  94         ;;
  95 sparc*)
  96         arch=sparc
  97         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  98         ;;
  99 metag*)
 100         arch=metag
 101         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 102         ;;
 103 mips*)
 104         arch=mips
 105         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 106         ;;
 107 alpha*)
 108         arch=alpha
 109         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 110         ;;
 111 powerpc*)
 112         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 113         AC_TRY_COMPILE(
 114 [#ifndef __LP64__
 115 # error 32 bit
 116 #endif], [], arch=powerpc64, arch=powerpc)
 117         if test "$arch" = "powerpc64"; then
 118                 arch_m32=powerpc
 119                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 120         fi
 121         ;;
 122 arm*)
 123         arch=arm
 124         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 125         ;;
 126 aarch64*)
 127         arch=aarch64
 128         arch_m32=arm
 129         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 130         ;;
 131 avr32*)
 132         arch=avr32
 133         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 134         ;;
 135 arc*)
 136         arch=arc
 137         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 138         ;;
 139 s390)
 140         arch=s390
 141         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 142         ;;
 143 s390x)
 144         arch=s390x
 145         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 146         ;;
 147 hppa*|parisc*)
 148         arch=hppa
 149         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 150         ;;
 151 sh64*)
 152         arch=sh64
 153         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 154         ;;
 155 sh*)
 156         arch=sh
 157         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 158         ;;
 159 x86?64*)
 160         arch_m32=i386
 161         AC_TRY_COMPILE(
 162 [#ifndef __ILP32__
 163 # error not x32
 164 #endif], [], arch=x32, arch=x86_64)
 165         if test "$arch" = "x86_64"; then
 166                 arch_mx32=x32
 167                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 168         else
 169                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 170         fi
 171         ;;
 172 cris|crisv10)
 173         arch=crisv10
 174         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 175         ;;
 176 crisv32)
 177         arch=crisv32
 178         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 microblaze*)
 185         arch=microblaze
 186         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 187         ;;
 188 nios2*)
 189         arch=nios2
 190         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 191         ;;
 192
 193 or1k*)
 194         arch=or1k
 195         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 196         ;;
 197
 198 xtensa*)
 199         arch=xtensa
 200         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 201         ;;
 202
 203 riscv*)
 204         arch=riscv
 205         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 206         ;;
 207
 208 *)
 209         AC_MSG_RESULT([NO!])
 210         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 211         ;;
 212 esac
 213 AC_MSG_RESULT($arch)
 214
 215 test -n "$arch_m32" ||
 216         arch_m32=$arch
 217 test -n "$arch_mx32" ||
 218         arch_mx32=$arch
 219 AC_SUBST(arch)
 220 AC_SUBST(arch_m32)
 221 AC_SUBST(arch_mx32)
 222
 223 MIPS_ABI=
 224 if test "$arch" = mips; then
 225         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 226                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 227                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 228
 229         # requires GCC >= 3.4
 230         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 231                 [AC_COMPILE_IFELSE(
 232                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 233                         [st_cv_mips_abi=o32],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=n32],
 237                 [AC_COMPILE_IFELSE(
 238                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 239                         [st_cv_mips_abi=n64],
 240                         [st_cv_mips_abi=unknown])])])])
 241
 242         case "$st_cv_mips_abi" in
 243                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 244                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 245                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 246                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 247         esac
 248         MIPS_ABI="$st_cv_mips_abi"
 249 fi
 250 AC_SUBST(MIPS_ABI)
 251
 252 AC_ARG_ENABLE([arm-oabi],
 253               [AS_HELP_STRING([--enable-arm-oabi],
 254                               [enable OABI support on ARM EABI])],
 255               [], [enable_arm_oabi=no])
 256 case "$enable_arm_oabi" in
 257         yes) enable_arm_oabi=1 ;;
 258         no) enable_arm_oabi=0 ;;
 259         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 260 esac
 261 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 262                    [Define to 1 if you want OABI support on ARM EABI.])
 263
 264 AC_C_BIGENDIAN
 265 AC_C_TYPEOF
 266
 267 AC_TYPE_UID_T
 268
 269 AC_CHECK_FUNCS(m4_normalize([
 270         accept4
 271         fallocate
 272         fanotify_mark
 273         fopen64
 274         fork
 275         fputs_unlocked
 276         fstatat
 277         ftruncate
 278         futimens
 279         if_indextoname
 280         open64
 281         prctl
 282         preadv
 283         process_vm_readv
 284         pwritev
 285         readahead
 286         signalfd
 287         stpcpy
 288         strerror
 289         strndup
 290         strsignal
 291         sync_file_range
 292         utimensat
 293 ]))
 294
 295 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 296
 297 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 298
 299 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 300 [#include <asm/posix_types.h>])
 301
 302 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 303 [#include <sys/types.h>
 304 #include <asm/stat.h>])
 305
 306 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 307
 308 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 309 [#include <sys/types.h>
 310 #include <asm/stat.h>])
 311
 312 AC_CHECK_TYPES(m4_normalize([
 313         struct pt_all_user_regs,
 314         struct ia64_fpreg,
 315         struct ptrace_peeksiginfo_args
 316 ]),,, [#include <sys/ptrace.h>])
 317
 318 AC_CHECK_TYPES(m4_normalize([
 319         struct flock,
 320         struct flock64,
 321         struct __kernel_flock,
 322         struct __kernel_flock64
 323 ]),,,
 324 [#include <sys/types.h>
 325 #include <linux/fcntl.h>])
 326
 327 AC_CHECK_TYPES(m4_normalize([
 328         struct crypto_report_aead,
 329         struct crypto_report_blkcipher,
 330         struct crypto_report_cipher,
 331         struct crypto_report_hash,
 332         struct crypto_report_rng
 333 ]),,, [#include <linux/cryptouser.h>])
 334
 335 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 336
 337 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 338
 339 AC_CHECK_MEMBERS(m4_normalize([
 340         siginfo_t.si_syscall,
 341         siginfo_t.si_timerid,
 342         siginfo_t.si_overrun
 343 ]),,, [#include <signal.h>])
 344
 345 AC_CHECK_MEMBERS(m4_normalize([
 346         struct perf_event_attr.precise_ip,
 347         struct perf_event_attr.mmap_data,
 348         struct perf_event_attr.sample_id_all,
 349         struct perf_event_attr.exclude_host,
 350         struct perf_event_attr.exclude_guest,
 351         struct perf_event_attr.exclude_callchain_kernel,
 352         struct perf_event_attr.exclude_callchain_user,
 353         struct perf_event_attr.mmap2,
 354         struct perf_event_attr.comm_exec,
 355         struct perf_event_attr.use_clockid,
 356         struct perf_event_attr.context_switch,
 357         struct perf_event_attr.write_backward,
 358         struct perf_event_attr.bp_type,
 359         struct perf_event_attr.config1,
 360         struct perf_event_attr.config2,
 361         struct perf_event_attr.branch_sample_type,
 362         struct perf_event_attr.sample_regs_user,
 363         struct perf_event_attr.sample_stack_user,
 364         struct perf_event_attr.sample_regs_intr,
 365         struct perf_event_attr.aux_watermark,
 366         struct perf_event_attr.sample_max_stack
 367 ]),,, [#include <linux/perf_event.h>])
 368
 369 AC_CHECK_HEADERS(m4_normalize([
 370         asm/cachectl.h
 371         asm/sysmips.h
 372         bluetooth/bluetooth.h
 373         elf.h
 374         inttypes.h
 375         linux/bsg.h
 376         linux/cryptouser.h
 377         linux/dm-ioctl.h
 378         linux/dqblk_xfs.h
 379         linux/falloc.h
 380         linux/fib_rules.h
 381         linux/fiemap.h
 382         linux/genetlink.h
 383         linux/hiddev.h
 384         linux/if_addr.h
 385         linux/ip_vs.h
 386         linux/ipc.h
 387         linux/mmtimer.h
 388         linux/msg.h
 389         linux/neighbour.h
 390         linux/netfilter/nfnetlink.h
 391         linux/nsfs.h
 392         linux/perf_event.h
 393         linux/quota.h
 394         linux/seccomp.h
 395         linux/securebits.h
 396         linux/sem.h
 397         linux/shm.h
 398         linux/userfaultfd.h
 399         linux/utsname.h
 400         mqueue.h
 401         netinet/sctp.h
 402         netipx/ipx.h
 403         scsi/sg.h
 404         stropts.h
 405         sys/conf.h
 406         sys/eventfd.h
 407         sys/fanotify.h
 408         sys/ipc.h
 409         sys/msg.h
 410         sys/quota.h
 411         sys/reg.h
 412         sys/sem.h
 413         sys/shm.h
 414         sys/signalfd.h
 415         sys/xattr.h
 416         ustat.h
 417 ]))
 418
 419 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 420
 421 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 422
 423 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 424
 425 AC_CHECK_HEADERS(m4_normalize([
 426         linux/netfilter_arp/arp_tables.h
 427         linux/netfilter_bridge/ebtables.h
 428         linux/netfilter_ipv4/ip_tables.h
 429         linux/netfilter_ipv6/ip6_tables.h
 430 ]),,, [#include <netinet/in.h>
 431 #include <net/if.h>])
 432
 433 AC_CHECK_HEADERS([linux/input.h], [
 434         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 435 ])
 436
 437 AC_CHECK_HEADERS([linux/bpf.h], [
 438         st_CHECK_UNION_BPF_ATTR([attach_flags])
 439         st_CHECK_UNION_BPF_ATTR([bpf_fd])
 440         st_CHECK_UNION_BPF_ATTR([flags])
 441         st_CHECK_UNION_BPF_ATTR([inner_map_fd])
 442         st_CHECK_UNION_BPF_ATTR([prog_flags])
 443 ])
 444
 445 AC_CHECK_TYPES([struct br_port_msg],,, [#include <linux/if_bridge.h>])
 446 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 447 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 448 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 449
 450 AC_CHECK_TYPES(m4_normalize([
 451         struct rta_mfc_stats,
 452         struct rtvia
 453 ]),,, [#include <linux/rtnetlink.h>])
 454
 455 AC_CHECK_TYPES([struct statfs], [
 456         AC_CHECK_MEMBERS(m4_normalize([
 457                 struct statfs.f_frsize,
 458                 struct statfs.f_flags,
 459                 struct statfs.f_fsid.val,
 460                 struct statfs.f_fsid.__val
 461         ]),,, [#include <linux/types.h>
 462 #include <asm/statfs.h>])
 463 ],, [#include <linux/types.h>
 464 #include <asm/statfs.h>])
 465
 466 AC_CHECK_TYPES([struct statfs64], [
 467         AC_CHECK_MEMBERS(m4_normalize([
 468                 struct statfs64.f_frsize,
 469                 struct statfs64.f_flags,
 470                 struct statfs64.f_fsid.val,
 471                 struct statfs64.f_fsid.__val
 472         ]),,, [#include <linux/types.h>
 473 #include <asm/statfs.h>])
 474 ],, [#include <linux/types.h>
 475 #include <asm/statfs.h>])
 476
 477 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 478
 479 AC_CHECK_HEADERS([linux/btrfs.h], [
 480         AC_CHECK_MEMBERS(m4_normalize([
 481                 struct btrfs_ioctl_feature_flags.compat_flags,
 482                 struct btrfs_ioctl_fs_info_args.nodesize,
 483                 struct btrfs_ioctl_defrag_range_args.start,
 484                 struct btrfs_ioctl_search_args_v2.buf_size
 485                 ]),,, [ #include <stdio.h>
 486 #include <linux/btrfs.h>])
 487         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 488                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 489 #include <linux/btrfs.h>])])
 490
 491 AC_CHECK_DECLS([sys_errlist])
 492 AC_CHECK_DECLS(m4_normalize([
 493         PTRACE_PEEKUSER,
 494         PTRACE_POKEUSER
 495 ]),,, [#include <sys/ptrace.h>])
 496
 497 AC_CHECK_DECLS(m4_normalize([
 498         P_PID,
 499         P_PPID,
 500         P_PGID,
 501         P_SID,
 502         P_CID,
 503         P_UID,
 504         P_GID,
 505         P_ALL,
 506         P_LWPID
 507 ]),,, [#include <sys/wait.h>])
 508
 509 AC_CHECK_DECLS(m4_normalize([
 510         LO_FLAGS_READ_ONLY,
 511         LO_FLAGS_USE_AOPS,
 512         LO_FLAGS_AUTOCLEAR,
 513         LO_FLAGS_PARTSCAN,
 514         LO_FLAGS_DIRECT_IO
 515 ]),,, [#include <linux/loop.h>])
 516
 517 AC_CHECK_DECLS(m4_normalize([
 518         CTL_PROC,
 519         CTL_ARLAN,
 520         CTL_S390DBF,
 521         CTL_SUNRPC,
 522         CTL_PM,
 523         CTL_FRV,
 524         KERN_PRINTK_RATELIMIT,
 525         KERN_PRINTK_RATELIMIT_BURST,
 526         KERN_PTY,
 527         KERN_NGROUPS_MAX,
 528         KERN_SPARC_SCONS_PWROFF,
 529         KERN_HZ_TIMER,
 530         KERN_UNKNOWN_NMI_PANIC,
 531         KERN_BOOTLOADER_TYPE,
 532         KERN_RANDOMIZE,
 533         KERN_SETUID_DUMPABLE,
 534         KERN_SPIN_RETRY,
 535         KERN_ACPI_VIDEO_FLAGS,
 536         KERN_IA64_UNALIGNED,
 537         KERN_COMPAT_LOG,
 538         KERN_MAX_LOCK_DEPTH,
 539         KERN_NMI_WATCHDOG,
 540         KERN_PANIC_ON_NMI,
 541         NET_LLC,
 542         NET_NETFILTER,
 543         NET_DCCP,
 544         NET_IRDA,
 545         NET_CORE_DESTROY_DELAY,
 546         NET_CORE_BUDGET,
 547         NET_CORE_AEVENT_ETIME,
 548         NET_CORE_AEVENT_RSEQTH,
 549         NET_CORE_WARNINGS,
 550         NET_IPV4_IGMP_MAX_MSF,
 551         NET_TCP_NO_METRICS_SAVE,
 552         NET_TCP_DEFAULT_WIN_SCALE,
 553         NET_TCP_MODERATE_RCVBUF,
 554         NET_TCP_TSO_WIN_DIVISOR,
 555         NET_TCP_BIC_BETA,
 556         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 557         NET_TCP_CONG_CONTROL,
 558         NET_TCP_ABC,
 559         NET_IPV4_IPFRAG_MAX_DIST,
 560         NET_TCP_MTU_PROBING,
 561         NET_TCP_BASE_MSS,
 562         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 563         NET_TCP_DMA_COPYBREAK,
 564         NET_TCP_SLOW_START_AFTER_IDLE,
 565         NET_CIPSOV4_CACHE_ENABLE,
 566         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 567         NET_CIPSOV4_RBM_OPTFMT,
 568         NET_CIPSOV4_RBM_STRICTVALID,
 569         NET_TCP_AVAIL_CONG_CONTROL,
 570         NET_TCP_ALLOWED_CONG_CONTROL,
 571         NET_TCP_MAX_SSTHRESH,
 572         NET_TCP_FRTO_RESPONSE,
 573         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 574         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 575         NET_IPV4_CONF_ARP_ANNOUNCE,
 576         NET_IPV4_CONF_ARP_IGNORE,
 577         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 578         NET_IPV4_CONF_ARP_ACCEPT,
 579         NET_IPV4_CONF_ARP_NOTIFY,
 580         NET_IPV6_MLD_MAX_MSF,
 581         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 582         VM_MAX_MAP_COUNT,
 583         VM_LAPTOP_MODE,
 584         VM_BLOCK_DUMP,
 585         VM_HUGETLB_GROUP,
 586         VM_VFS_CACHE_PRESSURE,
 587         VM_LEGACY_VA_LAYOUT,
 588         VM_SWAP_TOKEN_TIMEOUT
 589 ]),,,
 590 [#include <sys/types.h>
 591 #include <linux/sysctl.h>])
 592
 593 AC_CHECK_DECLS(m4_normalize([
 594         V4L2_FIELD_ANY,
 595         V4L2_FIELD_NONE,
 596         V4L2_FIELD_TOP,
 597         V4L2_FIELD_BOTTOM,
 598         V4L2_FIELD_INTERLACED,
 599         V4L2_FIELD_SEQ_TB,
 600         V4L2_FIELD_SEQ_BT,
 601         V4L2_FIELD_ALTERNATE,
 602         V4L2_FIELD_INTERLACED_TB,
 603         V4L2_FIELD_INTERLACED_BT,
 604         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 605         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 606         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 607         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 608         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 609         V4L2_BUF_TYPE_VBI_CAPTURE,
 610         V4L2_BUF_TYPE_VBI_OUTPUT,
 611         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 612         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 613         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 614         V4L2_BUF_TYPE_SDR_CAPTURE,
 615         V4L2_BUF_TYPE_SDR_OUTPUT,
 616         V4L2_TUNER_RADIO,
 617         V4L2_TUNER_ANALOG_TV,
 618         V4L2_TUNER_DIGITAL_TV,
 619         V4L2_MEMORY_MMAP,
 620         V4L2_MEMORY_USERPTR,
 621         V4L2_MEMORY_OVERLAY,
 622         V4L2_MEMORY_DMABUF,
 623         V4L2_COLORSPACE_SMPTE170M,
 624         V4L2_COLORSPACE_SMPTE240M,
 625         V4L2_COLORSPACE_REC709,
 626         V4L2_COLORSPACE_BT878,
 627         V4L2_COLORSPACE_470_SYSTEM_M,
 628         V4L2_COLORSPACE_470_SYSTEM_BG,
 629         V4L2_COLORSPACE_JPEG,
 630         V4L2_COLORSPACE_SRGB,
 631         V4L2_PRIORITY_UNSET,
 632         V4L2_PRIORITY_BACKGROUND,
 633         V4L2_PRIORITY_INTERACTIVE,
 634         V4L2_PRIORITY_RECORD,
 635         V4L2_FRMSIZE_TYPE_DISCRETE,
 636         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 637         V4L2_FRMSIZE_TYPE_STEPWISE,
 638         V4L2_FRMIVAL_TYPE_DISCRETE,
 639         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 640         V4L2_FRMIVAL_TYPE_STEPWISE,
 641         V4L2_CTRL_TYPE_INTEGER,
 642         V4L2_CTRL_TYPE_BOOLEAN,
 643         V4L2_CTRL_TYPE_MENU,
 644         V4L2_CTRL_TYPE_BUTTON,
 645         V4L2_CTRL_TYPE_INTEGER64,
 646         V4L2_CTRL_TYPE_CTRL_CLASS,
 647         V4L2_CTRL_TYPE_STRING,
 648         V4L2_CTRL_TYPE_BITMASK,
 649         V4L2_CTRL_TYPE_INTEGER_MENU
 650 ]),,, [#include <sys/time.h>
 651 #include <linux/ioctl.h>
 652 #include <linux/types.h>
 653 #include <linux/videodev2.h>])
 654
 655 AC_CHECK_MEMBERS(m4_normalize([
 656         struct v4l2_window.global_alpha,
 657         struct v4l2_sdr_format.buffersize
 658 ]),,, [#include <sys/time.h>
 659 #include <linux/ioctl.h>
 660 #include <linux/types.h>
 661 #include <linux/videodev2.h>])
 662
 663 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 664         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 665 #include <stdlib.h>
 666 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 667                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 668         if test $ac_cv_have_blkgetsize64 = yes; then
 669                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 670         fi)
 671
 672 AC_CHECK_SIZEOF([long])
 673 AC_CHECK_SIZEOF([long long])
 674 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 675 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 676 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 677
 678 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 679                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 680                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 681                         grep '^[0-9]')"
 682                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 683 if test "x$st_cv_SIGRTMIN" != xno; then
 684         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 685                            [SIGRTMIN defined in <asm/signal.h>])
 686 fi
 687 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 688                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 689                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 690                         grep ^0x)"
 691                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 692 if test "x$st_cv_SA_RESTORER" != xno; then
 693         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 694                            [SA_RESTORER defined in <asm/signal.h>])
 695 fi
 696
 697 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 698                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 699                                [st_cv_have___builtin_popcount=yes],
 700                                [st_cv_have___builtin_popcount=no])])
 701 if test "x$st_cv_have___builtin_popcount" = xyes; then
 702         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 703                   [Define to 1 if the system provides __builtin_popcount function])
 704 fi
 705
 706 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 707                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 708                                                 [[return !*program_invocation_name]])],
 709                                [st_cv_have_program_invocation_name=yes],
 710                                [st_cv_have_program_invocation_name=no])])
 711 if test "x$st_cv_have_program_invocation_name" = xyes; then
 712         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 713                   [Define to 1 if the system provides program_invocation_name variable])
 714 fi
 715
 716 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 717 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 718         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 719 fi
 720 AC_SUBST(dl_LIBS)
 721
 722 AC_PATH_PROG([PERL], [perl])
 723
 724 dnl stack trace with libunwind
 725 libunwind_CPPFLAGS=
 726 libunwind_LDFLAGS=
 727 libunwind_LIBS=
 728 AC_ARG_WITH([libunwind],
 729             [AS_HELP_STRING([--with-libunwind],
 730                             [use libunwind to implement stack tracing support])],
 731             [case "${withval}" in
 732              yes|no|check) ;;
 733              *) with_libunwind=yes
 734                 libunwind_CPPFLAGS="-I${withval}/include"
 735                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 736              esac],
 737             [with_libunwind=check]
 738 )
 739
 740 use_libunwind=no
 741 AS_IF([test "x$with_libunwind" != xno],
 742       [saved_CPPFLAGS="$CPPFLAGS"
 743        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 744
 745        AC_CHECK_HEADERS([libunwind-ptrace.h],
 746          [saved_LDFLAGS="$LDFLAGS"
 747           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 748
 749           AC_CHECK_LIB([unwind], [backtrace],
 750             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 751
 752              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 753              saved_LIBS="$LIBS"
 754              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 755
 756              AC_LINK_IFELSE(
 757                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 758                                 [[return !unw_create_addr_space(0, 0)]])
 759                ],
 760                [AC_MSG_RESULT([yes])
 761                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 762
 763                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 764                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 765                    use_libunwind=yes
 766                   ],
 767                   [if test "x$with_libunwind" != xcheck; then
 768                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 769                    fi
 770                   ],
 771                   [$libunwind_LIBS]
 772                 )
 773                ],
 774                [AC_MSG_RESULT([no])
 775                 if test "x$with_libunwind" != xcheck; then
 776                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 777                 fi
 778                ]
 779              )
 780
 781              LIBS="$saved_LIBS"
 782             ],
 783             [if test "x$with_libunwind" != xcheck; then
 784                AC_MSG_FAILURE([failed to find libunwind])
 785              fi
 786             ],
 787             [$libunwind_LIBS]
 788           )
 789
 790           LDFLAGS="$saved_LDFLAGS"
 791          ],
 792          [if test "x$with_libunwind" != xcheck; then
 793             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 794           fi
 795          ]
 796        )
 797
 798        CPPFLAGS="$saved_CPPFLAGS"
 799       ]
 800 )
 801
 802 dnl enable libunwind
 803 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 804 if test "x$use_libunwind" = xyes; then
 805         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 806         AC_SUBST(libunwind_LIBS)
 807         AC_SUBST(libunwind_LDFLAGS)
 808         AC_SUBST(libunwind_CPPFLAGS)
 809 fi
 810 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 811 AC_MSG_RESULT([$use_libunwind])
 812
 813 if test "$arch" = mips && test "$no_create" != yes; then
 814         mkdir -p linux/mips
 815         if $srcdir/linux/mips/genstub.sh linux/mips; then
 816                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 817         else
 818                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 819         fi
 820 fi
 821
 822 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 823 st_MPERS([mx32], [x86_64])
 824
 825 AX_VALGRIND_DFLT([sgcheck], [off])
 826 AX_VALGRIND_CHECK
 827
 828 AC_CONFIG_FILES([Makefile
 829                  tests/Makefile
 830                  tests-m32/Makefile
 831                  tests-mx32/Makefile
 832                  strace.1
 833                  strace.spec
 834                  debian/changelog])
 835 AC_OUTPUT