granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.6])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AC_CONFIG_AUX_DIR([.])
   6 AM_CONFIG_HEADER([config.h])
   7 AM_INIT_AUTOMAKE([foreign check-news dist-xz no-dist-gzip silent-rules])
   8 AM_MAINTAINER_MODE
   9 AC_CANONICAL_HOST
  10
  11 AC_MSG_CHECKING([for supported operating system])
  12 case "$host_os" in
  13 *linux*)
  14         opsys=linux
  15         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  16         ;;
  17 sunos4*)
  18         opsys=sunos4
  19         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  20         ;;
  21 solaris2* | sysv[[45]]* | irix[[56]]*)
  22         opsys=svr4
  23         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  24 system or a derivative like Solaris 2.x or Irix 5.x.])
  25         case "$host_os" in
  26         sysv4.2uw*)
  27                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  28                 ;;
  29         sysv5*)
  30                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  31                 ;;
  32         esac
  33         ;;
  34 freebsd*)
  35         opsys=freebsd
  36         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  37         ;;
  38 *)
  39         AC_MSG_RESULT([NO!])
  40         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  41         ;;
  42 esac
  43 AC_MSG_RESULT($opsys)
  44
  45 AC_MSG_CHECKING([for supported architecture])
  46 case "$host_cpu" in
  47 bfin)
  48         arch=bfin
  49         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  50         ;;
  51 i[[3456]]86|pentium)
  52         arch=i386
  53         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  54         ;;
  55 ia64)
  56         arch=ia64
  57         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  58         ;;
  59 m68k)
  60         arch=m68k
  61         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  62         ;;
  63 sparc64*)
  64         arch=sparc64
  65         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  66         ;;
  67 sparc*)
  68         arch=sparc
  69         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  70         ;;
  71 mips*)
  72         arch=mips
  73         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  74         ;;
  75 alpha*)
  76         arch=alpha
  77         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  78         ;;
  79 powerpc*)
  80         arch=powerpc
  81         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  82         if test $host_cpu = powerpc64; then
  83                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
  84         fi
  85         ;;
  86 arm*)
  87         arch=arm
  88         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  89         ;;
  90 avr32*)
  91         arch=avr32
  92         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  93         ;;
  94 s390)
  95         arch=s390
  96         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  97         ;;
  98 s390x)
  99         arch=s390x
 100         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 101         ;;
 102 hppa*|parisc*)
 103         arch=hppa
 104         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 105         ;;
 106 sh64*)
 107         arch=sh64
 108         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 109         ;;
 110 sh*)
 111         arch=sh
 112         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 113         ;;
 114 x86?64*)
 115         arch=x86_64
 116         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 117         ;;
 118 cris|crisv10)
 119         arch=crisv10
 120         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 121         ;;
 122 crisv32)
 123         arch=crisv32
 124         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 125         ;;
 126 tile*)
 127         arch=tile
 128         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 129         ;;
 130 microblaze*)
 131         arch=microblaze
 132         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 133         ;;
 134 *)
 135         AC_MSG_RESULT([NO!])
 136         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 137         ;;
 138 esac
 139 AC_MSG_RESULT($arch)
 140
 141 AC_SUBST(opsys)
 142 AC_SUBST(arch)
 143
 144 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 145 AM_CONDITIONAL([I386], [test x$arch = xi386])
 146 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 147
 148 AC_PROG_CC
 149 AC_GNU_SOURCE
 150
 151 AC_INCLUDEDIR
 152
 153 gl_WARN_ADD([-Wall])
 154 gl_WARN_ADD([-Wwrite-strings])
 155 if test "x$opsys" = "xsunos4"
 156 then
 157         # SunOS 4.x header files don't declare int functions.
 158         gl_WARN_ADD([-Wno-implicit])
 159 fi
 160 AC_SUBST([WARN_CFLAGS])
 161
 162 AC_PROG_CPP
 163 AC_PROG_GCC_TRADITIONAL
 164 AC_PROG_INSTALL
 165 AC_C_CONST
 166 AC_C_BIGENDIAN
 167 AC_HEADER_STDC
 168 AC_HEADER_STDBOOL
 169 AC_HEADER_DIRENT
 170 AC_HEADER_STAT
 171 AC_CHECK_MEMBERS([struct stat.st_blksize,
 172                   struct stat.st_blocks,
 173                   struct stat.st_aclcnt,
 174                   struct stat.st_flags,
 175                   struct stat.st_fstype,
 176                   struct stat.st_gen,
 177                   struct stat.st_level,
 178                   struct stat.st_rdev])
 179 AC_STAT64
 180 AC_STATFS64
 181
 182 AC_TYPE_SIGNAL
 183 AC_TYPE_UID_T
 184 AC_TYPE_MODE_T
 185 AC_TYPE_GETGROUPS
 186 AC_HEADER_MAJOR
 187 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 188 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 189 [#include <sys/types.h>
 190 #include <sys/socket.h>
 191 #include <netinet/in.h>])
 192 AC_CHECK_TYPES([long long])
 193 AC_LITTLE_ENDIAN_LONG_LONG
 194 AC_OFF_T_IS_LONG_LONG
 195 AC_RLIM_T_IS_LONG_LONG
 196 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 197 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 198
 199 if test x$opsys != xlinux; then
 200 AC_CHECK_LIB(nsl, main)
 201 fi
 202
 203 AC_CHECK_FUNCS([ \
 204         fork \
 205         getdents \
 206         if_indextoname \
 207         inet_ntop \
 208         mctl \
 209         prctl \
 210         pread \
 211         sendmsg \
 212         sigaction \
 213         strerror \
 214         strsignal \
 215         sys_siglist \
 216         _sys_siglist \
 217         stpcpy \
 218         process_vm_readv \
 219 ])
 220 AC_CHECK_HEADERS([ \
 221         inttypes.h \
 222         ioctls.h \
 223         libaio.h \
 224         mqueue.h \
 225         poll.h \
 226         stropts.h \
 227         termio.h \
 228         sys/acl.h \
 229         sys/aio.h \
 230         sys/asynch.h \
 231         sys/conf.h \
 232         sys/door.h \
 233         sys/epoll.h \
 234         sys/filio.h \
 235         sys/ioctl.h \
 236         sys/nscsys.h \
 237         sys/poll.h \
 238         sys/ptrace.h \
 239         sys/reg.h \
 240         sys/stream.h \
 241         sys/sysconfig.h \
 242         sys/tihdr.h \
 243         sys/tiuser.h \
 244         sys/uio.h \
 245         sys/vfs.h \
 246         asm/cachectl.h \
 247         asm/sysmips.h \
 248         linux/capability.h \
 249         linux/ptrace.h \
 250         linux/utsname.h \
 251         netinet/sctp.h \
 252 ], [], [])
 253 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 254                  [], [], [#include <stddef.h>
 255 #include <sys/socket.h>
 256 #include <asm/types.h>])
 257 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 258 AC_CHECK_TYPES([struct sigcontext_struct,
 259                 struct sigcontext],,, [#include <signal.h>])
 260 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 261
 262 AC_MP_PROCFS
 263 AC_POLLABLE_PROCFS
 264
 265 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 266 AC_STRUCT_PR_SYSCALL
 267
 268 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 269                   struct T_conn_res.ACCEPTOR_id],,,
 270 [#include <sys/stream.h>
 271 #include <sys/tihdr.h>])
 272
 273 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 274
 275 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 276                [#include <sys/ptrace.h>])
 277
 278 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 279
 280 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 281
 282 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 283 #ifdef HAVE_ASM_SIGCONTEXT_H
 284 # include <asm/sigcontext.h>
 285 #endif])
 286
 287
 288 AC_CHECK_DECLS([sys_errlist])
 289 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 290 AC_CHECK_DECLS([
 291                 PTRACE_SETOPTIONS,
 292                 PTRACE_GETEVENTMSG,
 293                 PTRACE_GETSIGINFO,
 294                 PTRACE_O_TRACESYSGOOD,
 295                 PTRACE_O_TRACEFORK,
 296                 PTRACE_O_TRACEVFORK,
 297                 PTRACE_O_TRACECLONE,
 298                 PTRACE_O_TRACEEXEC,
 299                 PTRACE_O_TRACEEXIT,
 300                 PTRACE_EVENT_FORK,
 301                 PTRACE_EVENT_VFORK,
 302                 PTRACE_EVENT_CLONE,
 303                 PTRACE_EVENT_EXEC,
 304                 PTRACE_EVENT_VFORK_DONE,
 305                 PTRACE_EVENT_EXIT],,, [#include <sys/ptrace.h>])
 306
 307 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 308         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 309 #include <stdlib.h>
 310 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 311                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 312         if test $ac_cv_have_blkgetsize64 = yes; then
 313                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 314         fi)
 315
 316 AC_PATH_PROG([PERL], [perl])
 317
 318 AC_CONFIG_FILES([Makefile tests/Makefile])
 319 AC_OUTPUT