granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.5])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AM_CONFIG_HEADER([config.h])
   6 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2])
   7 AM_MAINTAINER_MODE
   8 AC_CANONICAL_HOST
   9
  10 AC_MSG_CHECKING([for supported operating system])
  11 case "$host_os" in
  12 linux*)
  13         opsys=linux
  14         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  15         ;;
  16 sunos4*)
  17         opsys=sunos4
  18         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  19         ;;
  20 solaris2* | sysv[[45]]* | irix[[56]]*)
  21         opsys=svr4
  22         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  23 system or a derivative like Solaris 2.x or Irix 5.x.])
  24         case "$host_os" in
  25         sysv4.2uw*)
  26                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  27                 ;;
  28         sysv5*)
  29                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  30                 ;;
  31         esac
  32         ;;
  33 freebsd*)
  34         opsys=freebsd
  35         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  36         ;;
  37 *)
  38         AC_MSG_RESULT([NO!])
  39         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  40         ;;
  41 esac
  42 AC_MSG_RESULT($opsys)
  43
  44 AC_MSG_CHECKING([for supported architecture])
  45 case "$host_cpu" in
  46 i[[3456]]86|pentium)
  47         arch=i386
  48         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  49         ;;
  50 ia64)
  51         arch=ia64
  52         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  53         ;;
  54 m68k)
  55         arch=m68k
  56         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  57         ;;
  58 sparc*)
  59         arch=sparc
  60         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  61         ;;
  62 mips*)
  63         arch=mips
  64         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  65         ;;
  66 alpha*)
  67         arch=alpha
  68         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  69         ;;
  70 powerpc*)
  71         arch=powerpc
  72         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  73         ;;
  74 arm*)
  75         arch=arm
  76         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  77         ;;
  78 s390)
  79         arch=s390
  80         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  81         ;;
  82 s390x)
  83         arch=s390x
  84         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  85         ;;
  86 hppa*|parisc*)
  87         arch=hppa
  88         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  89         ;;
  90 sh)
  91         arch=sh
  92         AC_DEFINE([SH], 1, [Define for the SH architecture.])
  93         ;;
  94 sh64)
  95         arch=sh64
  96         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
  97         ;;
  98 x86?64*)
  99         arch=x86_64
 100         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 101         ;;
 102 *)
 103         AC_MSG_RESULT([NO!])
 104         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 105         ;;
 106 esac
 107 AC_MSG_RESULT($arch)
 108
 109 AC_SUBST(opsys)
 110 AC_SUBST(arch)
 111
 112 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 113 AM_CONDITIONAL([I386], [test x$arch = xi386])
 114 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 115 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 116 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 117 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 118
 119 AC_PROG_CC
 120 dnl That set the default CFLAGS value, which we don't want to diddle first.
 121 CFLAGS="-D_GNU_SOURCE $CFLAGS"
 122
 123 AC_INCLUDEDIR
 124
 125 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 126 then
 127         AC_MSG_CHECKING(for valid machine include directory)
 128         if test -d "$includedir/sun4"
 129         then
 130                 rm -f machine
 131                 ln -s $includedir/sun4 machine
 132                 AC_MSG_RESULT(yes)
 133                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 134 Define if you are have a SPARC with SUNOS4 and your want a version
 135 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 136 Only useful if you have a symbolic link from machine to /usr/include/sun4
 137 in the compilation directory.])
 138         else
 139                 AC_MSG_RESULT(no)
 140         fi
 141 fi
 142
 143 AC_WARNFLAGS
 144 if test "x$opsys" = "xsunos4"
 145 then
 146         if test -n "$GCC"
 147         then
 148                 # SunOS 4.x header files don't declare int functions.
 149                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 150         fi
 151 fi
 152
 153 AC_PROG_CPP
 154 AC_PROG_GCC_TRADITIONAL
 155 AC_PROG_INSTALL
 156 AC_C_CONST
 157 AC_HEADER_STDC
 158 AC_HEADER_DIRENT
 159 AC_HEADER_STAT
 160 AC_CHECK_MEMBERS([struct stat.st_blksize,
 161                   struct stat.st_blocks,
 162                   struct stat.st_aclcnt,
 163                   struct stat.st_flags,
 164                   struct stat.st_fstype,
 165                   struct stat.st_gen,
 166                   struct stat.st_level,
 167                   struct stat.st_rdev])
 168 AC_STAT64
 169
 170 AC_TYPE_SIGNAL
 171 AC_TYPE_UID_T
 172 AC_TYPE_MODE_T
 173 AC_TYPE_GETGROUPS
 174 AC_HEADER_MAJOR
 175 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 176 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 177 [#include <sys/types.h>
 178 #include <sys/socket.h>
 179 #include <netinet/in.h>])
 180 AC_CHECK_TYPES([long long])
 181 AC_LITTLE_ENDIAN_LONG_LONG
 182 AC_OFF_T_IS_LONG_LONG
 183 AC_RLIM_T_IS_LONG_LONG
 184 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 185 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 186
 187 if test x$opsys != xlinux; then
 188 AC_CHECK_LIB(nsl, main)
 189 fi
 190
 191 AC_CHECK_FUNCS(sigaction strerror strsignal pread sys_siglist _sys_siglist getdents mctl prctl sendmsg inet_ntop if_indextoname)
 192 AC_CHECK_HEADERS([sys/reg.h sys/filio.h sys/acl.h sys/asynch.h sys/door.h stropts.h sys/conf.h sys/stream.h sys/tihdr.h sys/tiuser.h sys/sysconfig.h ioctls.h sys/ioctl.h sys/ptrace.h termio.h linux/ptrace.h asm/reg.h sys/uio.h sys/aio.h  poll.h sys/poll.h sys/vfs.h asm/sysmips.h linux/utsname.h sys/nscsys.h mqueue.h], [], [])
 193 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 194                  [], [], [#include <linux/socket.h>])
 195 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 196 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 197
 198 AC_MP_PROCFS
 199 AC_POLLABLE_PROCFS
 200
 201 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 202 AC_STRUCT_PR_SYSCALL
 203
 204 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 205                   struct T_conn_res.ACCEPTOR_id],,,
 206 [#include <sys/stream.h>
 207 #include <sys/tihdr.h>])
 208
 209 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 210
 211 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 212                [#include <sys/ptrace.h>])
 213
 214 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 215
 216 AC_CHECK_DECLS([sys_errlist])
 217 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 218
 219 AC_PATH_PROG([PERL], [perl])
 220
 221 AC_CONFIG_FILES([Makefile])
 222 AC_OUTPUT