granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.19])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AM_CONFIG_HEADER([config.h])
   6 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2])
   7 AM_MAINTAINER_MODE
   8 AC_CANONICAL_HOST
   9
  10 AC_MSG_CHECKING([for supported operating system])
  11 case "$host_os" in
  12 *linux*)
  13         opsys=linux
  14         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  15         ;;
  16 sunos4*)
  17         opsys=sunos4
  18         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  19         ;;
  20 solaris2* | sysv[[45]]* | irix[[56]]*)
  21         opsys=svr4
  22         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  23 system or a derivative like Solaris 2.x or Irix 5.x.])
  24         case "$host_os" in
  25         sysv4.2uw*)
  26                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  27                 ;;
  28         sysv5*)
  29                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  30                 ;;
  31         esac
  32         ;;
  33 freebsd*)
  34         opsys=freebsd
  35         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  36         ;;
  37 *)
  38         AC_MSG_RESULT([NO!])
  39         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  40         ;;
  41 esac
  42 AC_MSG_RESULT($opsys)
  43
  44 AC_MSG_CHECKING([for supported architecture])
  45 case "$host_cpu" in
  46 bfin)
  47         arch=bfin
  48         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  49         ;;
  50 i[[3456]]86|pentium)
  51         arch=i386
  52         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  53         ;;
  54 ia64)
  55         arch=ia64
  56         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  57         ;;
  58 m68k)
  59         arch=m68k
  60         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  61         ;;
  62 sparc64*)
  63         arch=sparc64
  64         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  65         ;;
  66 sparc*)
  67         arch=sparc
  68         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  69         ;;
  70 mips*)
  71         arch=mips
  72         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  73         ;;
  74 alpha*)
  75         arch=alpha
  76         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  77         ;;
  78 powerpc*)
  79         arch=powerpc
  80         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  81         ;;
  82 arm*)
  83         arch=arm
  84         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  85         ;;
  86 avr32*)
  87         arch=avr32
  88         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  89         ;;
  90 s390)
  91         arch=s390
  92         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  93         ;;
  94 s390x)
  95         arch=s390x
  96         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  97         ;;
  98 hppa*|parisc*)
  99         arch=hppa
 100         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 101         ;;
 102 sh64*)
 103         arch=sh64
 104         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 105         ;;
 106 sh*)
 107         arch=sh
 108         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 109         ;;
 110 x86?64*)
 111         arch=x86_64
 112         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 113         ;;
 114 cris|crisv10)
 115         arch=crisv10
 116         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 117         ;;
 118 crisv32)
 119         arch=crisv32
 120         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 121         ;;
 122 *)
 123         AC_MSG_RESULT([NO!])
 124         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 125         ;;
 126 esac
 127 AC_MSG_RESULT($arch)
 128
 129 AC_SUBST(opsys)
 130 AC_SUBST(arch)
 131
 132 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 133 AM_CONDITIONAL([I386], [test x$arch = xi386])
 134 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 135 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 136 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 137 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 138
 139 AC_PROG_CC
 140 AC_GNU_SOURCE
 141
 142 AC_INCLUDEDIR
 143
 144 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 145 then
 146         AC_MSG_CHECKING(for valid machine include directory)
 147         if test -d "$includedir/sun4"
 148         then
 149                 rm -f machine
 150                 ln -s $includedir/sun4 machine
 151                 AC_MSG_RESULT(yes)
 152                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 153 Define if you are have a SPARC with SUNOS4 and your want a version
 154 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 155 Only useful if you have a symbolic link from machine to /usr/include/sun4
 156 in the compilation directory.])
 157         else
 158                 AC_MSG_RESULT(no)
 159         fi
 160 fi
 161
 162 AC_WARNFLAGS
 163 if test "x$opsys" = "xsunos4"
 164 then
 165         if test -n "$GCC"
 166         then
 167                 # SunOS 4.x header files don't declare int functions.
 168                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 169         fi
 170 fi
 171
 172 AC_PROG_CPP
 173 AC_PROG_GCC_TRADITIONAL
 174 AC_PROG_INSTALL
 175 AC_C_CONST
 176 AC_HEADER_STDC
 177 AC_HEADER_STDBOOL
 178 AC_HEADER_DIRENT
 179 AC_HEADER_STAT
 180 AC_CHECK_MEMBERS([struct stat.st_blksize,
 181                   struct stat.st_blocks,
 182                   struct stat.st_aclcnt,
 183                   struct stat.st_flags,
 184                   struct stat.st_fstype,
 185                   struct stat.st_gen,
 186                   struct stat.st_level,
 187                   struct stat.st_rdev])
 188 AC_STAT64
 189
 190 AC_TYPE_SIGNAL
 191 AC_TYPE_UID_T
 192 AC_TYPE_MODE_T
 193 AC_TYPE_GETGROUPS
 194 AC_HEADER_MAJOR
 195 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 196 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 197 [#include <sys/types.h>
 198 #include <sys/socket.h>
 199 #include <netinet/in.h>])
 200 AC_CHECK_TYPES([long long])
 201 AC_LITTLE_ENDIAN_LONG_LONG
 202 AC_OFF_T_IS_LONG_LONG
 203 AC_RLIM_T_IS_LONG_LONG
 204 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 205 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 206
 207 if test x$opsys != xlinux; then
 208 AC_CHECK_LIB(nsl, main)
 209 fi
 210
 211 AC_CHECK_FUNCS([ \
 212         getdents \
 213         if_indextoname \
 214         inet_ntop \
 215         mctl \
 216         prctl \
 217         pread \
 218         sendmsg \
 219         sigaction \
 220         strerror \
 221         strsignal \
 222         sys_siglist \
 223         _sys_siglist \
 224 ])
 225 AC_CHECK_HEADERS([ \
 226         inttypes.h \
 227         ioctls.h \
 228         libaio.h \
 229         mqueue.h \
 230         poll.h \
 231         stropts.h \
 232         termio.h \
 233         sys/acl.h \
 234         sys/aio.h \
 235         sys/asynch.h \
 236         sys/conf.h \
 237         sys/door.h \
 238         sys/epoll.h \
 239         sys/filio.h \
 240         sys/ioctl.h \
 241         sys/nscsys.h \
 242         sys/poll.h \
 243         sys/ptrace.h \
 244         sys/reg.h \
 245         sys/stream.h \
 246         sys/sysconfig.h \
 247         sys/tihdr.h \
 248         sys/tiuser.h \
 249         sys/uio.h \
 250         sys/vfs.h \
 251         asm/cachectl.h \
 252         asm/reg.h \
 253         asm/sysmips.h \
 254         linux/capability.h \
 255         linux/ptrace.h \
 256         linux/utsname.h \
 257 ], [], [])
 258 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 259                  [], [], [#include <stddef.h>
 260 #include <linux/socket.h>])
 261 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 262 AC_CHECK_TYPES([struct sigcontext_struct,
 263                 struct sigcontext],,, [#include <signal.h>])
 264 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 265
 266 AC_MP_PROCFS
 267 AC_POLLABLE_PROCFS
 268
 269 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 270 AC_STRUCT_PR_SYSCALL
 271
 272 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 273                   struct T_conn_res.ACCEPTOR_id],,,
 274 [#include <sys/stream.h>
 275 #include <sys/tihdr.h>])
 276
 277 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 278
 279 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 280                [#include <sys/ptrace.h>])
 281
 282 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 283
 284 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 285
 286 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 287 #ifdef HAVE_ASM_SIGCONTEXT_H
 288 # include <asm/sigcontext.h>
 289 #endif])
 290
 291
 292 AC_CHECK_DECLS([sys_errlist])
 293 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 294
 295 AC_PATH_PROG([PERL], [perl])
 296
 297 AC_CONFIG_FILES([Makefile])
 298 AC_OUTPUT