granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  40 AM_MAINTAINER_MODE
  41 AC_CANONICAL_HOST
  42
  43 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  44 AC_SUBST(RPM_CHANGELOGTIME)
  45 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  46 AC_SUBST(DEB_CHANGELOGTIME)
  47
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AX_PROG_CC_FOR_BUILD
  51 AC_PROG_INSTALL
  52 AC_PROG_RANLIB
  53
  54 AC_USE_SYSTEM_EXTENSIONS
  55 AX_CODE_COVERAGE
  56
  57 AC_MSG_CHECKING([for supported architecture])
  58 arch_m32=
  59 arch_mx32=
  60 case "$host_cpu" in
  61 bfin)
  62         arch=bfin
  63         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  64         ;;
  65 i[[3456]]86|pentium)
  66         arch=i386
  67         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  68         ;;
  69 ia64)
  70         arch=ia64
  71         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  72         ;;
  73 m68k)
  74         arch=m68k
  75         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  76         ;;
  77 sparc64*)
  78         arch=sparc64
  79         arch_m32=sparc
  80         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  81         ;;
  82 sparc*)
  83         arch=sparc
  84         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  85         ;;
  86 metag*)
  87         arch=metag
  88         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  89         ;;
  90 mips*)
  91         arch=mips
  92         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  93         ;;
  94 alpha*)
  95         arch=alpha
  96         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  97         ;;
  98 powerpc*)
  99         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 100         AC_TRY_COMPILE(
 101 [#ifndef __LP64__
 102 # error 32 bit
 103 #endif], [], arch=powerpc64, arch=powerpc)
 104         if test "$arch" = "powerpc64"; then
 105                 arch_m32=powerpc
 106                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 107         fi
 108         ;;
 109 arm*)
 110         arch=arm
 111         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 112         ;;
 113 aarch64*)
 114         arch=aarch64
 115         arch_m32=arm
 116         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 117         ;;
 118 avr32*)
 119         arch=avr32
 120         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 121         ;;
 122 arc*)
 123         arch=arc
 124         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 125         ;;
 126 s390)
 127         arch=s390
 128         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 129         ;;
 130 s390x)
 131         arch=s390x
 132         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 133         ;;
 134 hppa*|parisc*)
 135         arch=hppa
 136         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 137         ;;
 138 sh64*)
 139         arch=sh64
 140         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 141         ;;
 142 sh*)
 143         arch=sh
 144         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 145         ;;
 146 x86?64*)
 147         arch_m32=i386
 148         AC_TRY_COMPILE(
 149 [#ifndef __ILP32__
 150 # error not x32
 151 #endif], [], arch=x32, arch=x86_64)
 152         if test "$arch" = "x86_64"; then
 153                 arch_mx32=x32
 154                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 155         else
 156                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 157         fi
 158         ;;
 159 cris|crisv10)
 160         arch=crisv10
 161         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 162         ;;
 163 crisv32)
 164         arch=crisv32
 165         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 166         ;;
 167 tile*)
 168         arch=tile
 169         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 170         ;;
 171 microblaze*)
 172         arch=microblaze
 173         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 174         ;;
 175 nios2*)
 176         arch=nios2
 177         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 178         ;;
 179
 180 or1k*)
 181         arch=or1k
 182         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 183         ;;
 184
 185 xtensa*)
 186         arch=xtensa
 187         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 188         ;;
 189
 190 riscv*)
 191         arch=riscv
 192         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 193         ;;
 194
 195 *)
 196         AC_MSG_RESULT([NO!])
 197         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 198         ;;
 199 esac
 200 AC_MSG_RESULT($arch)
 201
 202 test -n "$arch_m32" ||
 203         arch_m32=$arch
 204 test -n "$arch_mx32" ||
 205         arch_mx32=$arch
 206 AC_SUBST(arch)
 207 AC_SUBST(arch_m32)
 208 AC_SUBST(arch_mx32)
 209
 210 MIPS_ABI=
 211 if test "$arch" = mips; then
 212         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 213                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 214                                        [#include <sgidefs.h>],
 215                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 216
 217         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 218                 [AC_COMPILE_IFELSE(
 219                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 220                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 221                         [st_cv_mips_abi=o32],
 222                 [AC_COMPILE_IFELSE(
 223                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 224                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 225                         [st_cv_mips_abi=n32],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 228                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 229                         [st_cv_mips_abi=n64],
 230                         [st_cv_mips_abi=unknown])])])])
 231
 232         case "$st_cv_mips_abi" in
 233                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 234                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 235                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 236                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 237         esac
 238         MIPS_ABI="$st_cv_mips_abi"
 239 fi
 240 AC_SUBST(MIPS_ABI)
 241
 242 AC_ARG_ENABLE([arm-oabi],
 243               [AS_HELP_STRING([--enable-arm-oabi],
 244                               [enable OABI support on ARM EABI])],
 245               [], [enable_arm_oabi=no])
 246 case "$enable_arm_oabi" in
 247         yes) enable_arm_oabi=1 ;;
 248         no) enable_arm_oabi=0 ;;
 249         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 250 esac
 251 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 252                    [Define to 1 if you want OABI support on ARM EABI.])
 253
 254 gl_WARN_ADD([-Wall])
 255 gl_WARN_ADD([-Wempty-body])
 256 gl_WARN_ADD([-Wformat-security])
 257 gl_WARN_ADD([-Wignored-qualifiers])
 258 gl_WARN_ADD([-Winit-self])
 259 gl_WARN_ADD([-Wlogical-op])
 260 gl_WARN_ADD([-Wmissing-parameter-type])
 261 gl_WARN_ADD([-Wnested-externs])
 262 gl_WARN_ADD([-Wold-style-declaration])
 263 gl_WARN_ADD([-Wold-style-definition])
 264 gl_WARN_ADD([-Wsign-compare])
 265 gl_WARN_ADD([-Wtype-limits])
 266 gl_WARN_ADD([-Wwrite-strings])
 267 AC_ARG_ENABLE([gcc-Werror],
 268   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 269   [case $enableval in
 270      yes) gl_WARN_ADD([-Werror]) ;;
 271      no)  ;;
 272      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 273    esac]
 274 )
 275 AC_SUBST([WARN_CFLAGS])
 276
 277 AC_C_BIGENDIAN
 278 AC_C_TYPEOF
 279
 280 AC_TYPE_UID_T
 281
 282 AC_CHECK_FUNCS(m4_normalize([
 283         accept4
 284         fanotify_mark
 285         fopen64
 286         fork
 287         fputs_unlocked
 288         fstatat
 289         ftruncate
 290         futimens
 291         if_indextoname
 292         open64
 293         pipe2
 294         prctl
 295         preadv
 296         process_vm_readv
 297         pwritev
 298         readahead
 299         signalfd
 300         stpcpy
 301         strerror
 302         strsignal
 303         sync_file_range
 304         utimensat
 305 ]))
 306
 307 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 308
 309 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 310
 311 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 312 [#include <asm/posix_types.h>])
 313
 314 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 315 [#include <sys/types.h>
 316 #include <asm/stat.h>])
 317
 318 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 319 [#include <sys/types.h>
 320 #include <asm/stat.h>])
 321
 322 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 323
 324 AC_CHECK_TYPES(m4_normalize([
 325         struct pt_all_user_regs,
 326         struct ia64_fpreg,
 327         struct ptrace_peeksiginfo_args
 328 ]),,, [#include <sys/ptrace.h>])
 329
 330 AC_CHECK_TYPES(m4_normalize([
 331         struct flock,
 332         struct flock64,
 333         struct __kernel_flock,
 334         struct __kernel_flock64
 335 ]),,,
 336 [#include <sys/types.h>
 337 #include <linux/fcntl.h>])
 338
 339 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 340
 341 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 342
 343 AC_CHECK_MEMBERS(m4_normalize([
 344         siginfo_t.si_syscall,
 345         siginfo_t.si_timerid,
 346         siginfo_t.si_overrun
 347 ]),,, [#include <signal.h>])
 348
 349 AC_CHECK_HEADERS(m4_normalize([
 350         asm/cachectl.h
 351         asm/sysmips.h
 352         bluetooth/bluetooth.h
 353         elf.h
 354         inttypes.h
 355         linux/bsg.h
 356         linux/falloc.h
 357         linux/fiemap.h
 358         linux/filter.h
 359         linux/hiddev.h
 360         linux/ip_vs.h
 361         linux/ipc.h
 362         linux/mmtimer.h
 363         linux/msg.h
 364         linux/perf_event.h
 365         linux/seccomp.h
 366         linux/securebits.h
 367         linux/sem.h
 368         linux/shm.h
 369         linux/userfaultfd.h
 370         linux/utsname.h
 371         mqueue.h
 372         netinet/sctp.h
 373         netipx/ipx.h
 374         scsi/sg.h
 375         stropts.h
 376         sys/conf.h
 377         sys/eventfd.h
 378         sys/fanotify.h
 379         sys/ipc.h
 380         sys/msg.h
 381         sys/reg.h
 382         sys/sem.h
 383         sys/shm.h
 384         sys/signalfd.h
 385         sys/xattr.h
 386 ]))
 387
 388 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 389
 390 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 391
 392 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 393
 394 AC_CHECK_HEADERS(m4_normalize([
 395         linux/netfilter_arp/arp_tables.h
 396         linux/netfilter_bridge/ebtables.h
 397         linux/netfilter_ipv4/ip_tables.h
 398         linux/netfilter_ipv6/ip6_tables.h
 399 ]),,, [#include <netinet/in.h>
 400 #include <net/if.h>])
 401
 402 AC_CHECK_HEADERS([linux/input.h], [
 403         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 404 ])
 405
 406 AC_CHECK_HEADERS([linux/bpf.h], [
 407         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 408                        [st_cv_have_union_bpf_attr_log_buf],
 409                 [AC_COMPILE_IFELSE(
 410                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 411                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 412                         [st_cv_have_union_bpf_attr_log_buf=yes],
 413                         [st_cv_have_union_bpf_attr_log_buf=no])])
 414         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 415                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 416                           [Define to 1 if union bpf_attr.log_buf initialization works])
 417         fi
 418 ])
 419
 420 AC_CHECK_TYPES([struct statfs], [
 421         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 422 #include <asm/statfs.h>])
 423         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 424 #include <asm/statfs.h>])
 425         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 426 #include <asm/statfs.h>])
 427         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 428 #include <asm/statfs.h>])
 429 ],, [#include <linux/types.h>
 430 #include <asm/statfs.h>])
 431
 432 AC_CHECK_TYPES([struct statfs64], [
 433         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 434 #include <asm/statfs.h>])
 435         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 436 #include <asm/statfs.h>])
 437         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 438 #include <asm/statfs.h>])
 439         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 440 #include <asm/statfs.h>])
 441 ],, [#include <linux/types.h>
 442 #include <asm/statfs.h>])
 443
 444 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 445
 446 AC_CHECK_HEADERS([linux/btrfs.h], [
 447         AC_CHECK_MEMBERS(m4_normalize([
 448                 struct btrfs_ioctl_feature_flags.compat_flags,
 449                 struct btrfs_ioctl_fs_info_args.nodesize,
 450                 struct btrfs_ioctl_defrag_range_args.start,
 451                 struct btrfs_ioctl_search_args_v2.buf_size
 452                 ]),,, [ #include <stdio.h>
 453 #include <linux/btrfs.h>])
 454         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 455                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 456 #include <linux/btrfs.h>])])
 457
 458 AC_CHECK_DECLS([sys_errlist])
 459 AC_CHECK_DECLS(m4_normalize([
 460         PTRACE_PEEKUSER,
 461         PTRACE_POKEUSER
 462 ]),,, [#include <sys/ptrace.h>])
 463
 464 AC_CHECK_DECLS(m4_normalize([
 465         P_PID,
 466         P_PPID,
 467         P_PGID,
 468         P_SID,
 469         P_CID,
 470         P_UID,
 471         P_GID,
 472         P_ALL,
 473         P_LWPID
 474 ]),,, [#include <sys/wait.h>])
 475
 476 AC_CHECK_DECLS(m4_normalize([
 477         LO_FLAGS_READ_ONLY,
 478         LO_FLAGS_AUTOCLEAR,
 479         LO_FLAGS_PARTSCAN
 480 ]),,, [#include <linux/loop.h>])
 481
 482 AC_CHECK_DECLS(m4_normalize([
 483         CTL_PROC,
 484         CTL_ARLAN,
 485         CTL_S390DBF,
 486         CTL_SUNRPC,
 487         CTL_PM,
 488         CTL_FRV,
 489         KERN_PRINTK_RATELIMIT,
 490         KERN_PRINTK_RATELIMIT_BURST,
 491         KERN_PTY,
 492         KERN_NGROUPS_MAX,
 493         KERN_SPARC_SCONS_PWROFF,
 494         KERN_HZ_TIMER,
 495         KERN_UNKNOWN_NMI_PANIC,
 496         KERN_BOOTLOADER_TYPE,
 497         KERN_RANDOMIZE,
 498         KERN_SETUID_DUMPABLE,
 499         KERN_SPIN_RETRY,
 500         KERN_ACPI_VIDEO_FLAGS,
 501         KERN_IA64_UNALIGNED,
 502         KERN_COMPAT_LOG,
 503         KERN_MAX_LOCK_DEPTH,
 504         KERN_NMI_WATCHDOG,
 505         KERN_PANIC_ON_NMI,
 506         NET_LLC,
 507         NET_NETFILTER,
 508         NET_DCCP,
 509         NET_IRDA,
 510         NET_CORE_DESTROY_DELAY,
 511         NET_CORE_BUDGET,
 512         NET_CORE_AEVENT_ETIME,
 513         NET_CORE_AEVENT_RSEQTH,
 514         NET_CORE_WARNINGS,
 515         NET_IPV4_IGMP_MAX_MSF,
 516         NET_TCP_NO_METRICS_SAVE,
 517         NET_TCP_DEFAULT_WIN_SCALE,
 518         NET_TCP_MODERATE_RCVBUF,
 519         NET_TCP_TSO_WIN_DIVISOR,
 520         NET_TCP_BIC_BETA,
 521         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 522         NET_TCP_CONG_CONTROL,
 523         NET_TCP_ABC,
 524         NET_IPV4_IPFRAG_MAX_DIST,
 525         NET_TCP_MTU_PROBING,
 526         NET_TCP_BASE_MSS,
 527         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 528         NET_TCP_DMA_COPYBREAK,
 529         NET_TCP_SLOW_START_AFTER_IDLE,
 530         NET_CIPSOV4_CACHE_ENABLE,
 531         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 532         NET_CIPSOV4_RBM_OPTFMT,
 533         NET_CIPSOV4_RBM_STRICTVALID,
 534         NET_TCP_AVAIL_CONG_CONTROL,
 535         NET_TCP_ALLOWED_CONG_CONTROL,
 536         NET_TCP_MAX_SSTHRESH,
 537         NET_TCP_FRTO_RESPONSE,
 538         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 539         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 540         NET_IPV4_CONF_ARP_ANNOUNCE,
 541         NET_IPV4_CONF_ARP_IGNORE,
 542         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 543         NET_IPV4_CONF_ARP_ACCEPT,
 544         NET_IPV4_CONF_ARP_NOTIFY,
 545         NET_IPV6_MLD_MAX_MSF,
 546         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 547         VM_MAX_MAP_COUNT,
 548         VM_LAPTOP_MODE,
 549         VM_BLOCK_DUMP,
 550         VM_HUGETLB_GROUP,
 551         VM_VFS_CACHE_PRESSURE,
 552         VM_LEGACY_VA_LAYOUT,
 553         VM_SWAP_TOKEN_TIMEOUT
 554 ]),,,
 555 [#include <sys/types.h>
 556 #include <linux/sysctl.h>])
 557
 558 AC_CHECK_DECLS(m4_normalize([
 559         V4L2_FIELD_ANY,
 560         V4L2_FIELD_NONE,
 561         V4L2_FIELD_TOP,
 562         V4L2_FIELD_BOTTOM,
 563         V4L2_FIELD_INTERLACED,
 564         V4L2_FIELD_SEQ_TB,
 565         V4L2_FIELD_SEQ_BT,
 566         V4L2_FIELD_ALTERNATE,
 567         V4L2_FIELD_INTERLACED_TB,
 568         V4L2_FIELD_INTERLACED_BT,
 569         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 570         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 571         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 572         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 573         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 574         V4L2_BUF_TYPE_VBI_CAPTURE,
 575         V4L2_BUF_TYPE_VBI_OUTPUT,
 576         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 577         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 578         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 579         V4L2_TUNER_RADIO,
 580         V4L2_TUNER_ANALOG_TV,
 581         V4L2_TUNER_DIGITAL_TV,
 582         V4L2_MEMORY_MMAP,
 583         V4L2_MEMORY_USERPTR,
 584         V4L2_MEMORY_OVERLAY,
 585         V4L2_MEMORY_DMABUF,
 586         V4L2_COLORSPACE_SMPTE170M,
 587         V4L2_COLORSPACE_SMPTE240M,
 588         V4L2_COLORSPACE_REC709,
 589         V4L2_COLORSPACE_BT878,
 590         V4L2_COLORSPACE_470_SYSTEM_M,
 591         V4L2_COLORSPACE_470_SYSTEM_BG,
 592         V4L2_COLORSPACE_JPEG,
 593         V4L2_COLORSPACE_SRGB,
 594         V4L2_PRIORITY_UNSET,
 595         V4L2_PRIORITY_BACKGROUND,
 596         V4L2_PRIORITY_INTERACTIVE,
 597         V4L2_PRIORITY_RECORD,
 598         V4L2_FRMSIZE_TYPE_DISCRETE,
 599         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 600         V4L2_FRMSIZE_TYPE_STEPWISE,
 601         V4L2_FRMIVAL_TYPE_DISCRETE,
 602         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 603         V4L2_FRMIVAL_TYPE_STEPWISE,
 604         V4L2_CTRL_TYPE_INTEGER,
 605         V4L2_CTRL_TYPE_BOOLEAN,
 606         V4L2_CTRL_TYPE_MENU,
 607         V4L2_CTRL_TYPE_BUTTON,
 608         V4L2_CTRL_TYPE_INTEGER64,
 609         V4L2_CTRL_TYPE_CTRL_CLASS,
 610         V4L2_CTRL_TYPE_STRING,
 611         V4L2_CTRL_TYPE_BITMASK,
 612         V4L2_CTRL_TYPE_INTEGER_MENU
 613 ]),,, [#include <sys/time.h>
 614 #include <linux/ioctl.h>
 615 #include <linux/types.h>
 616 #include <linux/videodev2.h>])
 617
 618 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 619         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 620 #include <stdlib.h>
 621 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 622                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 623         if test $ac_cv_have_blkgetsize64 = yes; then
 624                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 625         fi)
 626
 627 AC_CHECK_SIZEOF([long])
 628 AC_CHECK_SIZEOF([long long])
 629 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 630 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 631
 632 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 633                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 634                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 635                         grep '^[0-9]')"
 636                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 637 if test "x$st_cv_SIGRTMIN" != xno; then
 638         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 639                            [SIGRTMIN defined in <asm/signal.h>])
 640 fi
 641 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 642                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 643                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 644                         grep ^0x)"
 645                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 646 if test "x$st_cv_SA_RESTORER" != xno; then
 647         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 648                            [SA_RESTORER defined in <asm/signal.h>])
 649 fi
 650
 651 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 652                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 653                                [st_cv_have___builtin_popcount=yes],
 654                                [st_cv_have___builtin_popcount=no])])
 655 if test "x$st_cv_have___builtin_popcount" = xyes; then
 656         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 657                   [Define to 1 if the system provides __builtin_popcount function])
 658 fi
 659
 660 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 661 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 662         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 663 fi
 664 AC_SUBST(dl_LIBS)
 665
 666 AC_PATH_PROG([PERL], [perl])
 667
 668 dnl stack trace with libunwind
 669 libunwind_CPPFLAGS=
 670 libunwind_LDFLAGS=
 671 libunwind_LIBS=
 672 AC_ARG_WITH([libunwind],
 673             [AS_HELP_STRING([--with-libunwind],
 674                             [use libunwind to implement stack tracing support])],
 675             [case "${withval}" in
 676              yes|no|check) ;;
 677              *) with_libunwind=yes
 678                 libunwind_CPPFLAGS="-I${withval}/include"
 679                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 680              esac],
 681             [with_libunwind=check]
 682 )
 683
 684 use_libunwind=no
 685 AS_IF([test "x$with_libunwind" != xno],
 686       [saved_CPPFLAGS="$CPPFLAGS"
 687        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 688
 689        AC_CHECK_HEADERS([libunwind-ptrace.h],
 690          [saved_LDFLAGS="$LDFLAGS"
 691           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 692
 693           AC_CHECK_LIB([unwind], [backtrace],
 694             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 695
 696              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 697              saved_LIBS="$LIBS"
 698              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 699
 700              AC_LINK_IFELSE(
 701                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 702                                 [[return !unw_create_addr_space(0, 0)]])
 703                ],
 704                [AC_MSG_RESULT([yes])
 705                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 706
 707                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 708                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 709                    use_libunwind=yes
 710                   ],
 711                   [if test "x$with_libunwind" != xcheck; then
 712                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 713                    fi
 714                   ],
 715                   [$libunwind_LIBS]
 716                 )
 717                ],
 718                [AC_MSG_RESULT([no])
 719                 if test "x$with_libunwind" != xcheck; then
 720                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 721                 fi
 722                ]
 723              )
 724
 725              LIBS="$saved_LIBS"
 726             ],
 727             [if test "x$with_libunwind" != xcheck; then
 728                AC_MSG_FAILURE([failed to find libunwind])
 729              fi
 730             ],
 731             [$libunwind_LIBS]
 732           )
 733
 734           LDFLAGS="$saved_LDFLAGS"
 735          ],
 736          [if test "x$with_libunwind" != xcheck; then
 737             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 738           fi
 739          ]
 740        )
 741
 742        CPPFLAGS="$saved_CPPFLAGS"
 743       ]
 744 )
 745
 746 dnl enable libunwind
 747 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 748 if test "x$use_libunwind" = xyes; then
 749         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 750         AC_SUBST(libunwind_LIBS)
 751         AC_SUBST(libunwind_LDFLAGS)
 752         AC_SUBST(libunwind_CPPFLAGS)
 753 fi
 754 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 755 AC_MSG_RESULT([$use_libunwind])
 756
 757 if test "$arch" = mips && test "$no_create" != yes; then
 758         mkdir -p linux/mips
 759         if $srcdir/linux/mips/genstub.sh linux/mips; then
 760                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 761         else
 762                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 763         fi
 764 fi
 765
 766 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 767 st_MPERS([mx32], [x86_64])
 768
 769 AC_CONFIG_FILES([Makefile
 770                  tests/Makefile
 771                  tests-m32/Makefile
 772                  tests-mx32/Makefile
 773                  strace.spec
 774                  debian/changelog])
 775 AC_OUTPUT