granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2018 The strace developers.
   9 # All rights reserved.
  10 #
  11 # SPDX-License-Identifier: LGPL-2.1-or-later
  12
  13 AC_PREREQ(2.57)
  14 AC_INIT([strace],
  15         m4_esyscmd([./git-version-gen .tarball-version]),
  16         [strace-devel@lists.strace.io],
  17         [strace],
  18         [https://strace.io])
  19 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  20 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  21 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  22 AC_CONFIG_SRCDIR([strace.c])
  23 AC_CONFIG_AUX_DIR([.])
  24 AC_CONFIG_HEADERS([config.h])
  25 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  26 AM_MAINTAINER_MODE
  27 AC_CANONICAL_HOST
  28
  29 RPM_CHANGELOGTIME="$(LC_TIME=C date -u '+%a %b %d %Y')"
  30 AC_SUBST(RPM_CHANGELOGTIME)
  31 DEB_CHANGELOGTIME="$(LC_TIME=C date -u -R)"
  32 AC_SUBST(DEB_CHANGELOGTIME)
  33
  34 AC_PROG_CC
  35 AC_PROG_CC_STDC
  36 AC_PROG_CPP
  37 st_WARN_CFLAGS
  38 AX_PROG_CC_FOR_BUILD
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 AC_USE_SYSTEM_EXTENSIONS
  43 AX_CODE_COVERAGE
  44
  45 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  46 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  47
  48 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  49 AC_SUBST([MANPAGE_DATE], [manpage_date])
  50
  51 AC_MSG_CHECKING([for supported architecture])
  52 arch_m32=
  53 arch_mx32=
  54 cc_flags_m32=-m32
  55 cc_flags_mx32=-mx32
  56 case "$host_cpu" in
  57 aarch64*)
  58         arch=aarch64
  59         arch_m32=arm
  60         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
  61         ;;
  62 alpha*)
  63         arch=alpha
  64         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  65         ;;
  66 arc*)
  67         arch=arc
  68         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
  69         ;;
  70 arm*)
  71         arch=arm
  72         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  73         ;;
  74 avr32*)
  75         arch=avr32
  76         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  77         ;;
  78 bfin)
  79         arch=bfin
  80         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  81         ;;
  82 hppa*|parisc*)
  83         arch=hppa
  84         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  85         ;;
  86 i[[3456]]86|pentium)
  87         arch=i386
  88         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  89         ;;
  90 ia64)
  91         arch=ia64
  92         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  93         ;;
  94 m68k)
  95         arch=m68k
  96         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  97         ;;
  98 metag*)
  99         arch=metag
 100         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 101         ;;
 102 microblaze*)
 103         arch=microblaze
 104         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 105         ;;
 106 mips*)
 107         arch=mips
 108         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 109         ;;
 110 nios2*)
 111         arch=nios2
 112         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 113         ;;
 114 or1k*)
 115         arch=or1k
 116         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 117         ;;
 118 powerpc*)
 119         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 120         AC_TRY_COMPILE(
 121 [#ifndef __LP64__
 122 # error 32 bit
 123 #endif], [], arch=powerpc64, arch=powerpc)
 124         if test "$arch" = "powerpc64"; then
 125                 arch_m32=powerpc
 126                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 127         fi
 128         ;;
 129 riscv*)
 130         arch=riscv
 131         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 132         ;;
 133 s390)
 134         arch=s390
 135         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 136         ;;
 137 s390x)
 138         arch=s390x
 139         arch_m32=s390
 140         cc_flags_m32=-m31
 141         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 142         ;;
 143 sh64*)
 144         arch=sh64
 145         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 146         ;;
 147 sh*)
 148         arch=sh
 149         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 150         ;;
 151 sparc64*)
 152         arch=sparc64
 153         arch_m32=sparc
 154         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
 155         ;;
 156 sparc*)
 157         arch=sparc
 158         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
 159         ;;
 160 tile*)
 161         arch=tile
 162         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 163         ;;
 164 x86?64*)
 165         arch_m32=i386
 166         AC_TRY_COMPILE(
 167 [#ifndef __ILP32__
 168 # error not x32
 169 #endif], [], arch=x32, arch=x86_64)
 170         if test "$arch" = "x86_64"; then
 171                 arch_mx32=x32
 172                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 173         else
 174                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 175         fi
 176         ;;
 177 xtensa*)
 178         arch=xtensa
 179         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 180         ;;
 181 *)
 182         AC_MSG_RESULT([NO!])
 183         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 184         ;;
 185 esac
 186 AC_MSG_RESULT($arch)
 187
 188 arch_native=$arch
 189
 190 test -n "$arch_m32" ||
 191         arch_m32=$arch
 192 test -n "$arch_mx32" ||
 193         arch_mx32=$arch
 194 AC_SUBST(arch)
 195 AC_SUBST(arch_m32)
 196 AC_SUBST(arch_mx32)
 197 AC_SUBST(cc_flags_m32)
 198 AC_SUBST(cc_flags_mx32)
 199 AC_SUBST(arch_native)
 200
 201 MIPS_ABI=
 202 if test "$arch" = mips; then
 203         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 204                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 205                                        [AC_MSG_FAILURE([_MIPS_SIM cannot be determined])])])
 206
 207         # requires GCC >= 3.4
 208         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 209                 [AC_COMPILE_IFELSE(
 210                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 211                         [st_cv_mips_abi=o32],
 212                 [AC_COMPILE_IFELSE(
 213                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 214                         [st_cv_mips_abi=n32],
 215                 [AC_COMPILE_IFELSE(
 216                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 217                         [st_cv_mips_abi=n64],
 218                         [st_cv_mips_abi=unknown])])])])
 219
 220         case "$st_cv_mips_abi" in
 221                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 222                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 223                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 224                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 225         esac
 226         MIPS_ABI="$st_cv_mips_abi"
 227 fi
 228 AC_SUBST(MIPS_ABI)
 229
 230 AC_ARG_ENABLE([arm-oabi],
 231               [AS_HELP_STRING([--enable-arm-oabi],
 232                               [enable OABI support on ARM EABI])],
 233               [], [enable_arm_oabi=no])
 234 case "$enable_arm_oabi" in
 235         yes) enable_arm_oabi=1 ;;
 236         no) enable_arm_oabi=0 ;;
 237         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 238 esac
 239 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 240                    [Define to 1 if you want OABI support on ARM EABI.])
 241
 242 AC_C_BIGENDIAN
 243 AC_C_TYPEOF
 244
 245 AC_TYPE_UID_T
 246
 247 AC_CHECK_FUNCS(m4_normalize([
 248         accept4
 249         be64toh
 250         fallocate
 251         fanotify_mark
 252         fopen64
 253         fork
 254         fputs_unlocked
 255         fstatat
 256         ftruncate
 257         futimens
 258         iconv_open
 259         if_indextoname
 260         open64
 261         prctl
 262         preadv
 263         process_vm_readv
 264         pwritev
 265         readahead
 266         signalfd
 267         stpcpy
 268         strerror
 269         strndup
 270         strsignal
 271         sync_file_range
 272         utimensat
 273 ]))
 274
 275 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 276
 277 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 278
 279 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 280 [#include <asm/posix_types.h>])
 281
 282 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 283 [#include <sys/types.h>
 284 #include <asm/stat.h>])
 285
 286 AC_CHECK_TYPES([struct user_desc],
 287                [AC_CHECK_MEMBERS([struct user_desc.lm],,,
 288                                  [#include <asm/ldt.h>])],,
 289                [#include <asm/ldt.h>])
 290
 291 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 292 [#include <sys/types.h>
 293 #include <asm/stat.h>])
 294
 295 AC_CHECK_TYPES(m4_normalize([
 296         struct pt_all_user_regs,
 297         struct ia64_fpreg,
 298         struct ptrace_peeksiginfo_args
 299 ]),,, [#include <sys/ptrace.h>])
 300
 301 # For kernels that do not have v3.10-rc1~201^2~11
 302 AC_CHECK_TYPES([s390_compat_regs],,, [#include <asm/ptrace.h>])
 303
 304 AC_CHECK_TYPES(m4_normalize([
 305         struct flock,
 306         struct flock64,
 307         struct __kernel_flock,
 308         struct __kernel_flock64,
 309         struct f_owner_ex,
 310         struct __kernel_f_owner_ex
 311 ]),,,
 312 [#include <sys/types.h>
 313 #include <linux/fcntl.h>])
 314
 315 AC_CHECK_TYPES(m4_normalize([
 316         struct crypto_report_aead,
 317         struct crypto_report_blkcipher,
 318         struct crypto_report_cipher,
 319         struct crypto_report_hash,
 320         struct crypto_report_rng
 321 ]),,, [#include <linux/cryptouser.h>])
 322
 323 AC_CHECK_TYPES(m4_normalize([
 324         struct kcmp_epoll_slot
 325 ]),,, [#include <linux/kcmp.h>])
 326
 327 AC_CHECK_TYPES(m4_normalize([
 328         struct keyctl_kdf_params
 329 ]),,, [#include <linux/keyctl.h>])
 330
 331 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 332
 333 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 334
 335 AC_CHECK_MEMBERS(m4_normalize([
 336         siginfo_t.si_syscall,
 337         siginfo_t.si_timerid,
 338         siginfo_t.si_overrun
 339 ]),,, [#include <signal.h>])
 340
 341 AC_CHECK_MEMBERS(m4_normalize([
 342         struct perf_event_attr.precise_ip,
 343         struct perf_event_attr.mmap_data,
 344         struct perf_event_attr.sample_id_all,
 345         struct perf_event_attr.exclude_host,
 346         struct perf_event_attr.exclude_guest,
 347         struct perf_event_attr.exclude_callchain_kernel,
 348         struct perf_event_attr.exclude_callchain_user,
 349         struct perf_event_attr.mmap2,
 350         struct perf_event_attr.comm_exec,
 351         struct perf_event_attr.use_clockid,
 352         struct perf_event_attr.context_switch,
 353         struct perf_event_attr.write_backward,
 354         struct perf_event_attr.namespaces,
 355         struct perf_event_attr.bp_type,
 356         struct perf_event_attr.config1,
 357         struct perf_event_attr.config2,
 358         struct perf_event_attr.branch_sample_type,
 359         struct perf_event_attr.sample_regs_user,
 360         struct perf_event_attr.sample_stack_user,
 361         struct perf_event_attr.sample_regs_intr,
 362         struct perf_event_attr.aux_watermark,
 363         struct perf_event_attr.sample_max_stack
 364 ]),,, [#include <linux/perf_event.h>])
 365
 366 AC_CHECK_HEADERS(m4_normalize([
 367         asm/cachectl.h
 368         asm/guarded_storage.h
 369         asm/sysmips.h
 370         elf.h
 371         iconv.h
 372         inttypes.h
 373         linux/bsg.h
 374         linux/cryptouser.h
 375         linux/dm-ioctl.h
 376         linux/dqblk_xfs.h
 377         linux/falloc.h
 378         linux/fib_rules.h
 379         linux/fiemap.h
 380         linux/hiddev.h
 381         linux/if_addr.h
 382         linux/if_link.h
 383         linux/ip_vs.h
 384         linux/ipc.h
 385         linux/kcmp.h
 386         linux/kvm.h
 387         linux/memfd.h
 388         linux/mmtimer.h
 389         linux/msg.h
 390         linux/neighbour.h
 391         linux/netfilter/ipset/ip_set.h
 392         linux/netfilter/nf_tables.h
 393         linux/netfilter/nf_tables_compat.h
 394         linux/netfilter/nfnetlink.h
 395         linux/netfilter/nfnetlink_acct.h
 396         linux/netfilter/nfnetlink_conntrack.h
 397         linux/netfilter/nfnetlink_cthelper.h
 398         linux/netfilter/nfnetlink_cttimeout.h
 399         linux/netfilter/nfnetlink_log.h
 400         linux/netfilter/nfnetlink_queue.h
 401         linux/nsfs.h
 402         linux/perf_event.h
 403         linux/quota.h
 404         linux/seccomp.h
 405         linux/securebits.h
 406         linux/sem.h
 407         linux/shm.h
 408         linux/userfaultfd.h
 409         linux/utsname.h
 410         mqueue.h
 411         netinet/sctp.h
 412         netipx/ipx.h
 413         paths.h
 414         scsi/sg.h
 415         stropts.h
 416         sys/conf.h
 417         sys/eventfd.h
 418         sys/fanotify.h
 419         sys/ipc.h
 420         sys/msg.h
 421         sys/quota.h
 422         sys/sem.h
 423         sys/shm.h
 424         sys/signalfd.h
 425         sys/xattr.h
 426         ustat.h
 427 ]))
 428
 429 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 430
 431 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 432
 433 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 434
 435 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 436 #include <linux/tcp.h>])
 437
 438 AC_CHECK_HEADERS(m4_normalize([
 439         linux/netfilter_arp/arp_tables.h
 440         linux/netfilter_bridge/ebtables.h
 441         linux/netfilter_ipv4/ip_tables.h
 442         linux/netfilter_ipv6/ip6_tables.h
 443 ]),,, [#include <netinet/in.h>
 444 #include <net/if.h>])
 445
 446 AC_CHECK_HEADERS([linux/input.h], [
 447         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 448 ])
 449
 450 AC_CHECK_HEADERS([linux/bpf.h], [
 451         AC_CHECK_TYPES(m4_normalize([
 452                 struct bpf_insn,
 453                 struct bpf_map_info,
 454                 struct bpf_prog_info
 455         ]),,, [#include <linux/bpf.h>])
 456         st_BPF_ATTR
 457 ])
 458
 459 AC_CHECK_HEADERS([bluetooth/bluetooth.h], [
 460         AC_CHECK_MEMBERS([struct sockaddr_l2.l2_bdaddr_type],,,
 461                          [#include <bluetooth/bluetooth.h>
 462                          #include <bluetooth/l2cap.h>])
 463 ])
 464
 465 AC_CHECK_TYPES(m4_normalize([
 466         struct br_mdb_entry,
 467         struct br_port_msg
 468 ]),,, [#include <linux/if_bridge.h>])
 469 AC_CHECK_MEMBERS(m4_normalize([
 470         struct br_mdb_entry.flags,
 471         struct br_mdb_entry.vid
 472 ]),,, [#include <linux/if_bridge.h>])
 473
 474 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 475 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 476 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 477
 478 AC_CHECK_TYPES(m4_normalize([
 479         struct rta_mfc_stats,
 480         struct rtvia
 481 ]),,, [#include <sys/socket.h>
 482 #include <linux/rtnetlink.h>])
 483
 484 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 485 AC_CHECK_TYPES(m4_normalize([
 486         struct ndt_config,
 487         struct ndt_stats
 488 ]),,, [#include <linux/neighbour.h>])
 489
 490 AC_CHECK_TYPES(m4_normalize([
 491         struct ifla_bridge_id,
 492         struct ifla_cacheinfo,
 493         struct ifla_port_vsi,
 494         struct rtnl_link_stats64
 495 ]),,, [#include <sys/socket.h>
 496 #include <linux/rtnetlink.h>])
 497 AC_CHECK_MEMBERS(m4_normalize([
 498         struct rtnl_link_stats.rx_nohandler,
 499         struct rtnl_link_stats64.rx_nohandler
 500 ]),,, [#include <sys/socket.h>
 501 #include <linux/rtnetlink.h>])
 502 AC_CHECK_DECLS(m4_normalize([
 503         IFLA_PORT_SELF,
 504         IFLA_PROTINFO,
 505         IFLA_AF_SPEC,
 506         IFLA_XDP
 507 ]),,, [#include <sys/socket.h>
 508 #include <linux/rtnetlink.h>])
 509
 510 AC_CHECK_TYPES(m4_normalize([
 511         struct gnet_stats_basic,
 512         struct gnet_stats_queue,
 513         struct gnet_stats_rate_est,
 514         struct gnet_stats_rate_est64
 515 ]),,, [#include <linux/gen_stats.h>])
 516
 517 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/types.h>
 518 #include <linux/pkt_sched.h>])
 519 AC_CHECK_DECLS([TCA_STAB_DATA],,, [#include <linux/types.h>
 520 #include <linux/pkt_sched.h>])
 521
 522 AC_CHECK_TYPES(m4_normalize([
 523         struct fib_rule_uid_range,
 524         struct fib_rule_port_range
 525 ]),,, [#include <linux/fib_rules.h>])
 526
 527 AC_CHECK_TYPES([struct statfs], [
 528         AC_CHECK_MEMBERS(m4_normalize([
 529                 struct statfs.f_frsize,
 530                 struct statfs.f_flags,
 531                 struct statfs.f_fsid.val,
 532                 struct statfs.f_fsid.__val
 533         ]),,, [#include <linux/types.h>
 534 #include <asm/statfs.h>])
 535 ],, [#include <linux/types.h>
 536 #include <asm/statfs.h>])
 537
 538 AC_CHECK_TYPES([struct statfs64], [
 539         AC_CHECK_MEMBERS(m4_normalize([
 540                 struct statfs64.f_frsize,
 541                 struct statfs64.f_flags,
 542                 struct statfs64.f_fsid.val,
 543                 struct statfs64.f_fsid.__val
 544         ]),,, [#include <linux/types.h>
 545 #include <asm/statfs.h>])
 546 ],, [#include <linux/types.h>
 547 #include <asm/statfs.h>])
 548
 549 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 550
 551 AC_CHECK_TYPES([struct mtd_write_req],,, [#include <mtd/mtd-abi.h>])
 552
 553 AC_CHECK_MEMBERS([struct ubi_attach_req.max_beb_per1024],,, [#include <mtd/ubi-user.h>])
 554
 555 AC_CHECK_TYPES(m4_normalize([
 556         struct ptp_sys_offset
 557 ]),,, [#include <linux/ptp_clock.h>])
 558
 559 AC_CHECK_TYPES(m4_normalize([
 560         struct kvm_cpuid2,
 561         struct kvm_regs,
 562         struct kvm_sregs,
 563         struct kvm_userspace_memory_region
 564 ]),,, [#include <linux/kvm.h>])
 565
 566 saved_CPPFLAGS="$CPPFLAGS"
 567
 568 AC_CACHE_CHECK([whether <linux/signal.h> can be used along with <signal.h>],
 569                [st_cv_linux_signal],
 570                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 571 #include <signal.h>
 572 #include <linux/signal.h>]],[])],
 573                                   [st_cv_linux_signal=yes],
 574                                   [st_cv_linux_signal=no])])
 575 if test "x$st_cv_linux_signal" = xno; then
 576         mkdir -p linux/linux
 577         cp $srcdir/linux/signal.h.in linux/linux/signal.h
 578         CPPFLAGS="$CPPFLAGS -Ilinux"
 579 fi
 580
 581 AC_CHECK_TYPES([struct __aio_sigset],,, [#include <linux/aio_abi.h>])
 582
 583 CPPFLAGS="$saved_CPPFLAGS"
 584
 585 AC_CHECK_HEADERS([linux/btrfs.h], [
 586         AC_CHECK_MEMBERS(m4_normalize([
 587                 struct btrfs_ioctl_feature_flags.compat_flags,
 588                 struct btrfs_ioctl_fs_info_args.nodesize,
 589                 struct btrfs_ioctl_defrag_range_args.start,
 590                 struct btrfs_ioctl_search_args_v2.buf_size,
 591                 struct btrfs_ioctl_logical_ino_args.flags
 592                 ]),,, [ #include <stdio.h>
 593 #include <linux/btrfs.h>])
 594         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 595                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 596 #include <linux/btrfs.h>])])
 597
 598 AC_CHECK_DECLS([sys_errlist])
 599 AC_CHECK_DECLS(m4_normalize([
 600         PTRACE_PEEKUSER,
 601         PTRACE_POKEUSER
 602 ]),,, [#include <sys/ptrace.h>])
 603
 604 AC_CHECK_DECLS(m4_normalize([
 605         P_PID,
 606         P_PPID,
 607         P_PGID,
 608         P_SID,
 609         P_CID,
 610         P_UID,
 611         P_GID,
 612         P_ALL,
 613         P_LWPID
 614 ]),,, [#include <sys/wait.h>])
 615
 616 AC_CHECK_DECLS(m4_normalize([
 617         LO_FLAGS_READ_ONLY,
 618         LO_FLAGS_USE_AOPS,
 619         LO_FLAGS_AUTOCLEAR,
 620         LO_FLAGS_PARTSCAN,
 621         LO_FLAGS_DIRECT_IO
 622 ]),,, [#include <linux/loop.h>])
 623
 624 AC_CHECK_DECLS(m4_normalize([
 625         CTL_PROC,
 626         CTL_ARLAN,
 627         CTL_S390DBF,
 628         CTL_SUNRPC,
 629         CTL_PM,
 630         CTL_FRV,
 631         KERN_PRINTK_RATELIMIT,
 632         KERN_PRINTK_RATELIMIT_BURST,
 633         KERN_PTY,
 634         KERN_NGROUPS_MAX,
 635         KERN_SPARC_SCONS_PWROFF,
 636         KERN_HZ_TIMER,
 637         KERN_UNKNOWN_NMI_PANIC,
 638         KERN_BOOTLOADER_TYPE,
 639         KERN_RANDOMIZE,
 640         KERN_SETUID_DUMPABLE,
 641         KERN_SPIN_RETRY,
 642         KERN_ACPI_VIDEO_FLAGS,
 643         KERN_IA64_UNALIGNED,
 644         KERN_COMPAT_LOG,
 645         KERN_MAX_LOCK_DEPTH,
 646         KERN_NMI_WATCHDOG,
 647         KERN_PANIC_ON_NMI,
 648         NET_LLC,
 649         NET_NETFILTER,
 650         NET_DCCP,
 651         NET_IRDA,
 652         NET_CORE_DESTROY_DELAY,
 653         NET_CORE_BUDGET,
 654         NET_CORE_AEVENT_ETIME,
 655         NET_CORE_AEVENT_RSEQTH,
 656         NET_CORE_WARNINGS,
 657         NET_IPV4_IGMP_MAX_MSF,
 658         NET_TCP_NO_METRICS_SAVE,
 659         NET_TCP_DEFAULT_WIN_SCALE,
 660         NET_TCP_MODERATE_RCVBUF,
 661         NET_TCP_TSO_WIN_DIVISOR,
 662         NET_TCP_BIC_BETA,
 663         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 664         NET_TCP_CONG_CONTROL,
 665         NET_TCP_ABC,
 666         NET_IPV4_IPFRAG_MAX_DIST,
 667         NET_TCP_MTU_PROBING,
 668         NET_TCP_BASE_MSS,
 669         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 670         NET_TCP_DMA_COPYBREAK,
 671         NET_TCP_SLOW_START_AFTER_IDLE,
 672         NET_CIPSOV4_CACHE_ENABLE,
 673         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 674         NET_CIPSOV4_RBM_OPTFMT,
 675         NET_CIPSOV4_RBM_STRICTVALID,
 676         NET_TCP_AVAIL_CONG_CONTROL,
 677         NET_TCP_ALLOWED_CONG_CONTROL,
 678         NET_TCP_MAX_SSTHRESH,
 679         NET_TCP_FRTO_RESPONSE,
 680         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 681         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 682         NET_IPV4_CONF_ARP_ANNOUNCE,
 683         NET_IPV4_CONF_ARP_IGNORE,
 684         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 685         NET_IPV4_CONF_ARP_ACCEPT,
 686         NET_IPV4_CONF_ARP_NOTIFY,
 687         NET_IPV6_MLD_MAX_MSF,
 688         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 689         VM_MAX_MAP_COUNT,
 690         VM_LAPTOP_MODE,
 691         VM_BLOCK_DUMP,
 692         VM_HUGETLB_GROUP,
 693         VM_VFS_CACHE_PRESSURE,
 694         VM_LEGACY_VA_LAYOUT,
 695         VM_SWAP_TOKEN_TIMEOUT
 696 ]),,,
 697 [#include <sys/types.h>
 698 #include <linux/sysctl.h>])
 699
 700 AC_CHECK_DECLS(m4_normalize([
 701         V4L2_FIELD_ANY,
 702         V4L2_FIELD_NONE,
 703         V4L2_FIELD_TOP,
 704         V4L2_FIELD_BOTTOM,
 705         V4L2_FIELD_INTERLACED,
 706         V4L2_FIELD_SEQ_TB,
 707         V4L2_FIELD_SEQ_BT,
 708         V4L2_FIELD_ALTERNATE,
 709         V4L2_FIELD_INTERLACED_TB,
 710         V4L2_FIELD_INTERLACED_BT,
 711         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 712         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 713         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 714         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 715         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 716         V4L2_BUF_TYPE_VBI_CAPTURE,
 717         V4L2_BUF_TYPE_VBI_OUTPUT,
 718         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 719         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 720         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 721         V4L2_BUF_TYPE_SDR_CAPTURE,
 722         V4L2_BUF_TYPE_SDR_OUTPUT,
 723         V4L2_TUNER_RADIO,
 724         V4L2_TUNER_ANALOG_TV,
 725         V4L2_TUNER_DIGITAL_TV,
 726         V4L2_MEMORY_MMAP,
 727         V4L2_MEMORY_USERPTR,
 728         V4L2_MEMORY_OVERLAY,
 729         V4L2_MEMORY_DMABUF,
 730         V4L2_COLORSPACE_SMPTE170M,
 731         V4L2_COLORSPACE_SMPTE240M,
 732         V4L2_COLORSPACE_REC709,
 733         V4L2_COLORSPACE_BT878,
 734         V4L2_COLORSPACE_470_SYSTEM_M,
 735         V4L2_COLORSPACE_470_SYSTEM_BG,
 736         V4L2_COLORSPACE_JPEG,
 737         V4L2_COLORSPACE_SRGB,
 738         V4L2_PRIORITY_UNSET,
 739         V4L2_PRIORITY_BACKGROUND,
 740         V4L2_PRIORITY_INTERACTIVE,
 741         V4L2_PRIORITY_RECORD,
 742         V4L2_FRMSIZE_TYPE_DISCRETE,
 743         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 744         V4L2_FRMSIZE_TYPE_STEPWISE,
 745         V4L2_FRMIVAL_TYPE_DISCRETE,
 746         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 747         V4L2_FRMIVAL_TYPE_STEPWISE,
 748         V4L2_CTRL_TYPE_INTEGER,
 749         V4L2_CTRL_TYPE_BOOLEAN,
 750         V4L2_CTRL_TYPE_MENU,
 751         V4L2_CTRL_TYPE_BUTTON,
 752         V4L2_CTRL_TYPE_INTEGER64,
 753         V4L2_CTRL_TYPE_CTRL_CLASS,
 754         V4L2_CTRL_TYPE_STRING,
 755         V4L2_CTRL_TYPE_BITMASK,
 756         V4L2_CTRL_TYPE_INTEGER_MENU
 757 ]),,, [#include <sys/time.h>
 758 #include <linux/ioctl.h>
 759 #include <linux/types.h>
 760 #include <linux/videodev2.h>])
 761
 762 AC_CHECK_MEMBERS(m4_normalize([
 763         struct v4l2_window.global_alpha,
 764         struct v4l2_sdr_format.buffersize
 765 ]),,, [#include <sys/time.h>
 766 #include <linux/ioctl.h>
 767 #include <linux/types.h>
 768 #include <linux/videodev2.h>])
 769
 770 AC_CHECK_SIZEOF([long])
 771 SIZEOF_LONG="$ac_cv_sizeof_long"
 772 AC_SUBST(SIZEOF_LONG)
 773 AC_CHECK_SIZEOF([long long])
 774 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 775 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 776 SIZEOF_KERNEL_LONG_T="$ac_cv_sizeof_kernel_long_t"
 777 AC_SUBST(SIZEOF_KERNEL_LONG_T)
 778 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 779
 780
 781 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 782                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 783                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 784                         grep '^[0-9]')"
 785                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 786 if test "x$st_cv_SIGRTMIN" != xno; then
 787         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 788                            [SIGRTMIN defined in <asm/signal.h>])
 789 fi
 790 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 791                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 792                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 793                         grep ^0x)"
 794                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 795 if test "x$st_cv_SA_RESTORER" != xno; then
 796         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 797                            [SA_RESTORER defined in <asm/signal.h>])
 798 fi
 799
 800 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 801                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 802                                [st_cv_have___builtin_popcount=yes],
 803                                [st_cv_have___builtin_popcount=no])])
 804 if test "x$st_cv_have___builtin_popcount" = xyes; then
 805         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 806                   [Define to 1 if the system provides __builtin_popcount function])
 807 fi
 808
 809 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 810                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 811                                                 [[return !*program_invocation_name]])],
 812                                [st_cv_have_program_invocation_name=yes],
 813                                [st_cv_have_program_invocation_name=no])])
 814 if test "x$st_cv_have_program_invocation_name" = xyes; then
 815         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 816                   [Define to 1 if the system provides program_invocation_name variable])
 817 fi
 818
 819 AC_CACHE_CHECK([for static_assert], [st_cv_have_static_assert],
 820                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <assert.h>]],
 821                                                 [[static_assert(1,"")]]
 822                                                )
 823                                ],
 824                                [st_cv_have_static_assert=yes],
 825                                [AC_LINK_IFELSE([AC_LANG_PROGRAM([],
 826                                                                 [[_Static_assert(1,"")]]
 827                                                                )
 828                                                ],
 829                                                [st_cv_have_static_assert=_Static_assert],
 830                                                [st_cv_have_static_assert=no]
 831                                               )
 832                                ]
 833                               )
 834                ]
 835               )
 836 case "x$st_cv_have_static_assert" in
 837         xyes)
 838                 AC_DEFINE([HAVE_STATIC_ASSERT], [1],
 839                           [Define to 1 if the system provides static_assert])
 840                 ;;
 841         x_Static_assert)
 842                 AC_DEFINE([HAVE__STATIC_ASSERT], [1],
 843                           [Define to 1 if the system provides _Static_assert])
 844                 ;;
 845 esac
 846
 847 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 848 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 849         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 850 fi
 851 AC_SUBST(dl_LIBS)
 852
 853 saved_LIBS="$LIBS"
 854 AC_SEARCH_LIBS([timer_create], [rt])
 855 LIBS="$saved_LIBS"
 856 case "$ac_cv_search_timer_create" in
 857         no) AC_MSG_FAILURE([failed to find timer_create]) ;;
 858         -l*) timer_LIBS="$ac_cv_search_timer_create" ;;
 859         *) timer_LIBS= ;;
 860 esac
 861 AC_SUBST(timer_LIBS)
 862
 863 saved_LIBS="$LIBS"
 864 AC_SEARCH_LIBS([clock_gettime], [rt])
 865 LIBS="$saved_LIBS"
 866 case "$ac_cv_search_clock_gettime" in
 867         no) AC_MSG_FAILURE([failed to find clock_gettime]) ;;
 868         -l*) clock_LIBS="$ac_cv_search_clock_gettime" ;;
 869         *) clock_LIBS= ;;
 870 esac
 871 AC_SUBST(clock_LIBS)
 872
 873 saved_LIBS="$LIBS"
 874 AC_SEARCH_LIBS([mq_open], [rt])
 875 LIBS="$saved_LIBS"
 876 case "$ac_cv_search_mq_open" in
 877         -l*) mq_LIBS="$ac_cv_search_mq_open" ;;
 878         *) mq_LIBS= ;;
 879 esac
 880 AC_SUBST(mq_LIBS)
 881
 882 AC_PATH_PROG([PERL], [perl])
 883
 884 AC_CHECK_TOOL([READELF], [readelf])
 885
 886 st_STACKTRACE
 887
 888 if test "$arch" = mips && test "$no_create" != yes; then
 889         mkdir -p linux/mips
 890         if $srcdir/linux/mips/genstub.sh linux/mips; then
 891                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 892         else
 893                 AC_MSG_ERROR([Failed to generate syscallent stubs])
 894         fi
 895 fi
 896
 897 AC_ARG_ENABLE([mpers],
 898         [AS_HELP_STRING([--enable-mpers=yes|no|check|m32|mx32],
 899                 [whether to enable multiple personalities support required
 900                  for proper decoding of structures used by tracees with
 901                  personalities that differ from the personality of strace,
 902                  default is yes.])],
 903         [case "$enableval" in
 904                 yes|no|check|m32|mx32) enable_mpers="$enableval" ;;
 905                 *) AC_MSG_ERROR([bad value $enableval for enable-mpers option.
 906                                  Valid options are: yes, no, check, m32, mx32.])
 907                 ;;
 908          esac],
 909         [enable_mpers=yes])
 910
 911 st_MPERS([m32], [aarch64|powerpc64|riscv|s390x|sparc64|tile|x32|x86_64])
 912 st_MPERS([mx32], [x86_64])
 913
 914 AX_VALGRIND_DFLT([sgcheck], [off])
 915 AX_VALGRIND_CHECK
 916
 917 AC_CONFIG_FILES([Makefile
 918                  tests/Makefile
 919                  tests-m32/Makefile
 920                  tests-mx32/Makefile
 921                  strace.1
 922                  strace-log-merge.1
 923                  strace.spec
 924                  debian/changelog])
 925 AC_OUTPUT