granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  68 AC_SUBST([MANPAGE_DATE], [manpage_date])
  69
  70 AC_MSG_CHECKING([for supported architecture])
  71 arch_m32=
  72 arch_mx32=
  73 case "$host_cpu" in
  74 bfin)
  75         arch=bfin
  76         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  77         ;;
  78 i[[3456]]86|pentium)
  79         arch=i386
  80         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  81         ;;
  82 ia64)
  83         arch=ia64
  84         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  85         ;;
  86 m68k)
  87         arch=m68k
  88         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  89         ;;
  90 sparc64*)
  91         arch=sparc64
  92         arch_m32=sparc
  93         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  94         ;;
  95 sparc*)
  96         arch=sparc
  97         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  98         ;;
  99 metag*)
 100         arch=metag
 101         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 102         ;;
 103 mips*)
 104         arch=mips
 105         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 106         ;;
 107 alpha*)
 108         arch=alpha
 109         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 110         ;;
 111 powerpc*)
 112         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 113         AC_TRY_COMPILE(
 114 [#ifndef __LP64__
 115 # error 32 bit
 116 #endif], [], arch=powerpc64, arch=powerpc)
 117         if test "$arch" = "powerpc64"; then
 118                 arch_m32=powerpc
 119                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 120         fi
 121         ;;
 122 arm*)
 123         arch=arm
 124         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 125         ;;
 126 aarch64*)
 127         arch=aarch64
 128         arch_m32=arm
 129         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 130         ;;
 131 avr32*)
 132         arch=avr32
 133         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 134         ;;
 135 arc*)
 136         arch=arc
 137         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 138         ;;
 139 s390)
 140         arch=s390
 141         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 142         ;;
 143 s390x)
 144         arch=s390x
 145         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 146         ;;
 147 hppa*|parisc*)
 148         arch=hppa
 149         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 150         ;;
 151 sh64*)
 152         arch=sh64
 153         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 154         ;;
 155 sh*)
 156         arch=sh
 157         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 158         ;;
 159 x86?64*)
 160         arch_m32=i386
 161         AC_TRY_COMPILE(
 162 [#ifndef __ILP32__
 163 # error not x32
 164 #endif], [], arch=x32, arch=x86_64)
 165         if test "$arch" = "x86_64"; then
 166                 arch_mx32=x32
 167                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 168         else
 169                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 170         fi
 171         ;;
 172 cris|crisv10)
 173         arch=crisv10
 174         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 175         ;;
 176 crisv32)
 177         arch=crisv32
 178         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 microblaze*)
 185         arch=microblaze
 186         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 187         ;;
 188 nios2*)
 189         arch=nios2
 190         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 191         ;;
 192
 193 or1k*)
 194         arch=or1k
 195         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 196         ;;
 197
 198 xtensa*)
 199         arch=xtensa
 200         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 201         ;;
 202
 203 riscv*)
 204         arch=riscv
 205         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 206         ;;
 207
 208 *)
 209         AC_MSG_RESULT([NO!])
 210         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 211         ;;
 212 esac
 213 AC_MSG_RESULT($arch)
 214
 215 arch_native=$arch
 216
 217 test -n "$arch_m32" ||
 218         arch_m32=$arch
 219 test -n "$arch_mx32" ||
 220         arch_mx32=$arch
 221 AC_SUBST(arch)
 222 AC_SUBST(arch_m32)
 223 AC_SUBST(arch_mx32)
 224 AC_SUBST(arch_native)
 225
 226 MIPS_ABI=
 227 if test "$arch" = mips; then
 228         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 229                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 230                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 231
 232         # requires GCC >= 3.4
 233         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=o32],
 237                 [AC_COMPILE_IFELSE(
 238                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 239                         [st_cv_mips_abi=n32],
 240                 [AC_COMPILE_IFELSE(
 241                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 242                         [st_cv_mips_abi=n64],
 243                         [st_cv_mips_abi=unknown])])])])
 244
 245         case "$st_cv_mips_abi" in
 246                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 247                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 248                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 249                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 250         esac
 251         MIPS_ABI="$st_cv_mips_abi"
 252 fi
 253 AC_SUBST(MIPS_ABI)
 254
 255 AC_ARG_ENABLE([arm-oabi],
 256               [AS_HELP_STRING([--enable-arm-oabi],
 257                               [enable OABI support on ARM EABI])],
 258               [], [enable_arm_oabi=no])
 259 case "$enable_arm_oabi" in
 260         yes) enable_arm_oabi=1 ;;
 261         no) enable_arm_oabi=0 ;;
 262         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 263 esac
 264 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 265                    [Define to 1 if you want OABI support on ARM EABI.])
 266
 267 AC_C_BIGENDIAN
 268 AC_C_TYPEOF
 269
 270 AC_TYPE_UID_T
 271
 272 AC_CHECK_FUNCS(m4_normalize([
 273         accept4
 274         be64toh
 275         fallocate
 276         fanotify_mark
 277         fopen64
 278         fork
 279         fputs_unlocked
 280         fstatat
 281         ftruncate
 282         futimens
 283         if_indextoname
 284         open64
 285         prctl
 286         preadv
 287         process_vm_readv
 288         pwritev
 289         readahead
 290         signalfd
 291         stpcpy
 292         strerror
 293         strndup
 294         strsignal
 295         sync_file_range
 296         utimensat
 297 ]))
 298
 299 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 300
 301 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 302
 303 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 304 [#include <asm/posix_types.h>])
 305
 306 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 307 [#include <sys/types.h>
 308 #include <asm/stat.h>])
 309
 310 AC_CHECK_TYPES([struct user_desc],
 311                [AC_CHECK_MEMBERS([struct user_desc.lm],,,
 312                                  [#include <asm/ldt.h>])],,
 313                [#include <asm/ldt.h>])
 314
 315 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 316 [#include <sys/types.h>
 317 #include <asm/stat.h>])
 318
 319 AC_CHECK_TYPES(m4_normalize([
 320         struct pt_all_user_regs,
 321         struct ia64_fpreg,
 322         struct ptrace_peeksiginfo_args
 323 ]),,, [#include <sys/ptrace.h>])
 324
 325 AC_CHECK_TYPES(m4_normalize([
 326         struct flock,
 327         struct flock64,
 328         struct __kernel_flock,
 329         struct __kernel_flock64
 330 ]),,,
 331 [#include <sys/types.h>
 332 #include <linux/fcntl.h>])
 333
 334 AC_CHECK_TYPES(m4_normalize([
 335         struct crypto_report_aead,
 336         struct crypto_report_blkcipher,
 337         struct crypto_report_cipher,
 338         struct crypto_report_hash,
 339         struct crypto_report_rng
 340 ]),,, [#include <linux/cryptouser.h>])
 341
 342 AC_CHECK_TYPES(m4_normalize([
 343         struct kcmp_epoll_slot
 344 ]),,, [#include <linux/kcmp.h>])
 345
 346 AC_CHECK_TYPES(m4_normalize([
 347         struct keyctl_kdf_params
 348 ]),,, [#include <linux/keyctl.h>])
 349
 350 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 351
 352 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 353
 354 AC_CHECK_MEMBERS(m4_normalize([
 355         siginfo_t.si_syscall,
 356         siginfo_t.si_timerid,
 357         siginfo_t.si_overrun
 358 ]),,, [#include <signal.h>])
 359
 360 AC_CHECK_MEMBERS(m4_normalize([
 361         struct perf_event_attr.precise_ip,
 362         struct perf_event_attr.mmap_data,
 363         struct perf_event_attr.sample_id_all,
 364         struct perf_event_attr.exclude_host,
 365         struct perf_event_attr.exclude_guest,
 366         struct perf_event_attr.exclude_callchain_kernel,
 367         struct perf_event_attr.exclude_callchain_user,
 368         struct perf_event_attr.mmap2,
 369         struct perf_event_attr.comm_exec,
 370         struct perf_event_attr.use_clockid,
 371         struct perf_event_attr.context_switch,
 372         struct perf_event_attr.write_backward,
 373         struct perf_event_attr.namespaces,
 374         struct perf_event_attr.bp_type,
 375         struct perf_event_attr.config1,
 376         struct perf_event_attr.config2,
 377         struct perf_event_attr.branch_sample_type,
 378         struct perf_event_attr.sample_regs_user,
 379         struct perf_event_attr.sample_stack_user,
 380         struct perf_event_attr.sample_regs_intr,
 381         struct perf_event_attr.aux_watermark,
 382         struct perf_event_attr.sample_max_stack
 383 ]),,, [#include <linux/perf_event.h>])
 384
 385 AC_CHECK_HEADERS(m4_normalize([
 386         asm/cachectl.h
 387         asm/sysmips.h
 388         bluetooth/bluetooth.h
 389         elf.h
 390         inttypes.h
 391         linux/bsg.h
 392         linux/cryptouser.h
 393         linux/dm-ioctl.h
 394         linux/dqblk_xfs.h
 395         linux/falloc.h
 396         linux/fib_rules.h
 397         linux/fiemap.h
 398         linux/genetlink.h
 399         linux/hiddev.h
 400         linux/if_addr.h
 401         linux/if_link.h
 402         linux/ip_vs.h
 403         linux/ipc.h
 404         linux/kcmp.h
 405         linux/kvm.h
 406         linux/memfd.h
 407         linux/mmtimer.h
 408         linux/msg.h
 409         linux/neighbour.h
 410         linux/netfilter/ipset/ip_set.h
 411         linux/netfilter/nf_tables.h
 412         linux/netfilter/nf_tables_compat.h
 413         linux/netfilter/nfnetlink.h
 414         linux/netfilter/nfnetlink_acct.h
 415         linux/netfilter/nfnetlink_conntrack.h
 416         linux/netfilter/nfnetlink_cthelper.h
 417         linux/netfilter/nfnetlink_cttimeout.h
 418         linux/netfilter/nfnetlink_log.h
 419         linux/netfilter/nfnetlink_queue.h
 420         linux/nsfs.h
 421         linux/perf_event.h
 422         linux/quota.h
 423         linux/seccomp.h
 424         linux/securebits.h
 425         linux/sem.h
 426         linux/shm.h
 427         linux/userfaultfd.h
 428         linux/utsname.h
 429         mqueue.h
 430         netinet/sctp.h
 431         netipx/ipx.h
 432         paths.h
 433         scsi/sg.h
 434         stropts.h
 435         sys/conf.h
 436         sys/eventfd.h
 437         sys/fanotify.h
 438         sys/ipc.h
 439         sys/msg.h
 440         sys/quota.h
 441         sys/reg.h
 442         sys/sem.h
 443         sys/shm.h
 444         sys/signalfd.h
 445         sys/xattr.h
 446         ustat.h
 447 ]))
 448
 449 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 450
 451 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 452
 453 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 454
 455 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 456 #include <linux/tcp.h>])
 457
 458 AC_CHECK_HEADERS(m4_normalize([
 459         linux/netfilter_arp/arp_tables.h
 460         linux/netfilter_bridge/ebtables.h
 461         linux/netfilter_ipv4/ip_tables.h
 462         linux/netfilter_ipv6/ip6_tables.h
 463 ]),,, [#include <netinet/in.h>
 464 #include <net/if.h>])
 465
 466 AC_CHECK_HEADERS([linux/input.h], [
 467         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 468 ])
 469
 470 AC_CHECK_HEADERS([linux/bpf.h], [
 471         AC_CHECK_MEMBERS(m4_normalize([
 472                 union bpf_attr.attach_flags,
 473                 union bpf_attr.bpf_fd,
 474                 union bpf_attr.flags,
 475                 union bpf_attr.info.info,
 476                 union bpf_attr.next_id,
 477                 union bpf_attr.numa_node,
 478                 union bpf_attr.prog_flags,
 479                 union bpf_attr.test.duration
 480         ]),,, [#include <linux/bpf.h>])
 481 ])
 482
 483 AC_CHECK_TYPES(m4_normalize([
 484         struct br_mdb_entry,
 485         struct br_port_msg
 486 ]),,, [#include <linux/if_bridge.h>])
 487 AC_CHECK_MEMBERS(m4_normalize([
 488         struct br_mdb_entry.flags,
 489         struct br_mdb_entry.vid
 490 ]),,, [#include <linux/if_bridge.h>])
 491
 492 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 493 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 494 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 495
 496 AC_CHECK_TYPES(m4_normalize([
 497         struct rta_mfc_stats,
 498         struct rtvia
 499 ]),,, [#include <linux/rtnetlink.h>])
 500
 501 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 502 AC_CHECK_TYPES(m4_normalize([
 503         struct ndt_config,
 504         struct ndt_stats
 505 ]),,, [#include <linux/neighbour.h>])
 506
 507 AC_CHECK_TYPES(m4_normalize([
 508         struct ifla_bridge_id,
 509         struct ifla_port_vsi,
 510         struct rtnl_link_stats64
 511 ]),,, [#include <linux/if_link.h>])
 512 AC_CHECK_MEMBERS(m4_normalize([
 513         struct rtnl_link_stats.rx_nohandler,
 514         struct rtnl_link_stats64.rx_nohandler
 515 ]),,, [#include <linux/if_link.h>])
 516
 517 AC_CHECK_TYPES(m4_normalize([
 518         struct gnet_stats_basic,
 519         struct gnet_stats_queue,
 520         struct gnet_stats_rate_est,
 521         struct gnet_stats_rate_est64
 522 ]),,, [#include <linux/gen_stats.h>])
 523
 524 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/pkt_sched.h>])
 525
 526 AC_CHECK_TYPES([struct fib_rule_uid_range],,, [#include <linux/fib_rules.h>])
 527
 528 AC_CHECK_TYPES([struct statfs], [
 529         AC_CHECK_MEMBERS(m4_normalize([
 530                 struct statfs.f_frsize,
 531                 struct statfs.f_flags,
 532                 struct statfs.f_fsid.val,
 533                 struct statfs.f_fsid.__val
 534         ]),,, [#include <linux/types.h>
 535 #include <asm/statfs.h>])
 536 ],, [#include <linux/types.h>
 537 #include <asm/statfs.h>])
 538
 539 AC_CHECK_TYPES([struct statfs64], [
 540         AC_CHECK_MEMBERS(m4_normalize([
 541                 struct statfs64.f_frsize,
 542                 struct statfs64.f_flags,
 543                 struct statfs64.f_fsid.val,
 544                 struct statfs64.f_fsid.__val
 545         ]),,, [#include <linux/types.h>
 546 #include <asm/statfs.h>])
 547 ],, [#include <linux/types.h>
 548 #include <asm/statfs.h>])
 549
 550 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 551
 552 AC_CHECK_TYPES([struct mtd_write_req],,, [#include <mtd/mtd-abi.h>])
 553
 554 AC_CHECK_MEMBERS([struct ubi_attach_req.max_beb_per1024],,, [#include <mtd/ubi-user.h>])
 555
 556 AC_CHECK_TYPES(m4_normalize([
 557         struct ptp_sys_offset
 558 ]),,, [#include <linux/ptp_clock.h>])
 559
 560 AC_CHECK_TYPES(m4_normalize([
 561         struct kvm_regs,
 562         struct kvm_sregs,
 563         struct kvm_userspace_memory_region
 564 ]),,, [#include <linux/kvm.h>])
 565
 566 AC_CHECK_HEADERS([linux/btrfs.h], [
 567         AC_CHECK_MEMBERS(m4_normalize([
 568                 struct btrfs_ioctl_feature_flags.compat_flags,
 569                 struct btrfs_ioctl_fs_info_args.nodesize,
 570                 struct btrfs_ioctl_defrag_range_args.start,
 571                 struct btrfs_ioctl_search_args_v2.buf_size
 572                 ]),,, [ #include <stdio.h>
 573 #include <linux/btrfs.h>])
 574         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 575                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 576 #include <linux/btrfs.h>])])
 577
 578 AC_CHECK_DECLS([sys_errlist])
 579 AC_CHECK_DECLS(m4_normalize([
 580         PTRACE_PEEKUSER,
 581         PTRACE_POKEUSER
 582 ]),,, [#include <sys/ptrace.h>])
 583
 584 AC_CHECK_DECLS(m4_normalize([
 585         P_PID,
 586         P_PPID,
 587         P_PGID,
 588         P_SID,
 589         P_CID,
 590         P_UID,
 591         P_GID,
 592         P_ALL,
 593         P_LWPID
 594 ]),,, [#include <sys/wait.h>])
 595
 596 AC_CHECK_DECLS(m4_normalize([
 597         LO_FLAGS_READ_ONLY,
 598         LO_FLAGS_USE_AOPS,
 599         LO_FLAGS_AUTOCLEAR,
 600         LO_FLAGS_PARTSCAN,
 601         LO_FLAGS_DIRECT_IO
 602 ]),,, [#include <linux/loop.h>])
 603
 604 AC_CHECK_DECLS(m4_normalize([
 605         CTL_PROC,
 606         CTL_ARLAN,
 607         CTL_S390DBF,
 608         CTL_SUNRPC,
 609         CTL_PM,
 610         CTL_FRV,
 611         KERN_PRINTK_RATELIMIT,
 612         KERN_PRINTK_RATELIMIT_BURST,
 613         KERN_PTY,
 614         KERN_NGROUPS_MAX,
 615         KERN_SPARC_SCONS_PWROFF,
 616         KERN_HZ_TIMER,
 617         KERN_UNKNOWN_NMI_PANIC,
 618         KERN_BOOTLOADER_TYPE,
 619         KERN_RANDOMIZE,
 620         KERN_SETUID_DUMPABLE,
 621         KERN_SPIN_RETRY,
 622         KERN_ACPI_VIDEO_FLAGS,
 623         KERN_IA64_UNALIGNED,
 624         KERN_COMPAT_LOG,
 625         KERN_MAX_LOCK_DEPTH,
 626         KERN_NMI_WATCHDOG,
 627         KERN_PANIC_ON_NMI,
 628         NET_LLC,
 629         NET_NETFILTER,
 630         NET_DCCP,
 631         NET_IRDA,
 632         NET_CORE_DESTROY_DELAY,
 633         NET_CORE_BUDGET,
 634         NET_CORE_AEVENT_ETIME,
 635         NET_CORE_AEVENT_RSEQTH,
 636         NET_CORE_WARNINGS,
 637         NET_IPV4_IGMP_MAX_MSF,
 638         NET_TCP_NO_METRICS_SAVE,
 639         NET_TCP_DEFAULT_WIN_SCALE,
 640         NET_TCP_MODERATE_RCVBUF,
 641         NET_TCP_TSO_WIN_DIVISOR,
 642         NET_TCP_BIC_BETA,
 643         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 644         NET_TCP_CONG_CONTROL,
 645         NET_TCP_ABC,
 646         NET_IPV4_IPFRAG_MAX_DIST,
 647         NET_TCP_MTU_PROBING,
 648         NET_TCP_BASE_MSS,
 649         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 650         NET_TCP_DMA_COPYBREAK,
 651         NET_TCP_SLOW_START_AFTER_IDLE,
 652         NET_CIPSOV4_CACHE_ENABLE,
 653         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 654         NET_CIPSOV4_RBM_OPTFMT,
 655         NET_CIPSOV4_RBM_STRICTVALID,
 656         NET_TCP_AVAIL_CONG_CONTROL,
 657         NET_TCP_ALLOWED_CONG_CONTROL,
 658         NET_TCP_MAX_SSTHRESH,
 659         NET_TCP_FRTO_RESPONSE,
 660         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 661         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 662         NET_IPV4_CONF_ARP_ANNOUNCE,
 663         NET_IPV4_CONF_ARP_IGNORE,
 664         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 665         NET_IPV4_CONF_ARP_ACCEPT,
 666         NET_IPV4_CONF_ARP_NOTIFY,
 667         NET_IPV6_MLD_MAX_MSF,
 668         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 669         VM_MAX_MAP_COUNT,
 670         VM_LAPTOP_MODE,
 671         VM_BLOCK_DUMP,
 672         VM_HUGETLB_GROUP,
 673         VM_VFS_CACHE_PRESSURE,
 674         VM_LEGACY_VA_LAYOUT,
 675         VM_SWAP_TOKEN_TIMEOUT
 676 ]),,,
 677 [#include <sys/types.h>
 678 #include <linux/sysctl.h>])
 679
 680 AC_CHECK_DECLS(m4_normalize([
 681         V4L2_FIELD_ANY,
 682         V4L2_FIELD_NONE,
 683         V4L2_FIELD_TOP,
 684         V4L2_FIELD_BOTTOM,
 685         V4L2_FIELD_INTERLACED,
 686         V4L2_FIELD_SEQ_TB,
 687         V4L2_FIELD_SEQ_BT,
 688         V4L2_FIELD_ALTERNATE,
 689         V4L2_FIELD_INTERLACED_TB,
 690         V4L2_FIELD_INTERLACED_BT,
 691         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 692         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 693         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 694         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 695         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 696         V4L2_BUF_TYPE_VBI_CAPTURE,
 697         V4L2_BUF_TYPE_VBI_OUTPUT,
 698         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 699         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 700         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 701         V4L2_BUF_TYPE_SDR_CAPTURE,
 702         V4L2_BUF_TYPE_SDR_OUTPUT,
 703         V4L2_TUNER_RADIO,
 704         V4L2_TUNER_ANALOG_TV,
 705         V4L2_TUNER_DIGITAL_TV,
 706         V4L2_MEMORY_MMAP,
 707         V4L2_MEMORY_USERPTR,
 708         V4L2_MEMORY_OVERLAY,
 709         V4L2_MEMORY_DMABUF,
 710         V4L2_COLORSPACE_SMPTE170M,
 711         V4L2_COLORSPACE_SMPTE240M,
 712         V4L2_COLORSPACE_REC709,
 713         V4L2_COLORSPACE_BT878,
 714         V4L2_COLORSPACE_470_SYSTEM_M,
 715         V4L2_COLORSPACE_470_SYSTEM_BG,
 716         V4L2_COLORSPACE_JPEG,
 717         V4L2_COLORSPACE_SRGB,
 718         V4L2_PRIORITY_UNSET,
 719         V4L2_PRIORITY_BACKGROUND,
 720         V4L2_PRIORITY_INTERACTIVE,
 721         V4L2_PRIORITY_RECORD,
 722         V4L2_FRMSIZE_TYPE_DISCRETE,
 723         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 724         V4L2_FRMSIZE_TYPE_STEPWISE,
 725         V4L2_FRMIVAL_TYPE_DISCRETE,
 726         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 727         V4L2_FRMIVAL_TYPE_STEPWISE,
 728         V4L2_CTRL_TYPE_INTEGER,
 729         V4L2_CTRL_TYPE_BOOLEAN,
 730         V4L2_CTRL_TYPE_MENU,
 731         V4L2_CTRL_TYPE_BUTTON,
 732         V4L2_CTRL_TYPE_INTEGER64,
 733         V4L2_CTRL_TYPE_CTRL_CLASS,
 734         V4L2_CTRL_TYPE_STRING,
 735         V4L2_CTRL_TYPE_BITMASK,
 736         V4L2_CTRL_TYPE_INTEGER_MENU
 737 ]),,, [#include <sys/time.h>
 738 #include <linux/ioctl.h>
 739 #include <linux/types.h>
 740 #include <linux/videodev2.h>])
 741
 742 AC_CHECK_MEMBERS(m4_normalize([
 743         struct v4l2_window.global_alpha,
 744         struct v4l2_sdr_format.buffersize
 745 ]),,, [#include <sys/time.h>
 746 #include <linux/ioctl.h>
 747 #include <linux/types.h>
 748 #include <linux/videodev2.h>])
 749
 750 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 751         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 752 #include <stdlib.h>
 753 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 754                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 755         if test $ac_cv_have_blkgetsize64 = yes; then
 756                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 757         fi)
 758
 759 AC_CHECK_SIZEOF([long])
 760 AC_CHECK_SIZEOF([long long])
 761 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 762 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 763 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 764
 765 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 766                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 767                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 768                         grep '^[0-9]')"
 769                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 770 if test "x$st_cv_SIGRTMIN" != xno; then
 771         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 772                            [SIGRTMIN defined in <asm/signal.h>])
 773 fi
 774 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 775                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 776                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 777                         grep ^0x)"
 778                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 779 if test "x$st_cv_SA_RESTORER" != xno; then
 780         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 781                            [SA_RESTORER defined in <asm/signal.h>])
 782 fi
 783
 784 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 785                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 786                                [st_cv_have___builtin_popcount=yes],
 787                                [st_cv_have___builtin_popcount=no])])
 788 if test "x$st_cv_have___builtin_popcount" = xyes; then
 789         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 790                   [Define to 1 if the system provides __builtin_popcount function])
 791 fi
 792
 793 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 794                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 795                                                 [[return !*program_invocation_name]])],
 796                                [st_cv_have_program_invocation_name=yes],
 797                                [st_cv_have_program_invocation_name=no])])
 798 if test "x$st_cv_have_program_invocation_name" = xyes; then
 799         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 800                   [Define to 1 if the system provides program_invocation_name variable])
 801 fi
 802
 803 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 804 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 805         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 806 fi
 807 AC_SUBST(dl_LIBS)
 808
 809 AC_PATH_PROG([PERL], [perl])
 810
 811 AC_CHECK_TOOL([READELF], [readelf])
 812
 813 dnl stack trace with libunwind
 814 libunwind_CPPFLAGS=
 815 libunwind_LDFLAGS=
 816 libunwind_LIBS=
 817 AC_ARG_WITH([libunwind],
 818             [AS_HELP_STRING([--with-libunwind],
 819                             [use libunwind to implement stack tracing support])],
 820             [case "${withval}" in
 821              yes|no|check) ;;
 822              *) with_libunwind=yes
 823                 libunwind_CPPFLAGS="-I${withval}/include"
 824                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 825              esac],
 826             [with_libunwind=check]
 827 )
 828
 829 use_libunwind=no
 830 AS_IF([test "x$with_libunwind" != xno],
 831       [saved_CPPFLAGS="$CPPFLAGS"
 832        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 833
 834        AC_CHECK_HEADERS([libunwind-ptrace.h],
 835          [saved_LDFLAGS="$LDFLAGS"
 836           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 837
 838           AC_CHECK_LIB([unwind], [backtrace],
 839             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 840
 841              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 842              saved_LIBS="$LIBS"
 843              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 844
 845              AC_LINK_IFELSE(
 846                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 847                                 [[return !unw_create_addr_space(0, 0)]])
 848                ],
 849                [AC_MSG_RESULT([yes])
 850                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 851
 852                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 853                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 854                    use_libunwind=yes
 855                   ],
 856                   [if test "x$with_libunwind" != xcheck; then
 857                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 858                    fi
 859                   ],
 860                   [$libunwind_LIBS]
 861                 )
 862                ],
 863                [AC_MSG_RESULT([no])
 864                 if test "x$with_libunwind" != xcheck; then
 865                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 866                 fi
 867                ]
 868              )
 869
 870              LIBS="$saved_LIBS"
 871             ],
 872             [if test "x$with_libunwind" != xcheck; then
 873                AC_MSG_FAILURE([failed to find libunwind])
 874              fi
 875             ],
 876             [$libunwind_LIBS]
 877           )
 878
 879           LDFLAGS="$saved_LDFLAGS"
 880          ],
 881          [if test "x$with_libunwind" != xcheck; then
 882             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 883           fi
 884          ]
 885        )
 886
 887        CPPFLAGS="$saved_CPPFLAGS"
 888       ]
 889 )
 890
 891 dnl enable libunwind
 892 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 893 if test "x$use_libunwind" = xyes; then
 894         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 895         AC_SUBST(libunwind_LIBS)
 896         AC_SUBST(libunwind_LDFLAGS)
 897         AC_SUBST(libunwind_CPPFLAGS)
 898 fi
 899 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 900 AC_MSG_RESULT([$use_libunwind])
 901
 902 dnl demangling symbols in the stack trace
 903 libiberty_CPPFLAGS=
 904 libiberty_LDFLAGS=
 905 libiberty_LIBS=
 906 AC_ARG_WITH([libiberty],
 907             [AS_HELP_STRING([--with-libiberty],
 908                             [use libiberty to demangle symbols in stack trace])],
 909             [case "${withval}" in
 910              yes|no|check) ;;
 911              *) with_libiberty=yes
 912                 libiberty_CPPFLAGS="-I${withval}/include"
 913                 libiberty_LDFLAGS="-L${withval}/lib" ;;
 914              esac],
 915             [with_libiberty=check]
 916 )
 917
 918 use_libiberty=no
 919 AS_IF([test "x$use_libunwind" = xyes && test "x$with_libiberty" != xno],
 920       [saved_CPPFLAGS="$CPPFLAGS"
 921        CPPFLAGS="$CPPFLAGS $libiberty_CPPFLAGS"
 922        AC_CHECK_HEADERS([demangle.h libiberty/demangle.h],
 923          [saved_LDFLAGS="$LDFLAGS"
 924           LDFLAGS="$LDFLAGS $libiberty_LDFLAGS"
 925           AC_CHECK_LIB([iberty],[cplus_demangle],
 926             [libiberty_LIBS="-liberty"
 927              use_libiberty=yes
 928             ],
 929             [if test "x$with_libiberty" != xcheck; then
 930                AC_MSG_FAILURE([failed to find cplus_demangle in libiberty])
 931              fi
 932             ]
 933           )
 934           LDFLAGS="$saved_LDFLAGS"
 935          ],
 936          [if test "x$with_libiberty" != xcheck; then
 937               AC_MSG_FAILURE([failed to find demangle.h])
 938           fi
 939          ]
 940        )
 941        CPPFLAGS="$saved_CPPFLAGS"
 942       ]
 943 )
 944
 945 dnl enable libiberty
 946 AC_MSG_CHECKING([whether to enable demangling symbols in stack trace])
 947 if test "x$use_libiberty" = xyes; then
 948         AC_DEFINE([USE_DEMANGLE], 1, [Do demangling symbols in stack trace])
 949         AC_SUBST(libiberty_LIBS)
 950         AC_SUBST(libiberty_LDFLAGS)
 951         AC_SUBST(libiberty_CPPFLAGS)
 952 fi
 953 AM_CONDITIONAL([USE_DEMANGLE], [test "x$use_libiberty" = xyes])
 954 AC_MSG_RESULT([$use_libiberty])
 955
 956 if test "$arch" = mips && test "$no_create" != yes; then
 957         mkdir -p linux/mips
 958         if $srcdir/linux/mips/genstub.sh linux/mips; then
 959                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 960         else
 961                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 962         fi
 963 fi
 964
 965 AC_ARG_ENABLE([mpers],
 966         [AS_HELP_STRING([--enable-mpers=yes|no|check],
 967                 [whether to enable multiple personalities support required
 968                  for proper decoding of structures used by tracees with
 969                  personalities that differ from the personality of strace,
 970                  default is yes.])],
 971         [case "$enableval" in
 972                 yes|no|check) enable_mpers="$enableval" ;;
 973                 *) AC_MSG_ERROR([bad value $enableval for enable-mpers option.
 974                                  Valid options are: yes, no, check.]) ;;
 975          esac],
 976         [enable_mpers=yes])
 977
 978 st_MPERS([m32], [aarch64|powerpc64|riscv|sparc64|tile|x32|x86_64])
 979 st_MPERS([mx32], [x86_64])
 980
 981 AX_VALGRIND_DFLT([sgcheck], [off])
 982 AX_VALGRIND_CHECK
 983
 984 AC_CONFIG_FILES([Makefile
 985                  tests/Makefile
 986                  tests-m32/Makefile
 987                  tests-mx32/Makefile
 988                  strace.1
 989                  strace-log-merge.1
 990                  strace.spec
 991                  debian/changelog])
 992 AC_OUTPUT