granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  41 AC_CONFIG_SRCDIR([strace.c])
  42 AC_CONFIG_AUX_DIR([.])
  43 AC_CONFIG_HEADERS([config.h])
  44 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  45 AM_EXTRA_RECURSIVE_TARGETS([check-valgrind])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_MSG_CHECKING([for supported architecture])
  68 arch_m32=
  69 arch_mx32=
  70 case "$host_cpu" in
  71 bfin)
  72         arch=bfin
  73         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  74         ;;
  75 i[[3456]]86|pentium)
  76         arch=i386
  77         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  78         ;;
  79 ia64)
  80         arch=ia64
  81         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  82         ;;
  83 m68k)
  84         arch=m68k
  85         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  86         ;;
  87 sparc64*)
  88         arch=sparc64
  89         arch_m32=sparc
  90         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  91         ;;
  92 sparc*)
  93         arch=sparc
  94         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  95         ;;
  96 metag*)
  97         arch=metag
  98         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  99         ;;
 100 mips*)
 101         arch=mips
 102         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 103         ;;
 104 alpha*)
 105         arch=alpha
 106         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 107         ;;
 108 powerpc*)
 109         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 110         AC_TRY_COMPILE(
 111 [#ifndef __LP64__
 112 # error 32 bit
 113 #endif], [], arch=powerpc64, arch=powerpc)
 114         if test "$arch" = "powerpc64"; then
 115                 arch_m32=powerpc
 116                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 117         fi
 118         ;;
 119 arm*)
 120         arch=arm
 121         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 122         ;;
 123 aarch64*)
 124         arch=aarch64
 125         arch_m32=arm
 126         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 127         ;;
 128 avr32*)
 129         arch=avr32
 130         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 131         ;;
 132 arc*)
 133         arch=arc
 134         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 135         ;;
 136 s390)
 137         arch=s390
 138         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 139         ;;
 140 s390x)
 141         arch=s390x
 142         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 143         ;;
 144 hppa*|parisc*)
 145         arch=hppa
 146         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 147         ;;
 148 sh64*)
 149         arch=sh64
 150         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 151         ;;
 152 sh*)
 153         arch=sh
 154         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 155         ;;
 156 x86?64*)
 157         arch_m32=i386
 158         AC_TRY_COMPILE(
 159 [#ifndef __ILP32__
 160 # error not x32
 161 #endif], [], arch=x32, arch=x86_64)
 162         if test "$arch" = "x86_64"; then
 163                 arch_mx32=x32
 164                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 165         else
 166                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 167         fi
 168         ;;
 169 cris|crisv10)
 170         arch=crisv10
 171         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 172         ;;
 173 crisv32)
 174         arch=crisv32
 175         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 176         ;;
 177 tile*)
 178         arch=tile
 179         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 180         ;;
 181 microblaze*)
 182         arch=microblaze
 183         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 184         ;;
 185 nios2*)
 186         arch=nios2
 187         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 188         ;;
 189
 190 or1k*)
 191         arch=or1k
 192         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 193         ;;
 194
 195 xtensa*)
 196         arch=xtensa
 197         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 198         ;;
 199
 200 riscv*)
 201         arch=riscv
 202         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 203         ;;
 204
 205 *)
 206         AC_MSG_RESULT([NO!])
 207         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 208         ;;
 209 esac
 210 AC_MSG_RESULT($arch)
 211
 212 test -n "$arch_m32" ||
 213         arch_m32=$arch
 214 test -n "$arch_mx32" ||
 215         arch_mx32=$arch
 216 AC_SUBST(arch)
 217 AC_SUBST(arch_m32)
 218 AC_SUBST(arch_mx32)
 219
 220 MIPS_ABI=
 221 if test "$arch" = mips; then
 222         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 223                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 224                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 225
 226         # requires GCC >= 3.4
 227         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 228                 [AC_COMPILE_IFELSE(
 229                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 230                         [st_cv_mips_abi=o32],
 231                 [AC_COMPILE_IFELSE(
 232                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 233                         [st_cv_mips_abi=n32],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=n64],
 237                         [st_cv_mips_abi=unknown])])])])
 238
 239         case "$st_cv_mips_abi" in
 240                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 241                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 242                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 243                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 244         esac
 245         MIPS_ABI="$st_cv_mips_abi"
 246 fi
 247 AC_SUBST(MIPS_ABI)
 248
 249 AC_ARG_ENABLE([arm-oabi],
 250               [AS_HELP_STRING([--enable-arm-oabi],
 251                               [enable OABI support on ARM EABI])],
 252               [], [enable_arm_oabi=no])
 253 case "$enable_arm_oabi" in
 254         yes) enable_arm_oabi=1 ;;
 255         no) enable_arm_oabi=0 ;;
 256         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 257 esac
 258 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 259                    [Define to 1 if you want OABI support on ARM EABI.])
 260
 261 AC_C_BIGENDIAN
 262 AC_C_TYPEOF
 263
 264 AC_TYPE_UID_T
 265
 266 AC_CHECK_FUNCS(m4_normalize([
 267         accept4
 268         fallocate
 269         fanotify_mark
 270         fopen64
 271         fork
 272         fputs_unlocked
 273         fstatat
 274         ftruncate
 275         futimens
 276         if_indextoname
 277         open64
 278         prctl
 279         preadv
 280         process_vm_readv
 281         pwritev
 282         readahead
 283         signalfd
 284         stpcpy
 285         strerror
 286         strsignal
 287         sync_file_range
 288         utimensat
 289 ]))
 290
 291 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 292
 293 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 294
 295 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 296 [#include <asm/posix_types.h>])
 297
 298 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 299 [#include <sys/types.h>
 300 #include <asm/stat.h>])
 301
 302 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 303
 304 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 305 [#include <sys/types.h>
 306 #include <asm/stat.h>])
 307
 308 AC_CHECK_TYPES(m4_normalize([
 309         struct pt_all_user_regs,
 310         struct ia64_fpreg,
 311         struct ptrace_peeksiginfo_args
 312 ]),,, [#include <sys/ptrace.h>])
 313
 314 AC_CHECK_TYPES(m4_normalize([
 315         struct flock,
 316         struct flock64,
 317         struct __kernel_flock,
 318         struct __kernel_flock64
 319 ]),,,
 320 [#include <sys/types.h>
 321 #include <linux/fcntl.h>])
 322
 323 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 324
 325 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 326
 327 AC_CHECK_MEMBERS(m4_normalize([
 328         siginfo_t.si_syscall,
 329         siginfo_t.si_timerid,
 330         siginfo_t.si_overrun
 331 ]),,, [#include <signal.h>])
 332
 333 AC_CHECK_MEMBERS(m4_normalize([
 334         struct perf_event_attr.precise_ip,
 335         struct perf_event_attr.mmap_data,
 336         struct perf_event_attr.sample_id_all,
 337         struct perf_event_attr.exclude_host,
 338         struct perf_event_attr.exclude_guest,
 339         struct perf_event_attr.exclude_callchain_kernel,
 340         struct perf_event_attr.exclude_callchain_user,
 341         struct perf_event_attr.mmap2,
 342         struct perf_event_attr.comm_exec,
 343         struct perf_event_attr.use_clockid,
 344         struct perf_event_attr.context_switch,
 345         struct perf_event_attr.write_backward,
 346         struct perf_event_attr.bp_type,
 347         struct perf_event_attr.config1,
 348         struct perf_event_attr.config2,
 349         struct perf_event_attr.branch_sample_type,
 350         struct perf_event_attr.sample_regs_user,
 351         struct perf_event_attr.sample_stack_user,
 352         struct perf_event_attr.sample_regs_intr,
 353         struct perf_event_attr.aux_watermark,
 354         struct perf_event_attr.sample_max_stack
 355 ]),,, [#include <linux/perf_event.h>])
 356
 357 AC_CHECK_HEADERS(m4_normalize([
 358         asm/cachectl.h
 359         asm/sysmips.h
 360         bluetooth/bluetooth.h
 361         elf.h
 362         inttypes.h
 363         linux/bsg.h
 364         linux/dm-ioctl.h
 365         linux/dqblk_xfs.h
 366         linux/falloc.h
 367         linux/fiemap.h
 368         linux/filter.h
 369         linux/hiddev.h
 370         linux/ip_vs.h
 371         linux/ipc.h
 372         linux/mmtimer.h
 373         linux/msg.h
 374         linux/netfilter/nfnetlink.h
 375         linux/nsfs.h
 376         linux/perf_event.h
 377         linux/quota.h
 378         linux/seccomp.h
 379         linux/securebits.h
 380         linux/sem.h
 381         linux/shm.h
 382         linux/userfaultfd.h
 383         linux/utsname.h
 384         mqueue.h
 385         netinet/sctp.h
 386         netipx/ipx.h
 387         scsi/sg.h
 388         stropts.h
 389         sys/conf.h
 390         sys/eventfd.h
 391         sys/fanotify.h
 392         sys/ipc.h
 393         sys/msg.h
 394         sys/quota.h
 395         sys/reg.h
 396         sys/sem.h
 397         sys/shm.h
 398         sys/signalfd.h
 399         sys/xattr.h
 400         ustat.h
 401 ]))
 402
 403 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 404
 405 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 406
 407 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 408
 409 AC_CHECK_HEADERS(m4_normalize([
 410         linux/netfilter_arp/arp_tables.h
 411         linux/netfilter_bridge/ebtables.h
 412         linux/netfilter_ipv4/ip_tables.h
 413         linux/netfilter_ipv6/ip6_tables.h
 414 ]),,, [#include <netinet/in.h>
 415 #include <net/if.h>])
 416
 417 AC_CHECK_HEADERS([linux/input.h], [
 418         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 419 ])
 420
 421 AC_CHECK_HEADERS([linux/bpf.h], [
 422         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 423                        [st_cv_have_union_bpf_attr_log_buf],
 424                 [AC_COMPILE_IFELSE(
 425                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 426                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 427                         [st_cv_have_union_bpf_attr_log_buf=yes],
 428                         [st_cv_have_union_bpf_attr_log_buf=no])])
 429         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 430                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 431                           [Define to 1 if union bpf_attr.log_buf initialization works])
 432         fi
 433         AC_CACHE_CHECK([whether union bpf_attr.bpf_fd initialization works],
 434                        [st_cv_have_union_bpf_attr_bpf_fd],
 435                 [AC_COMPILE_IFELSE(
 436                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 437                                          [[union bpf_attr a = { .bpf_fd = 0 };]])],
 438                         [st_cv_have_union_bpf_attr_bpf_fd=yes],
 439                         [st_cv_have_union_bpf_attr_bpf_fd=no])])
 440         if test $st_cv_have_union_bpf_attr_bpf_fd = yes; then
 441                 AC_DEFINE(HAVE_UNION_BPF_ATTR_BPF_FD, [1],
 442                           [Define to 1 if union bpf_attr.bpf_fd initialization works])
 443         fi
 444         AC_CACHE_CHECK([whether union bpf_attr.attach_flags initialization works],
 445                        [st_cv_have_union_bpf_attr_attach_flags],
 446                 [AC_COMPILE_IFELSE(
 447                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 448                                          [[union bpf_attr a = { .attach_flags = 0 };]])],
 449                         [st_cv_have_union_bpf_attr_attach_flags=yes],
 450                         [st_cv_have_union_bpf_attr_attach_flags=no])])
 451         if test $st_cv_have_union_bpf_attr_attach_flags = yes; then
 452                 AC_DEFINE(HAVE_UNION_BPF_ATTR_ATTACH_FLAGS, [1],
 453                           [Define to 1 if union bpf_attr.attach_flags initialization works])
 454         fi
 455 ])
 456
 457 AC_CHECK_TYPES([struct statfs], [
 458         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 459 #include <asm/statfs.h>])
 460         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 461 #include <asm/statfs.h>])
 462         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 463 #include <asm/statfs.h>])
 464         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 465 #include <asm/statfs.h>])
 466 ],, [#include <linux/types.h>
 467 #include <asm/statfs.h>])
 468
 469 AC_CHECK_TYPES([struct statfs64], [
 470         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 471 #include <asm/statfs.h>])
 472         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 473 #include <asm/statfs.h>])
 474         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 475 #include <asm/statfs.h>])
 476         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 477 #include <asm/statfs.h>])
 478 ],, [#include <linux/types.h>
 479 #include <asm/statfs.h>])
 480
 481 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 482
 483 AC_CHECK_HEADERS([linux/btrfs.h], [
 484         AC_CHECK_MEMBERS(m4_normalize([
 485                 struct btrfs_ioctl_feature_flags.compat_flags,
 486                 struct btrfs_ioctl_fs_info_args.nodesize,
 487                 struct btrfs_ioctl_defrag_range_args.start,
 488                 struct btrfs_ioctl_search_args_v2.buf_size
 489                 ]),,, [ #include <stdio.h>
 490 #include <linux/btrfs.h>])
 491         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 492                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 493 #include <linux/btrfs.h>])])
 494
 495 AC_CHECK_DECLS([sys_errlist])
 496 AC_CHECK_DECLS(m4_normalize([
 497         PTRACE_PEEKUSER,
 498         PTRACE_POKEUSER
 499 ]),,, [#include <sys/ptrace.h>])
 500
 501 AC_CHECK_DECLS(m4_normalize([
 502         P_PID,
 503         P_PPID,
 504         P_PGID,
 505         P_SID,
 506         P_CID,
 507         P_UID,
 508         P_GID,
 509         P_ALL,
 510         P_LWPID
 511 ]),,, [#include <sys/wait.h>])
 512
 513 AC_CHECK_DECLS(m4_normalize([
 514         LO_FLAGS_READ_ONLY,
 515         LO_FLAGS_USE_AOPS,
 516         LO_FLAGS_AUTOCLEAR,
 517         LO_FLAGS_PARTSCAN,
 518         LO_FLAGS_DIRECT_IO
 519 ]),,, [#include <linux/loop.h>])
 520
 521 AC_CHECK_DECLS(m4_normalize([
 522         CTL_PROC,
 523         CTL_ARLAN,
 524         CTL_S390DBF,
 525         CTL_SUNRPC,
 526         CTL_PM,
 527         CTL_FRV,
 528         KERN_PRINTK_RATELIMIT,
 529         KERN_PRINTK_RATELIMIT_BURST,
 530         KERN_PTY,
 531         KERN_NGROUPS_MAX,
 532         KERN_SPARC_SCONS_PWROFF,
 533         KERN_HZ_TIMER,
 534         KERN_UNKNOWN_NMI_PANIC,
 535         KERN_BOOTLOADER_TYPE,
 536         KERN_RANDOMIZE,
 537         KERN_SETUID_DUMPABLE,
 538         KERN_SPIN_RETRY,
 539         KERN_ACPI_VIDEO_FLAGS,
 540         KERN_IA64_UNALIGNED,
 541         KERN_COMPAT_LOG,
 542         KERN_MAX_LOCK_DEPTH,
 543         KERN_NMI_WATCHDOG,
 544         KERN_PANIC_ON_NMI,
 545         NET_LLC,
 546         NET_NETFILTER,
 547         NET_DCCP,
 548         NET_IRDA,
 549         NET_CORE_DESTROY_DELAY,
 550         NET_CORE_BUDGET,
 551         NET_CORE_AEVENT_ETIME,
 552         NET_CORE_AEVENT_RSEQTH,
 553         NET_CORE_WARNINGS,
 554         NET_IPV4_IGMP_MAX_MSF,
 555         NET_TCP_NO_METRICS_SAVE,
 556         NET_TCP_DEFAULT_WIN_SCALE,
 557         NET_TCP_MODERATE_RCVBUF,
 558         NET_TCP_TSO_WIN_DIVISOR,
 559         NET_TCP_BIC_BETA,
 560         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 561         NET_TCP_CONG_CONTROL,
 562         NET_TCP_ABC,
 563         NET_IPV4_IPFRAG_MAX_DIST,
 564         NET_TCP_MTU_PROBING,
 565         NET_TCP_BASE_MSS,
 566         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 567         NET_TCP_DMA_COPYBREAK,
 568         NET_TCP_SLOW_START_AFTER_IDLE,
 569         NET_CIPSOV4_CACHE_ENABLE,
 570         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 571         NET_CIPSOV4_RBM_OPTFMT,
 572         NET_CIPSOV4_RBM_STRICTVALID,
 573         NET_TCP_AVAIL_CONG_CONTROL,
 574         NET_TCP_ALLOWED_CONG_CONTROL,
 575         NET_TCP_MAX_SSTHRESH,
 576         NET_TCP_FRTO_RESPONSE,
 577         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 578         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 579         NET_IPV4_CONF_ARP_ANNOUNCE,
 580         NET_IPV4_CONF_ARP_IGNORE,
 581         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 582         NET_IPV4_CONF_ARP_ACCEPT,
 583         NET_IPV4_CONF_ARP_NOTIFY,
 584         NET_IPV6_MLD_MAX_MSF,
 585         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 586         VM_MAX_MAP_COUNT,
 587         VM_LAPTOP_MODE,
 588         VM_BLOCK_DUMP,
 589         VM_HUGETLB_GROUP,
 590         VM_VFS_CACHE_PRESSURE,
 591         VM_LEGACY_VA_LAYOUT,
 592         VM_SWAP_TOKEN_TIMEOUT
 593 ]),,,
 594 [#include <sys/types.h>
 595 #include <linux/sysctl.h>])
 596
 597 AC_CHECK_DECLS(m4_normalize([
 598         V4L2_FIELD_ANY,
 599         V4L2_FIELD_NONE,
 600         V4L2_FIELD_TOP,
 601         V4L2_FIELD_BOTTOM,
 602         V4L2_FIELD_INTERLACED,
 603         V4L2_FIELD_SEQ_TB,
 604         V4L2_FIELD_SEQ_BT,
 605         V4L2_FIELD_ALTERNATE,
 606         V4L2_FIELD_INTERLACED_TB,
 607         V4L2_FIELD_INTERLACED_BT,
 608         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 609         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 610         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 611         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 612         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 613         V4L2_BUF_TYPE_VBI_CAPTURE,
 614         V4L2_BUF_TYPE_VBI_OUTPUT,
 615         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 616         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 617         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 618         V4L2_BUF_TYPE_SDR_CAPTURE,
 619         V4L2_BUF_TYPE_SDR_OUTPUT,
 620         V4L2_TUNER_RADIO,
 621         V4L2_TUNER_ANALOG_TV,
 622         V4L2_TUNER_DIGITAL_TV,
 623         V4L2_MEMORY_MMAP,
 624         V4L2_MEMORY_USERPTR,
 625         V4L2_MEMORY_OVERLAY,
 626         V4L2_MEMORY_DMABUF,
 627         V4L2_COLORSPACE_SMPTE170M,
 628         V4L2_COLORSPACE_SMPTE240M,
 629         V4L2_COLORSPACE_REC709,
 630         V4L2_COLORSPACE_BT878,
 631         V4L2_COLORSPACE_470_SYSTEM_M,
 632         V4L2_COLORSPACE_470_SYSTEM_BG,
 633         V4L2_COLORSPACE_JPEG,
 634         V4L2_COLORSPACE_SRGB,
 635         V4L2_PRIORITY_UNSET,
 636         V4L2_PRIORITY_BACKGROUND,
 637         V4L2_PRIORITY_INTERACTIVE,
 638         V4L2_PRIORITY_RECORD,
 639         V4L2_FRMSIZE_TYPE_DISCRETE,
 640         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 641         V4L2_FRMSIZE_TYPE_STEPWISE,
 642         V4L2_FRMIVAL_TYPE_DISCRETE,
 643         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 644         V4L2_FRMIVAL_TYPE_STEPWISE,
 645         V4L2_CTRL_TYPE_INTEGER,
 646         V4L2_CTRL_TYPE_BOOLEAN,
 647         V4L2_CTRL_TYPE_MENU,
 648         V4L2_CTRL_TYPE_BUTTON,
 649         V4L2_CTRL_TYPE_INTEGER64,
 650         V4L2_CTRL_TYPE_CTRL_CLASS,
 651         V4L2_CTRL_TYPE_STRING,
 652         V4L2_CTRL_TYPE_BITMASK,
 653         V4L2_CTRL_TYPE_INTEGER_MENU
 654 ]),,, [#include <sys/time.h>
 655 #include <linux/ioctl.h>
 656 #include <linux/types.h>
 657 #include <linux/videodev2.h>])
 658
 659 AC_CHECK_MEMBERS(m4_normalize([
 660         struct v4l2_window.global_alpha,
 661         struct v4l2_sdr_format.buffersize
 662 ]),,, [#include <sys/time.h>
 663 #include <linux/ioctl.h>
 664 #include <linux/types.h>
 665 #include <linux/videodev2.h>])
 666
 667 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 668         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 669 #include <stdlib.h>
 670 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 671                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 672         if test $ac_cv_have_blkgetsize64 = yes; then
 673                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 674         fi)
 675
 676 AC_CHECK_SIZEOF([long])
 677 AC_CHECK_SIZEOF([long long])
 678 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 679 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 680 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 681
 682 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 683                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 684                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 685                         grep '^[0-9]')"
 686                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 687 if test "x$st_cv_SIGRTMIN" != xno; then
 688         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 689                            [SIGRTMIN defined in <asm/signal.h>])
 690 fi
 691 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 692                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 693                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 694                         grep ^0x)"
 695                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 696 if test "x$st_cv_SA_RESTORER" != xno; then
 697         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 698                            [SA_RESTORER defined in <asm/signal.h>])
 699 fi
 700
 701 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 702                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 703                                [st_cv_have___builtin_popcount=yes],
 704                                [st_cv_have___builtin_popcount=no])])
 705 if test "x$st_cv_have___builtin_popcount" = xyes; then
 706         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 707                   [Define to 1 if the system provides __builtin_popcount function])
 708 fi
 709
 710 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 711 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 712         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 713 fi
 714 AC_SUBST(dl_LIBS)
 715
 716 AC_PATH_PROG([PERL], [perl])
 717
 718 dnl stack trace with libunwind
 719 libunwind_CPPFLAGS=
 720 libunwind_LDFLAGS=
 721 libunwind_LIBS=
 722 AC_ARG_WITH([libunwind],
 723             [AS_HELP_STRING([--with-libunwind],
 724                             [use libunwind to implement stack tracing support])],
 725             [case "${withval}" in
 726              yes|no|check) ;;
 727              *) with_libunwind=yes
 728                 libunwind_CPPFLAGS="-I${withval}/include"
 729                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 730              esac],
 731             [with_libunwind=check]
 732 )
 733
 734 use_libunwind=no
 735 AS_IF([test "x$with_libunwind" != xno],
 736       [saved_CPPFLAGS="$CPPFLAGS"
 737        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 738
 739        AC_CHECK_HEADERS([libunwind-ptrace.h],
 740          [saved_LDFLAGS="$LDFLAGS"
 741           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 742
 743           AC_CHECK_LIB([unwind], [backtrace],
 744             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 745
 746              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 747              saved_LIBS="$LIBS"
 748              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 749
 750              AC_LINK_IFELSE(
 751                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 752                                 [[return !unw_create_addr_space(0, 0)]])
 753                ],
 754                [AC_MSG_RESULT([yes])
 755                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 756
 757                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 758                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 759                    use_libunwind=yes
 760                   ],
 761                   [if test "x$with_libunwind" != xcheck; then
 762                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 763                    fi
 764                   ],
 765                   [$libunwind_LIBS]
 766                 )
 767                ],
 768                [AC_MSG_RESULT([no])
 769                 if test "x$with_libunwind" != xcheck; then
 770                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 771                 fi
 772                ]
 773              )
 774
 775              LIBS="$saved_LIBS"
 776             ],
 777             [if test "x$with_libunwind" != xcheck; then
 778                AC_MSG_FAILURE([failed to find libunwind])
 779              fi
 780             ],
 781             [$libunwind_LIBS]
 782           )
 783
 784           LDFLAGS="$saved_LDFLAGS"
 785          ],
 786          [if test "x$with_libunwind" != xcheck; then
 787             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 788           fi
 789          ]
 790        )
 791
 792        CPPFLAGS="$saved_CPPFLAGS"
 793       ]
 794 )
 795
 796 dnl enable libunwind
 797 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 798 if test "x$use_libunwind" = xyes; then
 799         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 800         AC_SUBST(libunwind_LIBS)
 801         AC_SUBST(libunwind_LDFLAGS)
 802         AC_SUBST(libunwind_CPPFLAGS)
 803 fi
 804 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 805 AC_MSG_RESULT([$use_libunwind])
 806
 807 if test "$arch" = mips && test "$no_create" != yes; then
 808         mkdir -p linux/mips
 809         if $srcdir/linux/mips/genstub.sh linux/mips; then
 810                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 811         else
 812                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 813         fi
 814 fi
 815
 816 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 817 st_MPERS([mx32], [x86_64])
 818
 819 AX_VALGRIND_DFLT([sgcheck], [off])
 820 AX_VALGRIND_CHECK
 821
 822 AC_CONFIG_FILES([Makefile
 823                  tests/Makefile
 824                  tests-m32/Makefile
 825                  tests-mx32/Makefile
 826                  strace.spec
 827                  debian/changelog])
 828 AC_OUTPUT