granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2019 The strace developers.
   9 # All rights reserved.
  10 #
  11 # SPDX-License-Identifier: LGPL-2.1-or-later
  12
  13 AC_PREREQ(2.57)
  14 AC_INIT([strace],
  15         st_esyscmd_s([./git-version-gen .tarball-version]),
  16         [strace-devel@lists.strace.io],
  17         [strace],
  18         [https://strace.io])
  19 m4_define([copyright_year], st_esyscmd_s([./copyright-year-gen .year]))
  20 m4_define([manpage_date], st_esyscmd_s([./file-date-gen strace.1.in]))
  21 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  22 AC_CONFIG_SRCDIR([strace.c])
  23 AC_CONFIG_AUX_DIR([.])
  24 AC_CONFIG_HEADERS([config.h])
  25 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  26 AM_MAINTAINER_MODE
  27 AC_CANONICAL_HOST
  28
  29 RPM_CHANGELOGTIME="$(LC_TIME=C date -u '+%a %b %d %Y')"
  30 AC_SUBST(RPM_CHANGELOGTIME)
  31 DEB_CHANGELOGTIME="$(LC_TIME=C date -u -R)"
  32 AC_SUBST(DEB_CHANGELOGTIME)
  33
  34 AC_PROG_CC
  35 AC_PROG_CC_STDC
  36 AC_PROG_CPP
  37 st_WARN_CFLAGS
  38 AX_PROG_CC_FOR_BUILD
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 AC_USE_SYSTEM_EXTENSIONS
  43 AX_CODE_COVERAGE
  44
  45 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  46 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  47
  48 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  49 AC_SUBST([MANPAGE_DATE], [manpage_date])
  50
  51 AC_C_BIGENDIAN
  52
  53 AC_MSG_CHECKING([for supported architecture])
  54 arch_m32=
  55 arch_mx32=
  56 cc_flags_m32=-m32
  57 cc_flags_mx32=-mx32
  58 case "$host_cpu" in
  59 aarch64*)
  60         arch=aarch64
  61         arch_m32=arm
  62         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
  63         ;;
  64 alpha*)
  65         arch=alpha
  66         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  67         ;;
  68 arc*)
  69         arch=arc
  70         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
  71         ;;
  72 arm*)
  73         arch=arm
  74         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  75         ;;
  76 avr32*)
  77         arch=avr32
  78         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  79         ;;
  80 bfin)
  81         arch=bfin
  82         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  83         ;;
  84 csky*)
  85         arch=csky
  86         AC_DEFINE([CSKY], 1, [Define for the C-SKY architecture])
  87         ;;
  88 hppa*|parisc*)
  89         arch=hppa
  90         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  91         ;;
  92 i[[3456]]86|pentium)
  93         arch=i386
  94         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  95         ;;
  96 ia64)
  97         arch=ia64
  98         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  99         ;;
 100 m68k)
 101         arch=m68k
 102         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
 103         ;;
 104 metag*)
 105         arch=metag
 106         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 107         ;;
 108 microblaze*)
 109         arch=microblaze
 110         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 111         ;;
 112 mips*)
 113         arch=mips
 114         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 115         ;;
 116 nios2*)
 117         arch=nios2
 118         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 119         ;;
 120 or1k*)
 121         arch=or1k
 122         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 123         ;;
 124 powerpc*)
 125         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 126         AC_TRY_COMPILE(
 127 [#ifndef __LP64__
 128 # error 32 bit
 129 #endif], [], arch=powerpc64, arch=powerpc)
 130         if test "$arch" = "powerpc64"; then
 131                 # $ac_cv_c_bigendian is defined by AC_C_BIGENDIAN
 132                 case "$ac_cv_c_bigendian" in
 133                 no)
 134                         arch=powerpc64le
 135                         AC_DEFINE([POWERPC64LE], 1,
 136                                   [Define for the little endian PowerPC64 architecture.])
 137                         ;;
 138                 *)
 139                         arch_m32=powerpc
 140                         AC_DEFINE([POWERPC64], 1,
 141                                   [Define for the big endian PowerPC64 architecture.])
 142                         ;;
 143                 esac
 144         fi
 145         ;;
 146 riscv64*)
 147         arch=riscv64
 148         AC_DEFINE([RISCV64], 1, [Define for the RISC-V 64-bit architecture])
 149         ;;
 150 s390)
 151         arch=s390
 152         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 153         ;;
 154 s390x)
 155         arch=s390x
 156         arch_m32=s390
 157         cc_flags_m32=-m31
 158         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 159         ;;
 160 sh64*)
 161         arch=sh64
 162         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 163         ;;
 164 sh*)
 165         arch=sh
 166         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 167         ;;
 168 sparc64*)
 169         arch=sparc64
 170         arch_m32=sparc
 171         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
 172         ;;
 173 sparc*)
 174         arch=sparc
 175         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
 176         ;;
 177 tile*)
 178         arch=tile
 179         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 180         ;;
 181 x86?64*)
 182         arch_m32=i386
 183         AC_TRY_COMPILE(
 184 [#ifndef __ILP32__
 185 # error not x32
 186 #endif], [], arch=x32, arch=x86_64)
 187         if test "$arch" = "x86_64"; then
 188                 arch_mx32=x32
 189                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 190         else
 191                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 192         fi
 193         ;;
 194 xtensa*)
 195         arch=xtensa
 196         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 197         ;;
 198 *)
 199         AC_MSG_RESULT([NO!])
 200         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 201         ;;
 202 esac
 203 AC_MSG_RESULT($arch)
 204
 205 arch_native=$arch
 206
 207 test -n "$arch_m32" ||
 208         arch_m32=$arch
 209 test -n "$arch_mx32" ||
 210         arch_mx32=$arch
 211 AC_SUBST(arch)
 212 AC_SUBST(arch_m32)
 213 AC_SUBST(arch_mx32)
 214 AC_SUBST(cc_flags_m32)
 215 AC_SUBST(cc_flags_mx32)
 216 AC_SUBST(arch_native)
 217
 218 MIPS_ABI=
 219 if test "$arch" = mips; then
 220         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 221                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 222                                        [AC_MSG_FAILURE([_MIPS_SIM cannot be determined])])])
 223
 224         # requires GCC >= 3.4
 225         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 228                         [st_cv_mips_abi=o32],
 229                 [AC_COMPILE_IFELSE(
 230                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 231                         [st_cv_mips_abi=n32],
 232                 [AC_COMPILE_IFELSE(
 233                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 234                         [st_cv_mips_abi=n64],
 235                         [st_cv_mips_abi=unknown])])])])
 236
 237         case "$st_cv_mips_abi" in
 238                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 239                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 240                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 241                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 242         esac
 243         MIPS_ABI="$st_cv_mips_abi"
 244 fi
 245 AC_SUBST(MIPS_ABI)
 246
 247 AC_ARG_ENABLE([arm-oabi],
 248               [AS_HELP_STRING([--enable-arm-oabi],
 249                               [enable OABI support on ARM EABI])],
 250               [], [enable_arm_oabi=no])
 251 case "$enable_arm_oabi" in
 252         yes) enable_arm_oabi=1 ;;
 253         no) enable_arm_oabi=0 ;;
 254         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 255 esac
 256 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 257                    [Define to 1 if you want OABI support on ARM EABI.])
 258
 259 AC_C_TYPEOF
 260
 261 AC_TYPE_UID_T
 262
 263 AC_CHECK_FUNCS(m4_normalize([
 264         accept4
 265         be64toh
 266         fallocate
 267         fanotify_mark
 268         fopen64
 269         fork
 270         fputs_unlocked
 271         fstatat
 272         ftruncate
 273         futimens
 274         iconv_open
 275         if_indextoname
 276         open64
 277         open_memstream
 278         prctl
 279         preadv
 280         process_vm_readv
 281         pwritev
 282         readahead
 283         signalfd
 284         stpcpy
 285         strerror
 286         strndup
 287         strsignal
 288         sync_file_range
 289         utimensat
 290 ]))
 291
 292 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 293
 294 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 295
 296 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 297 [#include <asm/posix_types.h>])
 298
 299 AC_CHECK_TYPES([struct __kernel_timespec, struct __kernel_sock_timeval],,,
 300 [#include <linux/time_types.h>])
 301
 302 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 303 [#include <sys/types.h>
 304 #include <asm/stat.h>])
 305
 306 AC_CHECK_TYPES([struct user_desc],
 307                [AC_CHECK_MEMBERS([struct user_desc.lm],,,
 308                                  [#include <asm/ldt.h>])],,
 309                [#include <asm/ldt.h>])
 310
 311 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 312 [#include <sys/types.h>
 313 #include <asm/stat.h>])
 314
 315 AC_CHECK_TYPES(m4_normalize([
 316         struct pt_all_user_regs,
 317         struct ia64_fpreg,
 318         struct ptrace_peeksiginfo_args
 319 ]),,, [#include <sys/ptrace.h>])
 320
 321 # For kernels that do not have v3.10-rc1~201^2~11
 322 AC_CHECK_TYPES([s390_compat_regs],,, [#include <asm/ptrace.h>])
 323
 324 AC_CHECK_TYPES(m4_normalize([
 325         struct flock,
 326         struct flock64,
 327         struct __kernel_flock,
 328         struct __kernel_flock64,
 329         struct f_owner_ex,
 330         struct __kernel_f_owner_ex
 331 ]),,,
 332 [#include <sys/types.h>
 333 #include <linux/fcntl.h>])
 334
 335 AC_CHECK_TYPES(m4_normalize([
 336         struct crypto_report_aead,
 337         struct crypto_report_blkcipher,
 338         struct crypto_report_cipher,
 339         struct crypto_report_hash,
 340         struct crypto_report_rng
 341 ]),,, [#include <linux/cryptouser.h>])
 342
 343 AC_CHECK_TYPES(m4_normalize([
 344         struct kcmp_epoll_slot
 345 ]),,, [#include <linux/kcmp.h>])
 346
 347 AC_CHECK_TYPES(m4_normalize([
 348         struct keyctl_kdf_params
 349 ]),,, [#include <linux/keyctl.h>])
 350
 351 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 352
 353 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 354
 355 AC_CHECK_MEMBERS(m4_normalize([
 356         siginfo_t.si_syscall,
 357         siginfo_t.si_timerid,
 358         siginfo_t.si_overrun
 359 ]),,, [#include <signal.h>])
 360
 361 AC_CHECK_MEMBERS(m4_normalize([
 362         struct perf_event_attr.precise_ip,
 363         struct perf_event_attr.mmap_data,
 364         struct perf_event_attr.sample_id_all,
 365         struct perf_event_attr.exclude_host,
 366         struct perf_event_attr.exclude_guest,
 367         struct perf_event_attr.exclude_callchain_kernel,
 368         struct perf_event_attr.exclude_callchain_user,
 369         struct perf_event_attr.mmap2,
 370         struct perf_event_attr.comm_exec,
 371         struct perf_event_attr.use_clockid,
 372         struct perf_event_attr.context_switch,
 373         struct perf_event_attr.write_backward,
 374         struct perf_event_attr.namespaces,
 375         struct perf_event_attr.bp_type,
 376         struct perf_event_attr.config1,
 377         struct perf_event_attr.config2,
 378         struct perf_event_attr.branch_sample_type,
 379         struct perf_event_attr.sample_regs_user,
 380         struct perf_event_attr.sample_stack_user,
 381         struct perf_event_attr.sample_regs_intr,
 382         struct perf_event_attr.aux_watermark,
 383         struct perf_event_attr.sample_max_stack
 384 ]),,, [#include <linux/perf_event.h>])
 385
 386 AC_CHECK_HEADERS(m4_normalize([
 387         asm/cachectl.h
 388         asm/guarded_storage.h
 389         asm/sysmips.h
 390         elf.h
 391         iconv.h
 392         inttypes.h
 393         linux/bsg.h
 394         linux/cryptouser.h
 395         linux/dm-ioctl.h
 396         linux/dqblk_xfs.h
 397         linux/falloc.h
 398         linux/fib_rules.h
 399         linux/fiemap.h
 400         linux/hiddev.h
 401         linux/if_addr.h
 402         linux/if_link.h
 403         linux/io_uring.h
 404         linux/ip_vs.h
 405         linux/ipc.h
 406         linux/kcmp.h
 407         linux/kvm.h
 408         linux/memfd.h
 409         linux/mmtimer.h
 410         linux/mount.h
 411         linux/msg.h
 412         linux/neighbour.h
 413         linux/netfilter/ipset/ip_set.h
 414         linux/netfilter/nf_tables.h
 415         linux/netfilter/nf_tables_compat.h
 416         linux/netfilter/nfnetlink.h
 417         linux/netfilter/nfnetlink_acct.h
 418         linux/netfilter/nfnetlink_conntrack.h
 419         linux/netfilter/nfnetlink_cthelper.h
 420         linux/netfilter/nfnetlink_cttimeout.h
 421         linux/netfilter/nfnetlink_log.h
 422         linux/netfilter/nfnetlink_queue.h
 423         linux/nsfs.h
 424         linux/perf_event.h
 425         linux/quota.h
 426         linux/sched.h
 427         linux/seccomp.h
 428         linux/securebits.h
 429         linux/sem.h
 430         linux/shm.h
 431         linux/userfaultfd.h
 432         linux/utsname.h
 433         mqueue.h
 434         netinet/sctp.h
 435         netipx/ipx.h
 436         paths.h
 437         scsi/sg.h
 438         stropts.h
 439         sys/conf.h
 440         sys/eventfd.h
 441         sys/fanotify.h
 442         sys/ipc.h
 443         sys/msg.h
 444         sys/quota.h
 445         sys/sem.h
 446         sys/shm.h
 447         sys/signalfd.h
 448         sys/xattr.h
 449         ustat.h
 450 ]))
 451
 452 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 453
 454 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 455
 456 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 457
 458 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 459 #include <linux/tcp.h>])
 460
 461 AC_CHECK_HEADERS(m4_normalize([
 462         linux/netfilter_arp/arp_tables.h
 463         linux/netfilter_bridge/ebtables.h
 464         linux/netfilter_ipv4/ip_tables.h
 465         linux/netfilter_ipv6/ip6_tables.h
 466 ]),,, [#include <netinet/in.h>
 467 #include <net/if.h>])
 468
 469 AC_CHECK_HEADERS([linux/input.h], [
 470         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 471 ])
 472
 473 AC_CHECK_HEADERS([linux/bpf.h], [
 474         AC_CHECK_TYPES(m4_normalize([
 475                 struct bpf_insn,
 476                 struct bpf_map_info,
 477                 struct bpf_prog_info
 478         ]),,, [#include <linux/bpf.h>])
 479         st_BPF_ATTR
 480 ])
 481
 482 AC_CHECK_HEADERS([bluetooth/bluetooth.h], [
 483         AC_CHECK_MEMBERS([struct sockaddr_hci.hci_channel],,,
 484                          [#include <bluetooth/bluetooth.h>
 485                          #include <bluetooth/hci.h>])
 486         AC_CHECK_MEMBERS([struct sockaddr_l2.l2_bdaddr_type],,,
 487                          [#include <bluetooth/bluetooth.h>
 488                          #include <bluetooth/l2cap.h>])
 489 ])
 490
 491 AC_CHECK_TYPES(m4_normalize([
 492         struct br_mdb_entry,
 493         struct br_port_msg
 494 ]),,, [#include <linux/if_bridge.h>])
 495 AC_CHECK_MEMBERS(m4_normalize([
 496         struct br_mdb_entry.flags,
 497         struct br_mdb_entry.vid
 498 ]),,, [#include <linux/if_bridge.h>])
 499
 500 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 501 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 502 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 503
 504 AC_CHECK_TYPES(m4_normalize([
 505         struct rta_mfc_stats,
 506         struct rtvia
 507 ]),,, [#include <sys/socket.h>
 508 #include <linux/rtnetlink.h>])
 509
 510 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 511 AC_CHECK_TYPES(m4_normalize([
 512         struct ndt_config,
 513         struct ndt_stats
 514 ]),,, [#include <linux/neighbour.h>])
 515
 516 AC_CHECK_TYPES(m4_normalize([
 517         struct ifla_bridge_id,
 518         struct ifla_cacheinfo,
 519         struct ifla_port_vsi,
 520         struct rtnl_link_stats64
 521 ]),,, [#include <sys/socket.h>
 522 #include <linux/rtnetlink.h>])
 523 AC_CHECK_MEMBERS(m4_normalize([
 524         struct rtnl_link_stats.rx_nohandler,
 525         struct rtnl_link_stats64.rx_nohandler
 526 ]),,, [#include <sys/socket.h>
 527 #include <linux/rtnetlink.h>])
 528 AC_CHECK_DECLS(m4_normalize([
 529         IFLA_PORT_SELF,
 530         IFLA_PROTINFO,
 531         IFLA_AF_SPEC,
 532         IFLA_XDP
 533 ]),,, [#include <sys/socket.h>
 534 #include <linux/rtnetlink.h>])
 535
 536 AC_CHECK_TYPES(m4_normalize([
 537         struct gnet_stats_basic,
 538         struct gnet_stats_queue,
 539         struct gnet_stats_rate_est,
 540         struct gnet_stats_rate_est64
 541 ]),,, [#include <linux/gen_stats.h>])
 542
 543 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/types.h>
 544 #include <linux/pkt_sched.h>])
 545 AC_CHECK_DECLS([TCA_STAB_DATA],,, [#include <linux/types.h>
 546 #include <linux/pkt_sched.h>])
 547
 548 AC_CHECK_TYPES(m4_normalize([
 549         struct fib_rule_uid_range,
 550         struct fib_rule_port_range
 551 ]),,, [#include <linux/fib_rules.h>])
 552
 553 AC_CHECK_TYPES([struct statfs], [
 554         AC_CHECK_MEMBERS(m4_normalize([
 555                 struct statfs.f_frsize,
 556                 struct statfs.f_flags,
 557                 struct statfs.f_fsid.val,
 558                 struct statfs.f_fsid.__val
 559         ]),,, [#include <linux/types.h>
 560 #include <asm/statfs.h>])
 561 ],, [#include <linux/types.h>
 562 #include <asm/statfs.h>])
 563
 564 AC_CHECK_TYPES([struct statfs64], [
 565         AC_CHECK_MEMBERS(m4_normalize([
 566                 struct statfs64.f_frsize,
 567                 struct statfs64.f_flags,
 568                 struct statfs64.f_fsid.val,
 569                 struct statfs64.f_fsid.__val
 570         ]),,, [#include <linux/types.h>
 571 #include <asm/statfs.h>])
 572 ],, [#include <linux/types.h>
 573 #include <asm/statfs.h>])
 574
 575 AC_CHECK_TYPES([struct statx],,, [#include <linux/types.h>
 576 #include <linux/stat.h>])
 577
 578 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 579
 580 AC_CHECK_TYPES([struct mtd_write_req],,, [#include <mtd/mtd-abi.h>])
 581
 582 AC_CHECK_MEMBERS([struct ubi_attach_req.max_beb_per1024],,, [#include <mtd/ubi-user.h>])
 583
 584 AC_CHECK_TYPES(m4_normalize([
 585         struct ptp_sys_offset
 586 ]),,, [#include <linux/ptp_clock.h>])
 587
 588 AC_CHECK_TYPES(m4_normalize([
 589         struct kvm_cpuid2,
 590         struct kvm_regs,
 591         struct kvm_sregs,
 592         struct kvm_userspace_memory_region
 593 ]),,, [#include <linux/kvm.h>])
 594
 595 saved_CPPFLAGS="$CPPFLAGS"
 596
 597 AC_CACHE_CHECK([whether <linux/signal.h> can be used along with <signal.h>],
 598                [st_cv_linux_signal],
 599                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 600 #include <signal.h>
 601 #include <linux/signal.h>]],[])],
 602                                   [st_cv_linux_signal=yes],
 603                                   [st_cv_linux_signal=no])])
 604 if test "x$st_cv_linux_signal" = xno; then
 605         mkdir -p linux/linux
 606         cp $srcdir/linux/signal.h.in linux/linux/signal.h
 607         CPPFLAGS="$CPPFLAGS -Ilinux"
 608 fi
 609
 610 AC_CHECK_TYPES([struct __aio_sigset],,, [#include <linux/aio_abi.h>])
 611
 612 AC_CHECK_MEMBERS(m4_normalize([
 613                 struct iocb.aio_flags,
 614                 struct iocb.aio_rw_flags
 615                 ]),,, [#include <linux/aio_abi.h>])
 616
 617 AC_CHECK_TYPES([struct clone_args],,, [#include <linux/sched.h>])
 618
 619 CPPFLAGS="$saved_CPPFLAGS"
 620
 621 AC_CHECK_HEADERS([linux/btrfs.h], [
 622         AC_CHECK_MEMBERS(m4_normalize([
 623                 struct btrfs_ioctl_feature_flags.compat_flags,
 624                 struct btrfs_ioctl_fs_info_args.nodesize,
 625                 struct btrfs_ioctl_defrag_range_args.start,
 626                 struct btrfs_ioctl_search_args_v2.buf_size,
 627                 struct btrfs_ioctl_logical_ino_args.flags
 628                 ]),,, [ #include <stdio.h>
 629 #include <linux/btrfs.h>])
 630         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 631                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 632 #include <linux/btrfs.h>])])
 633
 634 AC_CHECK_DECLS([sys_errlist])
 635 AC_CHECK_DECLS(m4_normalize([
 636         PTRACE_PEEKUSER,
 637         PTRACE_POKEUSER
 638 ]),,, [#include <sys/ptrace.h>])
 639
 640 AC_CHECK_DECLS(m4_normalize([
 641         P_PID,
 642         P_PPID,
 643         P_PGID,
 644         P_SID,
 645         P_CID,
 646         P_UID,
 647         P_GID,
 648         P_ALL,
 649         P_LWPID
 650 ]),,, [#include <sys/wait.h>])
 651
 652 AC_CHECK_DECLS(m4_normalize([
 653         LO_FLAGS_READ_ONLY,
 654         LO_FLAGS_USE_AOPS,
 655         LO_FLAGS_AUTOCLEAR,
 656         LO_FLAGS_PARTSCAN,
 657         LO_FLAGS_DIRECT_IO
 658 ]),,, [#include <linux/loop.h>])
 659
 660 AC_CHECK_DECLS(m4_normalize([
 661         CTL_PROC,
 662         CTL_ARLAN,
 663         CTL_S390DBF,
 664         CTL_SUNRPC,
 665         CTL_PM,
 666         CTL_FRV,
 667         KERN_PRINTK_RATELIMIT,
 668         KERN_PRINTK_RATELIMIT_BURST,
 669         KERN_PTY,
 670         KERN_NGROUPS_MAX,
 671         KERN_SPARC_SCONS_PWROFF,
 672         KERN_HZ_TIMER,
 673         KERN_UNKNOWN_NMI_PANIC,
 674         KERN_BOOTLOADER_TYPE,
 675         KERN_RANDOMIZE,
 676         KERN_SETUID_DUMPABLE,
 677         KERN_SPIN_RETRY,
 678         KERN_ACPI_VIDEO_FLAGS,
 679         KERN_IA64_UNALIGNED,
 680         KERN_COMPAT_LOG,
 681         KERN_MAX_LOCK_DEPTH,
 682         KERN_NMI_WATCHDOG,
 683         KERN_PANIC_ON_NMI,
 684         KERN_PANIC_ON_WARN,
 685         KERN_PANIC_PRINT,
 686         NET_LLC,
 687         NET_NETFILTER,
 688         NET_DCCP,
 689         NET_IRDA,
 690         NET_CORE_DESTROY_DELAY,
 691         NET_CORE_BUDGET,
 692         NET_CORE_AEVENT_ETIME,
 693         NET_CORE_AEVENT_RSEQTH,
 694         NET_CORE_WARNINGS,
 695         NET_IPV4_IGMP_MAX_MSF,
 696         NET_TCP_NO_METRICS_SAVE,
 697         NET_TCP_DEFAULT_WIN_SCALE,
 698         NET_TCP_MODERATE_RCVBUF,
 699         NET_TCP_TSO_WIN_DIVISOR,
 700         NET_TCP_BIC_BETA,
 701         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 702         NET_TCP_CONG_CONTROL,
 703         NET_TCP_ABC,
 704         NET_IPV4_IPFRAG_MAX_DIST,
 705         NET_TCP_MTU_PROBING,
 706         NET_TCP_BASE_MSS,
 707         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 708         NET_TCP_DMA_COPYBREAK,
 709         NET_TCP_SLOW_START_AFTER_IDLE,
 710         NET_CIPSOV4_CACHE_ENABLE,
 711         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 712         NET_CIPSOV4_RBM_OPTFMT,
 713         NET_CIPSOV4_RBM_STRICTVALID,
 714         NET_TCP_AVAIL_CONG_CONTROL,
 715         NET_TCP_ALLOWED_CONG_CONTROL,
 716         NET_TCP_MAX_SSTHRESH,
 717         NET_TCP_FRTO_RESPONSE,
 718         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 719         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 720         NET_IPV4_CONF_ARP_ANNOUNCE,
 721         NET_IPV4_CONF_ARP_IGNORE,
 722         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 723         NET_IPV4_CONF_ARP_ACCEPT,
 724         NET_IPV4_CONF_ARP_NOTIFY,
 725         NET_IPV6_MLD_MAX_MSF,
 726         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 727         VM_MAX_MAP_COUNT,
 728         VM_LAPTOP_MODE,
 729         VM_BLOCK_DUMP,
 730         VM_HUGETLB_GROUP,
 731         VM_VFS_CACHE_PRESSURE,
 732         VM_LEGACY_VA_LAYOUT,
 733         VM_SWAP_TOKEN_TIMEOUT
 734 ]),,,
 735 [#include <sys/types.h>
 736 #include <linux/sysctl.h>])
 737
 738 AC_CHECK_DECLS(m4_normalize([
 739         V4L2_FIELD_ANY,
 740         V4L2_FIELD_NONE,
 741         V4L2_FIELD_TOP,
 742         V4L2_FIELD_BOTTOM,
 743         V4L2_FIELD_INTERLACED,
 744         V4L2_FIELD_SEQ_TB,
 745         V4L2_FIELD_SEQ_BT,
 746         V4L2_FIELD_ALTERNATE,
 747         V4L2_FIELD_INTERLACED_TB,
 748         V4L2_FIELD_INTERLACED_BT,
 749         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 750         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 751         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 752         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 753         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 754         V4L2_BUF_TYPE_VBI_CAPTURE,
 755         V4L2_BUF_TYPE_VBI_OUTPUT,
 756         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 757         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 758         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 759         V4L2_BUF_TYPE_SDR_CAPTURE,
 760         V4L2_BUF_TYPE_SDR_OUTPUT,
 761         V4L2_TUNER_RADIO,
 762         V4L2_TUNER_ANALOG_TV,
 763         V4L2_TUNER_DIGITAL_TV,
 764         V4L2_MEMORY_MMAP,
 765         V4L2_MEMORY_USERPTR,
 766         V4L2_MEMORY_OVERLAY,
 767         V4L2_MEMORY_DMABUF,
 768         V4L2_COLORSPACE_SMPTE170M,
 769         V4L2_COLORSPACE_SMPTE240M,
 770         V4L2_COLORSPACE_REC709,
 771         V4L2_COLORSPACE_BT878,
 772         V4L2_COLORSPACE_470_SYSTEM_M,
 773         V4L2_COLORSPACE_470_SYSTEM_BG,
 774         V4L2_COLORSPACE_JPEG,
 775         V4L2_COLORSPACE_SRGB,
 776         V4L2_PRIORITY_UNSET,
 777         V4L2_PRIORITY_BACKGROUND,
 778         V4L2_PRIORITY_INTERACTIVE,
 779         V4L2_PRIORITY_RECORD,
 780         V4L2_FRMSIZE_TYPE_DISCRETE,
 781         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 782         V4L2_FRMSIZE_TYPE_STEPWISE,
 783         V4L2_FRMIVAL_TYPE_DISCRETE,
 784         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 785         V4L2_FRMIVAL_TYPE_STEPWISE,
 786         V4L2_CTRL_TYPE_INTEGER,
 787         V4L2_CTRL_TYPE_BOOLEAN,
 788         V4L2_CTRL_TYPE_MENU,
 789         V4L2_CTRL_TYPE_BUTTON,
 790         V4L2_CTRL_TYPE_INTEGER64,
 791         V4L2_CTRL_TYPE_CTRL_CLASS,
 792         V4L2_CTRL_TYPE_STRING,
 793         V4L2_CTRL_TYPE_BITMASK,
 794         V4L2_CTRL_TYPE_INTEGER_MENU
 795 ]),,, [#include <sys/time.h>
 796 #include <linux/ioctl.h>
 797 #include <linux/types.h>
 798 #include <linux/videodev2.h>])
 799
 800 AC_CHECK_MEMBERS(m4_normalize([
 801         struct v4l2_window.global_alpha,
 802         struct v4l2_sdr_format.buffersize
 803 ]),,, [#include <sys/time.h>
 804 #include <linux/ioctl.h>
 805 #include <linux/types.h>
 806 #include <linux/videodev2.h>])
 807
 808 AC_CHECK_SIZEOF([long])
 809 SIZEOF_LONG="$ac_cv_sizeof_long"
 810 AC_SUBST(SIZEOF_LONG)
 811 AC_CHECK_SIZEOF([long long])
 812 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 813 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 814 SIZEOF_KERNEL_LONG_T="$ac_cv_sizeof_kernel_long_t"
 815 AC_SUBST(SIZEOF_KERNEL_LONG_T)
 816 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 817
 818
 819 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 820                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 821                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 822                         grep '^[0-9]')"
 823                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 824 if test "x$st_cv_SIGRTMIN" != xno; then
 825         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 826                            [SIGRTMIN defined in <asm/signal.h>])
 827 fi
 828 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 829                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 830                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 831                         grep ^0x)"
 832                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 833 if test "x$st_cv_SA_RESTORER" != xno; then
 834         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 835                            [SA_RESTORER defined in <asm/signal.h>])
 836 fi
 837
 838 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 839                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 840                                [st_cv_have___builtin_popcount=yes],
 841                                [st_cv_have___builtin_popcount=no])])
 842 if test "x$st_cv_have___builtin_popcount" = xyes; then
 843         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 844                   [Define to 1 if the system provides __builtin_popcount function])
 845 fi
 846
 847 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 848                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 849                                                 [[return !*program_invocation_name]])],
 850                                [st_cv_have_program_invocation_name=yes],
 851                                [st_cv_have_program_invocation_name=no])])
 852 if test "x$st_cv_have_program_invocation_name" = xyes; then
 853         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 854                   [Define to 1 if the system provides program_invocation_name variable])
 855 fi
 856
 857 AC_CACHE_CHECK([for static_assert], [st_cv_have_static_assert],
 858                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <assert.h>]],
 859                                                 [[static_assert(1,"")]]
 860                                                )
 861                                ],
 862                                [st_cv_have_static_assert=yes],
 863                                [AC_LINK_IFELSE([AC_LANG_PROGRAM([],
 864                                                                 [[_Static_assert(1,"")]]
 865                                                                )
 866                                                ],
 867                                                [st_cv_have_static_assert=_Static_assert],
 868                                                [st_cv_have_static_assert=no]
 869                                               )
 870                                ]
 871                               )
 872                ]
 873               )
 874 case "x$st_cv_have_static_assert" in
 875         xyes)
 876                 AC_DEFINE([HAVE_STATIC_ASSERT], [1],
 877                           [Define to 1 if the system provides static_assert])
 878                 ;;
 879         x_Static_assert)
 880                 AC_DEFINE([HAVE__STATIC_ASSERT], [1],
 881                           [Define to 1 if the system provides _Static_assert])
 882                 ;;
 883 esac
 884
 885 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 886 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 887         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 888 fi
 889 AC_SUBST(dl_LIBS)
 890
 891 saved_LIBS="$LIBS"
 892 AC_SEARCH_LIBS([timer_create], [rt])
 893 LIBS="$saved_LIBS"
 894 case "$ac_cv_search_timer_create" in
 895         no) AC_MSG_FAILURE([failed to find timer_create]) ;;
 896         -l*) timer_LIBS="$ac_cv_search_timer_create" ;;
 897         *) timer_LIBS= ;;
 898 esac
 899 AC_SUBST(timer_LIBS)
 900
 901 saved_LIBS="$LIBS"
 902 AC_SEARCH_LIBS([clock_gettime], [rt])
 903 LIBS="$saved_LIBS"
 904 case "$ac_cv_search_clock_gettime" in
 905         no) AC_MSG_FAILURE([failed to find clock_gettime]) ;;
 906         -l*) clock_LIBS="$ac_cv_search_clock_gettime" ;;
 907         *) clock_LIBS= ;;
 908 esac
 909 AC_SUBST(clock_LIBS)
 910
 911 saved_LIBS="$LIBS"
 912 AC_SEARCH_LIBS([mq_open], [rt])
 913 LIBS="$saved_LIBS"
 914 case "$ac_cv_search_mq_open" in
 915         -l*) mq_LIBS="$ac_cv_search_mq_open" ;;
 916         *) mq_LIBS= ;;
 917 esac
 918 AC_SUBST(mq_LIBS)
 919
 920 AC_PATH_PROG([PERL], [perl])
 921
 922 AC_CHECK_TOOL([READELF], [readelf])
 923
 924 st_STACKTRACE
 925
 926 if test "$arch" = mips && test "$no_create" != yes; then
 927         mkdir -p linux/mips
 928         if $srcdir/linux/mips/genstub.sh \
 929            $srcdir/linux/mips linux/mips n32 n64 o32 &&
 930            $srcdir/linux/mips/genstub.sh \
 931            $srcdir/linux linux/mips common common-32; then
 932                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 933         else
 934                 AC_MSG_ERROR([Failed to generate syscallent stubs])
 935         fi
 936 fi
 937
 938 AC_ARG_ENABLE([mpers],
 939         [AS_HELP_STRING([--enable-mpers=yes|no|check|m32|mx32],
 940                 [whether to enable multiple personalities support required
 941                  for proper decoding of structures used by tracees with
 942                  personalities that differ from the personality of strace,
 943                  default is yes.])],
 944         [case "$enableval" in
 945                 yes|no|check|m32|mx32) enable_mpers="$enableval" ;;
 946                 *) AC_MSG_ERROR([bad value $enableval for enable-mpers option.
 947                                  Valid options are: yes, no, check, m32, mx32.])
 948                 ;;
 949          esac],
 950         [enable_mpers=yes])
 951
 952 st_MPERS([m32], [aarch64|powerpc64|s390x|sparc64|tile|x32|x86_64])
 953 st_MPERS([mx32], [x86_64])
 954
 955 AX_VALGRIND_DFLT([sgcheck], [off])
 956 AX_VALGRIND_CHECK
 957
 958 AC_CONFIG_FILES([Makefile
 959                  tests/Makefile
 960                  tests-m32/Makefile
 961                  tests-mx32/Makefile
 962                  strace.1
 963                  strace-log-merge.1
 964                  strace.spec
 965                  debian/changelog])
 966 AC_OUTPUT