granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz no-dist-gzip silent-rules parallel-tests])
  40 AM_MAINTAINER_MODE
  41 AC_CANONICAL_HOST
  42
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_INSTALL
  47 AC_PROG_RANLIB
  48
  49 AC_USE_SYSTEM_EXTENSIONS
  50 AX_CODE_COVERAGE
  51
  52 AC_MSG_CHECKING([for supported architecture])
  53 arch_m32=
  54 arch_mx32=
  55 case "$host_cpu" in
  56 bfin)
  57         arch=bfin
  58         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  59         ;;
  60 i[[3456]]86|pentium)
  61         arch=i386
  62         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  63         ;;
  64 ia64)
  65         arch=ia64
  66         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  67         ;;
  68 m68k)
  69         arch=m68k
  70         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  71         ;;
  72 sparc64*)
  73         arch=sparc64
  74         arch_m32=sparc
  75         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  76         ;;
  77 sparc*)
  78         arch=sparc
  79         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  80         ;;
  81 metag*)
  82         arch=metag
  83         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  84         ;;
  85 mips*)
  86         arch=mips
  87         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  88         ;;
  89 alpha*)
  90         arch=alpha
  91         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  92         ;;
  93 powerpc*)
  94         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  95         AC_TRY_COMPILE(
  96 [#ifndef __LP64__
  97 # error 32 bit
  98 #endif], [], arch=powerpc64, arch=powerpc)
  99         if test "$arch" = "powerpc64"; then
 100                 arch_m32=powerpc
 101                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 102         fi
 103         ;;
 104 arm*)
 105         arch=arm
 106         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 107         ;;
 108 aarch64*)
 109         arch=aarch64
 110         arch_m32=arm
 111         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 112         ;;
 113 avr32*)
 114         arch=avr32
 115         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 116         ;;
 117 arc*)
 118         arch=arc
 119         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 120         ;;
 121 s390)
 122         arch=s390
 123         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 124         ;;
 125 s390x)
 126         arch=s390x
 127         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 128         ;;
 129 hppa*|parisc*)
 130         arch=hppa
 131         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 132         ;;
 133 sh64*)
 134         arch=sh64
 135         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 136         ;;
 137 sh*)
 138         arch=sh
 139         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 140         ;;
 141 x86?64*)
 142         arch_m32=i386
 143         AC_TRY_COMPILE(
 144 [#ifndef __ILP32__
 145 # error not x32
 146 #endif], [], arch=x32, arch=x86_64)
 147         if test "$arch" = "x86_64"; then
 148                 arch_mx32=x32
 149                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 150         else
 151                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 152         fi
 153         ;;
 154 cris|crisv10)
 155         arch=crisv10
 156         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 157         ;;
 158 crisv32)
 159         arch=crisv32
 160         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 161         ;;
 162 tile*)
 163         arch=tile
 164         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 165         ;;
 166 microblaze*)
 167         arch=microblaze
 168         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 169         ;;
 170 nios2*)
 171         arch=nios2
 172         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 173         ;;
 174
 175 or1k*)
 176         arch=or1k
 177         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 178         ;;
 179
 180 xtensa*)
 181         arch=xtensa
 182         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 183         ;;
 184
 185 *)
 186         AC_MSG_RESULT([NO!])
 187         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 188         ;;
 189 esac
 190 AC_MSG_RESULT($arch)
 191
 192 test -n "$arch_m32" ||
 193         arch_m32=$arch
 194 test -n "$arch_mx32" ||
 195         arch_mx32=$arch
 196 AC_SUBST(arch)
 197 AC_SUBST(arch_m32)
 198 AC_SUBST(arch_mx32)
 199
 200 if test "$arch" = mips; then
 201         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 202                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 203                                        [#include <sgidefs.h>],
 204                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 205
 206         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 207                 [AC_COMPILE_IFELSE(
 208                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 209                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 210                         [st_cv_mips_abi=o32],
 211                 [AC_COMPILE_IFELSE(
 212                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 213                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 214                         [st_cv_mips_abi=n32],
 215                 [AC_COMPILE_IFELSE(
 216                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 217                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 218                         [st_cv_mips_abi=n64],
 219                         [st_cv_mips_abi=unknown])])])])
 220
 221         case "$st_cv_mips_abi" in
 222                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 223                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 224                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 225                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 226         esac
 227 fi
 228
 229 AC_ARG_ENABLE([arm-oabi],
 230               [AS_HELP_STRING([--enable-arm-oabi],
 231                               [enable OABI support on ARM EABI])],
 232               [], [enable_arm_oabi=no])
 233 case "$enable_arm_oabi" in
 234         yes) enable_arm_oabi=1 ;;
 235         no) enable_arm_oabi=0 ;;
 236         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 237 esac
 238 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 239                    [Define to 1 if you want OABI support on ARM EABI.])
 240
 241 gl_WARN_ADD([-Wall])
 242 gl_WARN_ADD([-Wwrite-strings])
 243 gl_WARN_ADD([-Wsign-compare])
 244 AC_ARG_ENABLE([gcc-Werror],
 245   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 246   [case $enableval in
 247      yes) gl_WARN_ADD([-Werror]) ;;
 248      no)  ;;
 249      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 250    esac]
 251 )
 252 AC_SUBST([WARN_CFLAGS])
 253
 254 AC_C_BIGENDIAN
 255 AC_C_CONST
 256 AC_C_TYPEOF
 257
 258 AC_TYPE_GETGROUPS
 259 AC_TYPE_MODE_T
 260 AC_TYPE_SIGNAL
 261 AC_TYPE_UID_T
 262
 263 AC_HEADER_DIRENT
 264 AC_HEADER_MAJOR
 265 AC_HEADER_STAT
 266 AC_HEADER_STDBOOL
 267 AC_HEADER_STDC
 268
 269 AC_CHECK_FUNCS(m4_normalize([
 270         fanotify_mark
 271         fopen64
 272         fork
 273         fputs_unlocked
 274         fstatat
 275         ftruncate
 276         futimens
 277         if_indextoname
 278         inet_ntop
 279         inet_pton
 280         pipe2
 281         prctl
 282         preadv
 283         process_vm_readv
 284         pwritev
 285         recvmmsg
 286         sendmmsg
 287         sigaction
 288         signalfd
 289         stpcpy
 290         strerror
 291         strsignal
 292         sync_file_range
 293         utimensat
 294 ]))
 295
 296 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 297
 298 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 299
 300 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 301 [#include <asm/posix_types.h>])
 302
 303 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 304 [#include <sys/types.h>
 305 #include <asm/stat.h>])
 306
 307 AC_CHECK_TYPES(m4_normalize([
 308         struct pt_all_user_regs,
 309         struct ia64_fpreg,
 310         struct ptrace_peeksiginfo_args
 311 ]),,, [#include <sys/ptrace.h>])
 312
 313 AC_CHECK_TYPES(m4_normalize([
 314         struct flock,
 315         struct flock64,
 316         struct __kernel_flock,
 317         struct __kernel_flock64
 318 ]),,,
 319 [#include <sys/types.h>
 320 #include <linux/fcntl.h>])
 321
 322 AC_CHECK_MEMBERS(m4_normalize([
 323         struct stat.st_atim.tv_nsec,
 324         struct stat.st_blksize,
 325         struct stat.st_blocks,
 326         struct stat.st_ctim.tv_nsec,
 327         struct stat.st_flags,
 328         struct stat.st_fstype,
 329         struct stat.st_gen,
 330         struct stat.st_mtim.tv_nsec,
 331         struct stat.st_rdev
 332 ]))
 333
 334 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 335
 336 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 337
 338 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 339
 340 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 341 [#include <sys/types.h>
 342 #include <sys/socket.h>
 343 #include <netinet/in.h>])
 344
 345 AC_CHECK_MEMBERS(m4_normalize([
 346         struct stat.st_atime_nsec,
 347         struct stat.st_ctime_nsec,
 348         struct stat.st_mtime_nsec
 349 ]),,, [#include <sys/types.h>
 350 #include <asm/stat.h>])
 351
 352 AC_CHECK_MEMBERS(m4_normalize([
 353         siginfo_t.si_syscall,
 354         siginfo_t.si_timerid,
 355         siginfo_t.si_overrun
 356 ]),,, [#include <signal.h>])
 357
 358 AC_CHECK_HEADERS(m4_normalize([
 359         asm/cachectl.h
 360         asm/sysmips.h
 361         bluetooth/bluetooth.h
 362         elf.h
 363         inttypes.h
 364         linux/bsg.h
 365         linux/falloc.h
 366         linux/fiemap.h
 367         linux/filter.h
 368         linux/hiddev.h
 369         linux/ip_vs.h
 370         linux/ipc.h
 371         linux/mmtimer.h
 372         linux/msg.h
 373         linux/perf_event.h
 374         linux/seccomp.h
 375         linux/securebits.h
 376         linux/sem.h
 377         linux/shm.h
 378         linux/userfaultfd.h
 379         linux/utsname.h
 380         mqueue.h
 381         netinet/sctp.h
 382         scsi/sg.h
 383         stropts.h
 384         sys/conf.h
 385         sys/eventfd.h
 386         sys/fanotify.h
 387         sys/ipc.h
 388         sys/msg.h
 389         sys/reg.h
 390         sys/sem.h
 391         sys/shm.h
 392         sys/signalfd.h
 393         sys/xattr.h
 394 ]))
 395
 396 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 397
 398 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 399
 400 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 401
 402 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],,,
 403 [#include <stddef.h>
 404 #include <sys/socket.h>
 405 #include <asm/types.h>])
 406
 407 AC_CHECK_HEADERS(m4_normalize([
 408         linux/netfilter_arp/arp_tables.h
 409         linux/netfilter_bridge/ebtables.h
 410         linux/netfilter_ipv4/ip_tables.h
 411         linux/netfilter_ipv6/ip6_tables.h
 412 ]),,, [#include <netinet/in.h>
 413 #include <net/if.h>])
 414
 415 AC_CHECK_HEADERS([linux/input.h], [
 416         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 417 ])
 418
 419 AC_CHECK_HEADERS([linux/bpf.h], [
 420         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 421                        [st_cv_have_union_bpf_attr_log_buf],
 422                 [AC_COMPILE_IFELSE(
 423                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 424                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 425                         [st_cv_have_union_bpf_attr_log_buf=yes],
 426                         [st_cv_have_union_bpf_attr_log_buf=no])])
 427         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 428                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 429                           [Define to 1 if union bpf_attr.log_buf initialization works])
 430         fi
 431 ])
 432
 433 AC_CHECK_TYPES([struct statfs], [
 434         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 435 #include <asm/statfs.h>])
 436         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 437 #include <asm/statfs.h>])
 438         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 439 #include <asm/statfs.h>])
 440         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 441 #include <asm/statfs.h>])
 442 ],, [#include <linux/types.h>
 443 #include <asm/statfs.h>])
 444
 445 AC_CHECK_TYPES([struct statfs64], [
 446         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 447 #include <asm/statfs.h>])
 448         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 449 #include <asm/statfs.h>])
 450         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 451 #include <asm/statfs.h>])
 452         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 453 #include <asm/statfs.h>])
 454 ],, [#include <linux/types.h>
 455 #include <asm/statfs.h>])
 456
 457 AC_CHECK_HEADERS([linux/btrfs.h], [
 458         AC_CHECK_MEMBERS(m4_normalize([
 459                 struct btrfs_ioctl_feature_flags.compat_flags,
 460                 struct btrfs_ioctl_fs_info_args.nodesize,
 461                 struct btrfs_ioctl_defrag_range_args.start
 462                 struct btrfs_ioctl_search_args_v2.buf_size
 463                 ]),,, [ #include <stdio.h>
 464 #include <linux/btrfs.h>])
 465         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 466                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 467 #include <linux/btrfs.h>])])
 468
 469 AC_CHECK_DECLS([sys_errlist])
 470 AC_CHECK_DECLS(m4_normalize([
 471         PTRACE_PEEKUSER,
 472         PTRACE_POKEUSER
 473 ]),,, [#include <sys/ptrace.h>])
 474
 475 AC_CHECK_DECLS(m4_normalize([
 476         P_PID,
 477         P_PPID,
 478         P_PGID,
 479         P_SID,
 480         P_CID,
 481         P_UID,
 482         P_GID,
 483         P_ALL,
 484         P_LWPID
 485 ]),,, [#include <sys/wait.h>])
 486
 487 AC_CHECK_DECLS(m4_normalize([
 488         LO_FLAGS_READ_ONLY,
 489         LO_FLAGS_AUTOCLEAR,
 490         LO_FLAGS_PARTSCAN
 491 ]),,, [#include <linux/loop.h>])
 492
 493 AC_CHECK_DECLS(m4_normalize([
 494         CTL_KERN,
 495         CTL_VM,
 496         CTL_NET,
 497         CTL_PROC,
 498         CTL_FS,
 499         CTL_DEBUG,
 500         CTL_DEV,
 501         CTL_BUS,
 502         CTL_ABI,
 503         CTL_CPU,
 504         CTL_ARLAN,
 505         CTL_S390DBF,
 506         CTL_SUNRPC,
 507         CTL_PM,
 508         CTL_FRV,
 509         KERN_OSTYPE,
 510         KERN_OSRELEASE,
 511         KERN_OSREV,
 512         KERN_VERSION,
 513         KERN_SECUREMASK,
 514         KERN_PROF,
 515         KERN_NODENAME,
 516         KERN_DOMAINNAME,
 517         KERN_PANIC,
 518         KERN_REALROOTDEV,
 519         KERN_SPARC_REBOOT,
 520         KERN_CTLALTDEL,
 521         KERN_PRINTK,
 522         KERN_NAMETRANS,
 523         KERN_PPC_HTABRECLAIM,
 524         KERN_PPC_ZEROPAGED,
 525         KERN_PPC_POWERSAVE_NAP,
 526         KERN_MODPROBE,
 527         KERN_SG_BIG_BUFF,
 528         KERN_ACCT,
 529         KERN_PPC_L2CR,
 530         KERN_RTSIGNR,
 531         KERN_RTSIGMAX,
 532         KERN_SHMMAX,
 533         KERN_MSGMAX,
 534         KERN_MSGMNB,
 535         KERN_MSGPOOL,
 536         KERN_SYSRQ,
 537         KERN_MAX_THREADS,
 538         KERN_RANDOM,
 539         KERN_SHMALL,
 540         KERN_MSGMNI,
 541         KERN_SEM,
 542         KERN_SPARC_STOP_A,
 543         KERN_SHMMNI,
 544         KERN_OVERFLOWUID,
 545         KERN_OVERFLOWGID,
 546         KERN_SHMPATH,
 547         KERN_HOTPLUG,
 548         KERN_IEEE_EMULATION_WARNINGS,
 549         KERN_S390_USER_DEBUG_LOGGING,
 550         KERN_CORE_USES_PID,
 551         KERN_TAINTED,
 552         KERN_CADPID,
 553         KERN_PIDMAX,
 554         KERN_CORE_PATTERN,
 555         KERN_PANIC_ON_OOPS,
 556         KERN_HPPA_PWRSW,
 557         KERN_HPPA_UNALIGNED,
 558         KERN_PRINTK_RATELIMIT,
 559         KERN_PRINTK_RATELIMIT_BURST,
 560         KERN_PTY,
 561         KERN_NGROUPS_MAX,
 562         KERN_SPARC_SCONS_PWROFF,
 563         KERN_HZ_TIMER,
 564         KERN_UNKNOWN_NMI_PANIC,
 565         KERN_BOOTLOADER_TYPE,
 566         KERN_RANDOMIZE,
 567         KERN_SETUID_DUMPABLE,
 568         KERN_SPIN_RETRY,
 569         KERN_ACPI_VIDEO_FLAGS,
 570         KERN_IA64_UNALIGNED,
 571         KERN_COMPAT_LOG,
 572         KERN_MAX_LOCK_DEPTH,
 573         KERN_NMI_WATCHDOG,
 574         KERN_PANIC_ON_NMI,
 575         NET_CORE,
 576         NET_ETHER,
 577         NET_802,
 578         NET_UNIX,
 579         NET_IPV4,
 580         NET_IPX,
 581         NET_ATALK,
 582         NET_NETROM,
 583         NET_AX25,
 584         NET_BRIDGE,
 585         NET_ROSE,
 586         NET_IPV6,
 587         NET_X25,
 588         NET_TR,
 589         NET_DECNET,
 590         NET_ECONET,
 591         NET_SCTP,
 592         NET_LLC,
 593         NET_NETFILTER,
 594         NET_DCCP,
 595         NET_IRDA,
 596         NET_CORE_WMEM_MAX,
 597         NET_CORE_RMEM_MAX,
 598         NET_CORE_WMEM_DEFAULT,
 599         NET_CORE_RMEM_DEFAULT,
 600         NET_CORE_DESTROY_DELAY,
 601         NET_CORE_MAX_BACKLOG,
 602         NET_CORE_FASTROUTE,
 603         NET_CORE_MSG_COST,
 604         NET_CORE_MSG_BURST,
 605         NET_CORE_OPTMEM_MAX,
 606         NET_CORE_HOT_LIST_LENGTH,
 607         NET_CORE_DIVERT_VERSION,
 608         NET_CORE_NO_CONG_THRESH,
 609         NET_CORE_NO_CONG,
 610         NET_CORE_LO_CONG,
 611         NET_CORE_MOD_CONG,
 612         NET_CORE_DEV_WEIGHT,
 613         NET_CORE_SOMAXCONN,
 614         NET_CORE_BUDGET,
 615         NET_CORE_AEVENT_ETIME,
 616         NET_CORE_AEVENT_RSEQTH,
 617         NET_CORE_WARNINGS,
 618         NET_IPV4_FORWARD,
 619         NET_IPV4_DYNADDR,
 620         NET_IPV4_CONF,
 621         NET_IPV4_NEIGH,
 622         NET_IPV4_ROUTE,
 623         NET_IPV4_FIB_HASH,
 624         NET_IPV4_NETFILTER,
 625         NET_IPV4_TCP_TIMESTAMPS,
 626         NET_IPV4_TCP_WINDOW_SCALING,
 627         NET_IPV4_TCP_SACK,
 628         NET_IPV4_TCP_RETRANS_COLLAPSE,
 629         NET_IPV4_DEFAULT_TTL,
 630         NET_IPV4_AUTOCONFIG,
 631         NET_IPV4_NO_PMTU_DISC,
 632         NET_IPV4_TCP_SYN_RETRIES,
 633         NET_IPV4_IPFRAG_HIGH_THRESH,
 634         NET_IPV4_IPFRAG_LOW_THRESH,
 635         NET_IPV4_IPFRAG_TIME,
 636         NET_IPV4_TCP_MAX_KA_PROBES,
 637         NET_IPV4_TCP_KEEPALIVE_TIME,
 638         NET_IPV4_TCP_KEEPALIVE_PROBES,
 639         NET_IPV4_TCP_RETRIES1,
 640         NET_IPV4_TCP_RETRIES2,
 641         NET_IPV4_TCP_FIN_TIMEOUT,
 642         NET_IPV4_IP_MASQ_DEBUG,
 643         NET_TCP_SYNCOOKIES,
 644         NET_TCP_STDURG,
 645         NET_TCP_RFC1337,
 646         NET_TCP_SYN_TAILDROP,
 647         NET_TCP_MAX_SYN_BACKLOG,
 648         NET_IPV4_LOCAL_PORT_RANGE,
 649         NET_IPV4_ICMP_ECHO_IGNORE_ALL,
 650         NET_IPV4_ICMP_ECHO_IGNORE_BROADCASTS,
 651         NET_IPV4_ICMP_SOURCEQUENCH_RATE,
 652         NET_IPV4_ICMP_DESTUNREACH_RATE,
 653         NET_IPV4_ICMP_TIMEEXCEED_RATE,
 654         NET_IPV4_ICMP_PARAMPROB_RATE,
 655         NET_IPV4_ICMP_ECHOREPLY_RATE,
 656         NET_IPV4_ICMP_IGNORE_BOGUS_ERROR_RESPONSES,
 657         NET_IPV4_IGMP_MAX_MEMBERSHIPS,
 658         NET_TCP_TW_RECYCLE,
 659         NET_IPV4_ALWAYS_DEFRAG,
 660         NET_IPV4_TCP_KEEPALIVE_INTVL,
 661         NET_IPV4_INET_PEER_THRESHOLD,
 662         NET_IPV4_INET_PEER_MINTTL,
 663         NET_IPV4_INET_PEER_MAXTTL,
 664         NET_IPV4_INET_PEER_GC_MINTIME,
 665         NET_IPV4_INET_PEER_GC_MAXTIME,
 666         NET_TCP_ORPHAN_RETRIES,
 667         NET_TCP_ABORT_ON_OVERFLOW,
 668         NET_TCP_SYNACK_RETRIES,
 669         NET_TCP_MAX_ORPHANS,
 670         NET_TCP_MAX_TW_BUCKETS,
 671         NET_TCP_FACK,
 672         NET_TCP_REORDERING,
 673         NET_TCP_ECN,
 674         NET_TCP_DSACK,
 675         NET_TCP_MEM,
 676         NET_TCP_WMEM,
 677         NET_TCP_RMEM,
 678         NET_TCP_APP_WIN,
 679         NET_TCP_ADV_WIN_SCALE,
 680         NET_IPV4_NONLOCAL_BIND,
 681         NET_IPV4_ICMP_RATELIMIT,
 682         NET_IPV4_ICMP_RATEMASK,
 683         NET_TCP_TW_REUSE,
 684         NET_TCP_FRTO,
 685         NET_TCP_LOW_LATENCY,
 686         NET_IPV4_IPFRAG_SECRET_INTERVAL,
 687         NET_IPV4_IGMP_MAX_MSF,
 688         NET_TCP_NO_METRICS_SAVE,
 689         NET_TCP_DEFAULT_WIN_SCALE,
 690         NET_TCP_MODERATE_RCVBUF,
 691         NET_TCP_TSO_WIN_DIVISOR,
 692         NET_TCP_BIC_BETA,
 693         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 694         NET_TCP_CONG_CONTROL,
 695         NET_TCP_ABC,
 696         NET_IPV4_IPFRAG_MAX_DIST,
 697         NET_TCP_MTU_PROBING,
 698         NET_TCP_BASE_MSS,
 699         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 700         NET_TCP_DMA_COPYBREAK,
 701         NET_TCP_SLOW_START_AFTER_IDLE,
 702         NET_CIPSOV4_CACHE_ENABLE,
 703         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 704         NET_CIPSOV4_RBM_OPTFMT,
 705         NET_CIPSOV4_RBM_STRICTVALID,
 706         NET_TCP_AVAIL_CONG_CONTROL,
 707         NET_TCP_ALLOWED_CONG_CONTROL,
 708         NET_TCP_MAX_SSTHRESH,
 709         NET_TCP_FRTO_RESPONSE,
 710         NET_IPV4_ROUTE_FLUSH,
 711         NET_IPV4_ROUTE_MIN_DELAY,
 712         NET_IPV4_ROUTE_MAX_DELAY,
 713         NET_IPV4_ROUTE_GC_THRESH,
 714         NET_IPV4_ROUTE_MAX_SIZE,
 715         NET_IPV4_ROUTE_GC_MIN_INTERVAL,
 716         NET_IPV4_ROUTE_GC_TIMEOUT,
 717         NET_IPV4_ROUTE_GC_INTERVAL,
 718         NET_IPV4_ROUTE_REDIRECT_LOAD,
 719         NET_IPV4_ROUTE_REDIRECT_NUMBER,
 720         NET_IPV4_ROUTE_REDIRECT_SILENCE,
 721         NET_IPV4_ROUTE_ERROR_COST,
 722         NET_IPV4_ROUTE_ERROR_BURST,
 723         NET_IPV4_ROUTE_GC_ELASTICITY,
 724         NET_IPV4_ROUTE_MTU_EXPIRES,
 725         NET_IPV4_ROUTE_MIN_PMTU,
 726         NET_IPV4_ROUTE_MIN_ADVMSS,
 727         NET_IPV4_ROUTE_SECRET_INTERVAL,
 728         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 729         NET_IPV4_CONF_FORWARDING,
 730         NET_IPV4_CONF_MC_FORWARDING,
 731         NET_IPV4_CONF_PROXY_ARP,
 732         NET_IPV4_CONF_ACCEPT_REDIRECTS,
 733         NET_IPV4_CONF_SECURE_REDIRECTS,
 734         NET_IPV4_CONF_SEND_REDIRECTS,
 735         NET_IPV4_CONF_SHARED_MEDIA,
 736         NET_IPV4_CONF_RP_FILTER,
 737         NET_IPV4_CONF_ACCEPT_SOURCE_ROUTE,
 738         NET_IPV4_CONF_BOOTP_RELAY,
 739         NET_IPV4_CONF_LOG_MARTIANS,
 740         NET_IPV4_CONF_TAG,
 741         NET_IPV4_CONF_ARPFILTER,
 742         NET_IPV4_CONF_MEDIUM_ID,
 743         NET_IPV4_CONF_NOXFRM,
 744         NET_IPV4_CONF_NOPOLICY,
 745         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 746         NET_IPV4_CONF_ARP_ANNOUNCE,
 747         NET_IPV4_CONF_ARP_IGNORE,
 748         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 749         NET_IPV4_CONF_ARP_ACCEPT,
 750         NET_IPV4_CONF_ARP_NOTIFY,
 751         NET_IPV6_CONF,
 752         NET_IPV6_NEIGH,
 753         NET_IPV6_ROUTE,
 754         NET_IPV6_ICMP,
 755         NET_IPV6_BINDV6ONLY,
 756         NET_IPV6_IP6FRAG_HIGH_THRESH,
 757         NET_IPV6_IP6FRAG_LOW_THRESH,
 758         NET_IPV6_IP6FRAG_TIME,
 759         NET_IPV6_IP6FRAG_SECRET_INTERVAL,
 760         NET_IPV6_MLD_MAX_MSF,
 761         NET_IPV6_ROUTE_FLUSH,
 762         NET_IPV6_ROUTE_GC_THRESH,
 763         NET_IPV6_ROUTE_MAX_SIZE,
 764         NET_IPV6_ROUTE_GC_MIN_INTERVAL,
 765         NET_IPV6_ROUTE_GC_TIMEOUT,
 766         NET_IPV6_ROUTE_GC_INTERVAL,
 767         NET_IPV6_ROUTE_GC_ELASTICITY,
 768         NET_IPV6_ROUTE_MTU_EXPIRES,
 769         NET_IPV6_ROUTE_MIN_ADVMSS,
 770         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 771         NET_UNIX_DESTROY_DELAY,
 772         NET_UNIX_DELETE_DELAY,
 773         NET_UNIX_MAX_DGRAM_QLEN,
 774         VM_OVERCOMMIT_MEMORY,
 775         VM_PAGE_CLUSTER,
 776         VM_DIRTY_BACKGROUND,
 777         VM_DIRTY_RATIO,
 778         VM_DIRTY_WB_CS,
 779         VM_DIRTY_EXPIRE_CS,
 780         VM_NR_PDFLUSH_THREADS,
 781         VM_OVERCOMMIT_RATIO,
 782         VM_PAGEBUF,
 783         VM_HUGETLB_PAGES,
 784         VM_SWAPPINESS,
 785         VM_LOWMEM_RESERVE_RATIO,
 786         VM_MIN_FREE_KBYTES,
 787         VM_MAX_MAP_COUNT,
 788         VM_LAPTOP_MODE,
 789         VM_BLOCK_DUMP,
 790         VM_HUGETLB_GROUP,
 791         VM_VFS_CACHE_PRESSURE,
 792         VM_LEGACY_VA_LAYOUT,
 793         VM_SWAP_TOKEN_TIMEOUT
 794 ]),,,
 795 [#include <sys/types.h>
 796 #include <linux/sysctl.h>])
 797
 798 AC_CHECK_DECLS(m4_normalize([
 799         V4L2_FIELD_ANY,
 800         V4L2_FIELD_NONE,
 801         V4L2_FIELD_TOP,
 802         V4L2_FIELD_BOTTOM,
 803         V4L2_FIELD_INTERLACED,
 804         V4L2_FIELD_SEQ_TB,
 805         V4L2_FIELD_SEQ_BT,
 806         V4L2_FIELD_ALTERNATE,
 807         V4L2_FIELD_INTERLACED_TB,
 808         V4L2_FIELD_INTERLACED_BT,
 809         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 810         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 811         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 812         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 813         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 814         V4L2_BUF_TYPE_VBI_CAPTURE,
 815         V4L2_BUF_TYPE_VBI_OUTPUT,
 816         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 817         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 818         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 819         V4L2_TUNER_RADIO,
 820         V4L2_TUNER_ANALOG_TV,
 821         V4L2_TUNER_DIGITAL_TV,
 822         V4L2_MEMORY_MMAP,
 823         V4L2_MEMORY_USERPTR,
 824         V4L2_MEMORY_OVERLAY,
 825         V4L2_MEMORY_DMABUF,
 826         V4L2_COLORSPACE_SMPTE170M,
 827         V4L2_COLORSPACE_SMPTE240M,
 828         V4L2_COLORSPACE_REC709,
 829         V4L2_COLORSPACE_BT878,
 830         V4L2_COLORSPACE_470_SYSTEM_M,
 831         V4L2_COLORSPACE_470_SYSTEM_BG,
 832         V4L2_COLORSPACE_JPEG,
 833         V4L2_COLORSPACE_SRGB,
 834         V4L2_PRIORITY_UNSET,
 835         V4L2_PRIORITY_BACKGROUND,
 836         V4L2_PRIORITY_INTERACTIVE,
 837         V4L2_PRIORITY_RECORD,
 838         V4L2_FRMSIZE_TYPE_DISCRETE,
 839         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 840         V4L2_FRMSIZE_TYPE_STEPWISE,
 841         V4L2_FRMIVAL_TYPE_DISCRETE,
 842         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 843         V4L2_FRMIVAL_TYPE_STEPWISE,
 844         V4L2_CTRL_TYPE_INTEGER,
 845         V4L2_CTRL_TYPE_BOOLEAN,
 846         V4L2_CTRL_TYPE_MENU,
 847         V4L2_CTRL_TYPE_BUTTON,
 848         V4L2_CTRL_TYPE_INTEGER64,
 849         V4L2_CTRL_TYPE_CTRL_CLASS,
 850         V4L2_CTRL_TYPE_STRING,
 851         V4L2_CTRL_TYPE_BITMASK,
 852         V4L2_CTRL_TYPE_INTEGER_MENU
 853 ]),,, [#include <sys/time.h>
 854 #include <linux/ioctl.h>
 855 #include <linux/types.h>
 856 #include <linux/videodev2.h>])
 857
 858 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 859         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 860 #include <stdlib.h>
 861 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 862                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 863         if test $ac_cv_have_blkgetsize64 = yes; then
 864                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 865         fi)
 866
 867 AC_CHECK_SIZEOF([long])
 868 AC_CHECK_SIZEOF([long long])
 869 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 870 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 871
 872 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 873                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 874                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 875                         grep '^[0-9]')"
 876                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 877 if test "x$st_cv_SIGRTMIN" != xno; then
 878         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 879                            [SIGRTMIN defined in <asm/signal.h>])
 880 fi
 881 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 882                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 883                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 884                         grep ^0x)"
 885                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 886 if test "x$st_cv_SA_RESTORER" != xno; then
 887         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 888                            [SA_RESTORER defined in <asm/signal.h>])
 889 fi
 890
 891 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 892                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 893                                [st_cv_have___builtin_popcount=yes],
 894                                [st_cv_have___builtin_popcount=no])])
 895 if test "x$st_cv_have___builtin_popcount" = xyes; then
 896         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 897                   [Define to 1 if the system provides __builtin_popcount function])
 898 fi
 899
 900 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 901 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 902         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 903 fi
 904 AC_SUBST(dl_LIBS)
 905
 906 AC_PATH_PROG([PERL], [perl])
 907
 908 dnl stack trace with libunwind
 909 libunwind_CPPFLAGS=
 910 libunwind_LDFLAGS=
 911 libunwind_LIBS=
 912 AC_ARG_WITH([libunwind],
 913             [AS_HELP_STRING([--with-libunwind],
 914                             [use libunwind to implement stack tracing support])],
 915             [case "${withval}" in
 916              yes|no|check) ;;
 917              *) with_libunwind=yes
 918                 libunwind_CPPFLAGS="-I${withval}/include"
 919                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 920              esac],
 921             [with_libunwind=check]
 922 )
 923
 924 use_libunwind=no
 925 AS_IF([test "x$with_libunwind" != xno],
 926       [saved_CPPFLAGS="$CPPFLAGS"
 927        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 928
 929        AC_CHECK_HEADERS([libunwind-ptrace.h],
 930          [saved_LDFLAGS="$LDFLAGS"
 931           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 932
 933           AC_CHECK_LIB([unwind], [backtrace],
 934             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 935
 936              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 937              saved_LIBS="$LIBS"
 938              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 939
 940              AC_LINK_IFELSE(
 941                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 942                                 [[return !unw_create_addr_space(0, 0)]])
 943                ],
 944                [AC_MSG_RESULT([yes])
 945                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 946
 947                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 948                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 949                    use_libunwind=yes
 950                   ],
 951                   [if test "x$with_libunwind" != xcheck; then
 952                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 953                    fi
 954                   ],
 955                   [$libunwind_LIBS]
 956                 )
 957                ],
 958                [AC_MSG_RESULT([no])
 959                 if test "x$with_libunwind" != xcheck; then
 960                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 961                 fi
 962                ]
 963              )
 964
 965              LIBS="$saved_LIBS"
 966             ],
 967             [if test "x$with_libunwind" != xcheck; then
 968                AC_MSG_FAILURE([failed to find libunwind])
 969              fi
 970             ],
 971             [$libunwind_LIBS]
 972           )
 973
 974           LDFLAGS="$saved_LDFLAGS"
 975          ],
 976          [if test "x$with_libunwind" != xcheck; then
 977             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 978           fi
 979          ]
 980        )
 981
 982        CPPFLAGS="$saved_CPPFLAGS"
 983       ]
 984 )
 985
 986 dnl enable libunwind
 987 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 988 if test "x$use_libunwind" = xyes; then
 989         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 990         AC_SUBST(libunwind_LIBS)
 991         AC_SUBST(libunwind_LDFLAGS)
 992         AC_SUBST(libunwind_CPPFLAGS)
 993 fi
 994 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 995 AC_MSG_RESULT([$use_libunwind])
 996
 997 if test "$arch" = mips && test "$no_create" != yes; then
 998         mkdir -p linux/mips
 999         if $srcdir/linux/mips/genstub.sh linux/mips; then
1000                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
1001         else
1002                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
1003         fi
1004 fi
1005
1006 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
1007 st_MPERS([mx32], [x86_64])
1008
1009 AC_CONFIG_FILES([Makefile tests/Makefile tests-m32/Makefile tests-mx32/Makefile])
1010 AC_OUTPUT