granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.6])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AC_CONFIG_AUX_DIR([.])
   6 AM_CONFIG_HEADER([config.h])
   7 AM_INIT_AUTOMAKE([foreign check-news dist-xz no-dist-gzip silent-rules])
   8 AM_MAINTAINER_MODE
   9 AC_CANONICAL_HOST
  10
  11 AC_PROG_CC
  12 AC_USE_SYSTEM_EXTENSIONS
  13
  14 AC_MSG_CHECKING([for supported architecture])
  15 case "$host_cpu" in
  16 bfin)
  17         arch=bfin
  18         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  19         ;;
  20 i[[3456]]86|pentium)
  21         arch=i386
  22         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  23         ;;
  24 ia64)
  25         arch=ia64
  26         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  27         ;;
  28 m68k)
  29         arch=m68k
  30         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  31         ;;
  32 sparc64*)
  33         arch=sparc64
  34         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  35         ;;
  36 sparc*)
  37         arch=sparc
  38         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  39         ;;
  40 mips*)
  41         arch=mips
  42         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  43         ;;
  44 alpha*)
  45         arch=alpha
  46         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  47         ;;
  48 powerpc*)
  49         arch=powerpc
  50         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  51         if test $host_cpu = powerpc64; then
  52                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
  53         fi
  54         ;;
  55 arm*)
  56         arch=arm
  57         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  58         ;;
  59 avr32*)
  60         arch=avr32
  61         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  62         ;;
  63 s390)
  64         arch=s390
  65         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  66         ;;
  67 s390x)
  68         arch=s390x
  69         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  70         ;;
  71 hppa*|parisc*)
  72         arch=hppa
  73         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  74         ;;
  75 sh64*)
  76         arch=sh64
  77         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
  78         ;;
  79 sh*)
  80         arch=sh
  81         AC_DEFINE([SH], 1, [Define for the SH architecture.])
  82         ;;
  83 x86?64*)
  84         AC_TRY_COMPILE(
  85 [#ifndef __ILP32__
  86 # error not x32
  87 #endif], [], arch=x32, arch=x86_64)
  88         if test "$arch" = "x86_64"; then
  89                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
  90         else
  91                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
  92         fi
  93         ;;
  94 cris|crisv10)
  95         arch=crisv10
  96         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
  97         ;;
  98 crisv32)
  99         arch=crisv32
 100         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 101         ;;
 102 tile*)
 103         arch=tile
 104         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 105         ;;
 106 microblaze*)
 107         arch=microblaze
 108         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 109         ;;
 110 *)
 111         AC_MSG_RESULT([NO!])
 112         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 113         ;;
 114 esac
 115 AC_MSG_RESULT($arch)
 116
 117 AC_SUBST(arch)
 118
 119 AM_CONDITIONAL([I386], [test x$arch = xi386])
 120 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 121 AM_CONDITIONAL([X32], [test x$arch = xx32])
 122
 123 AC_INCLUDEDIR
 124
 125 gl_WARN_ADD([-Wall])
 126 gl_WARN_ADD([-Wwrite-strings])
 127 AC_SUBST([WARN_CFLAGS])
 128
 129 AC_PROG_CPP
 130 AC_PROG_INSTALL
 131 AC_C_CONST
 132 AC_C_BIGENDIAN
 133 AC_HEADER_STDC
 134 AC_HEADER_STDBOOL
 135 AC_HEADER_DIRENT
 136 AC_HEADER_STAT
 137 AC_CHECK_MEMBERS(m4_normalize([
 138         struct stat.st_aclcnt,
 139         struct stat.st_blksize,
 140         struct stat.st_blocks,
 141         struct stat.st_flags,
 142         struct stat.st_fstype,
 143         struct stat.st_gen,
 144         struct stat.st_level,
 145         struct stat.st_rdev
 146 ]))
 147 AC_STAT64
 148 AC_STATFS64
 149
 150 AC_TYPE_SIGNAL
 151 AC_TYPE_UID_T
 152 AC_TYPE_MODE_T
 153 AC_TYPE_GETGROUPS
 154 AC_HEADER_MAJOR
 155 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 156 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 157 [#include <sys/types.h>
 158 #include <sys/socket.h>
 159 #include <netinet/in.h>])
 160 AC_CHECK_TYPES([long long])
 161 AC_LITTLE_ENDIAN_LONG_LONG
 162 AC_OFF_T_IS_LONG_LONG
 163 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 164 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 165
 166 AC_CHECK_FUNCS(m4_normalize([
 167         fork
 168         if_indextoname
 169         inet_ntop
 170         prctl
 171         process_vm_readv
 172         sendmsg
 173         sigaction
 174         stpcpy
 175         strerror
 176         strsignal
 177         _sys_siglist
 178         sys_siglist
 179 ]))
 180 AC_CHECK_HEADERS(m4_normalize([
 181         asm/cachectl.h
 182         asm/sysmips.h
 183         inttypes.h
 184         ioctls.h
 185         libaio.h
 186         linux/capability.h
 187         linux/ptrace.h
 188         linux/utsname.h
 189         mqueue.h
 190         netinet/sctp.h
 191         poll.h
 192         stropts.h
 193         sys/acl.h
 194         sys/asynch.h
 195         sys/conf.h
 196         sys/epoll.h
 197         sys/filio.h
 198         sys/ioctl.h
 199         sys/poll.h
 200         sys/ptrace.h
 201         sys/reg.h
 202         sys/uio.h
 203         sys/vfs.h
 204 ]))
 205 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 206                  [], [], [#include <stddef.h>
 207 #include <sys/socket.h>
 208 #include <asm/types.h>])
 209 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 210 AC_CHECK_TYPES([struct sigcontext_struct,
 211                 struct sigcontext],,, [#include <signal.h>])
 212 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 213
 214 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 215
 216 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 217                   struct T_conn_res.ACCEPTOR_id],,,
 218 [#include <sys/stream.h>
 219 #include <sys/tihdr.h>])
 220
 221 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 222
 223 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 224                [#include <sys/ptrace.h>])
 225
 226 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 227
 228 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 229
 230 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 231 #ifdef HAVE_ASM_SIGCONTEXT_H
 232 # include <asm/sigcontext.h>
 233 #endif])
 234
 235 AC_CHECK_DECLS([sys_errlist])
 236 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 237 AC_CHECK_DECLS(m4_normalize([
 238         PTRACE_EVENT_CLONE,
 239         PTRACE_EVENT_EXEC,
 240         PTRACE_EVENT_EXIT,
 241         PTRACE_EVENT_FORK,
 242         PTRACE_EVENT_VFORK,
 243         PTRACE_EVENT_VFORK_DONE,
 244         PTRACE_GETEVENTMSG,
 245         PTRACE_GETSIGINFO,
 246         PTRACE_O_TRACECLONE,
 247         PTRACE_O_TRACEEXEC,
 248         PTRACE_O_TRACEEXIT,
 249         PTRACE_O_TRACEFORK,
 250         PTRACE_O_TRACESYSGOOD,
 251         PTRACE_O_TRACEVFORK,
 252         PTRACE_SETOPTIONS
 253 ]),,, [#include <sys/ptrace.h>])
 254
 255 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 256         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 257 #include <stdlib.h>
 258 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 259                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 260         if test $ac_cv_have_blkgetsize64 = yes; then
 261                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 262         fi)
 263
 264 AC_CHECK_SIZEOF([long])
 265 AC_CHECK_SIZEOF([rlim_t],,[#include <sys/resource.h>])
 266
 267 AC_PATH_PROG([PERL], [perl])
 268
 269 AC_CONFIG_FILES([Makefile tests/Makefile])
 270 AC_OUTPUT