granicus.if.org Git - libass/blob - configure.ac

   1 AC_INIT(libass, 0.12.3)
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_MACRO_DIR([m4])
   4 # Disable Fortran checks
   5 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
   6 LT_INIT
   7 AC_CONFIG_SRCDIR([libass/ass.c])
   8 AC_CONFIG_HEADER([config.h])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AM_PROG_CC_C_O
  14 AM_PROG_AS
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_STDBOOL
  19 AC_CHECK_HEADERS([stdint.h unistd.h iconv.h])
  20
  21 # Checks for library functions.
  22 AC_CHECK_FUNCS([strdup strndup])
  23
  24 # Checks for libraries.
  25 AC_SEARCH_LIBS([libiconv_open], [iconv], AC_DEFINE(CONFIG_ICONV, 1, [use iconv]))
  26 AC_SEARCH_LIBS([iconv_open], [iconv], AC_DEFINE(CONFIG_ICONV, 1, [use iconv]))
  27 AC_CHECK_LIB([m], [fabs])
  28
  29 # Check for libraries via pkg-config
  30 AC_ARG_ENABLE([test], AS_HELP_STRING([--enable-test],
  31     [enable test program (requires libpng) @<:@default=no@:>@]))
  32 AC_ARG_ENABLE([profile], AS_HELP_STRING([--enable-profile],
  33     [enable profiling program @<:@default=no@:>@]))
  34 AC_ARG_ENABLE([enca], AS_HELP_STRING([--disable-enca],
  35     [disable enca (charset autodetect) support @<:@default=check@:>@]))
  36 AC_ARG_ENABLE([fontconfig], AS_HELP_STRING([--disable-fontconfig],
  37     [disable fontconfig support @<:@default=enabled@:>@]))
  38 AC_ARG_ENABLE([directwrite], AS_HELP_STRING([--disable-directwrite],
  39     [disable DirectWrite support (win32 only) @<:@default=check@:>@]))
  40 AC_ARG_ENABLE([coretext], AS_HELP_STRING([--disable-coretext],
  41     [disable CoreText support (OSX only) @<:@default=check@:>@]))
  42 AC_ARG_ENABLE([harfbuzz], AS_HELP_STRING([--disable-harfbuzz],
  43     [disable HarfBuzz support @<:@default=check@:>@]))
  44 AC_ARG_ENABLE([asm], AS_HELP_STRING([--disable-asm],
  45     [disable compiling with ASM @<:@default=check@:>@]))
  46 AC_ARG_ENABLE([rasterizer], AS_HELP_STRING([--disable-rasterizer],
  47     [disable internal rasterizer @<:@default=enabled@:>@]))
  48 AC_ARG_ENABLE([large-tiles], AS_HELP_STRING([--enable-large-tiles],
  49     [use larger tiles in the rasterizer (better performance, slightly worse quality) @<:@default=disabled@:>@]))
  50
  51 AS_IF([test x$enable_asm != xno], [
  52     AS_CASE([$host],
  53         [i?86-*], [
  54             INTEL=true
  55             AS=yasm
  56             X86=true
  57             BITS=32
  58             ASFLAGS="$ASFLAGS -DARCH_X86_64=0 -m x86" ],
  59         [x86_64-*|amd64-*], [
  60             AS=yasm
  61             INTEL=true
  62             X64=true
  63             BITS=64
  64             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -m amd64" ],
  65         )
  66     AS_CASE([$host],
  67         [*darwin*], [
  68             ASFLAGS="$ASFLAGS -f macho$BITS -DPREFIX -DHAVE_ALIGNED_STACK=1" ],
  69         [*linux*|*dragonfly*|*bsd*], [
  70             ASFLAGS="$ASFLAGS -f elf -DHAVE_ALIGNED_STACK=1" ],
  71         [*cygwin*|*mingw*], [
  72             ASFLAGS="$ASFLAGS -f win$BITS"
  73             AS_IF([test x$BITS = x64], [
  74                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=1"
  75             ], [
  76                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=0 -DPREFIX"
  77             ])
  78         ])
  79     AS_IF([test x$INTEL = xtrue], [
  80         AC_CHECK_PROG([yasm_check], [$AS], [yes])
  81         AS_IF([test x$yasm_check != xyes], [
  82             AC_MSG_WARN(yasm was not found; ASM functions are disabled.)
  83             AC_MSG_WARN(Install yasm for a significantly faster libass build.)
  84             enable_asm=no
  85         ], [
  86             AC_MSG_CHECKING([if $AS supports vpmovzxwd])
  87             echo "vpmovzxwd ymm0, xmm0" > conftest.asm
  88             AS_IF([$AS conftest.asm $ASFLAGS -o conftest.o >conftest.log 2>&1], [
  89                 AC_MSG_RESULT([yes])
  90             ], [
  91                 AC_MSG_RESULT([no])
  92                 VER=`($AS --version || echo no assembler) 2>/dev/null | head -n 1`
  93                 AC_MSG_WARN([yasm is too old (found $VER); ASM functions are disabled.])
  94                 AC_MSG_WARN([Install yasm-1.2.0 or later for a significantly faster libass build.])
  95                 enable_asm=no
  96             ])
  97             rm conftest.asm conftest.o > /dev/null 2>&1
  98         ])
  99     ])
 100 ])
 101
 102 AC_SUBST([ASFLAGS], ["$ASFLAGS"])
 103 AC_SUBST([AS], ["$AS"])
 104
 105 AM_CONDITIONAL([ASM], [test x$enable_asm != xno])
 106 AM_CONDITIONAL([INTEL], [test x$INTEL = xtrue])
 107 AM_CONDITIONAL([X86], [test x$X86 = xtrue])
 108 AM_CONDITIONAL([X64], [test x$X64 = xtrue])
 109
 110 AM_COND_IF([ASM],
 111     [AC_DEFINE(CONFIG_ASM, 1, [ASM enabled])],
 112     [AC_DEFINE(CONFIG_ASM, 0, [ASM enabled])]
 113     )
 114
 115 AM_CONDITIONAL([RASTERIZER], [test x$enable_rasterizer != xno])
 116
 117 AM_COND_IF([RASTERIZER],
 118     [AC_DEFINE(CONFIG_RASTERIZER, 1, [rasterizer enabled])],
 119     [AC_DEFINE(CONFIG_RASTERIZER, 0, [rasterizer enabled])]
 120     )
 121
 122 AM_CONDITIONAL([ENABLE_LARGE_TILES], [test x$enable_large_tiles = xyes])
 123
 124 AM_COND_IF([ENABLE_LARGE_TILES],
 125     [AC_DEFINE(CONFIG_LARGE_TILES, 1, [use large tiles])]
 126     [AC_DEFINE(CONFIG_LARGE_TILES, 0, [use small tiles])],
 127     )
 128
 129 PKG_CHECK_MODULES([FREETYPE], freetype2 >= 9.10.3, [
 130     CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 131     CXXFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 132     LIBS="$LIBS $FREETYPE_LIBS"
 133     AC_DEFINE(CONFIG_FREETYPE, 1, [found freetype2 via pkg-config])
 134     ])
 135
 136 PKG_CHECK_MODULES([FRIBIDI], fribidi >= 0.19.0, [
 137     CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
 138     LIBS="$LIBS $FRIBIDI_LIBS"
 139     AC_DEFINE(CONFIG_FRIBIDI, 1, [found fribidi via pkg-config])
 140     ])
 141
 142 if test x$enable_fontconfig != xno; then
 143 PKG_CHECK_MODULES([FONTCONFIG], fontconfig >= 2.4.2, [
 144     CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 145     LIBS="$LIBS $FONTCONFIG_LIBS"
 146     AC_DEFINE(CONFIG_FONTCONFIG, 1, [found fontconfig via pkg-config])
 147         fontconfig=true
 148     ])
 149 fi
 150
 151 if test x$enable_coretext != xno; then
 152 OLDLIBS="$LIBS"
 153 # Linking to CoreText directly only works from Mountain Lion and iOS6. In
 154 # earlier OS releases CoreText was part of the ApplicationServices umbrella
 155 # framework.
 156 LIBS="$LIBS -framework CoreText -framework CoreFoundation -framework CoreGraphics"
 157 AC_MSG_CHECKING([for CORETEXT])
 158 AC_LINK_IFELSE([
 159   AC_LANG_PROGRAM(
 160     [[#include <CoreText/CoreText.h>]],
 161     [[CTFontCreateWithFontDescriptor(NULL, 0.0, NULL);]],)
 162   ], [
 163     AC_DEFINE(CONFIG_CORETEXT, 1, [found CoreText in System library])
 164     coretext=true
 165     AC_MSG_RESULT([yes])
 166   ], [
 167     LIBS="$OLDLIBS"
 168     coretext=false
 169     AC_MSG_RESULT([no])
 170   ])
 171 fi
 172 AM_CONDITIONAL([CORETEXT], [test x$coretext = xtrue])
 173
 174
 175
 176 if test x$enable_directwrite != xno; then
 177 # Linking to DirectWrite directly only works from Windows
 178 AC_MSG_CHECKING([for DIRECTWRITE])
 179 AC_LINK_IFELSE([
 180   AC_LANG_PROGRAM(
 181     [[#include <windows.h>]],
 182     [[;]],)
 183   ], [
 184     AC_DEFINE(CONFIG_DIRECTWRITE, 1, [found DirectWrite])
 185     directwrite=true
 186     AC_MSG_RESULT([yes])
 187   ], [
 188     directwrite=false
 189     AC_MSG_RESULT([no])
 190   ])
 191 fi
 192 AM_CONDITIONAL([DIRECTWRITE], [test x$directwrite = xtrue])
 193
 194 if test x$enable_harfbuzz != xno; then
 195 PKG_CHECK_MODULES([HARFBUZZ], harfbuzz >= 0.9.5, [
 196     CFLAGS="$CFLAGS $HARFBUZZ_CFLAGS"
 197     LIBS="$LIBS $HARFBUZZ_LIBS"
 198     AC_DEFINE(CONFIG_HARFBUZZ, 1, [found harfbuzz-ng via pkg-config])
 199         harfbuzz=true
 200     ], [harfbuzz=false])
 201 fi
 202
 203 if test x$enable_enca != xno; then
 204 PKG_CHECK_MODULES([ENCA], enca, [
 205     CFLAGS="$CFLAGS $ENCA_CFLAGS"
 206     LIBS="$LIBS $ENCA_LIBS"
 207     AC_DEFINE(CONFIG_ENCA, 1, [found enca via pkg-config])
 208         enca=true
 209         ], [enca=false])
 210 fi
 211
 212 libpng=false
 213 if test x$enable_test = xyes; then
 214 PKG_CHECK_MODULES([LIBPNG], libpng >= 1.2.0, [
 215     CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
 216     AC_DEFINE(CONFIG_LIBPNG, 1, [found libpng via pkg-config])
 217     libpng=true])
 218 fi
 219
 220 AM_CONDITIONAL([HAVE_LIBPNG], [test x$libpng = xtrue])
 221
 222 AM_CONDITIONAL([ENABLE_PROFILE], [test x$enable_profile = xyes])
 223
 224 # add libraries/packages to pkg-config for static linking
 225 pkg_libs="-lm"
 226 pkg_requires="freetype2 >= 9.10.3"
 227 pkg_requires="fribidi >= 0.19.0, ${pkg_requires}"
 228 if test x$enca = xtrue; then
 229     pkg_requires="enca, ${pkg_requires}"
 230 fi
 231 if test x$fontconfig = xtrue; then
 232     pkg_requires="fontconfig >= 2.4.2, ${pkg_requires}"
 233 fi
 234 if test x$harfbuzz = xtrue; then
 235     pkg_requires="harfbuzz >= 0.9.5, ${pkg_requires}"
 236 fi
 237 if test x$directwrite = xtrue; then
 238     pkg_libs="${pkg_libs} -ldwrite"
 239 fi
 240
 241 AC_SUBST([PKG_LIBS_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_libs})])
 242 AC_SUBST([PKG_REQUIRES_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_requires})])
 243 AC_SUBST([PKG_LIBS_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_libs})])
 244 AC_SUBST([PKG_REQUIRES_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_requires})])
 245
 246 # Setup output beautifier.
 247 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 248
 249 AC_CONFIG_FILES([Makefile libass/Makefile test/Makefile profile/Makefile libass.pc])
 250 AC_OUTPUT