granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.7])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AM_CONFIG_HEADER([config.h])
   6 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2])
   7 AM_MAINTAINER_MODE
   8 AC_CANONICAL_HOST
   9
  10 AC_MSG_CHECKING([for supported operating system])
  11 case "$host_os" in
  12 linux*)
  13         opsys=linux
  14         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  15         ;;
  16 sunos4*)
  17         opsys=sunos4
  18         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  19         ;;
  20 solaris2* | sysv[[45]]* | irix[[56]]*)
  21         opsys=svr4
  22         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  23 system or a derivative like Solaris 2.x or Irix 5.x.])
  24         case "$host_os" in
  25         sysv4.2uw*)
  26                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  27                 ;;
  28         sysv5*)
  29                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  30                 ;;
  31         esac
  32         ;;
  33 freebsd*)
  34         opsys=freebsd
  35         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  36         ;;
  37 *)
  38         AC_MSG_RESULT([NO!])
  39         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  40         ;;
  41 esac
  42 AC_MSG_RESULT($opsys)
  43
  44 AC_MSG_CHECKING([for supported architecture])
  45 case "$host_cpu" in
  46 i[[3456]]86|pentium)
  47         arch=i386
  48         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  49         ;;
  50 ia64)
  51         arch=ia64
  52         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  53         ;;
  54 m68k)
  55         arch=m68k
  56         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  57         ;;
  58 sparc64*)
  59         arch=sparc64
  60         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  61         ;;
  62 sparc*)
  63         arch=sparc
  64         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  65         ;;
  66 mips*)
  67         arch=mips
  68         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  69         ;;
  70 alpha*)
  71         arch=alpha
  72         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  73         ;;
  74 powerpc*)
  75         arch=powerpc
  76         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  77         ;;
  78 arm*)
  79         arch=arm
  80         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  81         ;;
  82 s390)
  83         arch=s390
  84         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  85         ;;
  86 s390x)
  87         arch=s390x
  88         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  89         ;;
  90 hppa*|parisc*)
  91         arch=hppa
  92         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  93         ;;
  94 sh)
  95         arch=sh
  96         AC_DEFINE([SH], 1, [Define for the SH architecture.])
  97         ;;
  98 sh64)
  99         arch=sh64
 100         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 101         ;;
 102 x86?64*)
 103         arch=x86_64
 104         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 105         ;;
 106 *)
 107         AC_MSG_RESULT([NO!])
 108         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 109         ;;
 110 esac
 111 AC_MSG_RESULT($arch)
 112
 113 AC_SUBST(opsys)
 114 AC_SUBST(arch)
 115
 116 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 117 AM_CONDITIONAL([I386], [test x$arch = xi386])
 118 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 119 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 120 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 121 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 122
 123 AC_PROG_CC
 124 dnl That set the default CFLAGS value, which we don't want to diddle first.
 125 CFLAGS="-D_GNU_SOURCE $CFLAGS"
 126
 127 AC_INCLUDEDIR
 128
 129 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 130 then
 131         AC_MSG_CHECKING(for valid machine include directory)
 132         if test -d "$includedir/sun4"
 133         then
 134                 rm -f machine
 135                 ln -s $includedir/sun4 machine
 136                 AC_MSG_RESULT(yes)
 137                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 138 Define if you are have a SPARC with SUNOS4 and your want a version
 139 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 140 Only useful if you have a symbolic link from machine to /usr/include/sun4
 141 in the compilation directory.])
 142         else
 143                 AC_MSG_RESULT(no)
 144         fi
 145 fi
 146
 147 AC_WARNFLAGS
 148 if test "x$opsys" = "xsunos4"
 149 then
 150         if test -n "$GCC"
 151         then
 152                 # SunOS 4.x header files don't declare int functions.
 153                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 154         fi
 155 fi
 156
 157 AC_PROG_CPP
 158 AC_PROG_GCC_TRADITIONAL
 159 AC_PROG_INSTALL
 160 AC_C_CONST
 161 AC_HEADER_STDC
 162 AC_HEADER_DIRENT
 163 AC_HEADER_STAT
 164 AC_CHECK_MEMBERS([struct stat.st_blksize,
 165                   struct stat.st_blocks,
 166                   struct stat.st_aclcnt,
 167                   struct stat.st_flags,
 168                   struct stat.st_fstype,
 169                   struct stat.st_gen,
 170                   struct stat.st_level,
 171                   struct stat.st_rdev])
 172 AC_STAT64
 173
 174 AC_TYPE_SIGNAL
 175 AC_TYPE_UID_T
 176 AC_TYPE_MODE_T
 177 AC_TYPE_GETGROUPS
 178 AC_HEADER_MAJOR
 179 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 180 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 181 [#include <sys/types.h>
 182 #include <sys/socket.h>
 183 #include <netinet/in.h>])
 184 AC_CHECK_TYPES([long long])
 185 AC_LITTLE_ENDIAN_LONG_LONG
 186 AC_OFF_T_IS_LONG_LONG
 187 AC_RLIM_T_IS_LONG_LONG
 188 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 189 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 190
 191 if test x$opsys != xlinux; then
 192 AC_CHECK_LIB(nsl, main)
 193 fi
 194
 195 AC_CHECK_FUNCS(sigaction strerror strsignal pread sys_siglist _sys_siglist getdents mctl prctl sendmsg inet_ntop if_indextoname)
 196 AC_CHECK_HEADERS([sys/reg.h sys/filio.h sys/acl.h sys/asynch.h sys/door.h stropts.h sys/conf.h sys/stream.h sys/tihdr.h sys/tiuser.h sys/sysconfig.h ioctls.h sys/ioctl.h sys/ptrace.h termio.h linux/ptrace.h asm/reg.h sys/uio.h sys/aio.h  poll.h sys/poll.h sys/vfs.h asm/sysmips.h linux/utsname.h sys/nscsys.h mqueue.h], [], [])
 197 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 198                  [], [], [#include <linux/socket.h>])
 199 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 200 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 201
 202 AC_MP_PROCFS
 203 AC_POLLABLE_PROCFS
 204
 205 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 206 AC_STRUCT_PR_SYSCALL
 207
 208 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 209                   struct T_conn_res.ACCEPTOR_id],,,
 210 [#include <sys/stream.h>
 211 #include <sys/tihdr.h>])
 212
 213 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 214
 215 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 216                [#include <sys/ptrace.h>])
 217
 218 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 219
 220 AC_CHECK_DECLS([sys_errlist])
 221 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 222
 223 AC_PATH_PROG([PERL], [perl])
 224
 225 AC_CONFIG_FILES([Makefile])
 226 AC_OUTPUT