granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.20])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AC_CONFIG_AUX_DIR([.])
   6 AM_CONFIG_HEADER([config.h])
   7 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE
   9 AC_CANONICAL_HOST
  10
  11 AC_MSG_CHECKING([for supported operating system])
  12 case "$host_os" in
  13 *linux*)
  14         opsys=linux
  15         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  16         ;;
  17 sunos4*)
  18         opsys=sunos4
  19         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  20         ;;
  21 solaris2* | sysv[[45]]* | irix[[56]]*)
  22         opsys=svr4
  23         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  24 system or a derivative like Solaris 2.x or Irix 5.x.])
  25         case "$host_os" in
  26         sysv4.2uw*)
  27                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  28                 ;;
  29         sysv5*)
  30                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  31                 ;;
  32         esac
  33         ;;
  34 freebsd*)
  35         opsys=freebsd
  36         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  37         ;;
  38 *)
  39         AC_MSG_RESULT([NO!])
  40         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  41         ;;
  42 esac
  43 AC_MSG_RESULT($opsys)
  44
  45 AC_MSG_CHECKING([for supported architecture])
  46 case "$host_cpu" in
  47 bfin)
  48         arch=bfin
  49         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  50         ;;
  51 i[[3456]]86|pentium)
  52         arch=i386
  53         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  54         ;;
  55 ia64)
  56         arch=ia64
  57         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  58         ;;
  59 m68k)
  60         arch=m68k
  61         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  62         ;;
  63 sparc64*)
  64         arch=sparc64
  65         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  66         ;;
  67 sparc*)
  68         arch=sparc
  69         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  70         ;;
  71 mips*)
  72         arch=mips
  73         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  74         ;;
  75 alpha*)
  76         arch=alpha
  77         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  78         ;;
  79 powerpc*)
  80         arch=powerpc
  81         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  82         if test $host_cpu = powerpc64; then
  83                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
  84         fi
  85         ;;
  86 arm*)
  87         arch=arm
  88         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  89         ;;
  90 avr32*)
  91         arch=avr32
  92         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  93         ;;
  94 s390)
  95         arch=s390
  96         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  97         ;;
  98 s390x)
  99         arch=s390x
 100         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 101         ;;
 102 hppa*|parisc*)
 103         arch=hppa
 104         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 105         ;;
 106 sh64*)
 107         arch=sh64
 108         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 109         ;;
 110 sh*)
 111         arch=sh
 112         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 113         ;;
 114 x86?64*)
 115         arch=x86_64
 116         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 117         ;;
 118 cris|crisv10)
 119         arch=crisv10
 120         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 121         ;;
 122 crisv32)
 123         arch=crisv32
 124         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 125         ;;
 126 tile*)
 127         arch=tile
 128         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 129         ;;
 130 microblaze*)
 131         arch=microblaze
 132         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 133         ;;
 134 *)
 135         AC_MSG_RESULT([NO!])
 136         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 137         ;;
 138 esac
 139 AC_MSG_RESULT($arch)
 140
 141 AC_SUBST(opsys)
 142 AC_SUBST(arch)
 143
 144 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 145 AM_CONDITIONAL([I386], [test x$arch = xi386])
 146 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 147 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 148 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 149 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 150
 151 AC_PROG_CC
 152 AC_GNU_SOURCE
 153
 154 AC_INCLUDEDIR
 155
 156 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 157 then
 158         AC_MSG_CHECKING(for valid machine include directory)
 159         if test -d "$includedir/sun4"
 160         then
 161                 rm -f machine
 162                 ln -s $includedir/sun4 machine
 163                 AC_MSG_RESULT(yes)
 164                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 165 Define if you are have a SPARC with SUNOS4 and your want a version
 166 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 167 Only useful if you have a symbolic link from machine to /usr/include/sun4
 168 in the compilation directory.])
 169         else
 170                 AC_MSG_RESULT(no)
 171         fi
 172 fi
 173
 174 AC_WARNFLAGS
 175 if test "x$opsys" = "xsunos4"
 176 then
 177         if test -n "$GCC"
 178         then
 179                 # SunOS 4.x header files don't declare int functions.
 180                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 181         fi
 182 fi
 183
 184 AC_PROG_CPP
 185 AC_PROG_GCC_TRADITIONAL
 186 AC_PROG_INSTALL
 187 AC_C_CONST
 188 AC_HEADER_STDC
 189 AC_HEADER_STDBOOL
 190 AC_HEADER_DIRENT
 191 AC_HEADER_STAT
 192 AC_CHECK_MEMBERS([struct stat.st_blksize,
 193                   struct stat.st_blocks,
 194                   struct stat.st_aclcnt,
 195                   struct stat.st_flags,
 196                   struct stat.st_fstype,
 197                   struct stat.st_gen,
 198                   struct stat.st_level,
 199                   struct stat.st_rdev])
 200 AC_STAT64
 201 AC_STATFS64
 202
 203 AC_TYPE_SIGNAL
 204 AC_TYPE_UID_T
 205 AC_TYPE_MODE_T
 206 AC_TYPE_GETGROUPS
 207 AC_HEADER_MAJOR
 208 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 209 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 210 [#include <sys/types.h>
 211 #include <sys/socket.h>
 212 #include <netinet/in.h>])
 213 AC_CHECK_TYPES([long long])
 214 AC_LITTLE_ENDIAN_LONG_LONG
 215 AC_OFF_T_IS_LONG_LONG
 216 AC_RLIM_T_IS_LONG_LONG
 217 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 218 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 219
 220 if test x$opsys != xlinux; then
 221 AC_CHECK_LIB(nsl, main)
 222 fi
 223
 224 AC_CHECK_FUNCS([ \
 225         fork \
 226         getdents \
 227         if_indextoname \
 228         inet_ntop \
 229         mctl \
 230         prctl \
 231         pread \
 232         sendmsg \
 233         sigaction \
 234         strerror \
 235         strsignal \
 236         sys_siglist \
 237         _sys_siglist \
 238 ])
 239 AC_CHECK_HEADERS([ \
 240         inttypes.h \
 241         ioctls.h \
 242         libaio.h \
 243         mqueue.h \
 244         poll.h \
 245         stropts.h \
 246         termio.h \
 247         sys/acl.h \
 248         sys/aio.h \
 249         sys/asynch.h \
 250         sys/conf.h \
 251         sys/door.h \
 252         sys/epoll.h \
 253         sys/filio.h \
 254         sys/ioctl.h \
 255         sys/nscsys.h \
 256         sys/poll.h \
 257         sys/ptrace.h \
 258         sys/reg.h \
 259         sys/stream.h \
 260         sys/sysconfig.h \
 261         sys/tihdr.h \
 262         sys/tiuser.h \
 263         sys/uio.h \
 264         sys/vfs.h \
 265         asm/cachectl.h \
 266         asm/sysmips.h \
 267         linux/capability.h \
 268         linux/ptrace.h \
 269         linux/utsname.h \
 270 ], [], [])
 271 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 272                  [], [], [#include <stddef.h>
 273 #include <sys/socket.h>
 274 #include <asm/types.h>])
 275 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 276 AC_CHECK_TYPES([struct sigcontext_struct,
 277                 struct sigcontext],,, [#include <signal.h>])
 278 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 279
 280 AC_MP_PROCFS
 281 AC_POLLABLE_PROCFS
 282
 283 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 284 AC_STRUCT_PR_SYSCALL
 285
 286 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 287                   struct T_conn_res.ACCEPTOR_id],,,
 288 [#include <sys/stream.h>
 289 #include <sys/tihdr.h>])
 290
 291 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 292
 293 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 294                [#include <sys/ptrace.h>])
 295
 296 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 297
 298 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 299
 300 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 301 #ifdef HAVE_ASM_SIGCONTEXT_H
 302 # include <asm/sigcontext.h>
 303 #endif])
 304
 305
 306 AC_CHECK_DECLS([sys_errlist])
 307 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 308
 309 AC_PATH_PROG([PERL], [perl])
 310
 311 AC_CONFIG_FILES([Makefile])
 312 AC_OUTPUT