granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  68 AC_SUBST([MANPAGE_DATE], [manpage_date])
  69
  70 AC_MSG_CHECKING([for supported architecture])
  71 arch_m32=
  72 arch_mx32=
  73 case "$host_cpu" in
  74 bfin)
  75         arch=bfin
  76         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  77         ;;
  78 i[[3456]]86|pentium)
  79         arch=i386
  80         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  81         ;;
  82 ia64)
  83         arch=ia64
  84         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  85         ;;
  86 m68k)
  87         arch=m68k
  88         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  89         ;;
  90 sparc64*)
  91         arch=sparc64
  92         arch_m32=sparc
  93         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  94         ;;
  95 sparc*)
  96         arch=sparc
  97         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  98         ;;
  99 metag*)
 100         arch=metag
 101         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 102         ;;
 103 mips*)
 104         arch=mips
 105         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 106         ;;
 107 alpha*)
 108         arch=alpha
 109         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 110         ;;
 111 powerpc*)
 112         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 113         AC_TRY_COMPILE(
 114 [#ifndef __LP64__
 115 # error 32 bit
 116 #endif], [], arch=powerpc64, arch=powerpc)
 117         if test "$arch" = "powerpc64"; then
 118                 arch_m32=powerpc
 119                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 120         fi
 121         ;;
 122 arm*)
 123         arch=arm
 124         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 125         ;;
 126 aarch64*)
 127         arch=aarch64
 128         arch_m32=arm
 129         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 130         ;;
 131 avr32*)
 132         arch=avr32
 133         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 134         ;;
 135 arc*)
 136         arch=arc
 137         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 138         ;;
 139 s390)
 140         arch=s390
 141         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 142         ;;
 143 s390x)
 144         arch=s390x
 145         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 146         ;;
 147 hppa*|parisc*)
 148         arch=hppa
 149         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 150         ;;
 151 sh64*)
 152         arch=sh64
 153         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 154         ;;
 155 sh*)
 156         arch=sh
 157         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 158         ;;
 159 x86?64*)
 160         arch_m32=i386
 161         AC_TRY_COMPILE(
 162 [#ifndef __ILP32__
 163 # error not x32
 164 #endif], [], arch=x32, arch=x86_64)
 165         if test "$arch" = "x86_64"; then
 166                 arch_mx32=x32
 167                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 168         else
 169                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 170         fi
 171         ;;
 172 cris|crisv10)
 173         arch=crisv10
 174         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 175         ;;
 176 crisv32)
 177         arch=crisv32
 178         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 microblaze*)
 185         arch=microblaze
 186         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 187         ;;
 188 nios2*)
 189         arch=nios2
 190         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 191         ;;
 192
 193 or1k*)
 194         arch=or1k
 195         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 196         ;;
 197
 198 xtensa*)
 199         arch=xtensa
 200         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 201         ;;
 202
 203 riscv*)
 204         arch=riscv
 205         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 206         ;;
 207
 208 *)
 209         AC_MSG_RESULT([NO!])
 210         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 211         ;;
 212 esac
 213 AC_MSG_RESULT($arch)
 214
 215 test -n "$arch_m32" ||
 216         arch_m32=$arch
 217 test -n "$arch_mx32" ||
 218         arch_mx32=$arch
 219 AC_SUBST(arch)
 220 AC_SUBST(arch_m32)
 221 AC_SUBST(arch_mx32)
 222
 223 MIPS_ABI=
 224 if test "$arch" = mips; then
 225         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 226                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 227                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 228
 229         # requires GCC >= 3.4
 230         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 231                 [AC_COMPILE_IFELSE(
 232                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 233                         [st_cv_mips_abi=o32],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=n32],
 237                 [AC_COMPILE_IFELSE(
 238                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 239                         [st_cv_mips_abi=n64],
 240                         [st_cv_mips_abi=unknown])])])])
 241
 242         case "$st_cv_mips_abi" in
 243                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 244                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 245                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 246                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 247         esac
 248         MIPS_ABI="$st_cv_mips_abi"
 249 fi
 250 AC_SUBST(MIPS_ABI)
 251
 252 AC_ARG_ENABLE([arm-oabi],
 253               [AS_HELP_STRING([--enable-arm-oabi],
 254                               [enable OABI support on ARM EABI])],
 255               [], [enable_arm_oabi=no])
 256 case "$enable_arm_oabi" in
 257         yes) enable_arm_oabi=1 ;;
 258         no) enable_arm_oabi=0 ;;
 259         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 260 esac
 261 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 262                    [Define to 1 if you want OABI support on ARM EABI.])
 263
 264 AC_C_BIGENDIAN
 265 AC_C_TYPEOF
 266
 267 AC_TYPE_UID_T
 268
 269 AC_CHECK_FUNCS(m4_normalize([
 270         accept4
 271         be64toh
 272         fallocate
 273         fanotify_mark
 274         fopen64
 275         fork
 276         fputs_unlocked
 277         fstatat
 278         ftruncate
 279         futimens
 280         if_indextoname
 281         open64
 282         prctl
 283         preadv
 284         process_vm_readv
 285         pwritev
 286         readahead
 287         signalfd
 288         stpcpy
 289         strerror
 290         strndup
 291         strsignal
 292         sync_file_range
 293         utimensat
 294 ]))
 295
 296 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 297
 298 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 299
 300 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 301 [#include <asm/posix_types.h>])
 302
 303 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 304 [#include <sys/types.h>
 305 #include <asm/stat.h>])
 306
 307 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 308
 309 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 310 [#include <sys/types.h>
 311 #include <asm/stat.h>])
 312
 313 AC_CHECK_TYPES(m4_normalize([
 314         struct pt_all_user_regs,
 315         struct ia64_fpreg,
 316         struct ptrace_peeksiginfo_args
 317 ]),,, [#include <sys/ptrace.h>])
 318
 319 AC_CHECK_TYPES(m4_normalize([
 320         struct flock,
 321         struct flock64,
 322         struct __kernel_flock,
 323         struct __kernel_flock64
 324 ]),,,
 325 [#include <sys/types.h>
 326 #include <linux/fcntl.h>])
 327
 328 AC_CHECK_TYPES(m4_normalize([
 329         struct crypto_report_aead,
 330         struct crypto_report_blkcipher,
 331         struct crypto_report_cipher,
 332         struct crypto_report_hash,
 333         struct crypto_report_rng
 334 ]),,, [#include <linux/cryptouser.h>])
 335
 336 AC_CHECK_TYPES(m4_normalize([
 337         struct keyctl_kdf_params
 338 ]),,, [#include <linux/keyctl.h>])
 339
 340 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 341
 342 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 343
 344 AC_CHECK_MEMBERS(m4_normalize([
 345         siginfo_t.si_syscall,
 346         siginfo_t.si_timerid,
 347         siginfo_t.si_overrun
 348 ]),,, [#include <signal.h>])
 349
 350 AC_CHECK_MEMBERS(m4_normalize([
 351         struct perf_event_attr.precise_ip,
 352         struct perf_event_attr.mmap_data,
 353         struct perf_event_attr.sample_id_all,
 354         struct perf_event_attr.exclude_host,
 355         struct perf_event_attr.exclude_guest,
 356         struct perf_event_attr.exclude_callchain_kernel,
 357         struct perf_event_attr.exclude_callchain_user,
 358         struct perf_event_attr.mmap2,
 359         struct perf_event_attr.comm_exec,
 360         struct perf_event_attr.use_clockid,
 361         struct perf_event_attr.context_switch,
 362         struct perf_event_attr.write_backward,
 363         struct perf_event_attr.bp_type,
 364         struct perf_event_attr.config1,
 365         struct perf_event_attr.config2,
 366         struct perf_event_attr.branch_sample_type,
 367         struct perf_event_attr.sample_regs_user,
 368         struct perf_event_attr.sample_stack_user,
 369         struct perf_event_attr.sample_regs_intr,
 370         struct perf_event_attr.aux_watermark,
 371         struct perf_event_attr.sample_max_stack
 372 ]),,, [#include <linux/perf_event.h>])
 373
 374 AC_CHECK_HEADERS(m4_normalize([
 375         asm/cachectl.h
 376         asm/sysmips.h
 377         bluetooth/bluetooth.h
 378         elf.h
 379         inttypes.h
 380         linux/bsg.h
 381         linux/cryptouser.h
 382         linux/dm-ioctl.h
 383         linux/dqblk_xfs.h
 384         linux/falloc.h
 385         linux/fib_rules.h
 386         linux/fiemap.h
 387         linux/genetlink.h
 388         linux/hiddev.h
 389         linux/if_addr.h
 390         linux/if_link.h
 391         linux/ip_vs.h
 392         linux/ipc.h
 393         linux/mmtimer.h
 394         linux/msg.h
 395         linux/neighbour.h
 396         linux/netfilter/nfnetlink.h
 397         linux/nsfs.h
 398         linux/perf_event.h
 399         linux/quota.h
 400         linux/seccomp.h
 401         linux/securebits.h
 402         linux/sem.h
 403         linux/shm.h
 404         linux/userfaultfd.h
 405         linux/utsname.h
 406         mqueue.h
 407         netinet/sctp.h
 408         netipx/ipx.h
 409         scsi/sg.h
 410         stropts.h
 411         sys/conf.h
 412         sys/eventfd.h
 413         sys/fanotify.h
 414         sys/ipc.h
 415         sys/msg.h
 416         sys/quota.h
 417         sys/reg.h
 418         sys/sem.h
 419         sys/shm.h
 420         sys/signalfd.h
 421         sys/xattr.h
 422         ustat.h
 423 ]))
 424
 425 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 426
 427 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 428
 429 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 430
 431 AC_CHECK_HEADERS(m4_normalize([
 432         linux/netfilter_arp/arp_tables.h
 433         linux/netfilter_bridge/ebtables.h
 434         linux/netfilter_ipv4/ip_tables.h
 435         linux/netfilter_ipv6/ip6_tables.h
 436 ]),,, [#include <netinet/in.h>
 437 #include <net/if.h>])
 438
 439 AC_CHECK_HEADERS([linux/input.h], [
 440         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 441 ])
 442
 443 AC_CHECK_HEADERS([linux/bpf.h], [
 444         st_CHECK_UNION_BPF_ATTR([attach_flags])
 445         st_CHECK_UNION_BPF_ATTR([bpf_fd])
 446         st_CHECK_UNION_BPF_ATTR([flags])
 447         st_CHECK_UNION_BPF_ATTR([inner_map_fd])
 448         st_CHECK_UNION_BPF_ATTR([prog_flags])
 449 ])
 450
 451 AC_CHECK_TYPES([struct br_port_msg],,, [#include <linux/if_bridge.h>])
 452 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 453 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 454 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 455
 456 AC_CHECK_TYPES(m4_normalize([
 457         struct rta_mfc_stats,
 458         struct rtvia
 459 ]),,, [#include <linux/rtnetlink.h>])
 460
 461 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 462 AC_CHECK_TYPES(m4_normalize([
 463         struct ndt_config,
 464         struct ndt_stats
 465 ]),,, [#include <linux/neighbour.h>])
 466
 467 AC_CHECK_TYPES(m4_normalize([
 468         struct ifla_bridge_id,
 469         struct ifla_port_vsi,
 470         struct rtnl_link_stats64
 471 ]),,, [#include <linux/if_link.h>])
 472 AC_CHECK_MEMBERS(m4_normalize([
 473         struct rtnl_link_stats.rx_nohandler,
 474         struct rtnl_link_stats64.rx_nohandler
 475 ]),,, [#include <linux/if_link.h>])
 476
 477 AC_CHECK_TYPES(m4_normalize([
 478         struct gnet_stats_basic,
 479         struct gnet_stats_queue,
 480         struct gnet_stats_rate_est,
 481         struct gnet_stats_rate_est64
 482 ]),,, [#include <linux/gen_stats.h>])
 483
 484 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/pkt_sched.h>])
 485
 486 AC_CHECK_TYPES([struct fib_rule_uid_range],,, [#include <linux/fib_rules.h>])
 487
 488 AC_CHECK_TYPES([struct statfs], [
 489         AC_CHECK_MEMBERS(m4_normalize([
 490                 struct statfs.f_frsize,
 491                 struct statfs.f_flags,
 492                 struct statfs.f_fsid.val,
 493                 struct statfs.f_fsid.__val
 494         ]),,, [#include <linux/types.h>
 495 #include <asm/statfs.h>])
 496 ],, [#include <linux/types.h>
 497 #include <asm/statfs.h>])
 498
 499 AC_CHECK_TYPES([struct statfs64], [
 500         AC_CHECK_MEMBERS(m4_normalize([
 501                 struct statfs64.f_frsize,
 502                 struct statfs64.f_flags,
 503                 struct statfs64.f_fsid.val,
 504                 struct statfs64.f_fsid.__val
 505         ]),,, [#include <linux/types.h>
 506 #include <asm/statfs.h>])
 507 ],, [#include <linux/types.h>
 508 #include <asm/statfs.h>])
 509
 510 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 511
 512 AC_CHECK_HEADERS([linux/btrfs.h], [
 513         AC_CHECK_MEMBERS(m4_normalize([
 514                 struct btrfs_ioctl_feature_flags.compat_flags,
 515                 struct btrfs_ioctl_fs_info_args.nodesize,
 516                 struct btrfs_ioctl_defrag_range_args.start,
 517                 struct btrfs_ioctl_search_args_v2.buf_size
 518                 ]),,, [ #include <stdio.h>
 519 #include <linux/btrfs.h>])
 520         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 521                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 522 #include <linux/btrfs.h>])])
 523
 524 AC_CHECK_DECLS([sys_errlist])
 525 AC_CHECK_DECLS(m4_normalize([
 526         PTRACE_PEEKUSER,
 527         PTRACE_POKEUSER
 528 ]),,, [#include <sys/ptrace.h>])
 529
 530 AC_CHECK_DECLS(m4_normalize([
 531         P_PID,
 532         P_PPID,
 533         P_PGID,
 534         P_SID,
 535         P_CID,
 536         P_UID,
 537         P_GID,
 538         P_ALL,
 539         P_LWPID
 540 ]),,, [#include <sys/wait.h>])
 541
 542 AC_CHECK_DECLS(m4_normalize([
 543         LO_FLAGS_READ_ONLY,
 544         LO_FLAGS_USE_AOPS,
 545         LO_FLAGS_AUTOCLEAR,
 546         LO_FLAGS_PARTSCAN,
 547         LO_FLAGS_DIRECT_IO
 548 ]),,, [#include <linux/loop.h>])
 549
 550 AC_CHECK_DECLS(m4_normalize([
 551         CTL_PROC,
 552         CTL_ARLAN,
 553         CTL_S390DBF,
 554         CTL_SUNRPC,
 555         CTL_PM,
 556         CTL_FRV,
 557         KERN_PRINTK_RATELIMIT,
 558         KERN_PRINTK_RATELIMIT_BURST,
 559         KERN_PTY,
 560         KERN_NGROUPS_MAX,
 561         KERN_SPARC_SCONS_PWROFF,
 562         KERN_HZ_TIMER,
 563         KERN_UNKNOWN_NMI_PANIC,
 564         KERN_BOOTLOADER_TYPE,
 565         KERN_RANDOMIZE,
 566         KERN_SETUID_DUMPABLE,
 567         KERN_SPIN_RETRY,
 568         KERN_ACPI_VIDEO_FLAGS,
 569         KERN_IA64_UNALIGNED,
 570         KERN_COMPAT_LOG,
 571         KERN_MAX_LOCK_DEPTH,
 572         KERN_NMI_WATCHDOG,
 573         KERN_PANIC_ON_NMI,
 574         NET_LLC,
 575         NET_NETFILTER,
 576         NET_DCCP,
 577         NET_IRDA,
 578         NET_CORE_DESTROY_DELAY,
 579         NET_CORE_BUDGET,
 580         NET_CORE_AEVENT_ETIME,
 581         NET_CORE_AEVENT_RSEQTH,
 582         NET_CORE_WARNINGS,
 583         NET_IPV4_IGMP_MAX_MSF,
 584         NET_TCP_NO_METRICS_SAVE,
 585         NET_TCP_DEFAULT_WIN_SCALE,
 586         NET_TCP_MODERATE_RCVBUF,
 587         NET_TCP_TSO_WIN_DIVISOR,
 588         NET_TCP_BIC_BETA,
 589         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 590         NET_TCP_CONG_CONTROL,
 591         NET_TCP_ABC,
 592         NET_IPV4_IPFRAG_MAX_DIST,
 593         NET_TCP_MTU_PROBING,
 594         NET_TCP_BASE_MSS,
 595         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 596         NET_TCP_DMA_COPYBREAK,
 597         NET_TCP_SLOW_START_AFTER_IDLE,
 598         NET_CIPSOV4_CACHE_ENABLE,
 599         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 600         NET_CIPSOV4_RBM_OPTFMT,
 601         NET_CIPSOV4_RBM_STRICTVALID,
 602         NET_TCP_AVAIL_CONG_CONTROL,
 603         NET_TCP_ALLOWED_CONG_CONTROL,
 604         NET_TCP_MAX_SSTHRESH,
 605         NET_TCP_FRTO_RESPONSE,
 606         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 607         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 608         NET_IPV4_CONF_ARP_ANNOUNCE,
 609         NET_IPV4_CONF_ARP_IGNORE,
 610         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 611         NET_IPV4_CONF_ARP_ACCEPT,
 612         NET_IPV4_CONF_ARP_NOTIFY,
 613         NET_IPV6_MLD_MAX_MSF,
 614         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 615         VM_MAX_MAP_COUNT,
 616         VM_LAPTOP_MODE,
 617         VM_BLOCK_DUMP,
 618         VM_HUGETLB_GROUP,
 619         VM_VFS_CACHE_PRESSURE,
 620         VM_LEGACY_VA_LAYOUT,
 621         VM_SWAP_TOKEN_TIMEOUT
 622 ]),,,
 623 [#include <sys/types.h>
 624 #include <linux/sysctl.h>])
 625
 626 AC_CHECK_DECLS(m4_normalize([
 627         V4L2_FIELD_ANY,
 628         V4L2_FIELD_NONE,
 629         V4L2_FIELD_TOP,
 630         V4L2_FIELD_BOTTOM,
 631         V4L2_FIELD_INTERLACED,
 632         V4L2_FIELD_SEQ_TB,
 633         V4L2_FIELD_SEQ_BT,
 634         V4L2_FIELD_ALTERNATE,
 635         V4L2_FIELD_INTERLACED_TB,
 636         V4L2_FIELD_INTERLACED_BT,
 637         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 638         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 639         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 640         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 641         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 642         V4L2_BUF_TYPE_VBI_CAPTURE,
 643         V4L2_BUF_TYPE_VBI_OUTPUT,
 644         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 645         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 646         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 647         V4L2_BUF_TYPE_SDR_CAPTURE,
 648         V4L2_BUF_TYPE_SDR_OUTPUT,
 649         V4L2_TUNER_RADIO,
 650         V4L2_TUNER_ANALOG_TV,
 651         V4L2_TUNER_DIGITAL_TV,
 652         V4L2_MEMORY_MMAP,
 653         V4L2_MEMORY_USERPTR,
 654         V4L2_MEMORY_OVERLAY,
 655         V4L2_MEMORY_DMABUF,
 656         V4L2_COLORSPACE_SMPTE170M,
 657         V4L2_COLORSPACE_SMPTE240M,
 658         V4L2_COLORSPACE_REC709,
 659         V4L2_COLORSPACE_BT878,
 660         V4L2_COLORSPACE_470_SYSTEM_M,
 661         V4L2_COLORSPACE_470_SYSTEM_BG,
 662         V4L2_COLORSPACE_JPEG,
 663         V4L2_COLORSPACE_SRGB,
 664         V4L2_PRIORITY_UNSET,
 665         V4L2_PRIORITY_BACKGROUND,
 666         V4L2_PRIORITY_INTERACTIVE,
 667         V4L2_PRIORITY_RECORD,
 668         V4L2_FRMSIZE_TYPE_DISCRETE,
 669         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 670         V4L2_FRMSIZE_TYPE_STEPWISE,
 671         V4L2_FRMIVAL_TYPE_DISCRETE,
 672         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 673         V4L2_FRMIVAL_TYPE_STEPWISE,
 674         V4L2_CTRL_TYPE_INTEGER,
 675         V4L2_CTRL_TYPE_BOOLEAN,
 676         V4L2_CTRL_TYPE_MENU,
 677         V4L2_CTRL_TYPE_BUTTON,
 678         V4L2_CTRL_TYPE_INTEGER64,
 679         V4L2_CTRL_TYPE_CTRL_CLASS,
 680         V4L2_CTRL_TYPE_STRING,
 681         V4L2_CTRL_TYPE_BITMASK,
 682         V4L2_CTRL_TYPE_INTEGER_MENU
 683 ]),,, [#include <sys/time.h>
 684 #include <linux/ioctl.h>
 685 #include <linux/types.h>
 686 #include <linux/videodev2.h>])
 687
 688 AC_CHECK_MEMBERS(m4_normalize([
 689         struct v4l2_window.global_alpha,
 690         struct v4l2_sdr_format.buffersize
 691 ]),,, [#include <sys/time.h>
 692 #include <linux/ioctl.h>
 693 #include <linux/types.h>
 694 #include <linux/videodev2.h>])
 695
 696 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 697         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 698 #include <stdlib.h>
 699 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 700                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 701         if test $ac_cv_have_blkgetsize64 = yes; then
 702                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 703         fi)
 704
 705 AC_CHECK_SIZEOF([long])
 706 AC_CHECK_SIZEOF([long long])
 707 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 708 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 709 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 710
 711 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 712                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 713                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 714                         grep '^[0-9]')"
 715                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 716 if test "x$st_cv_SIGRTMIN" != xno; then
 717         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 718                            [SIGRTMIN defined in <asm/signal.h>])
 719 fi
 720 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 721                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 722                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 723                         grep ^0x)"
 724                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 725 if test "x$st_cv_SA_RESTORER" != xno; then
 726         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 727                            [SA_RESTORER defined in <asm/signal.h>])
 728 fi
 729
 730 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 731                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 732                                [st_cv_have___builtin_popcount=yes],
 733                                [st_cv_have___builtin_popcount=no])])
 734 if test "x$st_cv_have___builtin_popcount" = xyes; then
 735         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 736                   [Define to 1 if the system provides __builtin_popcount function])
 737 fi
 738
 739 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 740                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 741                                                 [[return !*program_invocation_name]])],
 742                                [st_cv_have_program_invocation_name=yes],
 743                                [st_cv_have_program_invocation_name=no])])
 744 if test "x$st_cv_have_program_invocation_name" = xyes; then
 745         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 746                   [Define to 1 if the system provides program_invocation_name variable])
 747 fi
 748
 749 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 750 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 751         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 752 fi
 753 AC_SUBST(dl_LIBS)
 754
 755 AC_PATH_PROG([PERL], [perl])
 756
 757 dnl stack trace with libunwind
 758 libunwind_CPPFLAGS=
 759 libunwind_LDFLAGS=
 760 libunwind_LIBS=
 761 AC_ARG_WITH([libunwind],
 762             [AS_HELP_STRING([--with-libunwind],
 763                             [use libunwind to implement stack tracing support])],
 764             [case "${withval}" in
 765              yes|no|check) ;;
 766              *) with_libunwind=yes
 767                 libunwind_CPPFLAGS="-I${withval}/include"
 768                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 769              esac],
 770             [with_libunwind=check]
 771 )
 772
 773 use_libunwind=no
 774 AS_IF([test "x$with_libunwind" != xno],
 775       [saved_CPPFLAGS="$CPPFLAGS"
 776        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 777
 778        AC_CHECK_HEADERS([libunwind-ptrace.h],
 779          [saved_LDFLAGS="$LDFLAGS"
 780           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 781
 782           AC_CHECK_LIB([unwind], [backtrace],
 783             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 784
 785              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 786              saved_LIBS="$LIBS"
 787              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 788
 789              AC_LINK_IFELSE(
 790                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 791                                 [[return !unw_create_addr_space(0, 0)]])
 792                ],
 793                [AC_MSG_RESULT([yes])
 794                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 795
 796                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 797                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 798                    use_libunwind=yes
 799                   ],
 800                   [if test "x$with_libunwind" != xcheck; then
 801                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 802                    fi
 803                   ],
 804                   [$libunwind_LIBS]
 805                 )
 806                ],
 807                [AC_MSG_RESULT([no])
 808                 if test "x$with_libunwind" != xcheck; then
 809                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 810                 fi
 811                ]
 812              )
 813
 814              LIBS="$saved_LIBS"
 815             ],
 816             [if test "x$with_libunwind" != xcheck; then
 817                AC_MSG_FAILURE([failed to find libunwind])
 818              fi
 819             ],
 820             [$libunwind_LIBS]
 821           )
 822
 823           LDFLAGS="$saved_LDFLAGS"
 824          ],
 825          [if test "x$with_libunwind" != xcheck; then
 826             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 827           fi
 828          ]
 829        )
 830
 831        CPPFLAGS="$saved_CPPFLAGS"
 832       ]
 833 )
 834
 835 dnl enable libunwind
 836 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 837 if test "x$use_libunwind" = xyes; then
 838         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 839         AC_SUBST(libunwind_LIBS)
 840         AC_SUBST(libunwind_LDFLAGS)
 841         AC_SUBST(libunwind_CPPFLAGS)
 842 fi
 843 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 844 AC_MSG_RESULT([$use_libunwind])
 845
 846 if test "$arch" = mips && test "$no_create" != yes; then
 847         mkdir -p linux/mips
 848         if $srcdir/linux/mips/genstub.sh linux/mips; then
 849                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 850         else
 851                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 852         fi
 853 fi
 854
 855 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 856 st_MPERS([mx32], [x86_64])
 857
 858 AX_VALGRIND_DFLT([sgcheck], [off])
 859 AX_VALGRIND_CHECK
 860
 861 AC_CONFIG_FILES([Makefile
 862                  tests/Makefile
 863                  tests-m32/Makefile
 864                  tests-mx32/Makefile
 865                  strace.1
 866                  strace.spec
 867                  debian/changelog])
 868 AC_OUTPUT