granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  40 AM_MAINTAINER_MODE
  41 AC_CANONICAL_HOST
  42
  43 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  44 AC_SUBST(RPM_CHANGELOGTIME)
  45 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  46 AC_SUBST(DEB_CHANGELOGTIME)
  47
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AX_PROG_CC_FOR_BUILD
  51 AC_PROG_INSTALL
  52 AC_PROG_RANLIB
  53
  54 AC_USE_SYSTEM_EXTENSIONS
  55 AX_CODE_COVERAGE
  56
  57 AC_MSG_CHECKING([for supported architecture])
  58 arch_m32=
  59 arch_mx32=
  60 case "$host_cpu" in
  61 bfin)
  62         arch=bfin
  63         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  64         ;;
  65 i[[3456]]86|pentium)
  66         arch=i386
  67         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  68         ;;
  69 ia64)
  70         arch=ia64
  71         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  72         ;;
  73 m68k)
  74         arch=m68k
  75         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  76         ;;
  77 sparc64*)
  78         arch=sparc64
  79         arch_m32=sparc
  80         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  81         ;;
  82 sparc*)
  83         arch=sparc
  84         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  85         ;;
  86 metag*)
  87         arch=metag
  88         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  89         ;;
  90 mips*)
  91         arch=mips
  92         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  93         ;;
  94 alpha*)
  95         arch=alpha
  96         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  97         ;;
  98 powerpc*)
  99         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 100         AC_TRY_COMPILE(
 101 [#ifndef __LP64__
 102 # error 32 bit
 103 #endif], [], arch=powerpc64, arch=powerpc)
 104         if test "$arch" = "powerpc64"; then
 105                 arch_m32=powerpc
 106                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 107         fi
 108         ;;
 109 arm*)
 110         arch=arm
 111         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 112         ;;
 113 aarch64*)
 114         arch=aarch64
 115         arch_m32=arm
 116         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 117         ;;
 118 avr32*)
 119         arch=avr32
 120         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 121         ;;
 122 arc*)
 123         arch=arc
 124         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 125         ;;
 126 s390)
 127         arch=s390
 128         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 129         ;;
 130 s390x)
 131         arch=s390x
 132         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 133         ;;
 134 hppa*|parisc*)
 135         arch=hppa
 136         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 137         ;;
 138 sh64*)
 139         arch=sh64
 140         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 141         ;;
 142 sh*)
 143         arch=sh
 144         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 145         ;;
 146 x86?64*)
 147         arch_m32=i386
 148         AC_TRY_COMPILE(
 149 [#ifndef __ILP32__
 150 # error not x32
 151 #endif], [], arch=x32, arch=x86_64)
 152         if test "$arch" = "x86_64"; then
 153                 arch_mx32=x32
 154                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 155         else
 156                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 157         fi
 158         ;;
 159 cris|crisv10)
 160         arch=crisv10
 161         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 162         ;;
 163 crisv32)
 164         arch=crisv32
 165         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 166         ;;
 167 tile*)
 168         arch=tile
 169         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 170         ;;
 171 microblaze*)
 172         arch=microblaze
 173         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 174         ;;
 175 nios2*)
 176         arch=nios2
 177         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 178         ;;
 179
 180 or1k*)
 181         arch=or1k
 182         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 183         ;;
 184
 185 xtensa*)
 186         arch=xtensa
 187         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 188         ;;
 189
 190 riscv*)
 191         arch=riscv
 192         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 193         ;;
 194
 195 *)
 196         AC_MSG_RESULT([NO!])
 197         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 198         ;;
 199 esac
 200 AC_MSG_RESULT($arch)
 201
 202 test -n "$arch_m32" ||
 203         arch_m32=$arch
 204 test -n "$arch_mx32" ||
 205         arch_mx32=$arch
 206 AC_SUBST(arch)
 207 AC_SUBST(arch_m32)
 208 AC_SUBST(arch_mx32)
 209
 210 MIPS_ABI=
 211 if test "$arch" = mips; then
 212         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 213                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 214                                        [#include <sgidefs.h>],
 215                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 216
 217         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 218                 [AC_COMPILE_IFELSE(
 219                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 220                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 221                         [st_cv_mips_abi=o32],
 222                 [AC_COMPILE_IFELSE(
 223                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 224                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 225                         [st_cv_mips_abi=n32],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 228                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 229                         [st_cv_mips_abi=n64],
 230                         [st_cv_mips_abi=unknown])])])])
 231
 232         case "$st_cv_mips_abi" in
 233                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 234                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 235                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 236                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 237         esac
 238         MIPS_ABI="$st_cv_mips_abi"
 239 fi
 240 AC_SUBST(MIPS_ABI)
 241
 242 AC_ARG_ENABLE([arm-oabi],
 243               [AS_HELP_STRING([--enable-arm-oabi],
 244                               [enable OABI support on ARM EABI])],
 245               [], [enable_arm_oabi=no])
 246 case "$enable_arm_oabi" in
 247         yes) enable_arm_oabi=1 ;;
 248         no) enable_arm_oabi=0 ;;
 249         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 250 esac
 251 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 252                    [Define to 1 if you want OABI support on ARM EABI.])
 253
 254 gl_WARN_ADD([-Wall])
 255 gl_WARN_ADD([-Wempty-body])
 256 gl_WARN_ADD([-Wformat-security])
 257 gl_WARN_ADD([-Wignored-qualifiers])
 258 gl_WARN_ADD([-Winit-self])
 259 gl_WARN_ADD([-Wlogical-op])
 260 gl_WARN_ADD([-Wmissing-parameter-type])
 261 gl_WARN_ADD([-Wnested-externs])
 262 gl_WARN_ADD([-Wold-style-declaration])
 263 gl_WARN_ADD([-Wold-style-definition])
 264 gl_WARN_ADD([-Wsign-compare])
 265 gl_WARN_ADD([-Wtype-limits])
 266 gl_WARN_ADD([-Wwrite-strings])
 267 AC_ARG_ENABLE([gcc-Werror],
 268   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 269   [case $enableval in
 270      yes) gl_WARN_ADD([-Werror]) ;;
 271      no)  ;;
 272      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 273    esac]
 274 )
 275 AC_SUBST([WARN_CFLAGS])
 276
 277 AC_C_BIGENDIAN
 278 AC_C_TYPEOF
 279
 280 AC_TYPE_UID_T
 281
 282 AC_CHECK_FUNCS(m4_normalize([
 283         accept4
 284         fallocate
 285         fanotify_mark
 286         fopen64
 287         fork
 288         fputs_unlocked
 289         fstatat
 290         ftruncate
 291         futimens
 292         if_indextoname
 293         open64
 294         pipe2
 295         prctl
 296         preadv
 297         process_vm_readv
 298         pwritev
 299         readahead
 300         signalfd
 301         stpcpy
 302         strerror
 303         strsignal
 304         sync_file_range
 305         utimensat
 306 ]))
 307
 308 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 309
 310 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 311
 312 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 313 [#include <asm/posix_types.h>])
 314
 315 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 316 [#include <sys/types.h>
 317 #include <asm/stat.h>])
 318
 319 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 320 [#include <sys/types.h>
 321 #include <asm/stat.h>])
 322
 323 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 324
 325 AC_CHECK_TYPES(m4_normalize([
 326         struct pt_all_user_regs,
 327         struct ia64_fpreg,
 328         struct ptrace_peeksiginfo_args
 329 ]),,, [#include <sys/ptrace.h>])
 330
 331 AC_CHECK_TYPES(m4_normalize([
 332         struct flock,
 333         struct flock64,
 334         struct __kernel_flock,
 335         struct __kernel_flock64
 336 ]),,,
 337 [#include <sys/types.h>
 338 #include <linux/fcntl.h>])
 339
 340 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 341
 342 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 343
 344 AC_CHECK_MEMBERS(m4_normalize([
 345         siginfo_t.si_syscall,
 346         siginfo_t.si_timerid,
 347         siginfo_t.si_overrun
 348 ]),,, [#include <signal.h>])
 349
 350 AC_CHECK_HEADERS(m4_normalize([
 351         asm/cachectl.h
 352         asm/sysmips.h
 353         bluetooth/bluetooth.h
 354         elf.h
 355         inttypes.h
 356         linux/bsg.h
 357         linux/dqblk_xfs.h
 358         linux/falloc.h
 359         linux/fiemap.h
 360         linux/filter.h
 361         linux/hiddev.h
 362         linux/ip_vs.h
 363         linux/ipc.h
 364         linux/mmtimer.h
 365         linux/msg.h
 366         linux/perf_event.h
 367         linux/quota.h
 368         linux/seccomp.h
 369         linux/securebits.h
 370         linux/sem.h
 371         linux/shm.h
 372         linux/userfaultfd.h
 373         linux/utsname.h
 374         mqueue.h
 375         netinet/sctp.h
 376         netipx/ipx.h
 377         scsi/sg.h
 378         stropts.h
 379         sys/conf.h
 380         sys/eventfd.h
 381         sys/fanotify.h
 382         sys/ipc.h
 383         sys/msg.h
 384         sys/quota.h
 385         sys/reg.h
 386         sys/sem.h
 387         sys/shm.h
 388         sys/signalfd.h
 389         sys/xattr.h
 390 ]))
 391
 392 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 393
 394 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 395
 396 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 397
 398 AC_CHECK_HEADERS(m4_normalize([
 399         linux/netfilter_arp/arp_tables.h
 400         linux/netfilter_bridge/ebtables.h
 401         linux/netfilter_ipv4/ip_tables.h
 402         linux/netfilter_ipv6/ip6_tables.h
 403 ]),,, [#include <netinet/in.h>
 404 #include <net/if.h>])
 405
 406 AC_CHECK_HEADERS([linux/input.h], [
 407         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 408 ])
 409
 410 AC_CHECK_HEADERS([linux/bpf.h], [
 411         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 412                        [st_cv_have_union_bpf_attr_log_buf],
 413                 [AC_COMPILE_IFELSE(
 414                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 415                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 416                         [st_cv_have_union_bpf_attr_log_buf=yes],
 417                         [st_cv_have_union_bpf_attr_log_buf=no])])
 418         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 419                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 420                           [Define to 1 if union bpf_attr.log_buf initialization works])
 421         fi
 422 ])
 423
 424 AC_CHECK_TYPES([struct statfs], [
 425         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 426 #include <asm/statfs.h>])
 427         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 428 #include <asm/statfs.h>])
 429         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 430 #include <asm/statfs.h>])
 431         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 432 #include <asm/statfs.h>])
 433 ],, [#include <linux/types.h>
 434 #include <asm/statfs.h>])
 435
 436 AC_CHECK_TYPES([struct statfs64], [
 437         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 438 #include <asm/statfs.h>])
 439         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 440 #include <asm/statfs.h>])
 441         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 442 #include <asm/statfs.h>])
 443         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 444 #include <asm/statfs.h>])
 445 ],, [#include <linux/types.h>
 446 #include <asm/statfs.h>])
 447
 448 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 449
 450 AC_CHECK_HEADERS([linux/btrfs.h], [
 451         AC_CHECK_MEMBERS(m4_normalize([
 452                 struct btrfs_ioctl_feature_flags.compat_flags,
 453                 struct btrfs_ioctl_fs_info_args.nodesize,
 454                 struct btrfs_ioctl_defrag_range_args.start,
 455                 struct btrfs_ioctl_search_args_v2.buf_size
 456                 ]),,, [ #include <stdio.h>
 457 #include <linux/btrfs.h>])
 458         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 459                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 460 #include <linux/btrfs.h>])])
 461
 462 AC_CHECK_DECLS([sys_errlist])
 463 AC_CHECK_DECLS(m4_normalize([
 464         PTRACE_PEEKUSER,
 465         PTRACE_POKEUSER
 466 ]),,, [#include <sys/ptrace.h>])
 467
 468 AC_CHECK_DECLS(m4_normalize([
 469         P_PID,
 470         P_PPID,
 471         P_PGID,
 472         P_SID,
 473         P_CID,
 474         P_UID,
 475         P_GID,
 476         P_ALL,
 477         P_LWPID
 478 ]),,, [#include <sys/wait.h>])
 479
 480 AC_CHECK_DECLS(m4_normalize([
 481         LO_FLAGS_READ_ONLY,
 482         LO_FLAGS_AUTOCLEAR,
 483         LO_FLAGS_PARTSCAN
 484 ]),,, [#include <linux/loop.h>])
 485
 486 AC_CHECK_DECLS(m4_normalize([
 487         CTL_PROC,
 488         CTL_ARLAN,
 489         CTL_S390DBF,
 490         CTL_SUNRPC,
 491         CTL_PM,
 492         CTL_FRV,
 493         KERN_PRINTK_RATELIMIT,
 494         KERN_PRINTK_RATELIMIT_BURST,
 495         KERN_PTY,
 496         KERN_NGROUPS_MAX,
 497         KERN_SPARC_SCONS_PWROFF,
 498         KERN_HZ_TIMER,
 499         KERN_UNKNOWN_NMI_PANIC,
 500         KERN_BOOTLOADER_TYPE,
 501         KERN_RANDOMIZE,
 502         KERN_SETUID_DUMPABLE,
 503         KERN_SPIN_RETRY,
 504         KERN_ACPI_VIDEO_FLAGS,
 505         KERN_IA64_UNALIGNED,
 506         KERN_COMPAT_LOG,
 507         KERN_MAX_LOCK_DEPTH,
 508         KERN_NMI_WATCHDOG,
 509         KERN_PANIC_ON_NMI,
 510         NET_LLC,
 511         NET_NETFILTER,
 512         NET_DCCP,
 513         NET_IRDA,
 514         NET_CORE_DESTROY_DELAY,
 515         NET_CORE_BUDGET,
 516         NET_CORE_AEVENT_ETIME,
 517         NET_CORE_AEVENT_RSEQTH,
 518         NET_CORE_WARNINGS,
 519         NET_IPV4_IGMP_MAX_MSF,
 520         NET_TCP_NO_METRICS_SAVE,
 521         NET_TCP_DEFAULT_WIN_SCALE,
 522         NET_TCP_MODERATE_RCVBUF,
 523         NET_TCP_TSO_WIN_DIVISOR,
 524         NET_TCP_BIC_BETA,
 525         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 526         NET_TCP_CONG_CONTROL,
 527         NET_TCP_ABC,
 528         NET_IPV4_IPFRAG_MAX_DIST,
 529         NET_TCP_MTU_PROBING,
 530         NET_TCP_BASE_MSS,
 531         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 532         NET_TCP_DMA_COPYBREAK,
 533         NET_TCP_SLOW_START_AFTER_IDLE,
 534         NET_CIPSOV4_CACHE_ENABLE,
 535         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 536         NET_CIPSOV4_RBM_OPTFMT,
 537         NET_CIPSOV4_RBM_STRICTVALID,
 538         NET_TCP_AVAIL_CONG_CONTROL,
 539         NET_TCP_ALLOWED_CONG_CONTROL,
 540         NET_TCP_MAX_SSTHRESH,
 541         NET_TCP_FRTO_RESPONSE,
 542         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 543         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 544         NET_IPV4_CONF_ARP_ANNOUNCE,
 545         NET_IPV4_CONF_ARP_IGNORE,
 546         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 547         NET_IPV4_CONF_ARP_ACCEPT,
 548         NET_IPV4_CONF_ARP_NOTIFY,
 549         NET_IPV6_MLD_MAX_MSF,
 550         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 551         VM_MAX_MAP_COUNT,
 552         VM_LAPTOP_MODE,
 553         VM_BLOCK_DUMP,
 554         VM_HUGETLB_GROUP,
 555         VM_VFS_CACHE_PRESSURE,
 556         VM_LEGACY_VA_LAYOUT,
 557         VM_SWAP_TOKEN_TIMEOUT
 558 ]),,,
 559 [#include <sys/types.h>
 560 #include <linux/sysctl.h>])
 561
 562 AC_CHECK_DECLS(m4_normalize([
 563         V4L2_FIELD_ANY,
 564         V4L2_FIELD_NONE,
 565         V4L2_FIELD_TOP,
 566         V4L2_FIELD_BOTTOM,
 567         V4L2_FIELD_INTERLACED,
 568         V4L2_FIELD_SEQ_TB,
 569         V4L2_FIELD_SEQ_BT,
 570         V4L2_FIELD_ALTERNATE,
 571         V4L2_FIELD_INTERLACED_TB,
 572         V4L2_FIELD_INTERLACED_BT,
 573         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 574         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 575         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 576         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 577         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 578         V4L2_BUF_TYPE_VBI_CAPTURE,
 579         V4L2_BUF_TYPE_VBI_OUTPUT,
 580         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 581         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 582         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 583         V4L2_TUNER_RADIO,
 584         V4L2_TUNER_ANALOG_TV,
 585         V4L2_TUNER_DIGITAL_TV,
 586         V4L2_MEMORY_MMAP,
 587         V4L2_MEMORY_USERPTR,
 588         V4L2_MEMORY_OVERLAY,
 589         V4L2_MEMORY_DMABUF,
 590         V4L2_COLORSPACE_SMPTE170M,
 591         V4L2_COLORSPACE_SMPTE240M,
 592         V4L2_COLORSPACE_REC709,
 593         V4L2_COLORSPACE_BT878,
 594         V4L2_COLORSPACE_470_SYSTEM_M,
 595         V4L2_COLORSPACE_470_SYSTEM_BG,
 596         V4L2_COLORSPACE_JPEG,
 597         V4L2_COLORSPACE_SRGB,
 598         V4L2_PRIORITY_UNSET,
 599         V4L2_PRIORITY_BACKGROUND,
 600         V4L2_PRIORITY_INTERACTIVE,
 601         V4L2_PRIORITY_RECORD,
 602         V4L2_FRMSIZE_TYPE_DISCRETE,
 603         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 604         V4L2_FRMSIZE_TYPE_STEPWISE,
 605         V4L2_FRMIVAL_TYPE_DISCRETE,
 606         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 607         V4L2_FRMIVAL_TYPE_STEPWISE,
 608         V4L2_CTRL_TYPE_INTEGER,
 609         V4L2_CTRL_TYPE_BOOLEAN,
 610         V4L2_CTRL_TYPE_MENU,
 611         V4L2_CTRL_TYPE_BUTTON,
 612         V4L2_CTRL_TYPE_INTEGER64,
 613         V4L2_CTRL_TYPE_CTRL_CLASS,
 614         V4L2_CTRL_TYPE_STRING,
 615         V4L2_CTRL_TYPE_BITMASK,
 616         V4L2_CTRL_TYPE_INTEGER_MENU
 617 ]),,, [#include <sys/time.h>
 618 #include <linux/ioctl.h>
 619 #include <linux/types.h>
 620 #include <linux/videodev2.h>])
 621
 622 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 623         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 624 #include <stdlib.h>
 625 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 626                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 627         if test $ac_cv_have_blkgetsize64 = yes; then
 628                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 629         fi)
 630
 631 AC_CHECK_SIZEOF([long])
 632 AC_CHECK_SIZEOF([long long])
 633 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 634 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 635
 636 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 637                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 638                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 639                         grep '^[0-9]')"
 640                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 641 if test "x$st_cv_SIGRTMIN" != xno; then
 642         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 643                            [SIGRTMIN defined in <asm/signal.h>])
 644 fi
 645 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 646                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 647                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 648                         grep ^0x)"
 649                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 650 if test "x$st_cv_SA_RESTORER" != xno; then
 651         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 652                            [SA_RESTORER defined in <asm/signal.h>])
 653 fi
 654
 655 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 656                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 657                                [st_cv_have___builtin_popcount=yes],
 658                                [st_cv_have___builtin_popcount=no])])
 659 if test "x$st_cv_have___builtin_popcount" = xyes; then
 660         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 661                   [Define to 1 if the system provides __builtin_popcount function])
 662 fi
 663
 664 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 665 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 666         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 667 fi
 668 AC_SUBST(dl_LIBS)
 669
 670 AC_PATH_PROG([PERL], [perl])
 671
 672 dnl stack trace with libunwind
 673 libunwind_CPPFLAGS=
 674 libunwind_LDFLAGS=
 675 libunwind_LIBS=
 676 AC_ARG_WITH([libunwind],
 677             [AS_HELP_STRING([--with-libunwind],
 678                             [use libunwind to implement stack tracing support])],
 679             [case "${withval}" in
 680              yes|no|check) ;;
 681              *) with_libunwind=yes
 682                 libunwind_CPPFLAGS="-I${withval}/include"
 683                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 684              esac],
 685             [with_libunwind=check]
 686 )
 687
 688 use_libunwind=no
 689 AS_IF([test "x$with_libunwind" != xno],
 690       [saved_CPPFLAGS="$CPPFLAGS"
 691        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 692
 693        AC_CHECK_HEADERS([libunwind-ptrace.h],
 694          [saved_LDFLAGS="$LDFLAGS"
 695           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 696
 697           AC_CHECK_LIB([unwind], [backtrace],
 698             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 699
 700              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 701              saved_LIBS="$LIBS"
 702              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 703
 704              AC_LINK_IFELSE(
 705                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 706                                 [[return !unw_create_addr_space(0, 0)]])
 707                ],
 708                [AC_MSG_RESULT([yes])
 709                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 710
 711                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 712                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 713                    use_libunwind=yes
 714                   ],
 715                   [if test "x$with_libunwind" != xcheck; then
 716                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 717                    fi
 718                   ],
 719                   [$libunwind_LIBS]
 720                 )
 721                ],
 722                [AC_MSG_RESULT([no])
 723                 if test "x$with_libunwind" != xcheck; then
 724                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 725                 fi
 726                ]
 727              )
 728
 729              LIBS="$saved_LIBS"
 730             ],
 731             [if test "x$with_libunwind" != xcheck; then
 732                AC_MSG_FAILURE([failed to find libunwind])
 733              fi
 734             ],
 735             [$libunwind_LIBS]
 736           )
 737
 738           LDFLAGS="$saved_LDFLAGS"
 739          ],
 740          [if test "x$with_libunwind" != xcheck; then
 741             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 742           fi
 743          ]
 744        )
 745
 746        CPPFLAGS="$saved_CPPFLAGS"
 747       ]
 748 )
 749
 750 dnl enable libunwind
 751 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 752 if test "x$use_libunwind" = xyes; then
 753         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 754         AC_SUBST(libunwind_LIBS)
 755         AC_SUBST(libunwind_LDFLAGS)
 756         AC_SUBST(libunwind_CPPFLAGS)
 757 fi
 758 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 759 AC_MSG_RESULT([$use_libunwind])
 760
 761 if test "$arch" = mips && test "$no_create" != yes; then
 762         mkdir -p linux/mips
 763         if $srcdir/linux/mips/genstub.sh linux/mips; then
 764                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 765         else
 766                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 767         fi
 768 fi
 769
 770 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 771 st_MPERS([mx32], [x86_64])
 772
 773 AC_CONFIG_FILES([Makefile
 774                  tests/Makefile
 775                  tests-m32/Makefile
 776                  tests-mx32/Makefile
 777                  strace.spec
 778                  debian/changelog])
 779 AC_OUTPUT