granicus.if.org Git - libass/blob - configure.ac

   1 AC_INIT(libass, 0.13.7)
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_MACRO_DIR([m4])
   4 # Disable Fortran checks
   5 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
   6 LT_INIT
   7 AC_CONFIG_SRCDIR([libass/ass.c])
   8 AC_CONFIG_HEADER([config.h])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AM_PROG_CC_C_O
  14 AM_PROG_AS
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_STDBOOL
  19 AC_CHECK_HEADERS([stdint.h iconv.h])
  20
  21 # Checks for library functions.
  22 AC_CHECK_FUNCS([strdup strndup])
  23
  24 # Checks for libraries.
  25 # Add them to pkg-config for static linking.
  26 OLDLIBS="$LIBS"
  27 LIBS=
  28 use_libiconv=false
  29 AC_SEARCH_LIBS([libiconv_open], [iconv], use_libiconv=true)
  30 AC_SEARCH_LIBS([iconv_open], [iconv], use_libiconv=true)
  31 AC_CHECK_LIB([m], [fabs])
  32 pkg_libs="$LIBS"
  33 LIBS="$OLDLIBS $LIBS"
  34
  35 # Check for libraries via pkg-config
  36 AC_ARG_ENABLE([test], AS_HELP_STRING([--enable-test],
  37     [enable test program (requires libpng) @<:@default=no@:>@]))
  38 AC_ARG_ENABLE([profile], AS_HELP_STRING([--enable-profile],
  39     [enable profiling program @<:@default=no@:>@]))
  40 AC_ARG_ENABLE([fontconfig], AS_HELP_STRING([--disable-fontconfig],
  41     [disable fontconfig support @<:@default=enabled@:>@]))
  42 AC_ARG_ENABLE([directwrite], AS_HELP_STRING([--disable-directwrite],
  43     [disable DirectWrite support (win32 only) @<:@default=check@:>@]))
  44 AC_ARG_ENABLE([coretext], AS_HELP_STRING([--disable-coretext],
  45     [disable CoreText support (OSX only) @<:@default=check@:>@]))
  46 AC_ARG_ENABLE([require-system-font-provider], AS_HELP_STRING([--disable-require-system-font-provider],
  47     [allow compilation even if no system font provider was found @<:@default=enabled:>@]))
  48 AC_ARG_ENABLE([harfbuzz], AS_HELP_STRING([--disable-harfbuzz],
  49     [disable HarfBuzz support @<:@default=check@:>@]))
  50 AC_ARG_ENABLE([asm], AS_HELP_STRING([--disable-asm],
  51     [disable compiling with ASM @<:@default=check@:>@]))
  52 AC_ARG_ENABLE([rasterizer], AS_HELP_STRING([--disable-rasterizer],
  53     [disable internal rasterizer @<:@default=enabled@:>@]))
  54 AC_ARG_ENABLE([large-tiles], AS_HELP_STRING([--enable-large-tiles],
  55     [use larger tiles in the rasterizer (better performance, slightly worse quality) @<:@default=disabled@:>@]))
  56
  57 AS_IF([test x$enable_asm != xno], [
  58     AS_CASE([$host],
  59         [i?86-*], [
  60             INTEL=true
  61             AS=yasm
  62             X86=true
  63             BITS=32
  64             ASFLAGS="$ASFLAGS -DARCH_X86_64=0 -m x86" ],
  65         [x86_64-*-gnux32|amd64-*-gnux32], [
  66             AS=yasm
  67             INTEL=true
  68             X64=true
  69             BITS=64
  70             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -m x32" ],
  71         [x86_64-*|amd64-*], [
  72             AS=yasm
  73             INTEL=true
  74             X64=true
  75             BITS=64
  76             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -m amd64" ],
  77         )
  78     AS_CASE([$host],
  79         [*darwin*], [
  80             ASFLAGS="$ASFLAGS -f macho$BITS -DPREFIX -DHAVE_ALIGNED_STACK=1" ],
  81         [*linux*|*dragonfly*|*bsd*|*solaris*], [
  82             ASFLAGS="$ASFLAGS -f elf -DHAVE_ALIGNED_STACK=1" ],
  83         [*cygwin*|*mingw*], [
  84             ASFLAGS="$ASFLAGS -f win$BITS"
  85             AS_IF([test x$BITS = x64], [
  86                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=1"
  87             ], [
  88                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=0 -DPREFIX"
  89             ])
  90         ])
  91     AS_IF([test x$INTEL = xtrue], [
  92         AC_CHECK_PROG([yasm_check], [$AS], [yes])
  93         AS_IF([test x$yasm_check != xyes], [
  94             AC_MSG_WARN(yasm was not found; ASM functions are disabled.)
  95             AC_MSG_WARN(Install yasm for a significantly faster libass build.)
  96             enable_asm=no
  97         ], [
  98             AC_MSG_CHECKING([if $AS supports vpmovzxwd])
  99             echo "vpmovzxwd ymm0, xmm0" > conftest.asm
 100             AS_IF([$AS conftest.asm $ASFLAGS -o conftest.o >conftest.log 2>&1], [
 101                 AC_MSG_RESULT([yes])
 102             ], [
 103                 AC_MSG_RESULT([no])
 104                 VER=`($AS --version || echo no assembler) 2>/dev/null | head -n 1`
 105                 AC_MSG_WARN([yasm is too old (found $VER); ASM functions are disabled.])
 106                 AC_MSG_WARN([Install yasm-1.2.0 or later for a significantly faster libass build.])
 107                 enable_asm=no
 108             ])
 109             rm conftest.asm conftest.o > /dev/null 2>&1
 110         ])
 111     ])
 112 ])
 113
 114 AC_SUBST([ASFLAGS], ["$ASFLAGS"])
 115 AC_SUBST([AS], ["$AS"])
 116
 117 AM_CONDITIONAL([ASM], [test x$enable_asm != xno])
 118 AM_CONDITIONAL([INTEL], [test x$INTEL = xtrue])
 119 AM_CONDITIONAL([X86], [test x$X86 = xtrue])
 120 AM_CONDITIONAL([X64], [test x$X64 = xtrue])
 121
 122 AM_COND_IF([ASM],
 123     [AC_DEFINE(CONFIG_ASM, 1, [ASM enabled])],
 124     [AC_DEFINE(CONFIG_ASM, 0, [ASM enabled])]
 125     )
 126
 127 AM_CONDITIONAL([ENABLE_LARGE_TILES], [test x$enable_large_tiles = xyes])
 128
 129 AM_COND_IF([ENABLE_LARGE_TILES],
 130     [AC_DEFINE(CONFIG_LARGE_TILES, 1, [use large tiles])]
 131     [AC_DEFINE(CONFIG_LARGE_TILES, 0, [use small tiles])],
 132     )
 133
 134 PKG_CHECK_MODULES([FREETYPE], freetype2 >= 9.10.3, [
 135     CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 136     CXXFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 137     LIBS="$LIBS $FREETYPE_LIBS"
 138     AC_DEFINE(CONFIG_FREETYPE, 1, [found freetype2 via pkg-config])
 139     ])
 140
 141 PKG_CHECK_MODULES([FRIBIDI], fribidi >= 0.19.0, [
 142     CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
 143     LIBS="$LIBS $FRIBIDI_LIBS"
 144     AC_DEFINE(CONFIG_FRIBIDI, 1, [found fribidi via pkg-config])
 145     ])
 146
 147 if test x$enable_fontconfig != xno; then
 148 PKG_CHECK_MODULES([FONTCONFIG], fontconfig >= 2.10.92, [
 149     CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 150     LIBS="$LIBS $FONTCONFIG_LIBS"
 151     AC_DEFINE(CONFIG_FONTCONFIG, 1, [found fontconfig via pkg-config])
 152         fontconfig=true
 153     ], [fontconfig=false])
 154 fi
 155
 156 if test x$enable_coretext != xno; then
 157 OLDLIBS="$LIBS"
 158 # Linking to CoreText directly only works from Mountain Lion and iOS6. In
 159 # earlier OS releases CoreText was part of the ApplicationServices umbrella
 160 # framework.
 161 LIBS="$LIBS -framework CoreText -framework CoreFoundation -framework CoreGraphics"
 162 AC_MSG_CHECKING([for CORETEXT])
 163 AC_LINK_IFELSE([
 164   AC_LANG_PROGRAM(
 165     [[#include <CoreText/CoreText.h>]],
 166     [[CTFontCreateWithFontDescriptor(NULL, 0.0, NULL);]],)
 167   ], [
 168     AC_DEFINE(CONFIG_CORETEXT, 1, [found CoreText in System library])
 169     coretext=true
 170     AC_MSG_RESULT([yes])
 171   ], [
 172     LIBS="$OLDLIBS"
 173     coretext=false
 174     AC_MSG_RESULT([no])
 175   ])
 176 fi
 177 AM_CONDITIONAL([CORETEXT], [test x$coretext = xtrue])
 178
 179
 180
 181 if test x$enable_directwrite != xno; then
 182 # Linking to DirectWrite directly only works from Windows
 183 AC_MSG_CHECKING([for DIRECTWRITE])
 184 AC_LINK_IFELSE([
 185   AC_LANG_PROGRAM(
 186     [[#include <windows.h>]],
 187     [[;]],)
 188   ], [
 189     AC_DEFINE(CONFIG_DIRECTWRITE, 1, [found DirectWrite])
 190     directwrite=true
 191     AC_MSG_RESULT([yes])
 192   ], [
 193     directwrite=false
 194     AC_MSG_RESULT([no])
 195   ])
 196 fi
 197 AM_CONDITIONAL([DIRECTWRITE], [test x$directwrite = xtrue])
 198
 199 if test x$enable_harfbuzz != xno; then
 200 PKG_CHECK_MODULES([HARFBUZZ], harfbuzz >= 0.9.5, [
 201     CFLAGS="$CFLAGS $HARFBUZZ_CFLAGS"
 202     LIBS="$LIBS $HARFBUZZ_LIBS"
 203     AC_DEFINE(CONFIG_HARFBUZZ, 1, [found harfbuzz-ng via pkg-config])
 204         harfbuzz=true
 205     ], [harfbuzz=false])
 206 fi
 207
 208 libpng=false
 209 if test x$enable_test = xyes; then
 210 PKG_CHECK_MODULES([LIBPNG], libpng >= 1.2.0, [
 211     CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
 212     AC_DEFINE(CONFIG_LIBPNG, 1, [found libpng via pkg-config])
 213     libpng=true])
 214 fi
 215
 216 AM_CONDITIONAL([HAVE_LIBPNG], [test x$libpng = xtrue])
 217
 218 AM_CONDITIONAL([ENABLE_PROFILE], [test x$enable_profile = xyes])
 219
 220 # add packages to pkg-config for static linking
 221 if test "$use_libiconv" = true; then
 222     AC_DEFINE(CONFIG_ICONV, 1, [use iconv])
 223     if test x"$ac_cv_search_libiconv_open" != x"none required" &&
 224        test x"$ac_cv_search_iconv_open" != x"none required"; then
 225         pkg_libs="${pkg_libs} -liconv"
 226     fi
 227 fi
 228 pkg_requires="freetype2 >= 9.10.3"
 229 pkg_requires="fribidi >= 0.19.0, ${pkg_requires}"
 230 if test x$fontconfig = xtrue; then
 231     pkg_requires="fontconfig >= 2.10.92, ${pkg_requires}"
 232 fi
 233 if test x$harfbuzz = xtrue; then
 234     pkg_requires="harfbuzz >= 0.9.5, ${pkg_requires}"
 235 fi
 236
 237 if test x$enable_require_system_font_provider != xno &&
 238    test x$fontconfig != xtrue &&
 239    test x$directwrite != xtrue &&
 240    test x$coretext != xtrue
 241 then
 242     AC_MSG_ERROR([\
 243 Either DirectWrite (on Windows), CoreText (on OSX), or Fontconfig \
 244 (Linux, other) is required. If you really want to compile without \
 245 a system font provider, add --disable-require-system-font-provider])
 246 fi
 247
 248 AC_SUBST([PKG_LIBS_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_libs})])
 249 AC_SUBST([PKG_REQUIRES_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_requires})])
 250 AC_SUBST([PKG_LIBS_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_libs})])
 251 AC_SUBST([PKG_REQUIRES_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_requires})])
 252
 253 # Setup output beautifier.
 254 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 255
 256 AC_CONFIG_FILES([Makefile libass/Makefile test/Makefile profile/Makefile libass.pc])
 257 AC_OUTPUT